serials/lateissues-export.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19 use CGI qw ( -utf8 );
  20 use C4::Auth;
  21 use C4::Serials;
  22 use C4::Acquisition;
  23 use C4::Output;
  24 use C4::Context;
  25
  26 use Koha::CsvProfiles;
  27
  28 use Text::CSV_XS;
  29
  30 my $query = new CGI;
  31 my $supplierid = $query->param('supplierid');
  32 my @serialids = $query->multi_param('serialid');
  33 my $op = $query->param('op') || q{};
  34
  35 my $csv_profile_id = $query->param('csv_profile');
  36 my $csv_profile = Koha::CsvProfiles->find( $csv_profile_id );
  37 die "There is no valid csv profile given" unless $csv_profile;
  38
  39 my $csv = Text::CSV_XS->new({
  40     'quote_char'  => '"',
  41     'escape_char' => '"',
  42     'sep_char'    => $csv_profile->csv_separator,
  43     'binary'      => 1
  44 });
  45
  46 my $content = $csv_profile->content;
  47 my ( @headers, @fields );
  48 while ( $content =~ /
  49     ([^=]+) # header
  50     =
  51     ([^\|]+) # fieldname (table.row or row)
  52     \|? /gxms
  53 ) {
  54     push @headers, $1;
  55     my $field = $2;
  56     $field =~ s/[^\.]*\.?//; # Remove the table name if exists.
  57     push @fields, $field;
  58 }
  59
  60 my @rows;
  61 for my $serialid ( @serialids ) {
  62     my @missingissues = GetLateOrMissingIssues($supplierid, $serialid);
  63     my $issue = $missingissues[0];
  64     my @row;
  65     for my $field ( @fields ) {
  66         push @row, $issue->{$field};
  67     }
  68     push @rows, \@row;
  69
  70     # update claim date to let one know they have looked at this missing item
  71     updateClaim($serialid);
  72 }
  73
  74 print $query->header(
  75     -type       => 'plain/text',
  76     -attachment => "serials-claims.csv",
  77 );
  78
  79 print join( $csv_profile->csv_separator, @headers ) . "\n";
  80
  81 for my $row ( @rows ) {
  82     $csv->combine(@$row);
  83     my $string = $csv->string;
  84     print $string, "\n";
  85 }