Koha/MetadataRecord.pm

   1 package Koha::MetadataRecord;
   2
   3 # Copyright 2013 C & P Bibliography Services
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 =head1 NAME
  21
  22 Koha::MetadataRecord - base class for metadata records
  23
  24 =head1 SYNOPSIS
  25
  26     my $record = new Koha::MetadataRecord({ 'record' => $record });
  27
  28 =head1 DESCRIPTION
  29
  30 Object-oriented class that encapsulates all metadata (i.e. bibliographic
  31 and authority) records in Koha.
  32
  33 =cut
  34
  35 use Modern::Perl;
  36
  37 use Carp;
  38 use C4::Biblio;
  39 use Koha::Util::MARC;
  40
  41 use base qw(Class::Accessor);
  42
  43 __PACKAGE__->mk_accessors(qw( record schema format id ));
  44
  45
  46 =head2 new
  47
  48     my $metadata_record = new Koha::MetadataRecord({
  49                                 record => $record,
  50                                 schema => $schema,
  51                                 format => $format,
  52                                 id     => $id
  53                           });
  54
  55 Returns a Koha::MetadataRecord object encapsulating record metadata.
  56
  57 C<$record> is expected to be a deserialized object (for example
  58 a MARC::Record or XML::LibXML::Document object or JSON).
  59
  60 C<$schema> is used to describe the metadata schema (for example
  61 marc21, unimarc, dc, mods, etc).
  62
  63 C<$format> is used to specify the serialization format. It is important
  64 for Koha::RecordProcessor because it will pick the right Koha::Filter
  65 implementation based on this parameter. Valid values are:
  66
  67    MARC (for MARC::Record objects)
  68    XML  (for XML::LibXML::Document objects)
  69    JSON (for JSON objects)
  70
  71 (optional) C<$id> is used so the record carries its own id and Koha doesn't
  72 need to look for it inside the record.
  73
  74 =cut
  75
  76 sub new {
  77
  78     my $class  = shift;
  79     my $params = shift;
  80
  81     if (!defined $params->{ record }) {
  82         carp 'No record passed';
  83         return;
  84     }
  85
  86     if (!defined $params->{ schema }) {
  87         carp 'No schema passed';
  88         return;
  89     }
  90
  91     $params->{format} //= 'MARC';
  92     my $self = $class->SUPER::new($params);
  93
  94     bless $self, $class;
  95     return $self;
  96 }
  97
  98 =head2 createMergeHash
  99
 100 Create a hash for use when merging records. At the moment the only
 101 metadata schema supported is MARC.
 102
 103 =cut
 104
 105 sub createMergeHash {
 106     my ($self, $tagslib) = @_;
 107     if ($self->schema =~ m/marc/) {
 108         return Koha::Util::MARC::createMergeHash($self->record, $tagslib);
 109     }
 110 }
 111
 112 =head2 getKohaField
 113
 114     $metadata->{$key} = $record->getKohaField($kohafield);
 115
 116 =cut
 117
 118 sub getKohaField {
 119     my ($self, $kohafield) = @_;
 120     if ($self->schema =~ m/marc/) {
 121         return C4::Biblio::TransformMarcToKohaOneField($kohafield, $self->record);
 122     }
 123 }
 124
 125 1;