opac/opac-account.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Katipo Communications 2002
   4 # Copyright Biblibre 2007,2010
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21
  22 use Modern::Perl;
  23 use CGI qw ( -utf8 );
  24 use C4::Members;
  25 use C4::Auth;
  26 use C4::Output;
  27 use Koha::Account::Lines;
  28 use Koha::Patrons;
  29 use Koha::Plugins;
  30
  31 my $query = new CGI;
  32 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  33     {
  34         template_name   => "opac-account.tt",
  35         query           => $query,
  36         type            => "opac",
  37         authnotrequired => 0,
  38         debug           => 1,
  39     }
  40 );
  41
  42 my $patron = Koha::Patrons->find( $borrowernumber );
  43 my $account = $patron->account;
  44 my $accountlines = $account->lines->search({ amountoutstanding => { '>=' => 0 }});
  45 my $total_outstanding = $accountlines->total_outstanding;
  46 my $outstanding_credits = $account->outstanding_credits;
  47
  48 if ( C4::Context->preference('AllowPatronToSetFinesVisibilityForGuarantor')
  49     || C4::Context->preference('AllowStaffToSetFinesVisibilityForGuarantor')
  50   )
  51 {
  52     my @relatives;
  53
  54     # Filter out guarantees that don't want guarantor to see checkouts
  55     foreach my $gr ( $patron->guarantee_relationships() ) {
  56         my $g = $gr->guarantee;
  57         if ( $g->privacy_guarantor_fines ) {
  58
  59             my $relatives_accountlines = Koha::Account::Lines->search(
  60                 { borrowernumber => $g->borrowernumber },
  61                 { order_by       => { -desc => 'accountlines_id' } }
  62             );
  63             push(
  64                 @relatives,
  65                 {
  66                     patron       => $g,
  67                     accountlines => $relatives_accountlines,
  68                 }
  69             );
  70         }
  71     }
  72     $template->param( relatives => \@relatives );
  73 }
  74
  75
  76 $template->param(
  77     ACCOUNT_LINES       => $accountlines,
  78     total               => $total_outstanding,
  79     outstanding_credits => $outstanding_credits,
  80     accountview         => 1,
  81     message             => scalar $query->param('message') || q{},
  82     message_value       => scalar $query->param('message_value') || q{},
  83     payment             => scalar $query->param('payment') || q{},
  84     payment_error       => scalar $query->param('payment-error') || q{},
  85 );
  86
  87 my $plugins_enabled = C4::Context->preference('UseKohaPlugins') && C4::Context->config("enable_plugins");
  88 if ( $plugins_enabled ) {
  89     my @plugins = Koha::Plugins->new()->GetPlugins({
  90         method => 'opac_online_payment',
  91     });
  92     # Only pass in plugins where opac online payment is enabled
  93     @plugins = grep { $_->opac_online_payment } @plugins;
  94     $template->param( plugins => \@plugins );
  95 }
  96
  97 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };