opac/opac-sendbasket.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright Doxulting 2004
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI qw ( -utf8 );
  24 use Encode qw(encode);
  25 use Carp;
  26
  27 use Mail::Sendmail;
  28 use MIME::QuotedPrint;
  29 use MIME::Base64;
  30 use C4::Biblio;
  31 use C4::Items;
  32 use C4::Auth;
  33 use C4::Output;
  34 use C4::Biblio;
  35 use C4::Members;
  36 use Koha::Email;
  37
  38 my $query = new CGI;
  39
  40 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  41     {
  42         template_name   => "opac-sendbasketform.tt",
  43         query           => $query,
  44         type            => "opac",
  45         authnotrequired => 0,
  46         flagsrequired   => { borrow => 1 },
  47     }
  48 );
  49
  50 my $bib_list     = $query->param('bib_list');
  51 my $email_add    = $query->param('email_add');
  52 my $email_sender = $query->param('email_sender');
  53
  54 my $dbh          = C4::Context->dbh;
  55
  56 if ( $email_add ) {
  57     my $email = Koha::Email->new();
  58     my $user = GetMember(borrowernumber => $borrowernumber);
  59     my $user_email = GetFirstValidEmailAddress($borrowernumber)
  60     || C4::Context->preference('KohaAdminEmailAddress');
  61
  62     my $email_replyto = "$user->{firstname} $user->{surname} <$user_email>";
  63     my $comment    = $query->param('comment');
  64
  65    # if you want to use the KohaAdmin address as from, that is the default no need to set it
  66     my %mail = $email->create_message_headers({
  67         to => $email_add,
  68         replyto => $email_replyto,
  69     });
  70     $mail{'X-Abuse-Report'} = C4::Context->preference('KohaAdminEmailAddress');
  71
  72     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  73         {
  74             template_name   => "opac-sendbasket.tt",
  75             query           => $query,
  76             type            => "opac",
  77             authnotrequired => 0,
  78             flagsrequired   => { borrow => 1 },
  79         }
  80     );
  81
  82     my @bibs = split( /\//, $bib_list );
  83     my @results;
  84     my $iso2709;
  85     my $marcflavour = C4::Context->preference('marcflavour');
  86     foreach my $biblionumber (@bibs) {
  87         $template2->param( biblionumber => $biblionumber );
  88
  89         my $dat              = GetBiblioData($biblionumber);
  90         next unless $dat;
  91         my $record           = GetMarcBiblio($biblionumber, 1);
  92         my $marcnotesarray   = GetMarcNotes( $record, $marcflavour );
  93         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  94         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  95
  96         my @items = GetItemsInfo( $biblionumber );
  97
  98         my $hasauthors = 0;
  99         if($dat->{'author'} || @$marcauthorsarray) {
 100           $hasauthors = 1;
 101         }
 102
 103
 104         $dat->{MARCNOTES}      = $marcnotesarray;
 105         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
 106         $dat->{MARCAUTHORS}    = $marcauthorsarray;
 107         $dat->{HASAUTHORS}     = $hasauthors;
 108         $dat->{'biblionumber'} = $biblionumber;
 109         $dat->{ITEM_RESULTS}   = \@items;
 110
 111         $iso2709 .= $record->as_usmarc();
 112
 113         push( @results, $dat );
 114     }
 115
 116     my $resultsarray = \@results;
 117
 118     $template2->param(
 119         BIBLIO_RESULTS => $resultsarray,
 120         email_sender   => $email_sender,
 121         comment        => $comment,
 122         firstname      => $user->{firstname},
 123         surname        => $user->{surname},
 124     );
 125
 126     # Getting template result
 127     my $template_res = $template2->output();
 128     my $body;
 129
 130     # Analysing information and getting mail properties
 131
 132     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 133         $mail{subject} = $1;
 134         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 135         $mail{subject} = Encode::encode("UTF-8", $mail{subject});
 136     }
 137     else { $mail{'subject'} = "no subject"; }
 138
 139     my $email_header = "";
 140     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 141         $email_header = $1;
 142         $email_header =~ s|\n?(.*)\n?|$1|;
 143         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 144     }
 145
 146     my $email_file = "basket.txt";
 147     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 148         $email_file = $1;
 149         $email_file =~ s|\n?(.*)\n?|$1|;
 150     }
 151
 152     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 153         $body = $1;
 154         $body =~ s|\n?(.*)\n?|$1|;
 155         $body = encode_qp(Encode::encode("UTF-8", $body));
 156     }
 157
 158     $mail{body} = $body;
 159
 160     my $boundary = "====" . time() . "====";
 161
 162     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 163     my $isofile = encode_base64(encode("UTF-8", $iso2709));
 164     $boundary = '--' . $boundary;
 165     $mail{body} = <<END_OF_BODY;
 166 $boundary
 167 MIME-Version: 1.0
 168 Content-Type: text/plain; charset="UTF-8"
 169 Content-Transfer-Encoding: quoted-printable
 170
 171 $email_header
 172 $body
 173 $boundary
 174 Content-Type: application/octet-stream; name="basket.iso2709"
 175 Content-Transfer-Encoding: base64
 176 Content-Disposition: attachment; filename="basket.iso2709"
 177
 178 $isofile
 179 $boundary--
 180 END_OF_BODY
 181
 182     # Sending mail (if not empty basket)
 183     if ( defined($iso2709) && sendmail %mail ) {
 184     # do something if it works....
 185         $template->param( SENT      => "1" );
 186     }
 187     else {
 188         # do something if it doesnt work....
 189     carp "Error sending mail: empty basket" if !defined($iso2709);
 190         carp "Error sending mail: $Mail::Sendmail::error" if $Mail::Sendmail::error;
 191         $template->param( error => 1 );
 192     }
 193     $template->param( email_add => $email_add );
 194     output_html_with_http_headers $query, $cookie, $template->output;
 195 }
 196 else {
 197     $template->param( bib_list => $bib_list );
 198     $template->param(
 199         url            => "/cgi-bin/koha/opac-sendbasket.pl",
 200         suggestion     => C4::Context->preference("suggestion"),
 201         virtualshelves => C4::Context->preference("virtualshelves"),
 202     );
 203     output_html_with_http_headers $query, $cookie, $template->output;
 204 }