members/moremember.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2010 BibLibre
   5 # Copyright 2014 ByWater Solutions
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22
  23 =head1 moremember.pl
  24
  25  script to do a borrower enquiry/bring up patron details etc
  26  Displays all the details about a patron
  27
  28 =cut
  29
  30 use Modern::Perl;
  31 use CGI qw ( -utf8 );
  32 use C4::Context;
  33 use C4::Auth;
  34 use C4::Output;
  35 use C4::Form::MessagingPreferences;
  36 use List::MoreUtils qw/uniq/;
  37 use Koha::Patron::Attribute::Types;
  38 use Koha::Patron::Debarments qw(GetDebarments);
  39 use Koha::Patron::Messages;
  40 use Koha::DateUtils;
  41 use Koha::CsvProfiles;
  42 use Koha::Patrons;
  43 use Koha::Patron::Files;
  44 use Koha::Token;
  45 use Koha::Checkouts;
  46
  47 use vars qw($debug);
  48
  49 BEGIN {
  50     $debug = $ENV{DEBUG} || 0;
  51 }
  52
  53 my $input = CGI->new;
  54 $debug or $debug = $input->param('debug') || 0;
  55
  56
  57 my $print = $input->param('print');
  58
  59 my $template_name;
  60
  61 if (defined $print and $print eq "brief") {
  62         $template_name = "members/moremember-brief.tt";
  63 } else {
  64         $template_name = "members/moremember.tt";
  65 }
  66
  67 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  68     {
  69         template_name   => $template_name,
  70         query           => $input,
  71         type            => "intranet",
  72         authnotrequired => 0,
  73         flagsrequired   => { borrowers => 'edit_borrowers' },
  74         debug           => 1,
  75     }
  76 );
  77 my $borrowernumber = $input->param('borrowernumber');
  78 my $error = $input->param('error');
  79 $template->param( error => $error ) if ( $error );
  80
  81 my $patron         = Koha::Patrons->find( $borrowernumber );
  82 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
  83 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  84
  85 my $category_type = $patron->category->category_type;
  86
  87 for (qw(gonenoaddress lost borrowernotes is_debarred)) {
  88     $patron->$_ and $template->param(flagged => 1) and last;
  89 }
  90
  91 if ( $patron->is_debarred ) {
  92     $template->param(
  93         debarments => scalar GetDebarments({ borrowernumber => $borrowernumber }),
  94     );
  95     if ( $patron->debarred ne "9999-12-31" ) {
  96         $template->param( 'userdebarreddate' => $patron->debarred );
  97     }
  98 }
  99 $template->param( flagged => 1 ) if $patron->account_locked;
 100
 101 my @relatives;
 102 my $guarantor_relationships = $patron->guarantor_relationships;
 103 my @guarantees              = $patron->guarantee_relationships->guarantees;
 104 my @guarantors              = $guarantor_relationships->guarantors;
 105 if (@guarantors) {
 106     push( @relatives, $_->id ) for @guarantors;
 107     push( @relatives, $_->id ) for $patron->siblings();
 108 }
 109 else {
 110     push( @relatives, $_->id ) for @guarantees;
 111 }
 112 $template->param(
 113     guarantor_relationships => $guarantor_relationships,
 114     guarantees              => \@guarantees,
 115 );
 116
 117 my $relatives_issues_count =
 118     Koha::Checkouts->count({ borrowernumber => \@relatives });
 119
 120 # Calculate and display patron's age
 121 if ( !$patron->is_valid_age ) {
 122     $template->param( age_limitations => 1 );
 123     $template->param( age_low => $patron->category->dateofbirthrequired );
 124     $template->param( age_high => $patron->category->upperagelimit );
 125 }
 126
 127 # Generate CSRF token for upload and delete image buttons
 128 $template->param(
 129     csrf_token => Koha::Token->new->generate_csrf({ session_id => $input->cookie('CGISESSID'),}),
 130 );
 131
 132 if (C4::Context->preference('ExtendedPatronAttributes')) {
 133     my @attributes = $patron->extended_attributes->as_list; # FIXME Must be improved!
 134     my @classes = uniq( map {$_->type->class} @attributes );
 135     @classes = sort @classes;
 136
 137     my @attributes_loop;
 138     for my $class (@classes) {
 139         my @items;
 140         for my $attr (@attributes) {
 141             push @items, $attr if $attr->type->class eq $class
 142         }
 143         my $av = Koha::AuthorisedValues->search({ category => 'PA_CLASS', authorised_value => $class });
 144         my $lib = $av->count ? $av->next->lib : $class;
 145
 146         push @attributes_loop, {
 147             class => $class,
 148             items => \@items,
 149             lib   => $lib,
 150         };
 151     }
 152
 153     $template->param(
 154         attributes_loop => \@attributes_loop
 155     );
 156
 157     my $library_id = C4::Context->userenv ? C4::Context->userenv->{'branch'} : undef;
 158     my $nb_of_attribute_types = Koha::Patron::Attribute::Types->search_with_library_limits({}, {}, $library_id)->count;
 159     if ( $nb_of_attribute_types == 0 ) {
 160         $template->param(no_patron_attribute_types => 1);
 161     }
 162 }
 163
 164 if (C4::Context->preference('EnhancedMessagingPreferences')) {
 165     C4::Form::MessagingPreferences::set_form_values({ borrowernumber => $borrowernumber }, $template);
 166     $template->param(messaging_form_inactive => 1);
 167 }
 168
 169 if ( C4::Context->preference("ExportCircHistory") ) {
 170     $template->param(csv_profiles => [ Koha::CsvProfiles->search({ type => 'marc' }) ]);
 171 }
 172
 173 my $patron_messages = Koha::Patron::Messages->search(
 174     {
 175         'me.borrowernumber' => $patron->borrowernumber,
 176     },
 177     {
 178         join => 'manager',
 179         '+select' => ['manager.surname', 'manager.firstname' ],
 180         '+as' => ['manager_surname', 'manager_firstname'],
 181     }
 182 );
 183
 184 if( $patron_messages->count > 0 ){
 185     $template->param( patron_messages => $patron_messages );
 186 }
 187
 188 # Display the language description instead of the code
 189 # Note that this is certainly wrong
 190 my ( $subtag, $region ) = split '-', $patron->lang;
 191 my $translated_language = C4::Languages::language_get_description( $subtag, $subtag, 'language' );
 192
 193 # if the expiry date is before today ie they have expired
 194 if ( $patron->is_expired || $patron->is_going_to_expire ) {
 195     $template->param(
 196         flagged => 1
 197     );
 198 }
 199
 200 $template->param(
 201     patron          => $patron,
 202     issuecount      => $patron->checkouts->count,
 203     holds_count     => $patron->holds->count,
 204     fines           => $patron->account->balance,
 205     translated_language => $translated_language,
 206     detailview      => 1,
 207     was_renewed     => scalar $input->param('was_renewed') ? 1 : 0,
 208     $category_type  => 1, # [% IF ( I ) %] = institutional/organisation
 209     housebound_role => scalar $patron->housebound_role,
 210     relatives_issues_count => $relatives_issues_count,
 211     relatives_borrowernumbers => \@relatives,
 212     logged_in_user => $logged_in_user,
 213     files => Koha::Patron::Files->new( borrowernumber => $borrowernumber ) ->GetFilesInfo(),
 214 );
 215
 216 output_html_with_http_headers $input, $cookie, $template->output;