acqui/neworderempty.pl

   1 #!/usr/bin/perl
   2
   3 #script to show display basket of orders
   4 #written by chris@katipo.co.nz 24/2/2000
   5
   6 # Copyright 2000-2002 Katipo Communications
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 =head1 NAME
  25
  26 neworderempty.pl
  27
  28 =head1 DESCRIPTION
  29
  30 this script allows to create a new record to order it. This record shouldn't exist
  31 on database.
  32
  33 =head1 CGI PARAMETERS
  34
  35 =over 4
  36
  37 =item booksellerid
  38 the bookseller the librarian has to buy a new book.
  39
  40 =item title
  41 the title of this new record.
  42
  43 =item author
  44 the author of this new record.
  45
  46 =item publication year
  47 the publication year of this new record.
  48
  49 =item ordernumber
  50 the number of this order.
  51
  52 =item biblio
  53
  54 =item basketno
  55 the basket number for this new order.
  56
  57 =item suggestionid
  58 if this order comes from a suggestion.
  59
  60 =item breedingid
  61 the item's id in the breeding reservoir
  62
  63 =item close
  64
  65 =back
  66
  67 =cut
  68
  69 use Modern::Perl;
  70 use CGI qw ( -utf8 );
  71 use C4::Context;
  72
  73 use C4::Auth;
  74 use C4::Budgets;
  75
  76 use C4::Acquisition;
  77 use C4::Contract;
  78 use C4::Suggestions;    # GetSuggestion
  79 use C4::Biblio;                 # GetBiblioData GetMarcPrice
  80 use C4::Items; #PrepareItemRecord
  81 use C4::Output;
  82 use C4::Koha;
  83 use C4::Members;
  84 use C4::Search qw/FindDuplicate/;
  85
  86 #needed for z3950 import:
  87 use C4::ImportBatch qw/GetImportRecordMarc SetImportRecordStatus/;
  88
  89 use Koha::Acquisition::Booksellers;
  90 use Koha::Acquisition::Currencies;
  91 use Koha::BiblioFrameworks;
  92 use Koha::DateUtils qw( dt_from_string );
  93 use Koha::MarcSubfieldStructures;
  94 use Koha::ItemTypes;
  95 use Koha::Patrons;
  96 use Koha::RecordProcessor;
  97
  98 our $input           = new CGI;
  99 my $booksellerid    = $input->param('booksellerid');    # FIXME: else ERROR!
 100 my $budget_id       = $input->param('budget_id') || 0;
 101 my $title           = $input->param('title');
 102 my $author          = $input->param('author');
 103 my $publicationyear = $input->param('publicationyear');
 104 my $ordernumber          = $input->param('ordernumber') || '';
 105 our $biblionumber    = $input->param('biblionumber');
 106 our $basketno        = $input->param('basketno');
 107 my $suggestionid    = $input->param('suggestionid');
 108 my $close           = $input->param('close');
 109 my $uncertainprice  = $input->param('uncertainprice');
 110 my $import_batch_id = $input->param('import_batch_id'); # if this is filled, we come from a staged file, and we will return here after saving the order !
 111 my $from_subscriptionid  = $input->param('from_subscriptionid');
 112 my $data;
 113 my $new = 'no';
 114
 115 my $budget_name;
 116
 117 our ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
 118     {
 119         template_name   => "acqui/neworderempty.tt",
 120         query           => $input,
 121         type            => "intranet",
 122         authnotrequired => 0,
 123         flagsrequired   => { acquisition => 'order_manage' },
 124         debug           => 1,
 125     }
 126 );
 127
 128 our $marcflavour = C4::Context->preference('marcflavour');
 129
 130 if(!$basketno) {
 131     my $order = GetOrder($ordernumber);
 132     $basketno = $order->{'basketno'};
 133 }
 134
 135 our $basket = GetBasket($basketno);
 136 my $basketobj = Koha::Acquisition::Baskets->find( $basketno );
 137 $booksellerid = $basket->{booksellerid} unless $booksellerid;
 138 my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
 139
 140 my $contract = GetContract({
 141     contractnumber => $basket->{contractnumber}
 142 });
 143
 144 #simple parameters reading (all in one :-)
 145 our $params = $input->Vars;
 146 my $listprice=0; # the price, that can be in MARC record if we have one
 147 if ( $ordernumber eq '' and defined $params->{'breedingid'}){
 148 #we want to import from the breeding reservoir (from a z3950 search)
 149     my ($marcrecord, $encoding) = MARCfindbreeding($params->{'breedingid'});
 150     die("Could not find the selected record in the reservoir, bailing") unless $marcrecord;
 151
 152     # Remove all the items (952) from the imported record
 153     foreach my $item ($marcrecord->field('952')) {
 154         $marcrecord->delete_field($item);
 155     }
 156
 157     my $duplicatetitle;
 158 #look for duplicates
 159     ($biblionumber,$duplicatetitle) = FindDuplicate($marcrecord);
 160     if($biblionumber && !$input->param('use_external_source')) {
 161         #if duplicate record found and user did not decide yet, first warn user
 162         #and let them choose between using a new record or an existing record
 163         Load_Duplicate($duplicatetitle);
 164         exit;
 165     }
 166     #from this point: add a new record
 167         my $bibitemnum;
 168         $params->{'frameworkcode'} or $params->{'frameworkcode'} = "";
 169         ( $biblionumber, $bibitemnum ) = AddBiblio( $marcrecord, $params->{'frameworkcode'} );
 170         # get the price if there is one.
 171         $listprice = GetMarcPrice($marcrecord, $marcflavour);
 172         SetImportRecordStatus($params->{'breedingid'}, 'imported');
 173 }
 174
 175
 176
 177 my ( @order_user_ids, @order_users, @catalog_details );
 178 our $tagslib = GetMarcStructure(1, 'ACQ', { unsafe => 1 } );
 179 my ( $itemnumber_tag, $itemnumber_subtag ) = GetMarcFromKohaField( 'items.itemnumber', 'ACQ' );
 180 if ( not $ordernumber ) {    # create order
 181     $new = 'yes';
 182
 183     if ( $biblionumber ) {
 184         $data = GetBiblioData($biblionumber);
 185     }
 186     # get suggestion fields if applicable. If it's a subscription renewal, then the biblio already exists
 187     # otherwise, retrieve suggestion information.
 188     elsif ($suggestionid) {
 189         $data = GetSuggestion($suggestionid);
 190         $budget_id ||= $data->{'budgetid'} // 0;
 191     }
 192
 193     if ( not $biblionumber and Koha::BiblioFrameworks->find('ACQ') ) {
 194         #my $acq_mss = Koha::MarcSubfieldStructures->search({ frameworkcode => 'ACQ', tagfield => { '!=' => $itemnumber_tag } });
 195         foreach my $tag ( sort keys %{$tagslib} ) {
 196             next if $tag eq '';
 197             next if $tag eq $itemnumber_tag;    # skip items fields
 198             foreach my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 199                 my $mss = $tagslib->{$tag}{$subfield};
 200                 next if IsMarcStructureInternal($mss);
 201                 next if $mss->{tab} == -1;
 202                 my $value = $mss->{defaultvalue};
 203
 204                 if ($suggestionid and $mss->{kohafield}) {
 205                     # Reading suggestion info if ordering from a suggestion
 206                     if ( $mss->{kohafield} eq 'biblio.title' ) {
 207                         $value = $data->{title};
 208                     }
 209                     elsif ( $mss->{kohafield} eq 'biblio.author' ) {
 210                         $value = $data->{author};
 211                     }
 212                     elsif ( $mss->{kohafield} eq 'biblioitems.publishercode' ) {
 213                         $value = $data->{publishercode};
 214                     }
 215                     elsif ( $mss->{kohafield} eq 'biblioitems.editionstatement' ) {
 216                         $value = $data->{editionstatement};
 217                     }
 218                     elsif ( $mss->{kohafield} eq 'biblioitems.publicationyear' ) {
 219                         $value = $data->{publicationyear};
 220                     }
 221                     elsif ( $mss->{kohafield} eq 'biblioitems.isbn' ) {
 222                         $value = $data->{isbn};
 223                     }
 224                     elsif ( $mss->{kohafield} eq 'biblio.seriestitle' ) {
 225                         $value = $data->{seriestitle};
 226                     }
 227                 }
 228
 229                 if ( $value eq '' ) {
 230
 231                     # get today date & replace <<YYYY>>, <<MM>>, <<DD>> if provided in the default value
 232                     my $today_dt = dt_from_string;
 233                     my $year     = $today_dt->strftime('%Y');
 234                     my $month    = $today_dt->strftime('%m');
 235                     my $day      = $today_dt->strftime('%d');
 236                     $value =~ s/<<YYYY>>/$year/g;
 237                     $value =~ s/<<MM>>/$month/g;
 238                     $value =~ s/<<DD>>/$day/g;
 239
 240                     # And <<USER>> with surname (?)
 241                     my $username =
 242                       (   C4::Context->userenv
 243                         ? C4::Context->userenv->{'surname'}
 244                         : "superlibrarian" );
 245                     $value =~ s/<<USER>>/$username/g;
 246                 }
 247                 push @catalog_details, {
 248                     tag      => $tag,
 249                     subfield => $subfield,
 250                     %$mss,    # Do we need plugins support (?)
 251                     value => $value,
 252                 };
 253             }
 254         }
 255     }
 256 }
 257 else {    #modify order
 258     $data   = GetOrder($ordernumber);
 259     $biblionumber = $data->{'biblionumber'};
 260     $budget_id = $data->{'budget_id'};
 261
 262     $template->param(
 263         subscriptionid => $data->{subscriptionid},
 264     );
 265
 266     $basket   = GetBasket( $data->{'basketno'} );
 267     $basketno = $basket->{'basketno'};
 268
 269     @order_user_ids = GetOrderUsers($ordernumber);
 270     foreach my $order_user_id (@order_user_ids) {
 271         # FIXME Could be improved with search -in
 272         my $order_patron = Koha::Patrons->find( $order_user_id );
 273         push @order_users, $order_patron if $order_patron;
 274     }
 275 }
 276
 277 # We can have:
 278 # - no ordernumber but a biblionumber: from a subscription, from an existing record
 279 # - no ordernumber, no biblionumber: from a suggestion, from a new order
 280 if ( not $ordernumber or $biblionumber ) {
 281     if ( C4::Context->preference('UseACQFrameworkForBiblioRecords') ) {
 282         my $record = $biblionumber ? GetMarcBiblio({ biblionumber => $biblionumber }) : undef;
 283         foreach my $tag ( sort keys %{$tagslib} ) {
 284             next if $tag eq '';
 285             next if $tag eq $itemnumber_tag; # skip items fields
 286             my @fields = $biblionumber ? $record->field($tag) : ();
 287             foreach my $subfield ( sort keys %{ $tagslib->{$tag} } ) {
 288                 my $mss = $tagslib->{$tag}{$subfield};
 289                 next if IsMarcStructureInternal($mss);
 290                 next if $mss->{tab} == -1;
 291                 # We only need to display the values
 292                 my $value = join '; ', map { $_->subfield( $subfield ) } @fields;
 293                 if ( $value ) {
 294                     push @catalog_details, {
 295                         tag => $tag,
 296                         subfield => $subfield,
 297                         %$mss,
 298                         value => $value,
 299                     };
 300                 }
 301             }
 302         }
 303     }
 304 }
 305
 306 $template->param( catalog_details => \@catalog_details, );
 307
 308 my $suggestion;
 309 $suggestion = GetSuggestionInfo($suggestionid) if $suggestionid;
 310
 311 my @currencies = Koha::Acquisition::Currencies->search;
 312 my $active_currency = Koha::Acquisition::Currencies->get_active;
 313
 314 # build bookfund list
 315 my $patron = Koha::Patrons->find( $loggedinuser )->unblessed;
 316
 317 my $budget =  GetBudget($budget_id);
 318 # build budget list
 319 my $budget_loop = [];
 320 my $budgets = GetBudgetHierarchy;
 321 foreach my $r (@{$budgets}) {
 322     next unless (CanUserUseBudget($patron, $r, $userflags));
 323     if (!defined $r->{budget_amount} || $r->{budget_amount} <0) {
 324         next;
 325     }
 326     push @{$budget_loop}, {
 327         b_id  => $r->{budget_id},
 328         b_txt => $r->{budget_name},
 329         b_sort1_authcat => $r->{'sort1_authcat'},
 330         b_sort2_authcat => $r->{'sort2_authcat'},
 331         b_active => $r->{budget_period_active},
 332         b_sel => ( $r->{budget_id} == $budget_id ) ? 1 : 0,
 333         b_level => $r->{budget_level},
 334     };
 335 }
 336
 337 if ($close) {
 338     $budget_id      =  $data->{'budget_id'};
 339     $budget_name    =   $budget->{'budget_name'};
 340
 341 }
 342
 343 $template->param( sort1 => $data->{'sort1'} );
 344 $template->param( sort2 => $data->{'sort2'} );
 345
 346 if ($basketobj->effective_create_items eq 'ordering' && !$ordernumber) {
 347     # Check if ACQ framework exists
 348     my $marc = GetMarcStructure(1, 'ACQ', { unsafe => 1 } );
 349     unless($marc) {
 350         $template->param('NoACQframework' => 1);
 351     }
 352     $template->param(
 353         AcqCreateItemOrdering => 1,
 354         UniqueItemFields => C4::Context->preference('UniqueItemFields'),
 355     );
 356 }
 357
 358 # Get the item types list, but only if item_level_itype is YES. Otherwise, it will be in the item, no need to display it in the biblio
 359 my @itemtypes;
 360 @itemtypes = Koha::ItemTypes->search unless C4::Context->preference('item-level_itypes');
 361
 362 if ( defined $from_subscriptionid ) {
 363     my $lastOrderReceived = GetLastOrderReceivedFromSubscriptionid $from_subscriptionid;
 364     if ( defined $lastOrderReceived ) {
 365         $budget_id              = $lastOrderReceived->{budgetid};
 366         $data->{listprice}      = $lastOrderReceived->{listprice};
 367         $data->{uncertainprice} = $lastOrderReceived->{uncertainprice};
 368         $data->{tax_rate}       = $lastOrderReceived->{tax_rate_on_ordering};
 369         $data->{discount}       = $lastOrderReceived->{discount};
 370         $data->{rrp}            = $lastOrderReceived->{rrp};
 371         $data->{replacementprice} = $lastOrderReceived->{replacementprice};
 372         $data->{ecost}          = $lastOrderReceived->{ecost};
 373         $data->{quantity}       = $lastOrderReceived->{quantity};
 374         $data->{unitprice}      = $lastOrderReceived->{unitprice};
 375         $data->{order_internalnote} = $lastOrderReceived->{order_internalnote};
 376         $data->{order_vendornote}   = $lastOrderReceived->{order_vendornote};
 377         $data->{sort1}          = $lastOrderReceived->{sort1};
 378         $data->{sort2}          = $lastOrderReceived->{sort2};
 379
 380         $basket = GetBasket( $input->param('basketno') );
 381     }
 382
 383     $template->param( subscriptionid => $from_subscriptionid );
 384 }
 385
 386 # Find the items.barcode subfield for barcode validations
 387 my (undef, $barcode_subfield) = GetMarcFromKohaField('items.barcode', '');
 388
 389 # fill template
 390 $template->param(
 391     close        => $close,
 392     budget_id    => $budget_id,
 393     budget_name  => $budget_name
 394 ) if ($close);
 395
 396 # get option values for gist syspref
 397 my @gst_values = map {
 398     option => $_ + 0.0
 399 }, split( '\|', C4::Context->preference("gist") );
 400
 401 my $quantity = $input->param('rr_quantity_to_order') ?
 402       $input->param('rr_quantity_to_order') :
 403       $data->{'quantity'};
 404 $quantity //= 0;
 405
 406 $template->param(
 407     existing         => $biblionumber,
 408     ordernumber           => $ordernumber,
 409     # basket informations
 410     basketno             => $basketno,
 411     basket               => $basket,
 412     basketname           => $basket->{'basketname'},
 413     basketnote           => $basket->{'note'},
 414     booksellerid         => $basket->{'booksellerid'},
 415     basketbooksellernote => $basket->{booksellernote},
 416     basketcontractno     => $basket->{contractnumber},
 417     basketcontractname   => $contract->{contractname},
 418     creationdate         => $basket->{creationdate},
 419     authorisedby         => $basket->{'authorisedby'},
 420     authorisedbyname     => $basket->{'authorisedbyname'},
 421     closedate            => $basket->{'closedate'},
 422     # order details
 423     suggestionid         => $suggestion->{suggestionid},
 424     surnamesuggestedby   => $suggestion->{surnamesuggestedby},
 425     firstnamesuggestedby => $suggestion->{firstnamesuggestedby},
 426     biblionumber         => $biblionumber,
 427     uncertainprice       => $data->{'uncertainprice'},
 428     discount_2dp         => sprintf( "%.2f",  $bookseller->discount ) ,   # for display
 429     discount             => $bookseller->discount,
 430     orderdiscount_2dp    => sprintf( "%.2f", $data->{'discount'} || 0 ),
 431     orderdiscount        => $data->{'discount'},
 432     order_internalnote   => $data->{'order_internalnote'},
 433     order_vendornote     => $data->{'order_vendornote'},
 434     listincgst       => $bookseller->listincgst,
 435     invoiceincgst    => $bookseller->invoiceincgst,
 436     name             => $bookseller->name,
 437     cur_active_sym   => $active_currency->symbol,
 438     cur_active       => $active_currency->currency,
 439     currencies       => \@currencies,
 440     currency         => $data->{currency},
 441     vendor_currency  => $bookseller->listprice,
 442     orderexists      => ( $new eq 'yes' ) ? 0 : 1,
 443     title            => $data->{'title'},
 444     author           => $data->{'author'},
 445     publicationyear  => $data->{'publicationyear'} ? $data->{'publicationyear'} : $data->{'copyrightdate'},
 446     editionstatement => $data->{'editionstatement'},
 447     budget_loop      => $budget_loop,
 448     isbn             => $data->{'isbn'},
 449     ean              => $data->{'ean'},
 450     seriestitle      => $data->{'seriestitle'},
 451     itemtypeloop     => \@itemtypes,
 452     quantity         => $quantity,
 453     quantityrec      => $quantity,
 454     rrp              => $data->{'rrp'},
 455     replacementprice => $data->{'replacementprice'},
 456     gst_values       => \@gst_values,
 457     tax_rate         => $data->{tax_rate_on_ordering} ? $data->{tax_rate_on_ordering}+0.0 : $bookseller->tax_rate ? $bookseller->tax_rate+0.0 : 0,
 458     listprice        => sprintf( "%.2f", $data->{listprice} || $data->{price} || $listprice),
 459     total            => sprintf( "%.2f", ($data->{ecost} || 0) * ($data->{'quantity'} || 0) ),
 460     ecost            => sprintf( "%.2f", $data->{ecost} || 0),
 461     unitprice        => sprintf( "%.2f", $data->{unitprice} || 0),
 462     publishercode    => $data->{'publishercode'},
 463     barcode_subfield => $barcode_subfield,
 464     import_batch_id  => $import_batch_id,
 465     acqcreate        => $basketobj->effective_create_items eq "ordering" ? 1 : "",
 466     users_ids        => join(':', @order_user_ids),
 467     users            => \@order_users,
 468     (uc(C4::Context->preference("marcflavour"))) => 1
 469 );
 470
 471 output_html_with_http_headers $input, $cookie, $template->output;
 472
 473
 474 =head2 MARCfindbreeding
 475
 476   $record = MARCfindbreeding($breedingid);
 477
 478 Look up the import record repository for the record with
 479 record with id $breedingid.  If found, returns the decoded
 480 MARC::Record; otherwise, -1 is returned (FIXME).
 481 Returns as second parameter the character encoding.
 482
 483 =cut
 484
 485 sub MARCfindbreeding {
 486     my ( $id ) = @_;
 487     my ($marc, $encoding) = GetImportRecordMarc($id);
 488     # remove the - in isbn, koha store isbn without any -
 489     if ($marc) {
 490         my $record = MARC::Record->new_from_usmarc($marc);
 491         my ($isbnfield,$isbnsubfield) = GetMarcFromKohaField('biblioitems.isbn','');
 492         if ( $record->field($isbnfield) ) {
 493             foreach my $field ( $record->field($isbnfield) ) {
 494                 foreach my $subfield ( $field->subfield($isbnsubfield) ) {
 495                     my $newisbn = $field->subfield($isbnsubfield);
 496                     $newisbn =~ s/-//g;
 497                     $field->update( $isbnsubfield => $newisbn );
 498                 }
 499             }
 500         }
 501         # fix the unimarc 100 coded field (with unicode information)
 502         if ($marcflavour eq 'UNIMARC' && $record->subfield(100,'a')) {
 503             my $f100a=$record->subfield(100,'a');
 504             my $f100 = $record->field(100);
 505             my $f100temp = $f100->as_string;
 506             $record->delete_field($f100);
 507             if ( length($f100temp) > 28 ) {
 508                 substr( $f100temp, 26, 2, "50" );
 509                 $f100->update( 'a' => $f100temp );
 510                 my $f100 = MARC::Field->new( '100', '', '', 'a' => $f100temp );
 511                 $record->insert_fields_ordered($f100);
 512             }
 513         }
 514
 515         if ( !defined(ref($record)) ) {
 516             return -1;
 517         }
 518         else {
 519             # normalize author : probably UNIMARC specific...
 520             if (    C4::Context->preference("z3950NormalizeAuthor")
 521                 and C4::Context->preference("z3950AuthorAuthFields") )
 522             {
 523                 my ( $tag, $subfield ) = GetMarcFromKohaField("biblio.author", '');
 524
 525                 my $auth_fields =
 526                 C4::Context->preference("z3950AuthorAuthFields");
 527                 my @auth_fields = split /,/, $auth_fields;
 528                 my $field;
 529
 530                 if ( $record->field($tag) ) {
 531                     foreach my $tmpfield ( $record->field($tag)->subfields ) {
 532
 533                         my $subfieldcode  = shift @$tmpfield;
 534                         my $subfieldvalue = shift @$tmpfield;
 535                         if ($field) {
 536                             $field->add_subfields(
 537                                 "$subfieldcode" => $subfieldvalue )
 538                             if ( $subfieldcode ne $subfield );
 539                         }
 540                         else {
 541                             $field =
 542                             MARC::Field->new( $tag, "", "",
 543                                 $subfieldcode => $subfieldvalue )
 544                             if ( $subfieldcode ne $subfield );
 545                         }
 546                     }
 547                 }
 548                 $record->delete_field( $record->field($tag) );
 549                 foreach my $fieldtag (@auth_fields) {
 550                     next unless ( $record->field($fieldtag) );
 551                     my $lastname  = $record->field($fieldtag)->subfield('a');
 552                     my $firstname = $record->field($fieldtag)->subfield('b');
 553                     my $title     = $record->field($fieldtag)->subfield('c');
 554                     my $number    = $record->field($fieldtag)->subfield('d');
 555                     if ($title) {
 556                         $field->add_subfields(
 557                                 "$subfield" => ucfirst($title) . " "
 558                             . ucfirst($firstname) . " "
 559                             . $number );
 560                     }
 561                     else {
 562                         $field->add_subfields(
 563                             "$subfield" => ucfirst($firstname) . ", "
 564                             . ucfirst($lastname) );
 565                     }
 566                 }
 567                 $record->insert_fields_ordered($field);
 568             }
 569             return $record, $encoding;
 570         }
 571     }
 572     return -1;
 573 }
 574
 575 sub Load_Duplicate {
 576   my ($duplicatetitle)= @_;
 577   ($template, $loggedinuser, $cookie) = get_template_and_user(
 578     {
 579         template_name   => "acqui/neworderempty_duplicate.tt",
 580         query           => $input,
 581         type            => "intranet",
 582         authnotrequired => 0,
 583         flagsrequired   => { acquisition => 'order_manage' },
 584 #        debug           => 1,
 585     }
 586   );
 587
 588   $template->param(
 589     biblionumber        => $biblionumber,
 590     basketno            => $basketno,
 591     booksellerid        => $basket->{'booksellerid'},
 592     breedingid          => $params->{'breedingid'},
 593     duplicatetitle      => $duplicatetitle,
 594     (uc(C4::Context->preference("marcflavour"))) => 1
 595   );
 596
 597   output_html_with_http_headers $input, $cookie, $template->output;
 598 }