opac/opac-reserve.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along with
  15 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  16 # Suite 330, Boston, MA  02111-1307 USA
  17
  18 use strict;
  19 use warnings;
  20 use CGI;
  21 use C4::Auth;    # checkauth, getborrowernumber.
  22 use C4::Koha;
  23 use C4::Circulation;
  24 use C4::Reserves;
  25 use C4::Biblio;
  26 use C4::Items;
  27 use C4::Output;
  28 use C4::Dates qw/format_date/;
  29 use C4::Context;
  30 use C4::Members;
  31 use C4::Branch; # GetBranches
  32 use C4::Debug;
  33 # use Data::Dumper;
  34
  35 my $MAXIMUM_NUMBER_OF_RESERVES = C4::Context->preference("maxreserves");
  36
  37 my $query = new CGI;
  38 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  39     {
  40         template_name   => "opac-reserve.tmpl",
  41         query           => $query,
  42         type            => "opac",
  43         authnotrequired => 0,
  44         flagsrequired   => { borrow => 1 },
  45         debug           => 1,
  46     }
  47 );
  48 my $OPACDisplayRequestPriority = (C4::Context->preference("OPACDisplayRequestPriority")) ? 1 : 0;
  49 sub get_out ($$$) {
  50         output_html_with_http_headers(shift,shift,shift); # $query, $cookie, $template->output;
  51         exit;
  52 }
  53
  54 # get borrower information ....
  55 my ( $borr ) = GetMemberDetails( $borrowernumber );
  56
  57 # get branches and itemtypes
  58 my $branches = GetBranches();
  59 my $itemTypes = GetItemTypes();
  60
  61 # There are two ways of calling this script, with a single biblio num
  62 # or multiple biblio nums.
  63 my $biblionumbers = $query->param('biblionumbers');
  64 my $reserveMode = $query->param('reserve_mode');
  65 if ($reserveMode && ($reserveMode eq 'single')) {
  66     my $bib = $query->param('single_bib');
  67     $biblionumbers = "$bib/";
  68 }
  69 if (! $biblionumbers) {
  70     $biblionumbers = $query->param('biblionumber');
  71 }
  72
  73 if ((! $biblionumbers) && (! $query->param('place_reserve'))) {
  74     $template->param(message=>1, no_biblionumber=>1);
  75     &get_out($query, $cookie, $template->output);
  76 }
  77
  78 # Pass the numbers to the page so they can be fed back
  79 # when the hold is confirmed. TODO: Not necessary?
  80 $template->param( biblionumbers => $biblionumbers );
  81
  82 # Each biblio number is suffixed with '/', e.g. "1/2/3/"
  83 my @biblionumbers = split /\//, $biblionumbers;
  84 if (($#biblionumbers < 0) && (! $query->param('place_reserve'))) {
  85     # TODO: New message?
  86     $template->param(message=>1, no_biblionumber=>1);
  87     &get_out($query, $cookie, $template->output);
  88 }
  89
  90 # pass the pickup branch along....
  91 my $branch = $query->param('branch') || C4::Context->userenv->{branch} || '' ;
  92 ($branches->{$branch}) or $branch = "";     # Confirm branch is real
  93 $template->param( branch => $branch );
  94
  95 # make branch selection options...
  96 my $CGIbranchloop = GetBranchesLoop($branch);
  97 $template->param( CGIbranch => $CGIbranchloop );
  98
  99 #
 100 #
 101 # Build hashes of the requested biblio(item)s and items.
 102 #
 103 #
 104
 105 # Hash of biblionumber to biblio/biblioitems record.
 106 my %biblioDataHash;
 107
 108 # Hash of itemnumber to item info.
 109 my %itemInfoHash;
 110
 111 foreach my $biblioNumber (@biblionumbers) {
 112
 113     my $biblioData = GetBiblioData($biblioNumber);
 114     $biblioDataHash{$biblioNumber} = $biblioData;
 115
 116     my @itemInfos = GetItemsInfo($biblioNumber);
 117     $biblioData->{itemInfos} = \@itemInfos;
 118     foreach my $itemInfo (@itemInfos) {
 119         $itemInfoHash{$itemInfo->{itemnumber}} = $itemInfo;
 120     }
 121
 122     # Compute the priority rank.
 123     my ( $rank, $reserves ) = GetReservesFromBiblionumber($biblioNumber,1);
 124     $biblioData->{reservecount} = $rank;
 125     foreach my $res (@$reserves) {
 126         my $found = $res->{'found'};
 127         if ( $found && ($found eq 'W') ) {
 128             $rank--;
 129         }
 130     }
 131     $rank++;
 132     $biblioData->{rank} = $rank;
 133 }
 134
 135 #
 136 #
 137 # If this is the second time through this script, it
 138 # means we are carrying out the hold request, possibly
 139 # with a specific item for each biblionumber.
 140 #
 141 #
 142 if ( $query->param('place_reserve') ) {
 143     my $notes = $query->param('notes');
 144         my $canreserve=0;
 145
 146     # List is composed of alternating biblio/item/branch
 147     my $selectedItems = $query->param('selecteditems');
 148
 149     if ($query->param('reserve_mode') eq 'single') {
 150         # This indicates non-JavaScript mode, so there was
 151         # only a single biblio number selected.
 152         my $bib = $query->param('single_bib');
 153         my $item = $query->param("checkitem_$bib");
 154         if ($item eq 'any') {
 155             $item = '';
 156         }
 157         my $branch = $query->param('branch');
 158         $selectedItems = "$bib/$item/$branch/";
 159     }
 160
 161     $selectedItems =~ s!/$!!;
 162     my @selectedItems = split /\//, $selectedItems, -1;
 163
 164     # Make sure there is a biblionum/itemnum/branch triplet for each item.
 165     # The itemnum can be 'any', meaning next available.
 166     my $selectionCount = @selectedItems;
 167     if (($selectionCount == 0) || (($selectionCount % 3) != 0)) {
 168         $template->param(message=>1, bad_data=>1);
 169         &get_out($query, $cookie, $template->output);
 170     }
 171
 172     while (@selectedItems) {
 173         my $biblioNum = shift(@selectedItems);
 174         my $itemNum   = shift(@selectedItems);
 175         my $branch    = shift(@selectedItems); # i.e., branch code, not name
 176
 177         my $singleBranchMode = $template->param('singleBranchMode');
 178         if ($singleBranchMode) {
 179             $branch = $borr->{'branchcode'};
 180         }
 181
 182         my $biblioData = $biblioDataHash{$biblioNum};
 183         my $found;
 184
 185         # Check for user supplied reserve date
 186         my $startdate;
 187         if (
 188             C4::Context->preference( 'AllowHoldDateInFuture' ) &&
 189             C4::Context->preference( 'OPACAllowHoldDateInFuture' )
 190             ) {
 191             $startdate = $query->param("reserve_date_$biblioNum");
 192         }
 193
 194         my $expiration_date = $query->param("expiration_date_$biblioNum");
 195
 196         # If a specific item was selected and the pickup branch is the same as the
 197         # holdingbranch, force the value $rank and $found.
 198         my $rank = $biblioData->{rank};
 199         if ($itemNum ne ''){
 200                 $canreserve = 1 if CanItemBeReserved($borrowernumber,$itemNum);
 201             $rank = '0' unless C4::Context->preference('ReservesNeedReturns');
 202             my $item = GetItem($itemNum);
 203             if ( $item->{'holdingbranch'} eq $branch ){
 204                 $found = 'W' unless C4::Context->preference('ReservesNeedReturns');
 205             }
 206         }
 207         else {
 208                 $canreserve = 1 if CanBookBeReserved($borrowernumber,$biblioNum);
 209             # Inserts a null into the 'itemnumber' field of 'reserves' table.
 210             $itemNum = undef;
 211         }
 212
 213         # Here we actually do the reserveration. Stage 3.
 214         AddReserve($branch, $borrowernumber, $biblioNum, 'a', [$biblioNum], $rank, $startdate, $expiration_date, $notes,
 215                    $biblioData->{'title'}, $itemNum, $found) if ($canreserve);
 216     }
 217
 218     print $query->redirect("/cgi-bin/koha/opac-user.pl#opac-user-holds");
 219     exit;
 220 }
 221
 222 #
 223 #
 224 # Here we check that the borrower can actually make reserves Stage 1.
 225 #
 226 #
 227 my $noreserves     = 0;
 228 my $maxoutstanding = C4::Context->preference("maxoutstanding");
 229 $template->param( noreserve => 1 ) unless $maxoutstanding;
 230 if ( $borr->{'amountoutstanding'} && ($borr->{'amountoutstanding'} > $maxoutstanding) ) {
 231     my $amount = sprintf "\$%.02f", $borr->{'amountoutstanding'};
 232     $template->param( message => 1 );
 233     $noreserves = 1;
 234     $template->param( too_much_oweing => $amount );
 235 }
 236 if ( $borr->{gonenoaddress} && ($borr->{gonenoaddress} eq 1) ) {
 237     $noreserves = 1;
 238     $template->param(
 239                      message => 1,
 240                      GNA     => 1
 241                     );
 242 }
 243 if ( $borr->{lost} && ($borr->{lost} eq 1) ) {
 244     $noreserves = 1;
 245     $template->param(
 246                      message => 1,
 247                      lost    => 1
 248                     );
 249 }
 250 if ( $borr->{debarred} && ($borr->{debarred} eq 1) ) {
 251     $noreserves = 1;
 252     $template->param(
 253                      message  => 1,
 254                      debarred => 1
 255                     );
 256 }
 257
 258 my @reserves = GetReservesFromBorrowernumber( $borrowernumber );
 259 $template->param( RESERVES => \@reserves );
 260 if ( $MAXIMUM_NUMBER_OF_RESERVES && (scalar(@reserves) >= $MAXIMUM_NUMBER_OF_RESERVES) ) {
 261     $template->param( message => 1 );
 262     $noreserves = 1;
 263     $template->param( too_many_reserves => scalar(@reserves));
 264 }
 265 foreach my $res (@reserves) {
 266     foreach my $biblionumber (@biblionumbers) {
 267         if ( $res->{'biblionumber'} == $biblionumber && $res->{'borrowernumber'} == $borrowernumber) {
 268 #            $template->param( message => 1 );
 269 #            $noreserves = 1;
 270 #            $template->param( already_reserved => 1 );
 271             $biblioDataHash{$biblionumber}->{already_reserved} = 1;
 272         }
 273     }
 274 }
 275
 276 unless ($noreserves) {
 277     $template->param( select_item_types => 1 );
 278 }
 279
 280
 281 #
 282 #
 283 # Build the template parameters that will show the info
 284 # and items for each biblionumber.
 285 #
 286 #
 287 my $notforloan_label_of = get_notforloan_label_of();
 288
 289 my $biblioLoop = [];
 290 my $numBibsAvailable = 0;
 291 my $itemdata_enumchron = 0;
 292 my $itemLevelTypes = C4::Context->preference('item-level_itypes');
 293 $template->param('item-level_itypes' => $itemLevelTypes);
 294
 295 foreach my $biblioNum (@biblionumbers) {
 296
 297     my $record = GetMarcBiblio($biblioNum);
 298     # Init the bib item with the choices for branch pickup
 299     my %biblioLoopIter = ( branchChoicesLoop => $CGIbranchloop );
 300
 301     # Get relevant biblio data.
 302     my $biblioData = $biblioDataHash{$biblioNum};
 303     if (! $biblioData) {
 304         $template->param(message=>1, bad_biblionumber=>$biblioNum);
 305         &get_out($query, $cookie, $template->output);
 306     }
 307
 308     $biblioLoopIter{biblionumber} = $biblioData->{biblionumber};
 309     $biblioLoopIter{title} = $biblioData->{title};
 310     $biblioLoopIter{subtitle} = GetRecordValue('subtitle', $record, GetFrameworkCode($biblioData->{biblionumber}));
 311     $biblioLoopIter{author} = $biblioData->{author};
 312     $biblioLoopIter{rank} = $biblioData->{rank};
 313     $biblioLoopIter{reservecount} = $biblioData->{reservecount};
 314     $biblioLoopIter{already_reserved} = $biblioData->{already_reserved};
 315
 316     if (!$itemLevelTypes && $biblioData->{itemtype}) {
 317         $biblioLoopIter{description} = $itemTypes->{$biblioData->{itemtype}}{description};
 318         $biblioLoopIter{imageurl} = getitemtypeimagesrc() . "/". $itemTypes->{$biblioData->{itemtype}}{imageurl};
 319     }
 320
 321     foreach my $itemInfo (@{$biblioData->{itemInfos}}) {
 322         $debug and warn $itemInfo->{'notforloan'};
 323
 324         # Get reserve fee.
 325         my $fee = GetReserveFee(undef, $borrowernumber, $itemInfo->{'biblionumber'}, 'a',
 326                                 ( $itemInfo->{'biblioitemnumber'} ) );
 327         $itemInfo->{'reservefee'} = sprintf "%.02f", ($fee ? $fee : 0.0);
 328
 329         if ($itemLevelTypes && $itemInfo->{itype}) {
 330             $itemInfo->{description} = $itemTypes->{$itemInfo->{itype}}{description};
 331             $itemInfo->{imageurl} = getitemtypeimagesrc() . "/". $itemTypes->{$itemInfo->{itype}}{imageurl};
 332         }
 333
 334         if (!$itemInfo->{'notforloan'} && !($itemInfo->{'itemnotforloan'} > 0)) {
 335             $biblioLoopIter{forloan} = 1;
 336         }
 337     }
 338
 339     $biblioLoopIter{itemTypeDescription} = $itemTypes->{$biblioData->{itemtype}}{description};
 340
 341     $biblioLoopIter{itemLoop} = [];
 342     my $numCopiesAvailable = 0;
 343     foreach my $itemInfo (@{$biblioData->{itemInfos}}) {
 344         my $itemNum = $itemInfo->{itemnumber};
 345         my $itemLoopIter = {};
 346
 347         $itemLoopIter->{itemnumber} = $itemNum;
 348         $itemLoopIter->{barcode} = $itemInfo->{barcode};
 349         $itemLoopIter->{homeBranchName} = $branches->{$itemInfo->{homebranch}}{branchname};
 350         $itemLoopIter->{callNumber} = $itemInfo->{itemcallnumber};
 351         $itemLoopIter->{enumchron} = $itemInfo->{enumchron};
 352         $itemLoopIter->{copynumber} = $itemInfo->{copynumber};
 353         if ($itemLevelTypes) {
 354             $itemLoopIter->{description} = $itemInfo->{description};
 355             $itemLoopIter->{imageurl} = $itemInfo->{imageurl};
 356         }
 357
 358         # If the holdingbranch is different than the homebranch, we show the
 359         # holdingbranch of the document too.
 360         if ( $itemInfo->{homebranch} ne $itemInfo->{holdingbranch} ) {
 361             $itemLoopIter->{holdingBranchName} =
 362               $branches->{ $itemInfo->{holdingbranch} }{branchname};
 363         }
 364
 365         # If the item is currently on loan, we display its return date and
 366         # change the background color.
 367         my $issues= GetItemIssue($itemNum);
 368         if ( $issues->{'date_due'} ) {
 369             $itemLoopIter->{dateDue} = format_date($issues->{'date_due'});
 370             $itemLoopIter->{backgroundcolor} = 'onloan';
 371         }
 372
 373         # checking reserve
 374         my ($reservedate,$reservedfor,$expectedAt) = GetReservesFromItemnumber($itemNum);
 375         my $ItemBorrowerReserveInfo = GetMemberDetails( $reservedfor, 0);
 376
 377         if ( defined $reservedate ) {
 378             $itemLoopIter->{backgroundcolor} = 'reserved';
 379             $itemLoopIter->{reservedate}     = format_date($reservedate);
 380             $itemLoopIter->{ReservedForBorrowernumber} = $reservedfor;
 381             $itemLoopIter->{ReservedForSurname}        = $ItemBorrowerReserveInfo->{'surname'};
 382             $itemLoopIter->{ReservedForFirstname}      = $ItemBorrowerReserveInfo->{'firstname'};
 383             $itemLoopIter->{ExpectedAtLibrary}         = $expectedAt;
 384         }
 385
 386         $itemLoopIter->{notforloan} = $itemInfo->{notforloan};
 387         $itemLoopIter->{itemnotforloan} = $itemInfo->{itemnotforloan};
 388
 389         # Management of the notforloan document
 390         if ( $itemLoopIter->{notforloan} || $itemLoopIter->{itemnotforloan}) {
 391             $itemLoopIter->{backgroundcolor} = 'other';
 392             $itemLoopIter->{notforloanvalue} =
 393               $notforloan_label_of->{ $itemLoopIter->{notforloan} };
 394         }
 395
 396         # Management of lost or long overdue items
 397         if ( $itemInfo->{itemlost} ) {
 398
 399             # FIXME localized strings should never be in Perl code
 400             $itemLoopIter->{message} =
 401                 $itemInfo->{itemlost} == 1 ? "(lost)"
 402               : $itemInfo->{itemlost} == 2 ? "(long overdue)"
 403               : "";
 404             $itemInfo->{backgroundcolor} = 'other';
 405         }
 406
 407         # Check of the transfered documents
 408         my ( $transfertwhen, $transfertfrom, $transfertto ) =
 409           GetTransfers($itemNum);
 410         if ( $transfertwhen && ($transfertwhen ne '') ) {
 411             $itemLoopIter->{transfertwhen} = format_date($transfertwhen);
 412             $itemLoopIter->{transfertfrom} =
 413               $branches->{$transfertfrom}{branchname};
 414             $itemLoopIter->{transfertto} = $branches->{$transfertto}{branchname};
 415             $itemLoopIter->{nocancel} = 1;
 416         }
 417
 418         # If there is no loan, return and transfer, we show a checkbox.
 419         $itemLoopIter->{notforloan} = $itemLoopIter->{notforloan} || 0;
 420
 421         my $branch = C4::Circulation::_GetCircControlBranch($itemLoopIter, $borr);
 422
 423         my $branchitemrule = GetBranchItemRule( $branch, $itemInfo->{'itype'} );
 424         my $policy_holdallowed = 1;
 425
 426         if ( $branchitemrule->{'holdallowed'} == 0 ||
 427                 ( $branchitemrule->{'holdallowed'} == 1 && $borr->{'branchcode'} ne $itemInfo->{'homebranch'} ) ) {
 428             $policy_holdallowed = 0;
 429         }
 430
 431         if (IsAvailableForItemLevelRequest($itemNum) and $policy_holdallowed and CanItemBeReserved($borrowernumber,$itemNum)) {
 432             $itemLoopIter->{available} = 1;
 433             $numCopiesAvailable++;
 434         }
 435
 436         # FIXME: move this to a pm
 437         my $dbh = C4::Context->dbh;
 438         my $sth2 = $dbh->prepare("SELECT * FROM reserves WHERE borrowernumber=? AND itemnumber=? AND found='W'");
 439         $sth2->execute($itemLoopIter->{ReservedForBorrowernumber}, $itemNum);
 440         while (my $wait_hashref = $sth2->fetchrow_hashref) {
 441             $itemLoopIter->{waitingdate} = format_date($wait_hashref->{waitingdate});
 442         }
 443         $itemLoopIter->{imageurl} = getitemtypeimagelocation( 'opac', $itemTypes->{ $itemInfo->{itype} }{imageurl} );
 444
 445     # Show serial enumeration when needed
 446     if ($itemLoopIter->{enumchron}) {
 447         $itemdata_enumchron = 1;
 448     }
 449     $template->param( itemdata_enumchron => $itemdata_enumchron );
 450
 451         push @{$biblioLoopIter{itemLoop}}, $itemLoopIter;
 452     }
 453
 454     if ($numCopiesAvailable > 0) {
 455         $numBibsAvailable++;
 456         $biblioLoopIter{bib_available} = 1;
 457         $biblioLoopIter{holdable} = 1;
 458     }
 459     if ($biblioLoopIter{already_reserved}) {
 460         $biblioLoopIter{holdable} = undef;
 461     }
 462     if(not CanBookBeReserved($borrowernumber,$biblioNum)){
 463         $biblioLoopIter{holdable} = undef;
 464     }
 465
 466     push @$biblioLoop, \%biblioLoopIter;
 467 }
 468
 469 if ( $numBibsAvailable == 0 ) {
 470     $template->param( none_available => 1, message => 1 );
 471 }
 472
 473 my $itemTableColspan = 5;
 474 if (!$template->param('OPACItemHolds')) {
 475     $itemTableColspan--;
 476 }
 477 if ($template->param('singleBranchMode')) {
 478     $itemTableColspan--;
 479 }
 480 $template->param(itemtable_colspan => $itemTableColspan);
 481
 482 # display infos
 483 $template->param(bibitemloop => $biblioLoop);
 484 $template->param( showpriority=>1 ) if $OPACDisplayRequestPriority;
 485 # can set reserve date in future
 486 if (
 487     C4::Context->preference( 'AllowHoldDateInFuture' ) &&
 488     C4::Context->preference( 'OPACAllowHoldDateInFuture' )
 489     ) {
 490     $template->param(
 491             reserve_in_future         => 1,
 492     );
 493 }
 494
 495 $template->param( DHTMLcalendar_dateformat  => C4::Dates->DHTMLcalendar() );
 496
 497 output_html_with_http_headers $query, $cookie, $template->output;
 498