opac/opac-sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 SARL Biblibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 use warnings;
  22
  23 use CGI qw ( -utf8 );
  24 use Encode qw( encode );
  25 use Carp;
  26
  27 use Mail::Sendmail;
  28 use MIME::QuotedPrint;
  29 use MIME::Base64;
  30 use C4::Auth;
  31 use C4::Biblio;
  32 use C4::Items;
  33 use C4::Output;
  34 use C4::Members;
  35 use Koha::Email;
  36 use Koha::Patrons;
  37 use Koha::Virtualshelves;
  38
  39 my $query = new CGI;
  40
  41 # if virtualshelves is disabled, leave immediately
  42 if ( ! C4::Context->preference('virtualshelves') ) {
  43     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  44     exit;
  45 }
  46
  47 my ( $template, $borrowernumber, $cookie ) = get_template_and_user (
  48     {
  49         template_name   => "opac-sendshelfform.tt",
  50         query           => $query,
  51         type            => "opac",
  52         authnotrequired => 0,
  53     }
  54 );
  55
  56 my $shelfid = $query->param('shelfid');
  57 my $email   = $query->param('email');
  58
  59 my $dbh          = C4::Context->dbh;
  60
  61 my $shelf = Koha::Virtualshelves->find( $shelfid );
  62 if ( $shelf and $shelf->can_be_viewed( $borrowernumber ) ) {
  63
  64 if ( $email ) {
  65     my $message = Koha::Email->new();
  66     my $comment    = $query->param('comment');
  67
  68     my %mail = $message->create_message_headers(
  69         {
  70             to => $email,
  71         }
  72     );
  73
  74     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  75         {
  76             template_name   => "opac-sendshelf.tt",
  77             query           => $query,
  78             type            => "opac",
  79             authnotrequired => 1,
  80         }
  81     );
  82
  83     my $shelf = Koha::Virtualshelves->find( $shelfid );
  84     my $contents = $shelf->get_contents;
  85     my $marcflavour         = C4::Context->preference('marcflavour');
  86     my $iso2709;
  87     my @results;
  88
  89     while ( my $content = $contents->next ) {
  90         my $biblionumber = $content->biblionumber;
  91         my $fw               = GetFrameworkCode($biblionumber);
  92         my $dat              = GetBiblioData($biblionumber);
  93         my $record           = GetMarcBiblio($biblionumber, 1);
  94         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  95         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  96         my $subtitle         = GetRecordValue('subtitle', $record, $fw);
  97
  98         my @items = GetItemsInfo( $biblionumber );
  99
 100         $dat->{ISBN}           = GetMarcISBN($record, $marcflavour);
 101         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
 102         $dat->{MARCAUTHORS}    = $marcauthorsarray;
 103         $dat->{'biblionumber'} = $biblionumber;
 104         $dat->{ITEM_RESULTS}   = \@items;
 105         $dat->{subtitle}       = $subtitle;
 106         $dat->{HASAUTHORS}     = $dat->{'author'} || @$marcauthorsarray;
 107
 108         $iso2709 .= $record->as_usmarc();
 109
 110         push( @results, $dat );
 111     }
 112
 113     my $patron = Koha::Patrons->find( $borrowernumber );
 114
 115     $template2->param(
 116         BIBLIO_RESULTS => \@results,
 117         comment        => $comment,
 118         shelfname      => $shelf->shelfname,
 119         firstname      => $patron->firstname,
 120         surname        => $patron->surname,
 121     );
 122
 123     # Getting template result
 124     my $template_res = $template2->output();
 125     my $body;
 126
 127     # Analysing information and getting mail properties
 128     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 129         $mail{subject} = $1;
 130         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 131     }
 132     else { $mail{'subject'} = "no subject"; }
 133     $mail{subject} = Encode::encode("UTF-8", $mail{subject});
 134
 135     my $email_header = "";
 136     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 137         $email_header = $1;
 138         $email_header =~ s|\n?(.*)\n?|$1|;
 139         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 140     }
 141
 142     my $email_file = "list.txt";
 143     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 144         $email_file = $1;
 145         $email_file =~ s|\n?(.*)\n?|$1|;
 146     }
 147
 148     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 149         $body = $1;
 150         $body =~ s|\n?(.*)\n?|$1|;
 151         $body = encode_qp(Encode::encode("UTF-8", $body));
 152     }
 153
 154     my $boundary = "====" . time() . "====";
 155
 156     # We set and put the multipart content
 157     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 158
 159     my $isofile = encode_base64(encode("UTF-8", $iso2709));
 160     $boundary = '--' . $boundary;
 161
 162     $mail{body} = <<END_OF_BODY;
 163 $boundary
 164 MIME-Version: 1.0
 165 Content-Type: text/plain; charset="utf-8"
 166 Content-Transfer-Encoding: quoted-printable
 167
 168 $email_header
 169 $body
 170 $boundary
 171 Content-Type: application/octet-stream; name="list.iso2709"
 172 Content-Transfer-Encoding: base64
 173 Content-Disposition: attachment; filename="list.iso2709"
 174
 175 $isofile
 176 $boundary--
 177 END_OF_BODY
 178
 179     # Sending mail
 180     if ( sendmail %mail ) {
 181         # do something if it works....
 182         $template->param( SENT      => "1" );
 183     }
 184     else {
 185         # do something if it doesnt work....
 186         carp "Error sending mail: $Mail::Sendmail::error \n";
 187         $template->param( error => 1 );
 188     }
 189
 190     $template->param(
 191         shelfid => $shelfid,
 192         email => $email,
 193     );
 194     output_html_with_http_headers $query, $cookie, $template->output;
 195
 196
 197 }else{
 198     $template->param( shelfid => $shelfid,
 199                       url     => "/cgi-bin/koha/opac-sendshelf.pl",
 200                     );
 201     output_html_with_http_headers $query, $cookie, $template->output;
 202 }
 203
 204 } else {
 205     $template->param( invalidlist => 1,
 206                       url     => "/cgi-bin/koha/opac-sendshelf.pl",
 207     );
 208     output_html_with_http_headers $query, $cookie, $template->output;
 209 }