members/moremember.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 # Copyright 2010 BibLibre
   5 # Copyright 2014 ByWater Solutions
   6 #
   7 # This file is part of Koha.
   8 #
   9 # Koha is free software; you can redistribute it and/or modify it
  10 # under the terms of the GNU General Public License as published by
  11 # the Free Software Foundation; either version 3 of the License, or
  12 # (at your option) any later version.
  13 #
  14 # Koha is distributed in the hope that it will be useful, but
  15 # WITHOUT ANY WARRANTY; without even the implied warranty of
  16 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  17 # GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License
  20 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  21
  22
  23 =head1 moremember.pl
  24
  25  script to do a borrower enquiry/bring up borrower details etc
  26  Displays all the details about a borrower
  27  written 20/12/99 by chris@katipo.co.nz
  28  last modified 21/1/2000 by chris@katipo.co.nz
  29  modified 31/1/2001 by chris@katipo.co.nz
  30    to not allow items on request to be renewed
  31
  32  needs html removed and to use the C4::Output more, but its tricky
  33
  34 =cut
  35
  36 use strict;
  37 #use warnings; FIXME - Bug 2505
  38 use CGI qw ( -utf8 );
  39 use C4::Context;
  40 use C4::Auth;
  41 use C4::Output;
  42 use C4::Members;
  43 use C4::Members::Attributes;
  44 use C4::Members::AttributeTypes;
  45 use C4::Reserves;
  46 use C4::Circulation;
  47 use C4::Koha;
  48 use C4::Letters;
  49 use C4::Biblio;
  50 use C4::Form::MessagingPreferences;
  51 use List::MoreUtils qw/uniq/;
  52 use C4::Members::Attributes qw(GetBorrowerAttributes);
  53 use Koha::AuthorisedValues;
  54 use Koha::CsvProfiles;
  55 use Koha::Patron::Debarments qw(GetDebarments);
  56 use Koha::Patron::Images;
  57 use Module::Load;
  58 if ( C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
  59     load Koha::NorwegianPatronDB, qw( NLGetSyncDataFromBorrowernumber );
  60 }
  61 #use Smart::Comments;
  62 #use Data::Dumper;
  63 use DateTime;
  64 use Koha::DateUtils;
  65 use Koha::Database;
  66 use Koha::Patrons;
  67 use Koha::Patron::Categories;
  68 use Koha::Token;
  69
  70 use vars qw($debug);
  71
  72 BEGIN {
  73         $debug = $ENV{DEBUG} || 0;
  74 }
  75
  76 my $dbh = C4::Context->dbh;
  77
  78 my $input = CGI->new;
  79 $debug or $debug = $input->param('debug') || 0;
  80 my $print = $input->param('print');
  81
  82 my $template_name;
  83 my $quickslip = 0;
  84
  85 my $flagsrequired;
  86 if (defined $print and $print eq "page") {
  87     $template_name = "members/moremember-print.tt";
  88     # circ staff who process checkouts but can't edit
  89     # patrons still need to be able to access print view
  90     $flagsrequired = { circulate => "circulate_remaining_permissions" };
  91 } elsif (defined $print and $print eq "slip") {
  92     $template_name = "members/moremember-receipt.tt";
  93     # circ staff who process checkouts but can't edit
  94     # patrons still need to be able to print receipts
  95     $flagsrequired =  { circulate => "circulate_remaining_permissions" };
  96 } elsif (defined $print and $print eq "qslip") {
  97     $template_name = "members/moremember-receipt.tt";
  98     $quickslip = 1;
  99     $flagsrequired =  { circulate => "circulate_remaining_permissions" };
 100 } elsif (defined $print and $print eq "brief") {
 101     $template_name = "members/moremember-brief.tt";
 102     $flagsrequired = { borrowers => 1 };
 103 } else {
 104     $template_name = "members/moremember.tt";
 105     $flagsrequired = { borrowers => 1 };
 106 }
 107
 108 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 109     {
 110         template_name   => $template_name,
 111         query           => $input,
 112         type            => "intranet",
 113         authnotrequired => 0,
 114         flagsrequired   => $flagsrequired,
 115         debug           => 1,
 116     }
 117 );
 118 my $borrowernumber = $input->param('borrowernumber');
 119 my $error = $input->param('error');
 120 $template->param( error => $error ) if ( $error );
 121
 122 my $patron        = Koha::Patrons->find($borrowernumber);
 123 unless ( $patron ) {
 124     $template->param (unknowuser => 1);
 125     output_html_with_http_headers $input, $cookie, $template->output;
 126     exit;
 127 }
 128
 129 my $issues        = $patron->checkouts;
 130 my $balance       = $patron->account->balance;
 131 $template->param(
 132     issuecount => $issues->count,
 133     fines      => $balance,
 134 );
 135
 136 my $category_type = $patron->category->category_type;
 137 my $data = $patron->unblessed;
 138
 139 $debug and printf STDERR "dates (enrolled,expiry,birthdate) raw: (%s, %s, %s)\n", map {$data->{$_}} qw(dateenrolled dateexpiry dateofbirth);
 140 foreach (qw(dateenrolled dateexpiry dateofbirth)) {
 141     my $userdate = $data->{$_};
 142     unless ($userdate) {
 143         $debug and warn sprintf "Empty \$data{%12s}", $_;
 144         $data->{$_} = '';
 145         next;
 146     }
 147     $data->{$_} = dt_from_string( $userdate );
 148 }
 149 $data->{'IS_ADULT'} = ( $data->{'categorycode'} ne 'I' );
 150
 151 for (qw(gonenoaddress lost borrowernotes)) {
 152          $data->{$_} and $template->param(flagged => 1) and last;
 153 }
 154
 155 if ( $patron->is_debarred ) {
 156     $template->param(
 157         userdebarred => 1,
 158         flagged => 1,
 159         debarments => GetDebarments({ borrowernumber => $borrowernumber }),
 160     );
 161     my $debar = $data->{'debarred'};
 162     if ( $debar ne "9999-12-31" ) {
 163         $template->param( 'userdebarreddate' => output_pref( { dt => dt_from_string( $debar ), dateonly => 1 } ) );
 164         $template->param( 'debarredcomment'  => $data->{debarredcomment} );
 165     }
 166 }
 167
 168 $data->{ "sex_".$data->{'sex'}."_p" } = 1 if defined $data->{sex};
 169
 170 if ( $category_type eq 'C') {
 171     my $patron_categories = Koha::Patron::Categories->search_limited({ category_type => 'A' }, {order_by => ['categorycode']});
 172     $template->param( 'CATCODE_MULTI' => 1) if $patron_categories->count > 1;
 173     $template->param( 'catcode' => $patron_categories->next )  if $patron_categories->count == 1;
 174 }
 175
 176 my @relatives;
 177 if ( my $guarantor = $patron->guarantor ) {
 178     $template->param( guarantor => $guarantor );
 179     push @relatives, $guarantor->borrowernumber;
 180     push @relatives, $_->borrowernumber for $patron->siblings;
 181 } elsif ( $patron->contactname || $patron->contactfirstname ) {
 182     $template->param(
 183         guarantor => {
 184             firstname => $patron->contactfirstname,
 185             surname   => $patron->contactname,
 186         }
 187     );
 188 } else {
 189     my @guarantees = $patron->guarantees;
 190     $template->param( guarantees => \@guarantees );
 191     push @relatives, $_->borrowernumber for @guarantees;
 192 }
 193
 194 my $relatives_issues_count =
 195   Koha::Database->new()->schema()->resultset('Issue')
 196   ->count( { borrowernumber => \@relatives } );
 197
 198 $template->param( adultborrower => 1 ) if ( $category_type eq 'A' || $category_type eq 'I' );
 199
 200 my %bor;
 201 $bor{'borrowernumber'} = $borrowernumber;
 202
 203 # Converts the branchcode to the branch name
 204 my $samebranch;
 205 if ( C4::Context->preference("IndependentBranches") ) {
 206     my $userenv = C4::Context->userenv;
 207     if ( C4::Context->IsSuperLibrarian() ) {
 208         $samebranch = 1;
 209     }
 210     else {
 211         $samebranch = ( $data->{'branchcode'} eq $userenv->{branch} );
 212     }
 213 }
 214 else {
 215     $samebranch = 1;
 216 }
 217 my $library = Koha::Libraries->find( $data->{branchcode})->unblessed;
 218 @{$data}{keys %$library} = values %$library; # merge in all branch columns
 219
 220 my ( $total, $accts, $numaccts) = GetMemberAccountRecords( $borrowernumber );
 221
 222 # If printing a page, send the account informations to the template
 223 if ($print eq "page") {
 224     foreach my $accountline (@$accts) {
 225         $accountline->{amount} = sprintf '%.2f', $accountline->{amount};
 226         $accountline->{amountoutstanding} = sprintf '%.2f', $accountline->{amountoutstanding};
 227
 228         if ($accountline->{accounttype} ne 'F' && $accountline->{accounttype} ne 'FU'){
 229             $accountline->{printtitle} = 1;
 230         }
 231     }
 232     $template->param( accounts => $accts );
 233 }
 234
 235 # Show OPAC privacy preference is system preference is set
 236 if ( C4::Context->preference('OPACPrivacy') ) {
 237     $template->param( OPACPrivacy => 1);
 238     $template->param( "privacy".$data->{'privacy'} => 1);
 239 }
 240
 241 my $today       = DateTime->now( time_zone => C4::Context->tz);
 242 $today->truncate(to => 'day');
 243 my $overdues_exist = 0;
 244 my $totalprice = 0;
 245
 246 # Calculate and display patron's age
 247 if ( $data->{dateofbirth} ) {
 248     $template->param( age => Koha::Patron->new({ dateofbirth => $data->{dateofbirth} })->get_age );
 249 }
 250
 251 ### ###############################################################################
 252 # BUILD HTML
 253 # show all reserves of this borrower, and the position of the reservation ....
 254 if ($borrowernumber) {
 255     $template->param(
 256         holds_count => Koha::Database->new()->schema()->resultset('Reserve')
 257           ->count( { borrowernumber => $borrowernumber } ) );
 258 }
 259
 260 # current alert subscriptions
 261 my $alerts = getalert($borrowernumber);
 262 foreach (@$alerts) {
 263     $_->{ $_->{type} } = 1;
 264     $_->{relatedto} = findrelatedto( $_->{type}, $_->{externalid} );
 265 }
 266
 267 # Add sync data to the user data
 268 if ( C4::Context->preference('NorwegianPatronDBEnable') && C4::Context->preference('NorwegianPatronDBEnable') == 1 ) {
 269     my $sync = NLGetSyncDataFromBorrowernumber( $borrowernumber );
 270     if ( $sync ) {
 271         $data->{'sync'}       = $sync->sync;
 272         $data->{'syncstatus'} = $sync->syncstatus;
 273         $data->{'lastsync'}   = $sync->lastsync;
 274     }
 275 }
 276
 277 # check to see if patron's image exists in the database
 278 # basically this gives us a template var to condition the display of
 279 # patronimage related interface on
 280 $template->param( picture => 1 ) if $patron->image;
 281 # Generate CSRF token for upload and delete image buttons
 282 $template->param(
 283     csrf_token => Koha::Token->new->generate_csrf({ session_id => $input->cookie('CGISESSID'),}),
 284 );
 285
 286
 287 $template->param(%$data);
 288
 289 if (C4::Context->preference('ExtendedPatronAttributes')) {
 290     my $attributes = C4::Members::Attributes::GetBorrowerAttributes($borrowernumber);
 291     my @classes = uniq( map {$_->{class}} @$attributes );
 292     @classes = sort @classes;
 293
 294     my @attributes_loop;
 295     for my $class (@classes) {
 296         my @items;
 297         for my $attr (@$attributes) {
 298             push @items, $attr if $attr->{class} eq $class
 299         }
 300         my $av = Koha::AuthorisedValues->search({ category => 'PA_CLASS', authorised_value => $class });
 301         my $lib = $av->count ? $av->next->lib : $class;
 302
 303         push @attributes_loop, {
 304             class => $class,
 305             items => \@items,
 306             lib   => $lib,
 307         };
 308     }
 309
 310     $template->param(
 311         ExtendedPatronAttributes => 1,
 312         attributes_loop => \@attributes_loop
 313     );
 314
 315     my @types = C4::Members::AttributeTypes::GetAttributeTypes();
 316     if (scalar(@types) == 0) {
 317         $template->param(no_patron_attribute_types => 1);
 318     }
 319 }
 320
 321 if (C4::Context->preference('EnhancedMessagingPreferences')) {
 322     C4::Form::MessagingPreferences::set_form_values({ borrowernumber => $borrowernumber }, $template);
 323     $template->param(messaging_form_inactive => 1);
 324     $template->param(SMSSendDriver => C4::Context->preference("SMSSendDriver"));
 325     $template->param(SMSnumber     => $data->{'smsalertnumber'});
 326     $template->param(TalkingTechItivaPhone => C4::Context->preference("TalkingTechItivaPhoneNotification"));
 327 }
 328
 329 if ( C4::Context->preference("ExportCircHistory") ) {
 330     $template->param(csv_profiles => [ Koha::CsvProfiles->search({ type => 'marc' }) ]);
 331 }
 332
 333 # in template <TMPL_IF name="I"> => institutional (A for Adult, C for children)
 334 $template->param( $data->{'categorycode'} => 1 );
 335
 336 # Display the language description instead of the code
 337 # Note that this is certainly wrong
 338 my ( $subtag, $region ) = split '-', $patron->lang;
 339 my $translated_language = C4::Languages::language_get_description( $subtag, $subtag, 'language' );
 340
 341 $template->param(
 342     patron          => $patron,
 343     translated_language => $translated_language,
 344     detailview      => 1,
 345     borrowernumber  => $borrowernumber,
 346     othernames      => $data->{'othernames'},
 347     categoryname    => $data->{'description'},
 348     was_renewed     => scalar $input->param('was_renewed') ? 1 : 0,
 349     todaysdate      => output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 }),
 350     totalprice      => sprintf("%.2f", $totalprice),
 351     totaldue        => sprintf("%.2f", $total),
 352     totaldue_raw    => $total,
 353     overdues_exist  => $overdues_exist,
 354     StaffMember     => $category_type eq 'S',
 355     is_child        => $category_type eq 'C',
 356     samebranch      => $samebranch,
 357     quickslip       => $quickslip,
 358     housebound_role => scalar $patron->housebound_role,
 359     privacy_guarantor_checkouts => $data->{'privacy_guarantor_checkouts'},
 360     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 361     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 362     RoutingSerials => C4::Context->preference('RoutingSerials'),
 363     PatronsPerPage => C4::Context->preference("PatronsPerPage") || 20,
 364     relatives_issues_count => $relatives_issues_count,
 365     relatives_borrowernumbers => \@relatives,
 366 );
 367
 368 output_html_with_http_headers $input, $cookie, $template->output;