Makefile.PL

   1 # Copyright 2007 MJ Ray
   2 #
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17 #
  18 # Current maintainer MJR http://mjr.towers.org.uk/
  19 #
  20
  21 use strict;
  22 use warnings;
  23 use ExtUtils::MakeMaker;
  24 use POSIX;
  25 use File::Spec;
  26 use Getopt::Long;
  27 use FindBin; # we need to enforce which C4::Installer::PerlModule is used in case more than one is installed
  28
  29 use lib $FindBin::Bin;
  30
  31 use C4::Installer;
  32
  33 my $koha_pm = C4::Installer::PerlModules->new;
  34
  35 my $DEBUG = 0;
  36 die "perl 5.10 or later required" unless ($] >= 5.010000);
  37
  38 # Hash up directory structure & files beginning with the directory we were called from (should be the base of koha)...
  39
  40 my $dirtree = hashdir('.');
  41 my %result = ();
  42
  43 =head1 NAME
  44
  45 Makefile.PL - Koha packager and installer
  46
  47 =head1 SYNOPSIS
  48
  49 =head2 BASIC INSTALLATION
  50
  51     perl Makefile.PL
  52     make
  53     make test
  54     sudo make install
  55
  56 =head2 UPGRADE INSTALLATION
  57
  58     NOTE: This option is only available if koha-install-log exists.
  59
  60     perl Makefile.PL --prev-install-log /path/to/koha-install-log
  61
  62     make
  63     make test
  64     sudo make upgrade
  65
  66 =head2 PACKAGING RELEASE TARBALLS
  67
  68     make manifest tardist
  69     make manifest zipdist
  70
  71 =head2 CLEANING UP
  72
  73         make clean
  74
  75 =head1 DESCRIPTION
  76
  77 This is a packager and installer that uses
  78 ExtUtils::MakeMaker, which is fairly common
  79 on perl systems.
  80 As well as building tar or zip files
  81 and installing with the above commands,
  82 it allows us to check pre-requisites
  83 and generate configuration files.
  84
  85 =head1 VARIABLES
  86
  87 =head2 NAME, VERSION_FROM, ABSTRACT, AUTHOR
  88
  89 Basic metadata about this software.
  90
  91 =head2 NO_META
  92
  93 Suppress generation of META.yml file.
  94
  95 =head2 PREREQ_PM
  96
  97 Hash of perl modules and versions required.
  98
  99 =head2 PM
 100
 101 Hash of file mappings
 102
 103 =head2 PL_FILES
 104
 105 This is a hash of PL scripts to run after installation and
 106 the files to ask them to generate.
 107 Maybe use the values from CONFIGURE
 108 to generate initial configuration files in future.
 109
 110 =cut
 111
 112 =head2 target_map
 113
 114 This is a hash mapping directories and files in the
 115 source tree to installation target directories.  The rules
 116 for this mapping are:
 117
 118 =over 4
 119
 120 =item If a directory or file is specified, it and its
 121 contents will be copied to the installation target directory.
 122
 123 =item If a subdirectory of a mapped directory is specified,
 124 its target overrides the parent's target for that subdirectory.
 125
 126 =item The value of each map entry may either be a scalar containing
 127 one target or a reference to a hash containing 'target' and 'trimdir'
 128 keys.
 129
 130 =item Any files at the top level of the source tree that are
 131 not included in the map will not be installed.
 132
 133 =item Any directories at the top level of the source tree
 134 that are not included in the map will be installed in
 135 INTRANET_CGI_DIR.  This is a sensible default given the
 136 current organization of the source tree, but (FIXME) it
 137 would be better to reorganize the source tree to better
 138 match the installation system, to allow adding new directories
 139 without having to adjust Makefile.PL each time.  The idea
 140 is to make the C<$target_map> hash as minimal as possible.
 141
 142 =back
 143
 144 The permitted installation targets are:
 145
 146 =over 4
 147
 148 =item INTRANET_CGI_DIR
 149
 150 CGI scripts for intranet (staff) interface.
 151
 152 =item INTRANET_TMPL_DIR
 153
 154 HTML templates for the intranet interface.
 155
 156 =item INTRANET_WWW_DIR
 157
 158 HTML files, images, etc. for DocumentRoot for the intranet interface.
 159
 160 =item OPAC_CGI_DIR
 161
 162 CGI scripts for OPAC (public) interface.
 163
 164 =item OPAC_TMPL_DIR
 165
 166 HTML templates for the OPAC interface.
 167
 168 =item OPAC_WWW_DIR
 169
 170 HTML files, images, etc. for DocumentRoot for the OPAC interface.
 171
 172 =item PERL_MODULE_DIR
 173
 174 Perl modules (at present just the C4 modules) that are intimately
 175 tied to Koha.  Depending on the installation options, these
 176 may or may not be installed one of the standard directories
 177 in Perl's default @LIB.
 178
 179 =item KOHA_CONF_DIR
 180
 181 Directory for Koha configuration files.
 182
 183 =item ZEBRA_CONF_DIR
 184
 185 Directory for Zebra configuration files.
 186
 187 =item ZEBRA_LOCK_DIR
 188
 189 Directory for Zebra's lock files.  This includes subdirs for authorities,
 190 biblios, and the zebra rebuild function.  Any activity to reindex
 191 zebra from koha should interlock here with rebuild_zebra.pl.
 192
 193 =item ZEBRA_DATA_DIR
 194
 195 Directory for Zebra's data files.
 196
 197 =item ZEBRA_RUN_DIR
 198
 199 Directory for Zebra's UNIX-domain sockets.
 200
 201 =item MISC_DIR
 202
 203 Directory for for miscellaenous scripts, among other
 204 things the translation toolkit and RSS feed tools.
 205
 206 =item SCRIPT_DIR
 207
 208 Directory for command-line scripts and daemons to
 209 be set up all for installation modes.
 210
 211 =item SCRIPT_NONDEV_DIR
 212
 213 Directory for command-line scripts that should
 214 be installed in the same directory as the
 215 SCRIPT_DIR target except 'dev' installs.
 216
 217 =item MAN_DIR
 218
 219 Directory for man pages created from POD -- will mostly
 220 contain information of interest to Koha developers.
 221
 222 =item DOC_DIR
 223
 224 Directory for Koha documentation accessed from the
 225 command-line, e.g., READMEs.
 226
 227 =item LOG_DIR
 228
 229 Directory for Apache and Zebra logs produced by Koha.
 230
 231 =item BACKUP_DIR
 232
 233 Directory for backup files produced by Koha.
 234
 235 =item PLUGINS_DIR
 236
 237 Directory for external Koha plugins.
 238
 239 =item PAZPAR2_CONF_DIR
 240
 241 Directory for PazPar2 configuration files.
 242
 243 =item FONT_DIR
 244
 245 Directory where DejaVu fonts are installed.
 246
 247 =item NONE
 248
 249 This is a dummy target used to explicitly state
 250 that a given file or directory is not to be installed.
 251 This is used either for parts of the installer itself
 252 or for development tools that are not applicable to a
 253 production installation.
 254
 255 =back
 256
 257 =cut
 258
 259 my $target_map = {
 260   './about.pl'                  => 'INTRANET_CGI_DIR',
 261   './acqui'                     => 'INTRANET_CGI_DIR',
 262   './admin'                     => 'INTRANET_CGI_DIR',
 263   './authorities'               => 'INTRANET_CGI_DIR',
 264   './basket'                    => 'INTRANET_CGI_DIR',
 265   './C4'                        => 'PERL_MODULE_DIR',
 266   './C4/SIP/t'                  => 'NONE',
 267   './C4/SIP/koha_test'          => 'NONE',
 268   './C4/tests'                  => 'NONE',
 269   './catalogue'                 => 'INTRANET_CGI_DIR',
 270   './cataloguing'               => 'INTRANET_CGI_DIR',
 271   './changelanguage.pl'         => 'INTRANET_CGI_DIR',
 272   './check_sysprefs.pl'         => 'NONE',
 273   './circ'                      => 'INTRANET_CGI_DIR',
 274   './course_reserves'           => 'INTRANET_CGI_DIR',
 275   './docs/history.txt'          => { target => 'DOC_DIR', trimdir => -1 },
 276   './offline_circ'              => 'INTRANET_CGI_DIR',
 277   './edithelp.pl'               => 'INTRANET_CGI_DIR',
 278   './etc'                       => { target => 'KOHA_CONF_DIR', trimdir => -1 },
 279   './etc/zebradb'               => { target => 'ZEBRA_CONF_DIR', trimdir => -1 },
 280   './etc/pazpar2'               => { target => 'PAZPAR2_CONF_DIR', trimdir => -1 },
 281   './help.pl'                   => 'INTRANET_CGI_DIR',
 282   './installer-CPAN.pl'         => 'NONE',
 283   './installer'                 => 'INTRANET_CGI_DIR',
 284   './errors'                    => {target => 'INTRANET_CGI_DIR'},
 285   './Koha'                      => 'PERL_MODULE_DIR',
 286   './Koha.pm'                   => 'PERL_MODULE_DIR',
 287   './koha-tmpl/intranet-tmpl'   => {target => 'INTRANET_TMPL_DIR', trimdir => -1},
 288   './koha-tmpl/opac-tmpl'       => {target => 'OPAC_TMPL_DIR', trimdir => -1},
 289   './kohaversion.pl'            => 'INTRANET_CGI_DIR',
 290   './labels'                    => 'INTRANET_CGI_DIR',
 291   './mainpage.pl'               => 'INTRANET_CGI_DIR',
 292   './Makefile.PL'               => 'NONE',
 293   './MANIFEST.SKIP'             => 'NONE',
 294   './members'                   => 'INTRANET_CGI_DIR',
 295   './misc'                      => { target => 'SCRIPT_NONDEV_DIR', trimdir => -1 },
 296   './misc/bin'                  => { target => 'SCRIPT_DIR', trimdir => -1 },
 297   './misc/release_notes'        => { target => 'DOC_DIR', trimdir => 2 },
 298   './misc/translator'           => { target => 'MISC_DIR', trimdir => 2 },
 299   './misc/koha-install-log'     => { target => 'MISC_DIR', trimdir => -1 },
 300   './misc/installer_devel_notes' => 'NONE',
 301   './opac'                      => 'OPAC_CGI_DIR',
 302   './OpenILS'                   => 'PERL_MODULE_DIR',
 303   './README.txt'                => 'NONE',
 304   './patroncards'               => 'INTRANET_CGI_DIR',
 305   './patron_lists'              => 'INTRANET_CGI_DIR',
 306   './plugins'                   => 'INTRANET_CGI_DIR',
 307   './reports'                   => 'INTRANET_CGI_DIR',
 308   './reserve'                   => 'INTRANET_CGI_DIR',
 309   './reviews'                   => 'INTRANET_CGI_DIR',
 310   './rewrite-config.PL'         => 'NONE',
 311   './reviews'                   => 'INTRANET_CGI_DIR',
 312   './rotating_collections'      => 'INTRANET_CGI_DIR',
 313   './serials'                   => 'INTRANET_CGI_DIR',
 314   './services'                  => 'INTRANET_CGI_DIR',
 315   './skel'                      => 'NONE',
 316   './skel/var/log/koha'         => { target => 'LOG_DIR', trimdir => -1 },
 317   './skel/var/spool/koha'       => { target => 'BACKUP_DIR', trimdir => -1 },
 318   './skel/var/run/koha/zebradb' => { target => 'ZEBRA_RUN_DIR', trimdir => -1 },
 319   './skel/var/lock/koha/zebradb/authorities' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 320   './skel/var/lib/koha/zebradb/authorities/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 321   './skel/var/lib/koha/zebradb/authorities/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 322   './skel/var/lib/koha/zebradb/authorities/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 323   './skel/var/lib/koha/zebradb/authorities/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 324   './skel/var/lock/koha/zebradb/biblios' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 325   './skel/var/lib/koha/zebradb/biblios/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 326   './skel/var/lib/koha/zebradb/biblios/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 327   './skel/var/lib/koha/zebradb/biblios/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 328   './skel/var/lib/koha/zebradb/biblios/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 329   './skel/var/lock/koha/zebradb/rebuild' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 330   './skel/var/lib/koha/plugins' => { target => 'PLUGINS_DIR', trimdir => 6 },
 331   './sms'                       => 'INTRANET_CGI_DIR',
 332   './suggestion'                => 'INTRANET_CGI_DIR',
 333   './svc'                       => 'INTRANET_CGI_DIR',
 334   './t'                         => 'NONE',
 335   './tags'                      => 'INTRANET_CGI_DIR',
 336   './tmp'                       => 'NONE', # FIXME need to determine whether
 337                                            # Koha generates any persistent temp files
 338                                            # that should go in /var/tmp/koha
 339   './tools'                     => 'INTRANET_CGI_DIR',
 340   './virtualshelves'            => 'INTRANET_CGI_DIR',
 341   './xml_sax.pl'                => 'PERL_MODULE_DIR',
 342   # ignore files and directories created by the install itself
 343   './pm_to_blib'                => 'NONE',
 344   './blib'                      => 'NONE',
 345 };
 346
 347 =head1 CONFIGURATION OPTIONS
 348
 349 The following configuration options are used by the installer.
 350
 351 =over 4
 352
 353 =item INSTALL_MODE
 354
 355 Specifies whether installation will be FHS-compliant (default,
 356 assumes user has root), put everything under
 357 a single directory (for users installing on a web host
 358 that allows CGI scripts and a MySQL database but not root
 359 access), or development (for a developer who wants to run
 360 Koha from a git clone with no fuss).
 361
 362 =item INSTALL_BASE
 363
 364 Directory under which most components will go.  Default
 365 value will vary depending on INSTALL_MODE.
 366
 367 =item DB_TYPE
 368
 369 Type of DBMS (e.g., mysql or Pg).
 370
 371 =item DB_HOST
 372
 373 Name of DBMS server.
 374
 375 =item DB_PORT
 376
 377 Port that DBMS server is listening on.
 378
 379 =item DB_NAME
 380
 381 Name of the DBMS database for Koha.
 382
 383 =item DB_USER
 384
 385 Name of DBMS user account for Koha's database.
 386
 387 =item DB_PASS
 388
 389 Pasword of DMBS user account for Koha's database.
 390
 391 =item ZEBRA_MARC_FORMAT
 392
 393 Specifies format of MARC records to be indexed by Zebra.
 394
 395 =item ZEBRA_LANGUAGE
 396
 397 Specifies primary language of records that will be
 398 indexed by Zebra.
 399
 400 =item ZEBRA_USER
 401
 402 Internal Zebra user account for the index.
 403
 404 =item ZEBRA_PASS
 405
 406 Internal Zebra user account's password.
 407
 408 =item KOHA_USER
 409
 410 System user account that will own Koha's files.
 411
 412 =item KOHA_GROUP
 413
 414 System group that will own Koha's files.
 415
 416 =back
 417
 418 =cut
 419
 420 # default configuration options
 421 my %config_defaults = (
 422   'DB_TYPE'           => 'mysql',
 423   'DB_HOST'           => 'localhost',
 424   'DB_NAME'           => 'koha',
 425   'DB_USER'           => 'kohaadmin',
 426   'DB_PASS'           => 'katikoan',
 427   'INSTALL_SRU'       => 'yes',
 428   'INSTALL_PAZPAR2'   => 'no',
 429   'AUTH_INDEX_MODE'   => 'dom',
 430   'BIB_INDEX_MODE'    => 'dom',
 431   'ZEBRA_MARC_FORMAT' => 'marc21',
 432   'ZEBRA_LANGUAGE'    => 'en',
 433   'ZEBRA_TOKENIZER'   => 'chr',
 434   'ZEBRA_USER'        => 'kohauser',
 435   'ZEBRA_PASS'        => 'zebrastripes',
 436   'ZEBRA_SRU_HOST'    => 'localhost',
 437   'ZEBRA_SRU_BIBLIOS_PORT'    => '9998',
 438   'ZEBRA_SRU_AUTHORITIES_PORT'    => '9999',
 439   'KOHA_USER'         => 'koha',
 440   'KOHA_GROUP'        => 'koha',
 441   'MERGE_SERVER_HOST' => 'localhost',
 442   'MERGE_SERVER_PORT' => '11001',
 443   'PAZPAR2_HOST' => 'localhost',
 444   'PAZPAR2_PORT' => '11002',
 445   'RUN_DATABASE_TESTS' => 'no',
 446   'PATH_TO_ZEBRA' => '',
 447   'USE_MEMCACHED'     => 'no',
 448   'MEMCACHED_SERVERS' => '127.0.0.1:11211',
 449   'MEMCACHED_NAMESPACE' => 'KOHA',
 450   'FONT_DIR'          => '/usr/share/fonts/truetype/ttf-dejavu'
 451 );
 452
 453 # set some default configuration options based on OS
 454 # more conditions need to be added for other OS's
 455
 456 warn "Your platform appears to be $^O.\n" if $DEBUG;
 457
 458 if ( $^O eq 'cygwin' ) {
 459         # Most Unix2Win32 ports seem to poke everything into the Program Files directory
 460         # this could be changed to put some files (ie. libraries) into system32, etc.
 461         $config_defaults{'INSTALL_MODE'} = 'single';
 462         $config_defaults{'INSTALL_BASE'} = 'c:/progra~1/koha';  # Use 8.3 names to be safe...
 463 }
 464 else {
 465         $config_defaults{'INSTALL_MODE'} = 'standard';
 466         $config_defaults{'INSTALL_BASE'} = '/usr/share/koha';
 467 }
 468
 469 # valid values for certain configuration options
 470 my %valid_config_values = (
 471   'INSTALL_MODE'  => { 'standard' => 1, 'single' => 1, 'dev' => 1 },
 472   'DB_TYPE' => { 'mysql' => 1, 'Pg' => 1 },
 473   'INSTALL_SRU' => { 'yes' => 1, 'no' => 1 },
 474   'AUTH_INDEX_MODE' => { 'grs1' => 1, 'dom' => 1 },
 475   'BIB_INDEX_MODE'  => { 'grs1' => 1, 'dom' => 1 },
 476   'ZEBRA_MARC_FORMAT' => { 'marc21' => 1, 'normarc' => 1, 'unimarc' => 1 }, # FIXME should generate from contents of distributation
 477   'ZEBRA_LANGUAGE'    => { 'en' => 1, 'es' => 1, 'fr' => 1, 'gr' => 1, 'nb' => 1, 'ru' => 1, 'uk' => 1 }, # FIXME should generate from contents of distribution
 478   'ZEBRA_TOKENIZER' => { chr => 1, icu => 1 },
 479   'RUN_DATABASE_TESTS' => { 'yes' => 1, 'no' => 1 },
 480   'USE_MEMCACHED'      => { 'yes' => 1, 'no' => 1 },
 481 );
 482
 483 # get settings from command-line
 484 my $koha_install_log = "";
 485 Getopt::Long::Configure('pass_through');
 486 my $results = GetOptions(
 487     "prev-install-log=s" => \$koha_install_log
 488 );
 489
 490 my %install_log_values = ();
 491 if ($koha_install_log ne "") {
 492     get_install_log_values($koha_install_log, \%install_log_values);
 493 }
 494
 495 my %config = get_configuration(\%config_defaults, \%valid_config_values, \%install_log_values);
 496 my ($target_directories, $skip_directories) = get_target_directories(\%config);
 497 display_configuration(\%config, $target_directories);
 498 my $file_map = {};
 499 get_file_map($target_map, $dirtree, $file_map);
 500
 501 my $pl_files = {
 502       'rewrite-config.PL' => [
 503          'blib/KOHA_CONF_DIR/koha-conf.xml',
 504          'blib/KOHA_CONF_DIR/koha-httpd.conf',
 505          'blib/ZEBRA_CONF_DIR/etc/default.idx',
 506          'blib/MISC_DIR/koha-install-log'
 507          ],
 508           'fix-perl-path.PL' => [       # this script ensures the correct shebang line for the platform installed on...
 509                  'blib'
 510                  ],
 511 };
 512
 513 push @{ $pl_files->{'rewrite-config.PL'} }, (
 514     'blib/ZEBRA_CONF_DIR/etc/passwd',
 515     'blib/ZEBRA_CONF_DIR/zebra-biblios.cfg',
 516     'blib/ZEBRA_CONF_DIR/zebra-biblios-dom.cfg',
 517     'blib/ZEBRA_CONF_DIR/zebra-authorities.cfg',
 518     'blib/ZEBRA_CONF_DIR/zebra-authorities-dom.cfg',
 519     'blib/ZEBRA_CONF_DIR/explain-authorities.xml',
 520     'blib/ZEBRA_CONF_DIR/explain-biblios.xml',
 521     'blib/ZEBRA_CONF_DIR/retrieval-info-auth-grs1.xml',
 522     'blib/ZEBRA_CONF_DIR/retrieval-info-auth-dom.xml',
 523     'blib/ZEBRA_CONF_DIR/retrieval-info-bib-grs1.xml',
 524     'blib/ZEBRA_CONF_DIR/retrieval-info-bib-dom.xml',
 525 );
 526 push @{ $pl_files->{'rewrite-config.PL'} }, (
 527     'blib/SCRIPT_DIR/koha-zebra-ctl.sh',
 528     'blib/SCRIPT_DIR/koha-pazpar2-ctl.sh',
 529     'blib/SCRIPT_DIR/koha-index-daemon-ctl.sh',
 530 );
 531 if ($config{'INSTALL_PAZPAR2'} eq 'yes') {
 532     push @{ $pl_files->{'rewrite-config.PL'} }, (
 533         'blib/PAZPAR2_CONF_DIR/koha-biblios.xml',
 534         'blib/PAZPAR2_CONF_DIR/pazpar2.xml'
 535     );
 536 }
 537 $config{'ZEBRA_AUTH_CFG'} = $config{'AUTH_INDEX_MODE'} eq 'dom'
 538                               ? 'zebra-authorities-dom.cfg'
 539                               : 'zebra-authorities.cfg';
 540 $config{'ZEBRA_BIB_CFG'}  = $config{'BIB_INDEX_MODE'} eq 'dom'
 541                               ? 'zebra-biblios-dom.cfg'
 542                               : 'zebra-biblios.cfg';
 543 $config{'AUTH_RETRIEVAL_CFG'} = $config{'AUTH_INDEX_MODE'} eq 'dom'
 544                                   ? 'retrieval-info-auth-dom.xml'
 545                                   : 'retrieval-info-auth-grs1.xml';
 546 $config{'BIB_RETRIEVAL_CFG'}  = $config{'BIB_INDEX_MODE'} eq 'dom'
 547                                   ? 'retrieval-info-bib-dom.xml'
 548                                   : 'retrieval-info-bib-grs1.xml';
 549
 550
 551 if ($config{'INSTALL_MODE'} ne "dev") {
 552     push @{ $pl_files->{'rewrite-config.PL'} }, (
 553         'blib/PERL_MODULE_DIR/C4/Context.pm',
 554         'blib/SCRIPT_NONDEV_DIR/kohalib.pl'
 555     );
 556 }
 557
 558 $config{ZEBRA_TOKENIZER_STMT} = $config{ZEBRA_TOKENIZER} eq 'icu'
 559     ? 'icuchain words-icu.xml'
 560     : 'charmap word-phrase-utf.chr';
 561
 562 $config{ZEBRA_PTOKENIZER_STMT} = $config{ZEBRA_TOKENIZER} eq 'icu'
 563     ? 'icuchain phrases-icu.xml'
 564     : 'charmap word-phrase-utf.chr';
 565
 566 my %test_suite_override_dirs = (
 567     KOHA_CONF_DIR  => ['etc'],
 568     ZEBRA_CONF_DIR => ['etc', 'zebradb'],
 569     LOG_DIR        => ['var', 'log'],
 570     BACKUP_DIR     => ['var', 'spool'],
 571     SCRIPT_DIR     => ['bin'],
 572     ZEBRA_LOCK_DIR => ['var', 'lock', 'zebradb'],
 573     ZEBRA_DATA_DIR => ['var', 'lib', 'zebradb'],
 574     ZEBRA_RUN_DIR  => ['var', 'run', 'zebradb'],
 575 );
 576
 577 WriteMakefile(
 578               NAME         => 'koha',
 579               #VERSION     => strftime('2.9.%Y%m%d%H',gmtime),
 580               VERSION_FROM => 'kohaversion.pl',
 581               ABSTRACT     => 'Award-winning integrated library system (ILS) and Web OPAC',
 582               AUTHOR       => 'Koha Contributors <http://koha-community.org/>',
 583               NO_META      => 1,
 584               PREREQ_PM    => $koha_pm->prereq_pm,
 585
 586               # File tree mapping
 587               PM => $file_map,
 588
 589               # Man pages generated from POD
 590               # ExtUtils::MakeMaker already manage $(DESTDIR)
 591               INSTALLMAN1DIR => File::Spec->catdir(_strip_destdir($target_directories->{'MAN_DIR'}), 'man1'),
 592               INSTALLMAN3DIR => File::Spec->catdir(_strip_destdir($target_directories->{'MAN_DIR'}), 'man3'),
 593
 594               PL_FILES => $pl_files,
 595 );
 596
 597 =head1 FUNCTIONS
 598
 599 =head2 hashdir
 600
 601 This function recurses through the directory structure and builds
 602 a hash of hashes containing the structure with arrays holding filenames.
 603 This directory hashing routine was taken from BrowserUK @ http://www.perlmonks.org/?node_id=219919
 604
 605 =cut
 606
 607 sub hashdir{
 608     my $dir = shift;
 609     opendir my $dh, $dir or die $!;
 610     my $tree = {}->{$dir} = {};
 611     while( my $file = readdir($dh) ) {
 612         next if $file =~ m/^\.{1,2}/ and $file !~ /^\.htaccess/; # .htaccess is a special case
 613         my $path = $dir .'/' . $file;
 614         $tree->{$file} = hashdir($path), next if -d $path;
 615         push @{$tree->{'.'}}, $file;
 616     }
 617     return $tree;
 618 }
 619
 620 =head2 get_file_map
 621
 622 This function combines the target_map and file hash to
 623 map each source file to its destination relative to
 624 the set of installation targets.
 625
 626 Output will be a hash mapping from each source file
 627 to its destination value, like this:
 628
 629 'mainpage.pl' => '$(INTRANET_CGI_DIR)/mainpage.pl'
 630
 631 =cut
 632
 633 sub get_file_map {
 634     my $target_map = shift;
 635     my $dirtree = shift;
 636     my $file_map = shift;
 637     my $curr_path = @_ ? shift : ['.'];
 638
 639     # Traverse the directory tree.
 640     # For each file or directory, identify the
 641     # most specific match in the target_map
 642     foreach my $dir (sort keys %{ $dirtree }) {
 643         if ($dir eq '.') {
 644             # deal with files in directory
 645             foreach my $file (sort @{ $dirtree->{$dir} }) {
 646                 my $targetdir = undef;
 647                 my $matchlevel = undef;
 648                 # first, see if there is a match on this specific
 649                 # file in the target map
 650                 my $filepath = join("/", @$curr_path, $file);
 651                 if (exists $target_map->{$filepath}) {
 652                     $targetdir = $target_map->{$filepath};
 653                     $matchlevel = scalar(@$curr_path) + 1;
 654                 } else {
 655                     # no match on the specific file; look for
 656                     # a directory match
 657                     for (my $i = scalar(@$curr_path) - 1; $i >= 0; $i--)  {
 658                         my $dirpath = join("/", @$curr_path[0..$i]);
 659                         if (exists $target_map->{$dirpath}) {
 660                             $targetdir = $target_map->{$dirpath};
 661                             $matchlevel = $i + 1;
 662                             last;
 663                         }
 664                     }
 665                 }
 666                 if (defined $targetdir) {
 667                      _add_to_file_map($file_map, $targetdir, $curr_path, $file, $matchlevel);
 668                 } else {
 669                     my $path = join("/", @$curr_path);
 670                     print "failed to map: $path/$file\n" if $DEBUG;
 671                 }
 672             }
 673         } else {
 674             # dealing with subdirectory
 675             push @$curr_path, $dir;
 676             get_file_map($target_map, $dirtree->{$dir}, $file_map, $curr_path);
 677             pop @$curr_path;
 678         }
 679     }
 680 }
 681
 682 sub _add_to_file_map {
 683     my $file_map = shift;
 684     my $targetdir = shift;
 685     my $curr_path = shift;
 686     my $file = shift;
 687     my $matchlevel = shift;
 688     my $dest_path = @_ ? shift : $curr_path;
 689
 690     # The target can be one of the following:
 691     # 1. scalar representing target symbol
 692     # 2. hash ref containing target and trimdir keys
 693     #
 694     # Consequently, this routine traverses this structure,
 695     # calling itself recursively, until it deals with
 696     # all of the scalar target symbols.
 697     if (ref $targetdir eq 'HASH') {
 698         my $subtarget = $targetdir->{target};
 699         if (exists $targetdir->{trimdir}) {
 700             # if we get here, we've specified that
 701             # rather than installing the file to
 702             # $(TARGET)/matching/dirs/subdirs/file,
 703             # we want to install it to
 704             # $(TARGET)/subdirs/file
 705             #
 706             # Note that this the only place where
 707             # $matchlevel is used.
 708             my @new_dest_path = @$dest_path;
 709             if ($targetdir->{trimdir} == -1)  {
 710                 splice @new_dest_path, 0, $matchlevel;
 711             } else {
 712                 splice @new_dest_path, 0, $targetdir->{trimdir};
 713             }
 714             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, \@new_dest_path);
 715         } else {
 716             # actually getting here means that the
 717             # target was unnecessarily listed
 718             # as a hash, but we'll forgive that
 719             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel);
 720         }
 721     } elsif ($targetdir ne 'NONE' and $targetdir ne '') {
 722         my $source = File::Spec->catfile(@$curr_path, $file);
 723         my $destination = File::Spec->catfile('blib', $targetdir, @$dest_path, $file);
 724         #print "$source => $destination\n"; # DEBUG
 725         # quote spaces in file names
 726         # FIXME: this is of questionable portability and
 727         # probably depends on user's make recognizing this
 728         # quoting syntax -- probably better to remove
 729         # spaces and shell metacharacters from all file names
 730         $source =~ s/ /\\ /g;
 731         $destination =~ s/ /\\ /g;
 732
 733         $file_map->{$source} = $destination;
 734     }
 735 }
 736
 737 =head2 get_install_log_values
 738
 739 Reads value from the Koha install log specified by
 740 --prev-install-log
 741
 742 =cut
 743
 744 sub get_install_log_values {
 745     my $install_log = shift;
 746     my $values = shift;
 747
 748     open LOG, "<$install_log" or die "Cannot open install log $install_log: $!\n";
 749     while (<LOG>) {
 750         chomp;
 751         next if /^#/ or /^\s*$/;
 752         next if /^=/;
 753         next unless m/=/;
 754         s/\s+$//g;
 755         my ($key, $value) = split /=/, $_, 2;
 756         $values->{$key} = $value;
 757     }
 758     close LOG;
 759
 760     print <<_EXPLAIN_INSTALL_LOG_;
 761 Reading values from install log $install_log.  You
 762 will be prompted only for settings that have been
 763 added since the last time you installed Koha.  To
 764 be prompted for all settings, run 'perl Makefile.PL'
 765 without the --prev-install-log option.
 766 _EXPLAIN_INSTALL_LOG_
 767 }
 768
 769 =head2 get_configuration
 770
 771 This prompts the user for various configuration options.
 772
 773 =cut
 774
 775 sub get_configuration {
 776   my $defaults = shift;
 777   my $valid_values = shift;
 778   my $install_log_values = shift;
 779   my %config = ();
 780
 781   my $msg = q(
 782 By default, Koha can be installed in one of three ways:
 783
 784 standard: Install files in conformance with the Filesystem
 785           Hierarchy Standard (FHS).  This is the default mode
 786           and should be used when installing a production
 787           Koha system.  On Unix systems, root access is
 788           needed to complete a standard installation.
 789
 790 single:   Install files under a single directory.  This option
 791           is useful for installing Koha without root access, e.g.,
 792           on a web host that allows CGI scripts and MySQL databases
 793           but requires the user to keep all files under the user's
 794           HOME directory.
 795
 796 dev:      Create a set of symbolic links and configuration files to
 797           allow Koha to run directly from the source distribution.
 798           This mode is useful for developers who want to run
 799           Koha from a git clone.
 800
 801 Installation mode);
 802     $msg .= _add_valid_values_disp('INSTALL_MODE', $valid_values);
 803     $config{'INSTALL_MODE'} = _get_value('INSTALL_MODE', $msg, $defaults->{'INSTALL_MODE'}, $valid_values, $install_log_values);
 804
 805     # set message and default value for INSTALL_BASE
 806     # depending on value of INSTALL_MODE
 807     my $install_base_default = $defaults->{'INSTALL_BASE'};
 808     if ($config{'INSTALL_MODE'} eq 'dev') {
 809         $msg = q(
 810 Please specify the directory in which to install Koha's
 811 active configuration files and (if applicable) the
 812 Zebra database.  Koha's CGI scripts and templates will
 813 be run from the current directory.
 814
 815 Configuration directory:);
 816         # FIXME - home directory portability consideration apply
 817         $install_base_default =
 818             $ENV{DESTDIR}
 819             || ( exists $ENV{HOME} ? "$ENV{HOME}/koha-dev" : "$defaults->{'INSTALL_BASE'}-dev" )
 820         ;
 821     } elsif ($config{'INSTALL_MODE'} eq 'single') {
 822         $msg = "\nPlease specify the directory in which to install Koha";
 823         # FIXME -- we're assuming under a 'single' mode install
 824         # that user will likely want to install under the home
 825         # directory.  This is OK in and of itself, but we should
 826         # use File::HomeDir to locate the home directory portably.
 827         # This is deferred for now because File::HomeDir is not yet
 828         # core.
 829                 # --we must also keep this portable to the major OS's -fbcit
 830         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha" : $defaults->{'INSTALL_BASE'};
 831     } else {
 832         # must be standard
 833         $msg = q(
 834 Please specify the directory under which most Koha files
 835 will be installed.
 836
 837 Note that if you are planning in installing more than
 838 one instance of Koha, you may want to modify the last
 839 component of the directory path, which will be used
 840 as the package name in the FHS layout.
 841
 842 Base installation directory);
 843     }
 844     $config{'INSTALL_BASE'} = _get_value('INSTALL_BASE', $msg, $install_base_default, $valid_values, $install_log_values);
 845
 846     $config{'INSTALL_BASE'} = File::Spec->rel2abs($config{'INSTALL_BASE'});
 847         print "INSTALL_BASE=$config{'INSTALL_BASE'}\r\n" if $DEBUG;
 848     if ($config{'INSTALL_MODE'} eq "standard") {
 849         $msg = q(
 850 Since you are using the 'standard' install
 851 mode, you should run 'make install' as root.
 852 However, it is recommended that a non-root
 853 user (on Unix and Linux platforms) have
 854 ownership of Koha's files, including the
 855 Zebra indexes if applicable.
 856
 857 Please specify a user account.  This
 858 user account does not need to exist
 859 right now, but it needs to exist
 860 before you run 'make install'.  Please
 861 note that for security reasons, this
 862 user should not be the same as the user
 863 account Apache runs under.
 864
 865 User account);
 866         $config{'KOHA_USER'} = _get_value('KOHA_USER', $msg, $defaults->{'KOHA_USER'}, $valid_values, $install_log_values);
 867
 868         $msg = q(
 869 Please specify the group that should own
 870 Koha's files.  As above, this group need
 871 not exist right now, but should be created
 872 before you run 'make install'.
 873
 874 Group);
 875         $config{'KOHA_GROUP'} = _get_value('KOHA_GROUP', $msg, $defaults->{'KOHA_GROUP'}, $valid_values, $install_log_values);
 876     }
 877
 878     $msg = q(
 879 Please specify which database engine you will use
 880 to store data in Koha.  The choices are MySQL and
 881 PostgreSQL; please note that at the moment
 882 PostgreSQL support is highly experimental.
 883
 884 DBMS to use);
 885     $msg .= _add_valid_values_disp('DB_TYPE', $valid_values);
 886     $config{'DB_TYPE'} = _get_value('DB_TYPE', $msg, $defaults->{'DB_TYPE'}, $valid_values, $install_log_values);
 887
 888     $msg = q(
 889 Please specify the name or address of your
 890 database server.  Note that the database
 891 does not have to exist at this point, it
 892 can be created after running 'make install'
 893 and before you try using Koha for the first time.
 894
 895 Database server);
 896     $config{'DB_HOST'} = _get_value('DB_HOST', $msg, $defaults->{'DB_HOST'}, $valid_values, $install_log_values);
 897
 898     $msg = q(
 899 Please specify the port used to connect to the
 900 DMBS);
 901     my $db_port_default = $config{'DB_TYPE'} eq 'mysql' ? '3306' : '5432';
 902     $config{'DB_PORT'} = _get_value('DB_PORT', $msg, $db_port_default, $valid_values, $install_log_values);
 903
 904     $msg = q(
 905 Please specify the name of the database to be
 906 used by Koha);
 907     $config{'DB_NAME'} = _get_value('DB_NAME', $msg, $defaults->{'DB_NAME'}, $valid_values, $install_log_values);
 908
 909     $msg = q(
 910 Please specify the user that owns the database to be
 911 used by Koha);
 912     $config{'DB_USER'} = _get_value('DB_USER', $msg, $defaults->{'DB_USER'}, $valid_values, $install_log_values);
 913
 914     $msg = q(
 915 Please specify the password of the user that owns the
 916 database to be used by Koha);
 917     $config{'DB_PASS'} = _get_value('DB_PASS', $msg, $defaults->{'DB_PASS'}, $valid_values, $install_log_values);
 918
 919     print q(
 920 Koha uses the Zebra search engine for high-performance
 921 searching of bibliographic and authority records.  Checking
 922 to see if you have installed the Zebra software...
 923 );
 924
 925     if (defined(my $zebra_path = find_zebra())) {
 926         $config{'PATH_TO_ZEBRA'} = $zebra_path;
 927         print qq(
 928 Found 'zebrasrv' and 'zebraidx' in $zebra_path.
 929 );
 930     } else {
 931         print q(
 932 Unable to find the Zebra programs 'zebrasrv' and 'zebraidx'
 933 in your PATH or in some of the usual places.  If you haven't
 934 installed Zebra yet, please do so and run Makefile.PL again.
 935
 936 );
 937     }
 938
 939     $msg = q(
 940 You must specify the primary MARC format of the
 941 records to be indexed by Zebra.
 942
 943 Koha provides Zebra configuration files for MARC21,
 944 NORMARC and UNIMARC.
 945
 946 MARC format for Zebra indexing);
 947     $msg .= _add_valid_values_disp('ZEBRA_MARC_FORMAT', $valid_values);
 948     $config{'ZEBRA_MARC_FORMAT'} = _get_value('ZEBRA_MARC_FORMAT', $msg, $defaults->{'ZEBRA_MARC_FORMAT'}, $valid_values, $install_log_values);
 949     $msg = q(
 950 Koha supplies Zebra configuration files tuned for
 951 searching either English (en) or French (fr) MARC
 952 records.
 953
 954 Primary language for Zebra indexing);
 955     $msg .= _add_valid_values_disp('ZEBRA_LANGUAGE', $valid_values);
 956     $config{'ZEBRA_LANGUAGE'} = _get_value('ZEBRA_LANGUAGE', $msg, $defaults->{'ZEBRA_LANGUAGE'}, $valid_values, $install_log_values);
 957
 958     $msg = q(
 959 Koha can use one of  two different indexing modes
 960 for the MARC bibliographic records:
 961
 962 dom  - uses the DOM XML filter; offers improved
 963        functionality.
 964 grs1 - [DEPRECATED] uses the Zebra GRS-1 filter,
 965        available for legacy support
 966
 967 Bibliographic indexing mode);
 968     $msg .= _add_valid_values_disp('BIB_INDEX_MODE', $valid_values);
 969     $config{'BIB_INDEX_MODE'} = _get_value('BIB_INDEX_MODE', $msg, $defaults->{'BIB_INDEX_MODE'}, $valid_values, $install_log_values);
 970
 971
 972     $msg = q(
 973 Koha can use one of  two different indexing modes
 974 for the MARC authorities records:
 975
 976 dom  - uses the DOM XML filter; offers improved
 977        functionality.
 978 grs1 - [DEPRECATED] uses the Zebra GRS-1 filter,
 979        available for legacy support
 980
 981 Authorities indexing mode);
 982     $msg .= _add_valid_values_disp('AUTH_INDEX_MODE', $valid_values);
 983     $config{'AUTH_INDEX_MODE'} = _get_value('AUTH_INDEX_MODE', $msg, $defaults->{'AUTH_INDEX_MODE'}, $valid_values, $install_log_values);
 984
 985     $msg = q(
 986 Zebra has two methods to perform records tokenization
 987 and characters normalization: CHR and ICU. ICU is
 988 recommended for catalogs containing non-Latin
 989 characters.);
 990
 991     $msg .= _add_valid_values_disp('ZEBRA_TOKENIZER', $valid_values);
 992     $config{'ZEBRA_TOKENIZER'} = _get_value('ZEBRA_TOKENIZER', $msg, $defaults->{'ZEBRA_TOKENIZER'}, $valid_values, $install_log_values);
 993
 994     $msg = q(
 995 Please specify Zebra database user);
 996     $config{'ZEBRA_USER'} = _get_value('ZEBRA_USER', $msg, $defaults->{'ZEBRA_USER'}, $valid_values, $install_log_values);
 997
 998     $msg = q(
 999 Please specify the Zebra database password);
1000     $config{'ZEBRA_PASS'} = _get_value('ZEBRA_PASS', $msg, $defaults->{'ZEBRA_PASS'}, $valid_values, $install_log_values);
1001
1002     $msg = q(
1003 Since you've chosen to use Zebra, you can enable the SRU/
1004 Z39.50 Server if you so choose, but you must specify a
1005 few configuration options for it.
1006
1007 Please note that if you choose *NOT* to configure SRU,
1008 koha-conf.xml will still contain some references to SRU
1009 settings.  Those references will be ignored by Koha.
1010
1011 Install the SRU configuration files?);
1012     $msg .= _add_valid_values_disp('INSTALL_SRU', $valid_values);
1013     $config{'INSTALL_SRU'} = _get_value('INSTALL_SRU', $msg, $defaults->{'INSTALL_SRU'}, $valid_values, $install_log_values);
1014
1015     if ($config{'INSTALL_SRU'} eq 'yes') {
1016         $msg = q(
1017 Since you've chosen to configure SRU, you must
1018 specify the host and port(s) that the SRU
1019 Servers (bibliographic and authority) should run on.
1020 );
1021         $msg = q(
1022 SRU Database host?);
1023         $config{'ZEBRA_SRU_HOST'} = _get_value('ZEBRA_SRU_HOST', $msg, $defaults->{'ZEBRA_SRU_HOST'}, $valid_values, $install_log_values);
1024
1025         $msg = q(
1026 SRU port for bibliographic data?);
1027         $config{'ZEBRA_SRU_BIBLIOS_PORT'} = _get_value('ZEBRA_SRU_BIBLIOS_PORT', $msg, $defaults->{'ZEBRA_SRU_BIBLIOS_PORT'}, $valid_values, $install_log_values);
1028
1029         $msg = q(
1030 SRU port for authority data?);
1031         $config{'ZEBRA_SRU_AUTHORITIES_PORT'} = _get_value('ZEBRA_SRU_AUTHORITIES_PORT', $msg, $defaults->{'ZEBRA_SRU_AUTHORITIES_PORT'}, $valid_values, $install_log_values);
1032
1033     }
1034
1035     $msg = q(
1036 Along with Zebra, you can also choose to install PazPar2,
1037 which is a metasearch tool.  With PazPar2,
1038 Koha can perform on-the-fly merging of bibliographic
1039 records during searching, allowing for FRBRization of
1040 the results list.
1041
1042 Install the PazPar2 configuration files?);
1043     $msg .= _add_valid_values_disp('INSTALL_PAZPAR2', $valid_values);
1044     $config{'INSTALL_PAZPAR2'} = _get_value('INSTALL_PAZPAR2', $msg, $defaults->{'INSTALL_PAZPAR2'}, $valid_values, $install_log_values);
1045
1046     if ($config{'INSTALL_PAZPAR2'} eq 'yes') {
1047         $msg = q(
1048 Since you've chosen to configure PazPar2, you must
1049 specify the host and port(s) that PazPar2
1050 uses:
1051 );
1052         $msg = q(
1053 Zebra bibliographic server host?);
1054         $config{'MERGE_SERVER_HOST'} = _get_value('MERGE_SERVER_HOST', $msg, $defaults->{'MERGE_SERVER_HOST'}, $valid_values, $install_log_values);
1055
1056         $msg = q(
1057 Zebra bibliographic port for PazPar2 to use?);
1058         $config{'MERGE_SERVER_PORT'} = _get_value('MERGE_SERVER_PORT', $msg, $defaults->{'MERGE_SERVER_PORT'}, $valid_values, $install_log_values);
1059
1060         $msg = q(
1061 PazPar2 host?);
1062         $config{'PAZPAR2_HOST'} = _get_value('PAZPAR2_HOST', $msg, $defaults->{'PAZPAR2_HOST'}, $valid_values, $install_log_values);
1063
1064         $msg = q(
1065 PazPar2 port?);
1066         $config{'PAZPAR2_PORT'} = _get_value('PAZPAR2_PORT', $msg, $defaults->{'PAZPAR2_PORT'}, $valid_values, $install_log_values);
1067
1068     }
1069
1070   $msg = q(
1071 Use memcached and memoize to cache the results of some function calls?
1072 This provides a signficant performance improvement.
1073 You will need a Memcached server running.);
1074   $msg .= _add_valid_values_disp('USE_MEMCACHED', $valid_values);
1075   $config{'USE_MEMCACHED'} = _get_value('USE_MEMCACHED', $msg, $defaults->{'USE_MEMCACHED'}, $valid_values, $install_log_values);
1076   if ($config{'USE_MEMCACHED'} eq 'yes'){
1077       $msg = q(
1078 Since you've chosen to use caching, you must specify the memcached servers and the namespace to use:
1079 );
1080       $msg = q(
1081 Memcached server address?);
1082       $config{'MEMCACHED_SERVERS'} = _get_value('MEMCACHED_SERVERS', $msg, $defaults->{'MEMCACHED_SERVERS'}, $valid_values, $install_log_values);
1083
1084       $msg = q(
1085 Memcached namespace?);
1086       $config{'MEMCACHED_NAMESPACE'} = _get_value('MEMCACHED_NAMESPACE', $msg, $defaults->{'MEMCACHED_NAMESPACE'}, $valid_values, $install_log_values);
1087   }
1088
1089   $msg = q(
1090 Path to DejaVu fonts?);
1091   $config{'FONT_DIR'} = _get_value('FONT_DIR', $msg, $defaults->{'FONT_DIR'}, $valid_values, $install_log_values);
1092
1093
1094   $msg = q(
1095 Would you like to run the database-dependent test suite?);
1096   $msg .= _add_valid_values_disp( 'RUN_DATABASE_TESTS', $valid_values );
1097     $config{'RUN_DATABASE_TESTS'} = _get_value( 'RUN_DATABASE_TESTS', $msg, $defaults->{'RUN_DATABASE_TESTS'}, $valid_values, $install_log_values );
1098
1099   if ( $config{'RUN_DATABASE_TESTS'} eq 'yes' ) {
1100       $config{'TEST_DB_TYPE'} = $config{'DB_TYPE'};
1101       $config{'TEST_DB_HOST'} = $config{'DB_HOST'};
1102       $msg = q(TEST DATABASE
1103
1104 THE DATA IN THIS DATABASE WILL BE DESTROYED during the process of
1105 testing. Please don't do this on your production database. It is not
1106 reversable.
1107
1108 YOU WILL SUFFER DATA LOSS if you run this test suite on your test
1109 database. You are better off not running this optional test suite than
1110 doing it in a database that you don't want to lose.
1111
1112 Please specify the name of the test database to be
1113 used by Koha);
1114
1115       $config{'TEST_DB_NAME'} = _get_value('TEST_DB_NAME', $msg, $defaults->{'TEST_DB_NAME'}, $valid_values, $install_log_values);
1116       while ( $config{'TEST_DB_NAME'} eq $config{'DB_NAME'} ) {
1117           $msg = q(Please do not use the same database for testing as you do for production. You run the severe risk of data loss.);
1118           $config{'TEST_DB_NAME'} = _get_value('TEST_DB_NAME', $msg, $defaults->{'TEST_DB_NAME'}, $valid_values, $install_log_values);
1119       }
1120
1121       $msg = q(
1122 Please specify the user that owns the database to be
1123 used by Koha);
1124     $config{'TEST_DB_USER'} = _get_value('TEST_DB_USER', $msg, $defaults->{'TEST_DB_USER'}, $valid_values, $install_log_values);
1125
1126       $msg = q(
1127 Please specify the password of the user that owns the
1128 database to be used by Koha);
1129       $config{'TEST_DB_PASS'} = _get_value('TEST_DB_PASS', $msg, $defaults->{'TEST_DB_PASS'}, $valid_values, $install_log_values);
1130   }
1131
1132     print "\n\n";
1133
1134     # add version number
1135     my $version = "no_version_found";
1136     eval {
1137         require 'kohaversion.pl';
1138         $version = kohaversion();
1139     };
1140     $config{'KOHA_INSTALLED_VERSION'} = $version;
1141
1142     return %config;
1143 }
1144
1145 sub _add_valid_values_disp {
1146     my $key = shift;
1147     my $valid_values = shift;
1148
1149     my $disp = "";
1150     if (exists $valid_values->{$key}) {
1151         $disp = " (" . join(", ", sort keys %{ $valid_values->{$key} }) . ")";
1152     }
1153     return $disp;
1154 }
1155
1156 sub _get_value {
1157     my $key = shift;
1158     my $msg = shift;
1159     my $default = shift;
1160     my $valid_values = shift;
1161     my $install_log_values = shift;
1162
1163     # take value from install log if present
1164     if (exists $install_log_values{$key}) {
1165         $install_log_values{$key} =~ s/\$/\$\$/g;
1166         return $install_log_values{$key};
1167     }
1168
1169     # override default value from environment
1170     if (exists $ENV{$key}) {
1171         $default = $ENV{$key};
1172         $msg .= " (default from environment)";
1173     }
1174
1175     my $val = prompt($msg, $default);
1176
1177     while (exists $valid_values->{$key} and
1178            $val ne $default and
1179            not exists $valid_values->{$key}->{$val}) {
1180         my $retry_msg = "Value '$val' is not a valid option.\n";
1181         $retry_msg .= "Please enter a value";
1182         $retry_msg .= _add_valid_values_disp($key, $valid_values);
1183         $val = prompt($retry_msg, $default);
1184     }
1185     $val =~ s/\$/\$\$/g;
1186     return $val;
1187 }
1188
1189 =head2 get_target_directories
1190
1191 Creates a hash mapping from symbols for installation target
1192 directories to actual directory paths.
1193
1194 Also returns a hash indicating targets for which
1195 files need not be copied -- this is used for the 'dev'
1196 mode installation, where some files are installed in place.
1197
1198 =cut
1199
1200 sub get_target_directories {
1201     my $config = shift;
1202
1203     my $base = $config->{'INSTALL_BASE'};
1204     my $mode = $config->{'INSTALL_MODE'};
1205
1206     # get last component of install base directory
1207     # to treat as package name
1208     my ($volume, $directories, $file) = File::Spec->splitpath($base, 1);
1209
1210     my @basedir = File::Spec->splitdir($directories);
1211
1212     if ( $^O eq 'cygwin' ) { shift @basedir; unshift @basedir, 'c:'; }   # in a cygwin environment, $volume is returned empty
1213
1214     my $package = pop @basedir;
1215
1216
1217     my %dirmap = ();
1218     my %skipdirs = ();
1219     if ($mode eq 'single') {
1220         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
1221         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
1222         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
1223         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
1224         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
1225         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
1226         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1227         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
1228         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
1229         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'pazpar2');
1230         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1231         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1232         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1233         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1234         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1235         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
1236         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
1237         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'spool');
1238         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'koha', 'plugins');
1239         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
1240         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
1241     } elsif ($mode eq 'dev') {
1242         my $curdir = File::Spec->rel2abs(File::Spec->curdir());
1243         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir($curdir);
1244         $skipdirs{'INTRANET_CGI_DIR'} = 1;
1245         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
1246         $skipdirs{'INTRANET_TMPL_DIR'} = 1;
1247         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
1248         $skipdirs{'INTRANET_WWW_DIR'} = 1;
1249         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir($curdir);
1250         $skipdirs{'OPAC_CGI_DIR'} = 1;
1251         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
1252         $skipdirs{'OPAC_TMPL_DIR'} = 1;
1253         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
1254         $skipdirs{'OPAC_WWW_DIR'} = 1;
1255         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir($curdir);
1256         $skipdirs{'PERL_MODULE_DIR'} = 1;
1257         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
1258         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
1259         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'pazpar2');
1260         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1261         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1262         #For dev install, point NONDEV_DIR to misc in current dir (not base)
1263         #Used by supportdir in koha-conf.xml (BZ 12031)
1264         $dirmap{'SCRIPT_NONDEV_DIR'} = File::Spec->catdir($curdir, 'misc');
1265         $skipdirs{'SCRIPT_NONDEV_DIR'} = 1;
1266         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1267         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1268         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
1269         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
1270         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'spool');
1271         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'plugins');
1272         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
1273         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
1274     } else {
1275         # mode is standard, i.e., 'fhs'
1276         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
1277         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
1278         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
1279         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
1280         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
1281         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
1282         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1283         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package);
1284         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'zebradb');
1285         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'pazpar2');
1286         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1287         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1288         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1289         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1290         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1291         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package, 'zebradb');
1292         $dirmap{'LOG_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'log', $package);
1293         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'spool', $package);
1294         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'plugins');
1295         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'zebradb');
1296         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'run', $package, 'zebradb');
1297     }
1298
1299     _get_env_overrides(\%dirmap);
1300     _get_argv_overrides(\%dirmap);
1301     _add_destdir(\%dirmap);
1302
1303     return \%dirmap, \%skipdirs;
1304 }
1305
1306 =head2 get_test_dir
1307
1308 Map a directory target to the corresponding path for
1309 the test suite.
1310
1311 =cut
1312
1313 sub get_test_dir {
1314     my ($dirname) = @_;
1315
1316     my @basedir = (File::Spec->rel2abs(File::Spec->curdir()), 't', 'run');
1317     if (exists $test_suite_override_dirs{$dirname}) {
1318         return File::Spec->catdir(@basedir, @{ $test_suite_override_dirs{$dirname} });
1319     } else {
1320         return;
1321     }
1322
1323 }
1324
1325 sub _get_env_overrides {
1326     my $dirmap = shift;
1327
1328     foreach my $key (keys %$dirmap) {
1329         if (exists $ENV{$key}) {
1330             $dirmap->{$key} = $ENV{$key};
1331             print "Setting $key from environment\n";
1332         }
1333     }
1334 }
1335
1336 sub _get_argv_overrides {
1337     my $dirmap = shift;
1338
1339     my @new_argv = ();
1340     for (my $i = 0; $i <= $#ARGV; $i++) {
1341         if ($ARGV[$i] =~ /^([^=]+)=([^=]+)$/ and exists $dirmap->{$1}) {
1342             $dirmap->{$1} = $2;
1343         } else {
1344             push @new_argv, $ARGV[$i];
1345         }
1346     }
1347     @ARGV = @new_argv;
1348 }
1349
1350 sub _strip_destdir {
1351     my $dir = shift;
1352     $dir =~ s/^\$\(DESTDIR\)//;
1353     return $dir;
1354 }
1355
1356 sub _add_destdir {
1357     my $dirmap = shift;
1358
1359     foreach my $key (keys %$dirmap) {
1360         $dirmap->{$key} = '$(DESTDIR)'.$dirmap->{$key};
1361     }
1362 }
1363
1364 sub display_configuration {
1365     my $config = shift;
1366     my $dirmap = shift;
1367     my @version = grep /\/usr\/share\/perl\//, @INC;
1368     push @version, ('/usr/share/perl/5.10') if !$version[0];
1369     print "\n\nKoha will be installed with the following configuration parameters:\n\n";
1370     foreach my $key (sort keys %$config) {
1371         print sprintf("%-25.25s%s\n", $key, $config->{$key});
1372     }
1373
1374     print "\nand in the following directories:\n\n";
1375     foreach my $key (sort keys %$dirmap) {
1376         print sprintf("%-25.25s%s\n", $key, $dirmap->{$key});
1377     }
1378     print "\n\nTo change any configuration setting, please run\n";
1379     print "perl Makefile.PL again.  To override one of the target\n";
1380     print "directories, you can do so on the command line like this:\n";
1381     print "\nperl Makefile.PL PERL_MODULE_DIR=$version[0]\n\n";
1382     print "You can also set different default values for parameters\n";
1383     print "or override directory locations by using environment variables.\n";
1384     print "\nFor example:\n\n";
1385     print "export DB_USER=my_koha\n";
1386     print "perl Makefile.PL\n";
1387     print "\nor\n\n";
1388     print "DB_USER=my_koha DOC_DIR=/usr/local/info perl Makefile.PL\n\n";
1389 }
1390
1391 =head2 find_zebra
1392
1393 Attempt to find Zebra - check user's PATH and
1394 a few other directories for zebrasrv and zebraidx.
1395
1396 =cut
1397
1398 sub find_zebra {
1399     my @search_dirs = map {
1400                             my $abs = File::Spec->rel2abs($_);
1401                             my ($toss, $directories);
1402                             ($toss, $directories, $toss) = File::Spec->splitpath($abs, 1);
1403                             $directories;
1404                         }  split /:/, $ENV{PATH};
1405     push @search_dirs, qw(/usr/local/bin /opt/local/bin /usr/bin);
1406     my @zebrasrv_dirs = grep { -x File::Spec->catpath('', $_, 'zebrasrv') } @search_dirs;
1407     return unless @zebrasrv_dirs;
1408     # verify that directory that contains zebrasrv also contains zebraidx
1409     foreach my $dir (@zebrasrv_dirs) {
1410         return $dir if -x File::Spec->catpath('', $dir, 'zebraidx');
1411     }
1412     return;
1413 }
1414
1415 package MY;
1416
1417 sub test {
1418     my $self = shift;
1419     my $test = $self->SUPER::test(@_);
1420     $test =~ s!\$\(INST_LIB\)!blib/PERL_MODULE_DIR!g;
1421
1422     # set KOHA_CONF
1423     $test =~ s!\$\(FULLPERLRUN\)!KOHA_CONF=blib/KOHA_CONF_DIR/koha-conf.xml \$(FULLPERLRUN)!g;
1424     return $test;
1425 }
1426
1427 sub install {
1428     my $self = shift;
1429     my $install = "";
1430     # NOTE: we're *not* doing this: my $install = $self->SUPER::install(@_);
1431     # This means that we're completely overriding EU::MM's default
1432     # installation and uninstallation targets.
1433
1434 # If installation is on Win32, we need to do permissions different from *nix
1435     if ( $^O =~ /darwin|linux|cygwin|freebsd|solaris/ ) { # this value needs to be verified for each platform and modified accordingly
1436             foreach my $key (sort keys %$target_directories) {
1437                     $install .= qq(
1438 KOHA_INST_$key = blib/$key
1439 KOHA_DEST_$key = $target_directories->{$key}
1440 ) unless exists $skip_directories->{$key};
1441                 }
1442                 $install .= qq(
1443 install :: all install_koha set_koha_ownership set_koha_permissions warn_koha_env_vars
1444 \t\$(NOECHO) \$(NOOP)
1445 );
1446                         $install .= "install_koha ::\n";
1447                         $install .= "\t\$(NOECHO) umask 022; \$(MOD_INSTALL) \\\n";
1448                         foreach my $key (sort keys %$target_directories) {
1449                                 $install .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1450           unless exists $skip_directories->{$key};
1451                         }
1452                         $install .= "\t\t\$(INST_MAN1DIR) \$(DESTINSTALLMAN1DIR) \\\n";
1453                         $install .= "\t\t\$(INST_MAN3DIR) \$(DESTINSTALLMAN3DIR)\n";
1454
1455                         $install .= "\n";
1456                         $install .= "set_koha_ownership ::\n";
1457 # Do not try to change ownership if DESTDIR is set
1458                         if ($config{'INSTALL_MODE'} eq 'standard' and $config{'KOHA_USER'} ne "root") {
1459                                 foreach my $key (sort keys %$target_directories) {
1460             $install .= "\t\$(NOECHO) if test -z \"\$(DESTDIR)\"; then chown -R $config{'KOHA_USER'}:$config{'KOHA_GROUP'} \$(KOHA_DEST_$key); fi\n"
1461             unless exists $skip_directories->{$key};
1462                                 }
1463                         } else {
1464                                 $install .= "\t\t\$(NOECHO) \$(NOOP)\n\n";
1465                         }
1466
1467                         $install .= "\n";
1468                         $install .= "set_koha_permissions ::\n";
1469                         # This is necessary because EU::MM installs files
1470                         # as either 0444 or 0555, and we want the owner
1471                         # of Koha's files to have write permission by default.
1472                         foreach my $key (sort keys %$target_directories) {
1473                                 $install .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_$key)\n"
1474           unless exists $skip_directories->{$key};
1475                         }
1476         }
1477
1478         $install .= "\n";
1479
1480     $install .= "warn_koha_env_vars ::\n";
1481     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1482     $install .= "\t\$(NOECHO) \$(ECHO) Koha\\'s files have now been installed. \n";
1483     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1484     $install .= "\t\$(NOECHO) \$(ECHO) In order to use Koha\\'s command-line batch jobs,\n";
1485     $install .= "\t\$(NOECHO) \$(ECHO) you should set the following environment variables:\n";
1486     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1487     $install .= "\t\$(NOECHO) \$(ECHO) export KOHA_CONF=\$(KOHA_DEST_KOHA_CONF_DIR)/koha-conf.xml\n";
1488     $install .= "\t\$(NOECHO) \$(ECHO) export PERL5LIB=$target_directories->{'PERL_MODULE_DIR'}\n";
1489     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1490     $install .= "\t\$(NOECHO) \$(ECHO) For other post-installation tasks, please consult the README.\n";
1491     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1492
1493     $install .= _update_zebra_conf_target();
1494
1495     $install .= upgrade();
1496
1497     return $install;
1498 }
1499
1500 =head2 _update_zebra_conf_target
1501
1502 Add an installation target for updating
1503 Zebra's configuration files.
1504
1505 =cut
1506
1507 sub _update_zebra_conf_target {
1508
1509     my $target = "\nupdate_zebra_conf ::\n";
1510     $target .= "\tumask 022; \$(MOD_INSTALL) \\\n";
1511     $target .= "\t\t\$(KOHA_INST_ZEBRA_CONF_DIR) \$(KOHA_DEST_ZEBRA_CONF_DIR) \n";
1512     $target .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_ZEBRA_CONF_DIR)\n";
1513     $target .= "\tumask 022; \$(MOD_INSTALL) \\\n";
1514     $target .= "\t\t\$(KOHA_INST_PAZPAR2_CONF_DIR) \$(KOHA_DEST_PAZPAR2_CONF_DIR) \n";
1515     $target .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_PAZPAR2_CONF_DIR)\n";
1516
1517     return $target;
1518 }
1519
1520 sub upgrade {
1521     my $upgrade = "";
1522
1523     my $backup_suffix;
1524     if (exists $install_log_values{'KOHA_INSTALLED_VERSION'}) {
1525         my $version = $install_log_values{'KOHA_INSTALLED_VERSION'};
1526         $version =~ s/\./_/g;
1527         $backup_suffix = "_koha_$version";
1528     } else {
1529         $backup_suffix = "_upgrade_backup";
1530     }
1531
1532     $upgrade .= qq/
1533 MOD_BACKUP = \$(ABSPERLRUN) -Minstall_misc::UpgradeBackup -e 'backup_changed_files({\@ARGV}, '$backup_suffix', '\''\$(VERBINST)'\'', '\''\$(UNINST)'\'');' --
1534
1535 upgrade :: make_upgrade_backup install
1536 \t\$(NOECHO) \$(NOOP)
1537 make_upgrade_backup ::
1538 \t\$(NOECHO) umask 022; \$(MOD_BACKUP) \\
1539 /;
1540     foreach my $key (qw/KOHA_CONF_DIR INTRANET_TMPL_DIR INTRANET_WWW_DIR OPAC_TMPL_DIR OPAC_WWW_DIR
1541                      PAZPAR2_CONF_DIR ZEBRA_CONF_DIR PLUGINS_DIR/) {
1542         $upgrade .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1543             unless exists $skip_directories->{$key} or
1544                    not exists $target_directories->{$key};
1545     }
1546     $upgrade =~ s/\\\n$/\n/;
1547
1548     return $upgrade;
1549 }
1550 sub postamble {
1551     # put directory mappings into Makefile
1552     # so that Make will export as environment
1553     # variables -- this is for the use of
1554     # rewrite-confg.PL
1555
1556     my $env;
1557         # Hereagain, we must alter syntax per platform...
1558         {
1559                 $env = join("\n", map { "export __${_}__ := $target_directories->{$_}" } keys %$target_directories);
1560                 $env .= "\n\n";
1561                 $env .= join("\n", map { "export __${_}__ := $config{$_}" } keys %config);
1562         }
1563
1564     return "$env\n";
1565 }
1566
1567
1568 __END__
1569
1570
1571 =head1 SEE ALSO
1572
1573 ExtUtils::MakeMaker(3)
1574
1575 =head1 AUTHORS
1576
1577 MJ Ray mjr at phonecoop.coop
1578 Galen Charlton galen.charlton at liblime.com
1579
1580 =cut
1581
1582 FIXME: deal with .htaccess