opac/opac-ics.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2007 Liblime Ltd
   4
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 # This script builds an ICalendar file (rfc 2445) for use in programs such as Ical
  21
  22 use Modern::Perl;
  23
  24 use CGI qw ( -utf8 );
  25 use Data::ICal;
  26 use Data::ICal::Entry::Event;
  27 use DateTime;
  28 use DateTime::Format::ICal;
  29 use DateTime::Event::ICal;
  30 use URI;
  31
  32 use C4::Auth;
  33 use C4::Koha;
  34 use C4::Circulation;
  35 use C4::Members;
  36 use Koha::DateUtils;
  37
  38 my $query = new CGI;
  39 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  40     {
  41         template_name   => "opac-ics.tt",
  42         query           => $query,
  43         type            => "opac",
  44         authnotrequired => 0,
  45         debug           => 1,
  46     }
  47 );
  48
  49 # Create Calendar
  50 my $calendar = Data::ICal->new();
  51
  52 my $patron = Koha::Patrons->find( $borrowernumber );
  53 my $pending_checkouts = $patron->pending_checkouts;
  54
  55 while ( my $c = $pending_checkouts->next ) {
  56     my $issue = $c->unblessed_all_relateds;
  57     my $vevent = Data::ICal::Entry::Event->new();
  58     my $timestamp = DateTime->now(); # Defaults to UTC
  59     # Send some values to the template to generate summary and description
  60     $issue->{overdue} = $c->is_overdue;
  61     $template->param(
  62         overdue => $issue->{'overdue'},
  63         title   => $issue->{'title'},
  64         barcode => $issue->{'barcode'},
  65     );
  66     # Catch the result of the template and split on newline
  67     my ($summary,$description) = split /\n/, $template->output;
  68     my $datestart;
  69     if ($issue->{'overdue'} && $issue->{'overdue'} == 1) {
  70         # Not much use adding an event in the past for a book that is overdue
  71         # so we set datestart = now
  72         $datestart = $timestamp;
  73     } else {
  74         $datestart = dt_from_string($issue->{'date_due'});
  75         $datestart->set_time_zone('UTC');
  76     }
  77     # Create a UID that includes the issue number and the domain
  78     my $domain = '';
  79     my $baseurl = C4::Context->preference('OPACBaseURL');
  80     if ( $baseurl ne '' ) {
  81         my $url = URI->new($baseurl);
  82         $domain = $url->host;
  83     } else {
  84         warn "Make sure the systempreference OPACBaseURL is set!";
  85     }
  86     my $uid = 'issue-' . $issue->{'issue_id'} . '@' . $domain;
  87     # Create the event
  88     $vevent->add_properties(
  89         summary     => $summary,
  90         description => $description,
  91         dtstamp     => DateTime::Format::ICal->format_datetime($timestamp),
  92         dtstart     => DateTime::Format::ICal->format_datetime($datestart),
  93         uid         => $uid,
  94     );
  95     # Add it to the calendar
  96     $calendar->add_entry($vevent);
  97 }
  98
  99 print $query->header(
 100     -type       => 'application/octet-stream',
 101     -attachment => 'koha.ics'
 102 );
 103
 104 print $calendar->as_string;