opac/opac-readingrecord.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18
  19 use Modern::Perl;
  20
  21 use CGI qw ( -utf8 );
  22
  23 use C4::Auth;
  24 use C4::Koha;
  25 use C4::Biblio;
  26 use C4::Circulation;
  27 use C4::Members;
  28 use Koha::DateUtils;
  29 use MARC::Record;
  30
  31 use C4::Output;
  32 use C4::Charset qw(StripNonXmlChars);
  33 use Koha::Patrons;
  34
  35 use Koha::ItemTypes;
  36 use Koha::Ratings;
  37
  38 my $query = new CGI;
  39
  40 # if opacreadinghistory is disabled, leave immediately
  41 if ( ! C4::Context->preference('opacreadinghistory') ) {
  42     print $query->redirect("/cgi-bin/koha/errors/404.pl");
  43     exit;
  44 }
  45
  46 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  47     {
  48         template_name   => "opac-readingrecord.tt",
  49         query           => $query,
  50         type            => "opac",
  51         authnotrequired => 0,
  52         debug           => 1,
  53     }
  54 );
  55
  56 my $borr = Koha::Patrons->find( $borrowernumber )->unblessed;
  57
  58 $template->param(%{$borr});
  59
  60 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
  61
  62 # get the record
  63 my $order = $query->param('order') || '';
  64 if ( $order eq 'title' ) {
  65     $template->param( orderbytitle => 1 );
  66 }
  67 elsif ( $order eq 'author' ) {
  68     $template->param( orderbyauthor => 1 );
  69 }
  70 else {
  71     $order = "date_due desc";
  72     $template->param( orderbydate => 1 );
  73 }
  74
  75
  76 my $limit = $query->param('limit');
  77 $limit //= '';
  78 $limit = ( $limit eq 'full' ) ? 0 : 50;
  79
  80 my $issues = GetAllIssues( $borrowernumber, $order, $limit );
  81
  82 my $itype_attribute =
  83   ( C4::Context->preference('item-level_itypes') ) ? 'itype' : 'itemtype';
  84
  85 my $opac_summary_html = C4::Context->preference('OPACMySummaryHTML');
  86 foreach my $issue ( @{$issues} ) {
  87     $issue->{normalized_isbn} = GetNormalizedISBN( $issue->{isbn} );
  88     if ( $issue->{$itype_attribute} ) {
  89         $issue->{translated_description} =
  90           $itemtypes->{ $issue->{$itype_attribute} }->{translated_description};
  91         $issue->{imageurl} =
  92           getitemtypeimagelocation( 'opac',
  93             $itemtypes->{ $issue->{$itype_attribute} }->{imageurl} );
  94     }
  95     my $marcxml = C4::Biblio::GetXmlBiblio( $issue->{biblionumber} );
  96     if ( $marcxml ) {
  97         $marcxml = StripNonXmlChars( $marcxml );
  98         my $marc_rec =
  99           MARC::Record::new_from_xml( $marcxml, 'utf8',
 100             C4::Context->preference('marcflavour') );
 101         $issue->{subtitle} =
 102           GetRecordValue( 'subtitle', $marc_rec, $issue->{frameworkcode} );
 103         $issue->{normalized_upc} = GetNormalizedUPC( $marc_rec, C4::Context->preference('marcflavour') );
 104     }
 105     # My Summary HTML
 106     if ($opac_summary_html) {
 107         my $my_summary_html = $opac_summary_html;
 108         $issue->{author}
 109           ? $my_summary_html =~ s/{AUTHOR}/$issue->{author}/g
 110           : $my_summary_html =~ s/{AUTHOR}//g;
 111         my $title = $issue->{title};
 112         $title =~ s/\/+$//;    # remove trailing slash
 113         $title =~ s/\s+$//;    # remove trailing space
 114         $title
 115           ? $my_summary_html =~ s/{TITLE}/$title/g
 116           : $my_summary_html =~ s/{TITLE}//g;
 117         $issue->{normalized_isbn}
 118           ? $my_summary_html =~ s/{ISBN}/$issue->{normalized_isbn}/g
 119           : $my_summary_html =~ s/{ISBN}//g;
 120         $issue->{biblionumber}
 121           ? $my_summary_html =~ s/{BIBLIONUMBER}/$issue->{biblionumber}/g
 122           : $my_summary_html =~ s/{BIBLIONUMBER}//g;
 123         $issue->{MySummaryHTML} = $my_summary_html;
 124     }
 125     # Star ratings
 126     if ( C4::Context->preference('OpacStarRatings') eq 'all' ) {
 127         my $ratings = Koha::Ratings->search({ biblionumber => $issue->{biblionumber} });
 128         $issue->{ratings} = $ratings;
 129         $issue->{my_rating} = $borrowernumber ? $ratings->search({ borrowernumber => $borrowernumber })->next : undef;
 130     }
 131 }
 132
 133 if (C4::Context->preference('BakerTaylorEnabled')) {
 134         $template->param(
 135                 JacketImages=>1,
 136                 BakerTaylorEnabled  => 1,
 137                 BakerTaylorImageURL => &image_url(),
 138                 BakerTaylorLinkURL  => &link_url(),
 139                 BakerTaylorBookstoreURL => C4::Context->preference('BakerTaylorBookstoreURL'),
 140         );
 141 }
 142
 143 BEGIN {
 144         if (C4::Context->preference('BakerTaylorEnabled')) {
 145                 require C4::External::BakerTaylor;
 146                 import C4::External::BakerTaylor qw(&image_url &link_url);
 147         }
 148 }
 149
 150 for(qw(AmazonCoverImages GoogleJackets)) { # BakerTaylorEnabled handled above
 151         C4::Context->preference($_) or next;
 152         $template->param($_=>1);
 153         $template->param(JacketImages=>1);
 154 }
 155
 156 $template->param(
 157     READING_RECORD => $issues,
 158     limit          => $limit,
 159     readingrecview => 1,
 160     OPACMySummaryHTML => $opac_summary_html ? 1 : 0,
 161 );
 162
 163 output_html_with_http_headers $query, $cookie, $template->output, undef, { force_no_caching => 1 };