catalogue/itemsearch.pl

   1 #!/usr/bin/perl
   2 # Copyright 2013 BibLibre
   3 #
   4 # This file is part of Koha
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it under the
   7 # terms of the GNU General Public License as published by the Free Software
   8 # Foundation; either version 3 of the License, or (at your option) any later
   9 # version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  12 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  13 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License along
  16 # with Koha; if not, write to the Free Software Foundation, Inc.,
  17 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  18
  19 use Modern::Perl;
  20 use CGI;
  21
  22 use JSON;
  23
  24 use C4::Auth;
  25 use C4::Output;
  26 use C4::Items;
  27 use C4::Biblio;
  28 use C4::Branch;
  29 use C4::Koha;
  30 use C4::ItemType;
  31
  32 use Koha::Item::Search::Field qw(GetItemSearchFields);
  33
  34 my $cgi = new CGI;
  35 my %params = $cgi->Vars;
  36
  37 my $format = $cgi->param('format');
  38 my ($template_name, $content_type);
  39 if (defined $format and $format eq 'json') {
  40     $template_name = 'catalogue/itemsearch.json.tt';
  41     $content_type = 'json';
  42
  43     # Map DataTables parameters with 'regular' parameters
  44     $cgi->param('rows', $cgi->param('iDisplayLength'));
  45     $cgi->param('page', ($cgi->param('iDisplayStart') / $cgi->param('iDisplayLength')) + 1);
  46     my @columns = split /,/, $cgi->param('sColumns');
  47     $cgi->param('sortby', $columns[ $cgi->param('iSortCol_0') ]);
  48     $cgi->param('sortorder', $cgi->param('sSortDir_0'));
  49
  50     my @f = $cgi->param('f');
  51     my @q = $cgi->param('q');
  52     push @q, '' if @q == 0;
  53     my @op = $cgi->param('op');
  54     my @c = $cgi->param('c');
  55     foreach my $i (0 .. ($cgi->param('iColumns') - 1)) {
  56         my $sSearch = $cgi->param("sSearch_$i");
  57         if (defined $sSearch and $sSearch ne '') {
  58             my @words = split /\s+/, $sSearch;
  59             foreach my $word (@words) {
  60                 push @f, $columns[$i];
  61                 push @q, "%$word%";
  62                 push @op, 'like';
  63                 push @c, 'and';
  64             }
  65         }
  66     }
  67     $cgi->param('f', @f);
  68     $cgi->param('q', @q);
  69     $cgi->param('op', @op);
  70     $cgi->param('c', @c);
  71 } elsif (defined $format and $format eq 'csv') {
  72     $template_name = 'catalogue/itemsearch.csv.tt';
  73
  74     # Retrieve all results
  75     $cgi->param('rows', 0);
  76 } else {
  77     $format = 'html';
  78     $template_name = 'catalogue/itemsearch.tt';
  79     $content_type = 'html';
  80 }
  81
  82 my ($template, $borrowernumber, $cookie) = get_template_and_user({
  83     template_name => $template_name,
  84     query => $cgi,
  85     type => 'intranet',
  86     authnotrequired => 0,
  87     flagsrequired   => { catalogue => 1 },
  88 });
  89
  90 my $notforloan_avcode = GetAuthValCode('items.notforloan');
  91 my $notforloan_values = GetAuthorisedValues($notforloan_avcode);
  92
  93 my $location_avcode = GetAuthValCode('items.location');
  94 my $location_values = GetAuthorisedValues($location_avcode);
  95
  96 if (scalar keys %params > 0) {
  97     # Parameters given, it's a search
  98
  99     my $filter = {
 100         conjunction => 'AND',
 101         filters => [],
 102     };
 103
 104     foreach my $p (qw(homebranch location itype ccode issues datelastborrowed notforloan)) {
 105         if (my @q = $cgi->param($p)) {
 106             if ($q[0] ne '') {
 107                 my $f = {
 108                     field => $p,
 109                     query => \@q,
 110                 };
 111                 if (my $op = $cgi->param($p . '_op')) {
 112                     $f->{operator} = $op;
 113                 }
 114                 push @{ $filter->{filters} }, $f;
 115             }
 116         }
 117     }
 118
 119     my @c = $cgi->param('c');
 120     my @fields = $cgi->param('f');
 121     my @q = $cgi->param('q');
 122     my @op = $cgi->param('op');
 123
 124     my $f;
 125     for (my $i = 0; $i < @fields; $i++) {
 126         my $field = $fields[$i];
 127         my $q = shift @q;
 128         my $op = shift @op;
 129         if (defined $q and $q ne '') {
 130             if ($i == 0) {
 131                 $f = {
 132                     field => $field,
 133                     query => $q,
 134                     operator => $op,
 135                 };
 136             } else {
 137                 my $c = shift @c;
 138                 $f = {
 139                     conjunction => $c,
 140                     filters => [
 141                         $f, {
 142                             field => $field,
 143                             query => $q,
 144                             operator => $op,
 145                         }
 146                     ],
 147                 };
 148             }
 149         }
 150     }
 151     push @{ $filter->{filters} }, $f;
 152
 153     # Yes/No parameters
 154     foreach my $p (qw(damaged itemlost)) {
 155         my $v = $cgi->param($p) // '';
 156         my $f = {
 157             field => $p,
 158             query => 0,
 159         };
 160         if ($v eq 'yes') {
 161             $f->{operator} = '!=';
 162             push @{ $filter->{filters} }, $f;
 163         } elsif ($v eq 'no') {
 164             $f->{operator} = '=';
 165             push @{ $filter->{filters} }, $f;
 166         }
 167     }
 168
 169     if (my $itemcallnumber_from = $cgi->param('itemcallnumber_from')) {
 170         push @{ $filter->{filters} }, {
 171             field => 'itemcallnumber',
 172             query => $itemcallnumber_from,
 173             operator => '>=',
 174         };
 175     }
 176     if (my $itemcallnumber_to = $cgi->param('itemcallnumber_to')) {
 177         push @{ $filter->{filters} }, {
 178             field => 'itemcallnumber',
 179             query => $itemcallnumber_to,
 180             operator => '<=',
 181         };
 182     }
 183
 184     my $search_params = {
 185         rows => $cgi->param('rows') // 20,
 186         page => $cgi->param('page') || 1,
 187         sortby => $cgi->param('sortby') || 'itemnumber',
 188         sortorder => $cgi->param('sortorder') || 'asc',
 189     };
 190
 191     my ($results, $total_rows) = SearchItems($filter, $search_params);
 192     if ($results) {
 193         # Get notforloan labels
 194         my $notforloan_map = {};
 195         foreach my $nfl_value (@$notforloan_values) {
 196             $notforloan_map->{$nfl_value->{authorised_value}} = $nfl_value->{lib};
 197         }
 198
 199         # Get location labels
 200         my $location_map = {};
 201         foreach my $loc_value (@$location_values) {
 202             $location_map->{$loc_value->{authorised_value}} = $loc_value->{lib};
 203         }
 204
 205         foreach my $item (@$results) {
 206             $item->{biblio} = GetBiblio($item->{biblionumber});
 207             ($item->{biblioitem}) = GetBiblioItemByBiblioNumber($item->{biblionumber});
 208             $item->{status} = $notforloan_map->{$item->{notforloan}};
 209             if (defined $item->{location}) {
 210                 $item->{location} = $location_map->{$item->{location}};
 211             }
 212         }
 213     }
 214
 215     $template->param(
 216         filter => $filter,
 217         search_params => $search_params,
 218         results => $results,
 219         total_rows => $total_rows,
 220         search_done => 1,
 221     );
 222
 223     if ($format eq 'html') {
 224         # Build pagination bar
 225         my $url = $cgi->url(-absolute => 1);
 226         my @params;
 227         foreach my $p (keys %params) {
 228             my @v = $cgi->param($p);
 229             push @params, map { "$p=" . $_ } @v;
 230         }
 231         $url .= '?' . join ('&', @params);
 232         my $nb_pages = 1 + int($total_rows / $search_params->{rows});
 233         my $current_page = $search_params->{page};
 234         my $pagination_bar = pagination_bar($url, $nb_pages, $current_page, 'page');
 235
 236         $template->param(pagination_bar => $pagination_bar);
 237     }
 238 }
 239
 240 if ($format eq 'html') {
 241     # Retrieve data required for the form.
 242
 243     my $branches = GetBranches();
 244     my @branches;
 245     foreach my $branchcode (keys %$branches) {
 246         push @branches, {
 247             value => $branchcode,
 248             label => $branches->{$branchcode}->{branchname},
 249         };
 250     }
 251     my @locations;
 252     foreach my $location (@$location_values) {
 253         push @locations, {
 254             value => $location->{authorised_value},
 255             label => $location->{lib} // $location->{authorised_value},
 256         };
 257     }
 258     my @itemtypes = C4::ItemType->all();
 259     foreach my $itemtype (@itemtypes) {
 260         $itemtype->{value} = $itemtype->{itemtype};
 261         $itemtype->{label} = $itemtype->{description};
 262     }
 263     my $ccode_avcode = GetAuthValCode('items.ccode') || 'CCODE';
 264     my $ccodes = GetAuthorisedValues($ccode_avcode);
 265     my @ccodes;
 266     foreach my $ccode (@$ccodes) {
 267         push @ccodes, {
 268             value => $ccode->{authorised_value},
 269             label => $ccode->{lib},
 270         };
 271     }
 272
 273     my @notforloans;
 274     foreach my $value (@$notforloan_values) {
 275         push @notforloans, {
 276             value => $value->{authorised_value},
 277             label => $value->{lib},
 278         };
 279     }
 280
 281     my @items_search_fields = GetItemSearchFields();
 282
 283     my $authorised_values = {};
 284     foreach my $field (@items_search_fields) {
 285         if (my $category = ($field->{authorised_values_category})) {
 286             $authorised_values->{$category} = GetAuthorisedValues($category);
 287         }
 288     }
 289
 290     $template->param(
 291         branches => \@branches,
 292         locations => \@locations,
 293         itemtypes => \@itemtypes,
 294         ccodes => \@ccodes,
 295         notforloans => \@notforloans,
 296         items_search_fields => \@items_search_fields,
 297         authorised_values_json => to_json($authorised_values),
 298     );
 299 }
 300
 301 if ($format eq 'csv') {
 302     print $cgi->header({
 303         type => 'text/csv',
 304         attachment => 'items.csv',
 305     });
 306     print $template->output;
 307 } else {
 308     output_with_http_headers $cgi, $cookie, $template->output, $content_type;
 309 }