members/boraccount.pl

   1 #!/usr/bin/perl
   2
   3
   4 #written 11/1/2000 by chris@katipo.oc.nz
   5 #script to display borrowers account details
   6
   7
   8 # Copyright 2000-2002 Katipo Communications
   9 #
  10 # This file is part of Koha.
  11 #
  12 # Koha is free software; you can redistribute it and/or modify it
  13 # under the terms of the GNU General Public License as published by
  14 # the Free Software Foundation; either version 3 of the License, or
  15 # (at your option) any later version.
  16 #
  17 # Koha is distributed in the hope that it will be useful, but
  18 # WITHOUT ANY WARRANTY; without even the implied warranty of
  19 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  20 # GNU General Public License for more details.
  21 #
  22 # You should have received a copy of the GNU General Public License
  23 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  24
  25 use Modern::Perl;
  26
  27 use C4::Auth;
  28 use C4::Output;
  29 use CGI qw ( -utf8 );
  30 use C4::Members;
  31 use C4::Accounts;
  32 use Koha::Cash::Registers;
  33 use Koha::Patrons;
  34 use Koha::Patron::Categories;
  35
  36 my $input=new CGI;
  37
  38
  39 my ($template, $loggedinuser, $cookie) = get_template_and_user(
  40     {
  41         template_name   => "members/boraccount.tt",
  42         query           => $input,
  43         type            => "intranet",
  44         authnotrequired => 0,
  45         flagsrequired   => { borrowers     => 'edit_borrowers',
  46                              updatecharges => 'remaining_permissions'},
  47         debug           => 1,
  48     }
  49 );
  50
  51 my $schema         = Koha::Database->new->schema;
  52 my $borrowernumber = $input->param('borrowernumber');
  53 my $payment_id     = $input->param('payment_id');
  54 my $change_given   = $input->param('change_given');
  55 my $action         = $input->param('action') || '';
  56
  57 my $logged_in_user = Koha::Patrons->find( $loggedinuser );
  58 my $library_id = C4::Context->userenv->{'branch'};
  59 my $patron = Koha::Patrons->find( $borrowernumber );
  60 unless ( $patron ) {
  61     print $input->redirect("/cgi-bin/koha/circ/circulation.pl?borrowernumber=$borrowernumber");
  62     exit;
  63 }
  64
  65 output_and_exit_if_error( $input, $cookie, $template, { module => 'members', logged_in_user => $logged_in_user, current_patron => $patron } );
  66
  67 my $registerid;
  68 if ( C4::Context->preference('UseCashRegisters') ) {
  69     $registerid = scalar $input->param('registerid');
  70     my $registers  = Koha::Cash::Registers->search(
  71         { branch   => $library_id, archived => 0 },
  72         { order_by => { '-asc' => 'name' } }
  73     );
  74
  75     if ( !$registers->count ) {
  76         $template->param( error_registers => 1 );
  77     }
  78     else {
  79
  80         if ( !$registerid ) {
  81             my $default_register = Koha::Cash::Registers->find(
  82                 { branch => $library_id, branch_default => 1 } );
  83             $registerid = $default_register->id if $default_register;
  84         }
  85         $registerid = $registers->next->id if !$registerid;
  86
  87         $template->param(
  88             registerid => $registerid,
  89             registers  => $registers,
  90         );
  91     }
  92 }
  93
  94 if ( $action eq 'void' ) {
  95     my $payment_id = scalar $input->param('accountlines_id');
  96     my $payment    = Koha::Account::Lines->find( $payment_id );
  97     $payment->void();
  98 }
  99
 100 if ( $action eq 'payout' ) {
 101     my $payment_id        = scalar $input->param('accountlines_id');
 102     my $payment           = Koha::Account::Lines->find($payment_id);
 103     my $amount           = scalar $input->param('amount');
 104     my $transaction_type = scalar $input->param('transaction_type');
 105     $schema->txn_do(
 106         sub {
 107             my $payout = $payment->payout(
 108                 {
 109                     payout_type   => $transaction_type,
 110                     branch        => $library_id,
 111                     staff_id      => $logged_in_user->id,
 112                     cash_register => $registerid,
 113                     interface     => 'intranet',
 114                     amount        => $amount
 115                 }
 116             );
 117         }
 118     );
 119 }
 120
 121 if ( $action eq 'refund' ) {
 122     my $charge_id        = scalar $input->param('accountlines_id');
 123     my $charge           = Koha::Account::Lines->find($charge_id);
 124     my $amount           = scalar $input->param('amount');
 125     my $transaction_type = scalar $input->param('transaction_type');
 126     $schema->txn_do(
 127         sub {
 128
 129             my $refund = $charge->reduce(
 130                 {
 131                     reduction_type => 'REFUND',
 132                     branch         => $library_id,
 133                     staff_id       => $logged_in_user->id,
 134                     interface      => 'intranet',
 135                     amount         => $amount
 136                 }
 137             );
 138             unless ( $transaction_type eq 'AC' ) {
 139                 my $payout = $refund->payout(
 140                     {
 141                         payout_type   => $transaction_type,
 142                         branch        => $library_id,
 143                         staff_id      => $logged_in_user->id,
 144                         cash_register => $registerid,
 145                         interface     => 'intranet',
 146                         amount        => $amount
 147                     }
 148                 );
 149             }
 150         }
 151     );
 152 }
 153
 154 #get account details
 155 my $total = $patron->account->balance;
 156
 157 my @accountlines = Koha::Account::Lines->search(
 158     { borrowernumber => $patron->borrowernumber },
 159     { order_by       => { -desc => 'accountlines_id' } }
 160 );
 161
 162 my $totalcredit;
 163 if($total <= 0){
 164         $totalcredit = 1;
 165 }
 166
 167 $template->param(
 168     patron              => $patron,
 169     finesview           => 1,
 170     total               => sprintf("%.2f",$total),
 171     totalcredit         => $totalcredit,
 172     accounts            => \@accountlines,
 173     payment_id          => $payment_id,
 174     change_given        => $change_given,
 175 );
 176
 177 output_html_with_http_headers $input, $cookie, $template->output;