Koha/Virtualshelves.pm

   1 package Koha::Virtualshelves;
   2
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17
  18 use Modern::Perl;
  19
  20 use Carp;
  21
  22 use Koha::Database;
  23
  24 use Koha::Virtualshelf;
  25
  26 use base qw(Koha::Objects);
  27
  28 =head1 NAME
  29
  30 Koha::Virtualshelf - Koha Virtualshelf Object class
  31
  32 =head1 API
  33
  34 =head2 Class Methods
  35
  36 =cut
  37
  38 =head3 type
  39
  40 =cut
  41
  42 sub get_private_shelves {
  43     my ( $self, $params ) = @_;
  44     my $page = $params->{page};
  45     my $rows = $params->{rows};
  46     my $borrowernumber = $params->{borrowernumber} || 0;
  47
  48     $self->search(
  49         {
  50             category => 1,
  51             -or => {
  52                 'virtualshelfshares.borrowernumber' => $borrowernumber,
  53                 'me.owner' => $borrowernumber,
  54             }
  55         },
  56         {
  57             join => [ 'virtualshelfshares' ],
  58             distinct => 'shelfnumber',
  59             order_by => 'shelfname',
  60             ( ( $page and $rows ) ? ( page => $page, rows => $rows ) : () ),
  61         }
  62     );
  63 }
  64
  65
  66 sub get_public_shelves {
  67     my ( $self, $params ) = @_;
  68     my $page = $params->{page};
  69     my $rows = $params->{rows};
  70
  71     $self->search(
  72         {
  73             category => 2,
  74         },
  75         {
  76             distinct => 'shelfnumber',
  77             order_by => 'shelfname',
  78             ( ( $page and $rows ) ? ( page => $page, rows => $rows ) : () ),
  79         }
  80     );
  81 }
  82
  83 sub get_some_shelves {
  84     my ( $self, $params ) = @_;
  85     my $borrowernumber = $params->{borrowernumber} || 0;
  86     my $category = $params->{category} || 1;
  87     my $add_allowed = $params->{add_allowed};
  88
  89     my @conditions;
  90     if ( $add_allowed ) {
  91         push @conditions, {
  92             -or =>
  93             [
  94                 {
  95                     "me.owner" => $borrowernumber,
  96                     "me.allow_change_from_owner" => 1,
  97                 },
  98                 "me.allow_change_from_others" => 1,
  99             ]
 100         };
 101     }
 102     if ( $category == 1 ) {
 103         push @conditions, {
 104             -or =>
 105             {
 106                 "virtualshelfshares.borrowernumber" => $borrowernumber,
 107                 "me.owner" => $borrowernumber,
 108             }
 109         };
 110     }
 111
 112     $self->search(
 113         {
 114             category => $category,
 115             ( @conditions ? ( -and => \@conditions ) : () ),
 116         },
 117         {
 118             join => [ 'virtualshelfshares' ],
 119             distinct => 'shelfnumber',
 120             order_by => { -desc => 'lastmodified' },
 121         }
 122     );
 123 }
 124
 125 sub get_shelves_containing_record {
 126     my ( $self, $params ) = @_;
 127     my $borrowernumber = $params->{borrowernumber};
 128     my $biblionumber   = $params->{biblionumber};
 129
 130     my @conditions = ( 'virtualshelfcontents.biblionumber' => $biblionumber );
 131     if ($borrowernumber) {
 132         push @conditions,
 133           {
 134               -or => [
 135                 {
 136                     category => 1,
 137                     -or      => {
 138                         'me.owner' => $borrowernumber,
 139                         -or        => {
 140                             'virtualshelfshares.borrowernumber' => $borrowernumber,
 141                         },
 142                     }
 143                 },
 144                 { category => 2 },
 145             ]
 146           };
 147     } else {
 148         push @conditions, { category => 2 };
 149     }
 150
 151     return Koha::Virtualshelves->search(
 152         {
 153             -and => \@conditions
 154         },
 155         {
 156             join     => [ 'virtualshelfcontents', 'virtualshelfshares' ],
 157             distinct => 'shelfnumber',
 158             order_by => { -asc => 'shelfname' },
 159         }
 160     );
 161 }
 162
 163 sub _type {
 164     return 'Virtualshelve';
 165 }
 166
 167 sub object_class {
 168     return 'Koha::Virtualshelf';
 169 }
 170
 171 1;