Koha/Library.pm

   1 package Koha::Library;
   2
   3 # Copyright 2015 Koha Development team
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use C4::Context;
  25
  26 use Koha::Database;
  27 use Koha::StockRotationStages;
  28 use Koha::SMTP::Servers;
  29
  30 use base qw(Koha::Object);
  31
  32 =head1 NAME
  33
  34 Koha::Library - Koha Library Object class
  35
  36 =head1 API
  37
  38 =head2 Class methods
  39
  40 =head3 stockrotationstages
  41
  42   my $stages = Koha::Library->stockrotationstages;
  43
  44 Returns the stockrotation stages associated with this Library.
  45
  46 =cut
  47
  48 sub stockrotationstages {
  49     my ( $self ) = @_;
  50     my $rs = $self->_result->stockrotationstages;
  51     return Koha::StockRotationStages->_new_from_dbic( $rs );
  52 }
  53
  54 =head3 get_effective_marcorgcode
  55
  56     my $marcorgcode = Koha::Libraries->find( $library_id )->get_effective_marcorgcode();
  57
  58 Returns the effective MARC organization code of the library. It falls back to the value
  59 from the I<MARCOrgCode> syspref if undefined for the library.
  60
  61 =cut
  62
  63 sub get_effective_marcorgcode {
  64     my ( $self )  = @_;
  65
  66     return $self->marcorgcode || C4::Context->preference("MARCOrgCode");
  67 }
  68
  69 =head3 smtp_server
  70
  71     my $smtp_server = $library->smtp_server;
  72     $library->smtp_server({ smtp_server => $smtp_server });
  73     $library->smtp_server({ smtp_server => undef });
  74
  75 Accessor for getting and setting the library's SMTP server.
  76
  77 Returns the effective SMTP server configuration to be used on the library. The returned
  78 value is always a I<Koha::SMTP::Server> object.
  79
  80 Setting it to undef will remove the link to a specific SMTP server and effectively
  81 make the library use the default setting
  82
  83 =cut
  84
  85 sub smtp_server {
  86     my ( $self, $params ) = @_;
  87
  88     my $library_smtp_server_rs = $self->_result->library_smtp_server;
  89
  90     if ( exists $params->{smtp_server} ) {
  91
  92         $self->_result->result_source->schema->txn_do( sub {
  93             $library_smtp_server_rs->delete
  94                 if $library_smtp_server_rs;
  95
  96             if ( defined $params->{smtp_server} ) {
  97                 # Set the new server
  98                 # Remove any already set SMTP server
  99
 100                 my $smtp_server = $params->{smtp_server};
 101                 $smtp_server->_result->add_to_library_smtp_servers({ library_id => $self->id });
 102             }
 103         });
 104     } # else => reset to default
 105     else {
 106         # Getter
 107         if ( $library_smtp_server_rs ) {
 108             return Koha::SMTP::Servers->find(
 109                 $library_smtp_server_rs->smtp_server_id );
 110         }
 111
 112         return Koha::SMTP::Servers->get_default;
 113     }
 114
 115     return $self;
 116 }
 117
 118 =head3 inbound_email_address
 119
 120   my $to_email = Koha::Library->inbound_email_address;
 121
 122 Returns an effective email address which should be accessible to librarians at the branch.
 123
 124 =cut
 125
 126 sub inbound_email_address {
 127     my ($self) = @_;
 128
 129     return
 130          $self->branchreplyto
 131       || $self->branchemail
 132       || C4::Context->preference('ReplytoDefault')
 133       || C4::Context->preference('KohaAdminEmailAddress')
 134       || undef;
 135 }
 136
 137 =head3 library_groups
 138
 139 Return the Library groups of this library
 140
 141 =cut
 142
 143 sub library_groups {
 144     my ( $self ) = @_;
 145     my $rs = $self->_result->library_groups;
 146     return Koha::Library::Groups->_new_from_dbic( $rs );
 147 }
 148
 149 =head3 cash_registers
 150
 151 Return Cash::Registers associated with this Library
 152
 153 =cut
 154
 155 sub cash_registers {
 156     my ( $self ) = @_;
 157     my $rs = $self->_result->cash_registers;
 158     return Koha::Cash::Registers->_new_from_dbic( $rs );
 159 }
 160
 161 =head3 to_api_mapping
 162
 163 This method returns the mapping for representing a Koha::Library object
 164 on the API.
 165
 166 =cut
 167
 168 sub to_api_mapping {
 169     return {
 170         branchcode       => 'library_id',
 171         branchname       => 'name',
 172         branchaddress1   => 'address1',
 173         branchaddress2   => 'address2',
 174         branchaddress3   => 'address3',
 175         branchzip        => 'postal_code',
 176         branchcity       => 'city',
 177         branchstate      => 'state',
 178         branchcountry    => 'country',
 179         branchphone      => 'phone',
 180         branchfax        => 'fax',
 181         branchemail      => 'email',
 182         branchillemail   => 'illemail',
 183         branchreplyto    => 'reply_to_email',
 184         branchreturnpath => 'return_path_email',
 185         branchurl        => 'url',
 186         issuing          => undef,
 187         branchip         => 'ip',
 188         branchnotes      => 'notes',
 189         marcorgcode      => 'marc_org_code',
 190     };
 191 }
 192
 193 =head3 get_hold_libraries
 194
 195 Return all libraries (including self) that belong to the same hold groups
 196
 197 =cut
 198
 199 sub get_hold_libraries {
 200     my ( $self ) = @_;
 201     my $library_groups = $self->library_groups;
 202     my @hold_libraries;
 203     while ( my $library_group = $library_groups->next ) {
 204         my $root = Koha::Library::Groups->get_root_ancestor({id => $library_group->id});
 205         if($root->ft_local_hold_group) {
 206             push @hold_libraries, $root->all_libraries;
 207         }
 208     }
 209
 210     my %seen;
 211     @hold_libraries =
 212       grep { !$seen{ $_->id }++ } @hold_libraries;
 213
 214     return @hold_libraries;
 215 }
 216
 217 =head3 validate_hold_sibling
 218
 219 Return if given library is a valid hold group member
 220
 221 =cut
 222
 223 sub validate_hold_sibling {
 224     my ( $self, $params ) = @_;
 225     my @hold_libraries = $self->get_hold_libraries;
 226
 227     foreach (@hold_libraries) {
 228         my $hold_library = $_;
 229         my $is_valid = 1;
 230         foreach my $key (keys %$params) {
 231             unless($hold_library->$key eq $params->{$key}) {
 232                 $is_valid=0;
 233                 last;
 234             }
 235         }
 236         if($is_valid) {
 237             #Found one library that meets all search parameters
 238             return 1;
 239         }
 240     }
 241     return 0;
 242 }
 243
 244 =head2 Internal methods
 245
 246 =head3 _type
 247
 248 =cut
 249
 250 sub _type {
 251     return 'Branch';
 252 }
 253
 254 1;