opac/ilsdi.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 SARL Biblibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use C4::ILSDI::Services;
  23 use C4::Auth;
  24 use C4::Output;
  25 use C4::Context;
  26
  27 use List::MoreUtils qw(any);
  28 use XML::Simple;
  29 use CGI qw ( -utf8 );
  30 use Net::Netmask;
  31
  32 =head1 DLF ILS-DI for Koha
  33
  34 This script is a basic implementation of ILS-DI protocol for Koha.
  35 It acts like a dispatcher, that get the CGI request, check required and
  36 optionals arguments, call a function from C4::ILS-DI, and finally
  37 outputs the returned hashref as XML.
  38
  39 =cut
  40
  41 # Instanciate the CGI request
  42 my $cgi = new CGI;
  43
  44 # List of available services, sorted by level
  45 my @services = (
  46     'Describe',    # Not part of ILS-DI, online API doc
  47
  48     #   Level 1: Basic Discovery Interfaces
  49     #   'HarvestBibliographicRecords',       # OAI-PMH
  50     #   'HarvestExpandedRecords',            # OAI-PMH
  51     'GetAvailability',    # FIXME Add bibliographic level
  52
  53     #   'GoToBibliographicRequestPage'       # I don't understant this one
  54     #   Level 2: Elementary OPAC supplement
  55     #   'HarvestAuthorityRecords',           # OAI-PMH
  56     #   'HarvestHoldingsRecords',            # OAI-PMH
  57     'GetRecords',         # Note that we can use OAI-PMH for this too
  58
  59     #   'Search',                            # TODO
  60     #   'Scan',                              # TODO
  61     'GetAuthorityRecords',
  62
  63     #   'OutputRewritablePage',              # I don't understant this one
  64     #   'OutputIntermediateFormat',          # I don't understant this one
  65     #   Level 3: Elementary OPAC alternative
  66     'LookupPatron',
  67     'AuthenticatePatron',
  68     'GetPatronInfo',
  69     'GetPatronStatus',
  70     'GetServices',    # FIXME Loans
  71     'RenewLoan',
  72     'HoldTitle',      # FIXME Add dates support
  73     'HoldItem',       # FIXME Add dates support
  74     'CancelHold',
  75
  76     #   'RecallItem',                        # Not supported by Koha
  77     #   'CancelRecall',                      # Not supported by Koha
  78     #   Level 4: Robust/domain specific discovery platforms
  79     #   'SearchCourseReserves',              # TODO
  80     #   'Explain'                            # TODO
  81 );
  82
  83 # List of required arguments
  84 my %required = (
  85     'Describe'            => ['verb'],
  86     'GetAvailability'     => [ 'id', 'id_type' ],
  87     'GetRecords'          => ['id'],
  88     'GetAuthorityRecords' => ['id'],
  89     'LookupPatron'        => ['id'],
  90     'AuthenticatePatron'  => [ 'username', 'password' ],
  91     'GetPatronInfo'       => ['patron_id'],
  92     'GetPatronStatus'     => ['patron_id'],
  93     'GetServices'         => [ 'patron_id', 'item_id' ],
  94     'RenewLoan'           => [ 'patron_id', 'item_id' ],
  95     'HoldTitle'           => [ 'patron_id', 'bib_id', 'request_location' ],
  96     'HoldItem'            => [ 'patron_id', 'bib_id', 'item_id' ],
  97     'CancelHold' => [ 'patron_id', 'item_id' ],
  98 );
  99
 100 # List of optional arguments
 101 my %optional = (
 102     'Describe'            => [],
 103     'GetAvailability'     => [ 'return_type', 'return_fmt' ],
 104     'GetRecords'          => ['schema'],
 105     'GetAuthorityRecords' => ['schema'],
 106     'LookupPatron'        => ['id_type'],
 107     'AuthenticatePatron'  => [],
 108     'GetPatronInfo'       => [ 'show_contact', 'show_fines', 'show_holds', 'show_loans', 'loans_per_page', 'loans_page', 'show_attributes' ],
 109     'GetPatronStatus'     => [],
 110     'GetServices'         => [],
 111     'RenewLoan'           => ['desired_due_date'],
 112     'HoldTitle'  => [ 'pickup_location', 'start_date', 'expiry_date' ],
 113     'HoldItem'   => [ 'pickup_location', 'start_date', 'expiry_date' ],
 114     'CancelHold' => [],
 115 );
 116
 117 # If no service is requested, display the online documentation
 118 unless ( $cgi->param('service') ) {
 119     my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 120         {   template_name   => "ilsdi.tt",
 121             query           => $cgi,
 122             type            => "opac",
 123             authnotrequired => 1,
 124             debug           => 1,
 125         }
 126     );
 127     output_html_with_http_headers $cgi, $cookie, $template->output;
 128     exit 0;
 129 }
 130
 131 # Set the userenv
 132 C4::Context->_new_userenv( 'ILSDI_'.time() );
 133 C4::Context->set_userenv(
 134     undef, undef, undef, 'ILSDI', 'ILSDI',
 135     undef, undef, undef, undef, undef,
 136 );
 137 C4::Context->interface('opac');
 138
 139 # If user requested a service description, then display it
 140 if ( scalar $cgi->param('service') eq "Describe" and any { scalar $cgi->param('verb') eq $_ } @services ) {
 141     my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
 142         {   template_name   => "ilsdi.tt",
 143             query           => $cgi,
 144             type            => "opac",
 145             authnotrequired => 1,
 146             debug           => 1,
 147         }
 148     );
 149     $template->param( scalar $cgi->param('verb') => 1 );
 150     output_html_with_http_headers $cgi, $cookie, $template->output;
 151     exit 0;
 152 }
 153
 154 # any output after this point will be UTF-8 XML
 155 binmode STDOUT, ':encoding(UTF-8)';
 156 print CGI::header('-type'=>'text/xml', '-charset'=>'utf-8');
 157
 158 my $out;
 159
 160 # If ILS-DI module is disabled in System->Preferences, redirect to 404
 161 unless ( C4::Context->preference('ILS-DI') ) {
 162     $out->{'code'} = "NotAllowed";
 163     $out->{'message'} = "ILS-DI is disabled.";
 164 }
 165
 166 # If the remote address is not allowed, redirect to 403
 167 my @AuthorizedIPs = split( /,/, C4::Context->preference('ILS-DI:AuthorizedIPs') );
 168 if (@AuthorizedIPs) {    # If no filter set, allow access to everybody
 169     my $authorized = 0;
 170     foreach my $ip (@AuthorizedIPs) {
 171         my $netmask = Net::Netmask->new2($ip);
 172         if ( $netmask && $netmask->match( $ENV{REMOTE_ADDR} ) ) {
 173             $authorized = 1;
 174             last;
 175         }
 176     }
 177     unless ($authorized) {
 178         $out->{'code'} = "NotAllowed";
 179         $out->{'message'} = "Unauthorized IP address: $ENV{REMOTE_ADDR}.";
 180     }
 181 }
 182
 183 my $service = $cgi->param('service') || "ilsdi";
 184
 185 # Check if the requested service is in the list
 186 if ( $service and any { $service eq $_ } @services ) {
 187
 188     my @parmsrequired = @{ $required{$service} };
 189     my @parmsoptional = @{ $optional{$service} };
 190     my @parmsall      = ( @parmsrequired, @parmsoptional );
 191     my @names         = $cgi->multi_param;
 192     my %paramhash;
 193     $paramhash{$_} = 1 for @names;
 194
 195     # check for missing parameters
 196     for ( @parmsrequired ) {
 197         unless ( exists $paramhash{$_} ) {
 198             $out->{'code'} = "MissingParameter";
 199             $out->{'message'} = "The required parameter ".$_." is missing.";
 200         }
 201     }
 202
 203     # check for illegal parameters
 204     for my $name ( @names ) {
 205         my $found = 0;
 206         for my $name2 (@parmsall) {
 207             if ( $name eq $name2 ) {
 208                 $found = 1;
 209             }
 210         }
 211         if ( $found == 0 && $name ne 'service' ) {
 212             $out->{'code'} = "IllegalParameter";
 213             $out->{'message'} = "The parameter ".$name." is illegal.";
 214         }
 215     }
 216
 217     # check for multiple parameters
 218     for ( @names ) {
 219         my @values = $cgi->multi_param($_);
 220         if ( $#values != 0 ) {
 221             $out->{'code'} = "MultipleValuesNotAllowed";
 222             $out->{'message'} = "Multiple values not allowed for the parameter ".$_.".";
 223         }
 224     }
 225
 226     if ( !$out->{'message'} ) {
 227
 228         # GetAvailability is a special case, as it cannot use XML::Simple
 229         if ( $service eq "GetAvailability" ) {
 230             print C4::ILSDI::Services::GetAvailability($cgi);
 231             exit 0;
 232         } else {
 233
 234             # Variable functions
 235             my $sub = do {
 236 #                no strict 'refs';
 237                 my $symbol = 'C4::ILSDI::Services::' . $service;
 238                 \&{"$symbol"};
 239             };
 240
 241             # Call the requested service, and get its return value
 242             $out = &$sub($cgi);
 243         }
 244     }
 245 } else {
 246     $out->{'message'} = "NotSupported";
 247 }
 248
 249 # Output XML by passing the hashref to XMLOut
 250 print XMLout(
 251     $out,
 252     noattr        => 1,
 253     nosort        => 1,
 254     xmldecl       => '<?xml version="1.0" encoding="UTF-8" ?>',
 255     RootName      => $service,
 256     SuppressEmpty => 1
 257 );
 258 exit 0;
 259