tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use strict;
  44 use warnings;
  45 use CGI;
  46 use C4::Auth;
  47 use C4::Context;
  48 use C4::Output;
  49 use C4::Branch; # GetBranches
  50 use C4::Letters;
  51 use C4::Members::Attributes;
  52
  53 # $protected_letters = protected_letters()
  54 # - return a hashref of letter_codes representing letters that should never be deleted
  55 sub protected_letters {
  56     my $dbh = C4::Context->dbh;
  57     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  58     return { map { $_->[0] => 1 } @{$codes} };
  59 }
  60
  61 our $input       = new CGI;
  62 my $searchfield = $input->param('searchfield');
  63 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  64 our $branchcode  = $input->param('branchcode');
  65 my $code        = $input->param('code');
  66 my $module      = $input->param('module') || '';
  67 my $content     = $input->param('content');
  68 my $op          = $input->param('op') || '';
  69 my $dbh = C4::Context->dbh;
  70
  71 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  72     {
  73         template_name   => 'tools/letter.tt',
  74         query           => $input,
  75         type            => 'intranet',
  76         authnotrequired => 0,
  77         flagsrequired   => { tools => 'edit_notices' },
  78         debug           => 1,
  79     }
  80 );
  81
  82 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  83   ?  C4::Context->userenv()->{'branch'}
  84   : undef;
  85 # we show only the TMPL_VAR names $op
  86
  87 $template->param(
  88     independant_branch => $my_branch,
  89         script_name => $script_name,
  90   searchfield => $searchfield,
  91     branchcode => $branchcode,
  92         action => $script_name
  93 );
  94
  95 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
  96     add_validate();
  97     $op = q{}; # we return to the default screen for the next operation
  98 }
  99 if ($op eq 'copy_form') {
 100     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 101     my $branchcode = $input->param('branchcode') || q||;
 102     add_form($oldbranchcode, $module, $code);
 103     $template->param(
 104         oldbranchcode => $oldbranchcode,
 105         branchcode => $branchcode,
 106         branchloop => _branchloop($branchcode),
 107         copying => 1,
 108         modify => 0,
 109     );
 110 }
 111 elsif ( $op eq 'add_form' ) {
 112     add_form($branchcode, $module, $code);
 113 }
 114 elsif ( $op eq 'delete_confirm' ) {
 115     delete_confirm($branchcode, $module, $code);
 116 }
 117 elsif ( $op eq 'delete_confirmed' ) {
 118     delete_confirmed($branchcode, $module, $code);
 119     $op = q{}; # next operation is to return to default screen
 120 }
 121 else {
 122     default_display($branchcode,$searchfield);
 123 }
 124
 125 # Do this last as delete_confirmed resets
 126 if ($op) {
 127     $template->param($op  => 1);
 128 } else {
 129     $template->param(no_op_set => 1);
 130 }
 131
 132 output_html_with_http_headers $input, $cookie, $template->output;
 133
 134 sub add_form {
 135     my ( $branchcode,$module, $code ) = @_;
 136
 137     my $letters;
 138     # if code has been passed we can identify letter and its an update action
 139     if ($code) {
 140         $letters = C4::Letters::GetLetterTemplates(
 141             {
 142                 branchcode => $branchcode,
 143                 module     => $module,
 144                 code       => $code,
 145             }
 146         );
 147     }
 148
 149     my $message_transport_types = GetMessageTransportTypes();
 150     my @letter_loop;
 151     if ($letters) {
 152         $template->param(
 153             modify     => 1,
 154             code       => $code,
 155             branchcode => $branchcode,
 156         );
 157         my $first_flag = 1;
 158         # The letter name is contained into each mtt row.
 159         # So we can only sent the first one to the template.
 160         for my $mtt ( @$message_transport_types ) {
 161             # The letter_name
 162             if ( $first_flag and $letters->{$mtt}{name} ) {
 163                 $template->param(
 164                     letter_name=> $letters->{$mtt}{name},
 165                 );
 166                 $first_flag = 0;
 167             }
 168
 169             push @letter_loop, {
 170                 message_transport_type => $mtt,
 171                 is_html    => $letters->{$mtt}{is_html},
 172                 title      => $letters->{$mtt}{title},
 173                 content    => $letters->{$mtt}{content}//'',
 174             };
 175         }
 176     }
 177     else { # initialize the new fields
 178         for my $mtt ( @$message_transport_types ) {
 179             push @letter_loop, {
 180                 message_transport_type => $mtt,
 181             }
 182         }
 183         $template->param(
 184             branchcode => $branchcode,
 185             module     => $module,
 186         );
 187         $template->param( adding => 1 );
 188     }
 189
 190     $template->param(
 191         letters => \@letter_loop,
 192     );
 193
 194     my $field_selection;
 195     push @{$field_selection}, add_fields('branches');
 196     if ($module eq 'reserves') {
 197         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'items');
 198     }
 199     elsif ($module eq 'claimacquisition') {
 200         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'biblioitems');
 201     }
 202     elsif ($module eq 'claimissues') {
 203         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription');
 204         push @{$field_selection},
 205         {
 206             value => q{},
 207             text => '---BIBLIO---'
 208         };
 209         foreach(qw(title author serial)) {
 210             push @{$field_selection}, {value => "biblio.$_", text => ucfirst $_ };
 211         }
 212     }
 213     elsif ($module eq 'suggestions') {
 214         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 215     }
 216     else {
 217         push @{$field_selection}, add_fields('biblio','biblioitems'),
 218             add_fields('items'),
 219             {value => 'items.content', text => 'items.content'},
 220             {value => 'items.fine',    text => 'items.fine'},
 221             add_fields('borrowers');
 222         if ($module eq 'circulation') {
 223             push @{$field_selection}, add_fields('opac_news');
 224
 225         }
 226
 227         if ( $module eq 'circulation' and $code and $code eq "CHECKIN" ) {
 228             push @{$field_selection}, add_fields('old_issues');
 229         } else {
 230             push @{$field_selection}, add_fields('issues');
 231         }
 232     }
 233
 234     $template->param(
 235         module     => $module,
 236         branchloop => _branchloop($branchcode),
 237         SQLfieldnames => $field_selection,
 238         branchcode => $branchcode,
 239     );
 240     return;
 241 }
 242
 243 sub add_validate {
 244     my $dbh        = C4::Context->dbh;
 245     my $branchcode    = $input->param('branchcode') || '';
 246     my $module        = $input->param('module');
 247     my $oldmodule     = $input->param('oldmodule');
 248     my $code          = $input->param('code');
 249     my $name          = $input->param('name');
 250     my @mtt           = $input->param('message_transport_type');
 251     my @title         = $input->param('title');
 252     my @content       = $input->param('content');
 253     for my $mtt ( @mtt ) {
 254         my $is_html = $input->param("is_html_$mtt");
 255         my $title   = shift @title;
 256         my $content = shift @content;
 257         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt);
 258
 259         # getletter can return the default letter even if we pass a branchcode
 260         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 261         if ( $letter and $branchcode ne $letter->{branchcode} ) {
 262             $letter = undef;
 263         }
 264         unless ( $title and $content ) {
 265             # Delete this mtt if no title or content given
 266             delete_confirmed( $branchcode, $oldmodule, $code, $mtt );
 267             next;
 268         }
 269         elsif ( $letter and $letter->{message_transport_type} eq $mtt ) {
 270             $dbh->do(
 271                 q{
 272                     UPDATE letter
 273                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?
 274                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ?
 275                 },
 276                 undef,
 277                 $branchcode, $module, $name, $is_html || 0, $title, $content,
 278                 $branchcode, $oldmodule, $code, $mtt
 279             );
 280         } else {
 281             $dbh->do(
 282                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type) VALUES (?,?,?,?,?,?,?,?)},
 283                 undef,
 284                 $branchcode, $module, $code, $name, $is_html || 0, $title, $content, $mtt
 285             );
 286         }
 287     }
 288     # set up default display
 289     default_display($branchcode);
 290     return 1;
 291 }
 292
 293 sub delete_confirm {
 294     my ($branchcode, $module, $code) = @_;
 295     my $dbh = C4::Context->dbh;
 296     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 297     my @values = values %$letter;
 298     $template->param(
 299         letter => $letter,
 300     );
 301     return;
 302 }
 303
 304 sub delete_confirmed {
 305     my ($branchcode, $module, $code, $mtt) = @_;
 306     C4::Letters::DelLetter(
 307         {
 308             branchcode => $branchcode,
 309             module     => $module,
 310             code       => $code,
 311             mtt        => $mtt
 312         }
 313     );
 314     # setup default display for screen
 315     default_display($branchcode);
 316     return;
 317 }
 318
 319 sub retrieve_letters {
 320     my ($branchcode, $searchstring) = @_;
 321
 322     $branchcode = $my_branch if $branchcode && $my_branch;
 323
 324     my $dbh = C4::Context->dbh;
 325     my ($sql, @where, @args);
 326     $sql = "SELECT branchcode, module, code, name, branchname
 327             FROM letter
 328             LEFT OUTER JOIN branches USING (branchcode)
 329     ";
 330     if ($searchstring && $searchstring=~m/(\S+)/) {
 331         $searchstring = $1 . q{%};
 332         push @where, 'code LIKE ?';
 333         push @args, $searchstring;
 334     }
 335     elsif ($branchcode) {
 336         push @where, 'branchcode = ?';
 337         push @args, $branchcode || '';
 338     }
 339     elsif ($my_branch) {
 340         push @where, "(branchcode = ? OR branchcode = '')";
 341         push @args, $my_branch;
 342     }
 343
 344     $sql .= " WHERE ".join(" AND ", @where) if @where;
 345     $sql .= " GROUP BY branchcode,module,code";
 346     $sql .= " ORDER BY module, code, branchcode";
 347
 348     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 349 }
 350
 351 sub default_display {
 352     my ($branchcode, $searchfield) = @_;
 353
 354     if ( $searchfield  ) {
 355         $template->param( search      => 1 );
 356     }
 357     my $results = retrieve_letters($branchcode,$searchfield);
 358
 359     my $loop_data = [];
 360     my $protected_letters = protected_letters();
 361     foreach my $row (@{$results}) {
 362         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 363         push @{$loop_data}, $row;
 364
 365     }
 366
 367     $template->param(
 368         letter => $loop_data,
 369         branchloop => _branchloop($branchcode),
 370     );
 371 }
 372
 373 sub _branchloop {
 374     my ($branchcode) = @_;
 375
 376     my $branches = GetBranches();
 377     my @branchloop;
 378     for my $thisbranch (sort { $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname} } keys %$branches) {
 379         push @branchloop, {
 380             value      => $thisbranch,
 381             selected   => $branchcode && $thisbranch eq $branchcode,
 382             branchname => $branches->{$thisbranch}->{'branchname'},
 383         };
 384     }
 385
 386     return \@branchloop;
 387 }
 388
 389 sub add_fields {
 390     my @tables = @_;
 391     my @fields = ();
 392
 393     for my $table (@tables) {
 394         push @fields, get_columns_for($table);
 395
 396     }
 397     return @fields;
 398 }
 399
 400 sub get_columns_for {
 401     my $table = shift;
 402 # FIXME untranslateable
 403     my %column_map = (
 404         aqbooksellers => '---BOOKSELLERS---',
 405         aqorders      => '---ORDERS---',
 406         serial        => '---SERIALS---',
 407         reserves      => '---HOLDS---',
 408         suggestions   => '---SUGGESTIONS---',
 409     );
 410     my @fields = ();
 411     if (exists $column_map{$table} ) {
 412         push @fields, {
 413             value => q{},
 414             text  => $column_map{$table} ,
 415         };
 416     }
 417     else {
 418         my $tlabel = '---' . uc $table;
 419         $tlabel.= '---';
 420         push @fields, {
 421             value => q{},
 422             text  => $tlabel,
 423         };
 424     }
 425
 426     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 427     my $table_prefix = $table . q|.|;
 428     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 429     for my $row (@{$rows}) {
 430         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 431         push @fields, {
 432             value => $table_prefix . $row->{Field},
 433             text  => $table_prefix . $row->{Field},
 434         }
 435     }
 436     if ($table eq 'borrowers') {
 437         if ( my $attributes = C4::Members::Attributes::GetAttributes() ) {
 438             foreach (@$attributes) {
 439                 push @fields, {
 440                     value => "borrower-attribute:$_",
 441                     text  => "attribute:$_",
 442                 }
 443             }
 444         }
 445     }
 446     return @fields;
 447 }