Makefile.PL

   1 # Copyright 2007 MJ Ray
   2 #
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it under the
   6 # terms of the GNU General Public License as published by the Free Software
   7 # Foundation; either version 2 of the License, or (at your option) any later
   8 # version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  11 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  12 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU General Public License along with
  15 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  16 # Suite 330, Boston, MA  02111-1307 USA
  17 #
  18 # Current maintainer MJR http://mjr.towers.org.uk/
  19 # See http://www.koha.org/wiki/?page=KohaInstaller
  20 #
  21
  22 use strict;
  23 use warnings;
  24 use ExtUtils::MakeMaker;
  25 use POSIX;
  26 use File::Spec;
  27 use Getopt::Long;
  28
  29 my $DEBUG = 0;
  30 die "perl 5.6.1 or later required" unless ($] >= 5.006001);
  31
  32 # Hash up directory structure & files beginning with the directory we were called from (should be the base of koha)...
  33
  34 my $dirtree = hashdir('.');
  35 my %result = ();
  36
  37 =head1 NAME
  38
  39 Makefile.PL - Koha packager and installer
  40
  41 =head1 SYNOPSIS
  42
  43 =head2 BASIC INSTALLATION
  44
  45     perl Makefile.PL
  46     make
  47     make test
  48     sudo make install
  49
  50 =head2 UPGRADE INSTALLATION
  51
  52     NOTE: This option is only available if koha-install-log exists.
  53
  54     perl Makefile.PL --prev-install-log /path/to/koha-install-log
  55
  56     make
  57     make test
  58     sudo make upgrade
  59
  60 =head2 PACKAGING RELEASE TARBALLS
  61
  62     make manifest tardist
  63     make manifest zipdist
  64
  65 =head2 CLEANING UP
  66
  67         make clean
  68
  69 =head1 DESCRIPTION
  70
  71 This is a packager and installer that uses
  72 ExtUtils::MakeMaker, which is fairly common
  73 on perl systems.
  74 As well as building tar or zip files
  75 and installing with the above commands,
  76 it allows us to check pre-requisites
  77 and generate configuration files.
  78
  79 =head1 VARIABLES
  80
  81 =head2 NAME, VERSION_FROM, ABSTRACT, AUTHOR
  82
  83 Basic metadata about this software.
  84
  85 =head2 NO_META
  86
  87 Suppress generation of META.yml file.
  88
  89 =head2 PREREQ_PM
  90
  91 Hash of perl modules and versions required.
  92
  93 =head2 PM
  94
  95 Hash of file mappings
  96
  97 =head2 PL_FILES
  98
  99 This is a hash of PL scripts to run after installation and
 100 the files to ask them to generate.
 101 Maybe use the values from CONFIGURE
 102 to generate initial configuration files in future.
 103
 104 =cut
 105
 106 =head2 target_map
 107
 108 This is a hash mapping directories and files in the
 109 source tree to installation target directories.  The rules
 110 for this mapping are:
 111
 112 =over 4
 113
 114 =item If a directory or file is specified, it and its
 115 contents will be copied to the installation target directory.
 116
 117 =item If a subdirectory of a mapped directory is specified,
 118 its target overrides the parent's target for that subdirectory.
 119
 120 =item The value of each map entry may either be a scalar containing
 121 one target or a reference to a hash containing 'target' and 'trimdir'
 122 keys.
 123
 124 =item Any files at the top level of the source tree that are
 125 not included in the map will not be installed.
 126
 127 =item Any directories at the top level of the source tree
 128 that are not included in the map will be installed in
 129 INTRANET_CGI_DIR.  This is a sensible default given the
 130 current organization of the source tree, but (FIXME) it
 131 would be better to reorganize the source tree to better
 132 match the installation system, to allow adding new directories
 133 without having to adjust Makefile.PL each time.  The idea
 134 is to make the C<$target_map> hash as minimal as possible.
 135
 136 =back
 137
 138 The permitted installation targets are:
 139
 140 =over 4
 141
 142 =item INTRANET_CGI_DIR
 143
 144 CGI scripts for intranet (staff) interface.
 145
 146 =item INTRANET_TMPL_DIR
 147
 148 HTML templates for the intranet interface.
 149
 150 =item INTRANET_WWW_DIR
 151
 152 HTML files, images, etc. for DocumentRoot for the intranet interface.
 153
 154 =item OPAC_CGI_DIR
 155
 156 CGI scripts for OPAC (public) interface.
 157
 158 =item OPAC_TMPL_DIR
 159
 160 HTML templates for the OPAC interface.
 161
 162 =item OPAC_WWW_DIR
 163
 164 HTML files, images, etc. for DocumentRoot for the OPAC interface.
 165
 166 =item PERL_MODULE_DIR
 167
 168 Perl modules (at present just the C4 modules) that are intimately
 169 tied to Koha.  Depending on the installation options, these
 170 may or may not be installed one of the standard directories
 171 in Perl's default @LIB.
 172
 173 =item KOHA_CONF_DIR
 174
 175 Directory for Koha configuration files.
 176
 177 =item ZEBRA_CONF_DIR
 178
 179 Directory for Zebra configuration files.
 180
 181 =item ZEBRA_LOCK_DIR
 182
 183 Directory for Zebra's lock files.
 184
 185 =item ZEBRA_DATA_DIR
 186
 187 Directory for Zebra's data files.
 188
 189 =item ZEBRA_RUN_DIR
 190
 191 Directory for Zebra's UNIX-domain sockets.
 192
 193 =item MISC_DIR
 194
 195 Directory for for miscellaenous scripts, among other
 196 things the translation toolkit and RSS feed tools.
 197
 198 =item SCRIPT_DIR
 199
 200 Directory for command-line scripts and daemons to
 201 be set up all for installation modes.
 202
 203 =item SCRIPT_NONDEV_DIR
 204
 205 Directory for command-line scripts that should
 206 be installed in the same directory as the
 207 SCRIPT_DIR target except 'dev' installs.
 208
 209 =item MAN_DIR
 210
 211 Directory for man pages created from POD -- will mostly
 212 contain information of interest to Koha developers.
 213
 214 =item DOC_DIR
 215
 216 Directory for Koha documentation accessed from the
 217 command-line, e.g., READMEs.
 218
 219 =item LOG_DIR
 220
 221 Directory for Apache and Zebra logs produced by Koha.
 222
 223 =item PAZPAR2_CONF_DIR
 224
 225 Directory for PazPar2 configuration files.
 226
 227 =item NONE
 228
 229 This is a dummy target used to explicitly state
 230 that a given file or directory is not to be installed.
 231 This is used either for parts of the installer itself
 232 or for development tools that are not applicable to a
 233 production installation.
 234
 235 =back
 236
 237 =cut
 238
 239 my $target_map = {
 240   './about.pl'                  => 'INTRANET_CGI_DIR',
 241   './acqui'                     => 'INTRANET_CGI_DIR',
 242   './admin'                     => 'INTRANET_CGI_DIR',
 243   './authorities'               => 'INTRANET_CGI_DIR',
 244   './C4'                        => 'PERL_MODULE_DIR',
 245   './C4/SIP/t'                  => 'NONE',
 246   './C4/SIP/koha_test'          => 'NONE',
 247   './C4/tests'                  => 'NONE',
 248   './catalogue'                 => 'INTRANET_CGI_DIR',
 249   './cataloguing'               => 'INTRANET_CGI_DIR',
 250   './changelanguage.pl'         => 'INTRANET_CGI_DIR',
 251   './check_sysprefs.pl'         => 'NONE',
 252   './circ'                      => 'INTRANET_CGI_DIR',
 253   './edithelp.pl'               => 'INTRANET_CGI_DIR',
 254   './etc'                       => { target => 'KOHA_CONF_DIR', trimdir => -1 },
 255   './etc/zebradb'               => { target => 'ZEBRA_CONF_DIR', trimdir => -1 },
 256   './etc/pazpar2'               => { target => 'PAZPAR2_CONF_DIR', trimdir => -1 },
 257   './help.pl'                   => 'INTRANET_CGI_DIR',
 258   './installer-CPAN.pl'         => 'NONE',
 259   './installer'                 => 'INTRANET_CGI_DIR',
 260   './errors'                    => {target => 'INTRANET_CGI_DIR'},
 261   './koha-tmpl/intranet-tmpl'   => {target => 'INTRANET_TMPL_DIR', trimdir => -1},
 262   './koha-tmpl/opac-tmpl'       => {target => 'OPAC_TMPL_DIR', trimdir => -1},
 263   './kohaversion.pl'            => 'INTRANET_CGI_DIR',
 264   './labels'                    => 'INTRANET_CGI_DIR',
 265   './mainpage.pl'               => 'INTRANET_CGI_DIR',
 266   './Makefile.PL'               => 'NONE',
 267   './MANIFEST.SKIP'             => 'NONE',
 268   './members'                   => 'INTRANET_CGI_DIR',
 269   './misc'                      => { target => 'SCRIPT_NONDEV_DIR', trimdir => -1 },
 270   './misc/bin'                  => { target => 'SCRIPT_DIR', trimdir => -1 },
 271   './misc/release_notes'        => { target => 'DOC_DIR', trimdir => 2 },
 272   './misc/translator'           => { target => 'MISC_DIR', trimdir => 2 },
 273   './misc/koha-install-log'     => { target => 'MISC_DIR', trimdir => -1 },
 274   './misc/installer_devel_notes' => 'NONE',
 275   './opac'                      => 'OPAC_CGI_DIR',
 276   './README.txt'                => 'NONE',
 277   './reports'                   => 'INTRANET_CGI_DIR',
 278   './reserve'                   => 'INTRANET_CGI_DIR',
 279   './reviews'                   => 'INTRANET_CGI_DIR',
 280   './rewrite-config.PL'         => 'NONE',
 281   './reviews'                   => 'INTRANET_CGI_DIR',
 282   './rss'                       => 'MISC_DIR',
 283   './serials'                   => 'INTRANET_CGI_DIR',
 284   './skel'                      => 'NONE',
 285   './skel/var/log/koha'         => { target => 'LOG_DIR', trimdir => -1 },
 286   './skel/var/run/koha/zebradb' => { target => 'ZEBRA_RUN_DIR', trimdir => -1 },
 287   './skel/var/lock/koha/zebradb/authorities' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 288   './skel/var/lib/koha/zebradb/authorities/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 289   './skel/var/lib/koha/zebradb/authorities/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 290   './skel/var/lib/koha/zebradb/authorities/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 291   './skel/var/lib/koha/zebradb/authorities/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 292   './skel/var/lock/koha/zebradb/biblios' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 293   './skel/var/lib/koha/zebradb/biblios/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 294   './skel/var/lib/koha/zebradb/biblios/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 295   './skel/var/lib/koha/zebradb/biblios/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 296   './skel/var/lib/koha/zebradb/biblios/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 297   './sms'                       => 'INTRANET_CGI_DIR',
 298   './suggestion'                => 'INTRANET_CGI_DIR',
 299   './svc'                       => 'INTRANET_CGI_DIR',
 300   './t'                         => 'NONE',
 301   './tags'                      => 'INTRANET_CGI_DIR',
 302   './tmp'                       => 'NONE', # FIXME need to determine whether
 303                                            # Koha generates any persistent temp files
 304                                            # that should go in /var/tmp/koha
 305   './tools'                     => 'INTRANET_CGI_DIR',
 306   './virtualshelves'            => 'INTRANET_CGI_DIR',
 307   # ignore files and directories created by the install itself
 308   './pm_to_blib'                => 'NONE',
 309   './blib'                      => 'NONE',
 310 };
 311
 312 =head1 CONFIGURATION OPTIONS
 313
 314 The following configuration options are used by the installer.
 315
 316 =over 4
 317
 318 =item INSTALL_MODE
 319
 320 Specifies whether installation will be FHS-compliant (default,
 321 assumes user has root), put everything under
 322 a single directory (for users installing on a web host
 323 that allows CGI scripts and a MySQL database but not root
 324 access), or development (for a developer who wants to run
 325 Koha from a git clone with no fuss).
 326
 327 =item INSTALL_BASE
 328
 329 Directory under which most components will go.  Default
 330 value will vary depending on INSTALL_MODE.
 331
 332 =item DB_TYPE
 333
 334 Type of DBMS (e.g., mysql or Pg).
 335
 336 =item DB_HOST
 337
 338 Name of DBMS server.
 339
 340 =item DB_PORT
 341
 342 Port that DBMS server is listening on.
 343
 344 =item DB_NAME
 345
 346 Name of the DBMS database for Koha.
 347
 348 =item DB_USER
 349
 350 Name of DBMS user account for Koha's database.
 351
 352 =item DB_PASS
 353
 354 Pasword of DMBS user account for Koha's database.
 355
 356 =item INSTALL_ZEBRA
 357
 358 Whether to install Zebra configuration files and data
 359 directories.
 360
 361 =item ZEBRA_MARC_FORMAT
 362
 363 Specifies format of MARC records to be indexed by Zebra.
 364
 365 =item ZEBRA_LANGUAGE
 366
 367 Specifies primary language of records that will be
 368 indexed by Zebra.
 369
 370 =item ZEBRA_USER
 371
 372 Internal Zebra user account for the index.
 373
 374 =item ZEBRA_PASS
 375
 376 Internal Zebra user account's password.
 377
 378 =item KOHA_USER
 379
 380 System user account that will own Koha's files.
 381
 382 =item KOHA_GROUP
 383
 384 System group that will own Koha's files.
 385
 386 =back
 387
 388 =cut
 389
 390 # default configuration options
 391 my %config_defaults = (
 392   'DB_TYPE'           => 'mysql',
 393   'DB_HOST'           => 'localhost',
 394   'DB_NAME'           => 'koha',
 395   'DB_USER'           => 'kohaadmin',
 396   'DB_PASS'           => 'katikoan',
 397   'INSTALL_ZEBRA'     => 'yes',
 398   'INSTALL_SRU'       => 'yes',
 399   'INSTALL_PAZPAR2'   => 'no',
 400   'AUTH_INDEX_MODE'   => 'grs1',
 401   'ZEBRA_MARC_FORMAT' => 'marc21',
 402   'ZEBRA_LANGUAGE'    => 'en',
 403   'ZEBRA_USER'        => 'kohauser',
 404   'ZEBRA_PASS'        => 'zebrastripes',
 405   'ZEBRA_SRU_HOST'    => 'localhost',
 406   'ZEBRA_SRU_BIBLIOS_PORT'    => '9998',
 407   'ZEBRA_SRU_AUTHORITIES_PORT'    => '9999',
 408   'KOHA_USER'         => 'koha',
 409   'KOHA_GROUP'        => 'koha',
 410   'MERGE_SERVER_HOST' => 'localhost',
 411   'MERGE_SERVER_PORT' => '11001',
 412   'PAZPAR2_HOST' => 'localhost',
 413   'PAZPAR2_PORT' => '11002',
 414   'RUN_DATABASE_TESTS' => 'no',
 415   'PATH_TO_ZEBRA' => '',
 416 );
 417
 418 # set some default configuratio options based on OS
 419 # more conditions need to be added for other OS's
 420 # this should probably also incorporate usage of Win32::GetOSName() and/or Win32::GetOSVersion()
 421 # to allow for more granular decisions based on which Win32 platform
 422
 423 warn "Your platform appears to be $^O.\n" if $DEBUG;
 424
 425 if ( $^O eq 'MSWin32' ) {
 426         # Most Unix2Win32 ports seem to poke everything into the Program Files directory
 427         # this could be changed to put some files (ie. libraries) into system32, etc.
 428         $config_defaults{'INSTALL_MODE'} = 'single';
 429         $config_defaults{'INSTALL_BASE'} = 'c:/progra~1/koha';  # Use 8.3 names to be safe...
 430 }
 431 elsif ( $^O eq 'cygwin' ) {
 432         # Most Unix2Win32 ports seem to poke everything into the Program Files directory
 433         # this could be changed to put some files (ie. libraries) into system32, etc.
 434         $config_defaults{'INSTALL_MODE'} = 'single';
 435         $config_defaults{'INSTALL_BASE'} = 'c:/progra~1/koha';  # Use 8.3 names to be safe...
 436 }
 437 else {
 438         $config_defaults{'INSTALL_MODE'} = 'standard';
 439         $config_defaults{'INSTALL_BASE'} = '/usr/share/koha';
 440 }
 441
 442 # valid values for certain configuration options
 443 my %valid_config_values = (
 444   'INSTALL_MODE'  => { 'standard' => 1, 'single' => 1, 'dev' => 1 },
 445   'DB_TYPE' => { 'mysql' => 1, 'Pg' => 1 },
 446   'INSTALL_ZEBRA' => { 'yes' => 1, 'no' => 1 },
 447   'INSTALL_SRU' => { 'yes' => 1, 'no' => 1 },
 448   'AUTH_INDEX_MODE' => { 'grs1' => 1, 'dom' => 1 },
 449   'ZEBRA_MARC_FORMAT' => { 'marc21' => 1, 'unimarc' => 1 }, # FIXME should generate from contents of distributation
 450   'ZEBRA_LANGUAGE'    => { 'en' => 1, 'fr' => 1 }, # FIXME should generate from contents of distribution
 451   'RUN_DATABASE_TESTS' => { 'yes' => 1, 'no' => 1 },
 452 );
 453
 454 # get settings from command-line
 455 my $koha_install_log = "";
 456 Getopt::Long::Configure('pass_through');
 457 my $results = GetOptions(
 458     "prev-install-log=s" => \$koha_install_log
 459 );
 460
 461 my %install_log_values = ();
 462 if ($koha_install_log ne "") {
 463     get_install_log_values($koha_install_log, \%install_log_values);
 464 }
 465
 466 my %config = get_configuration(\%config_defaults, \%valid_config_values, \%install_log_values);
 467 my ($target_directories, $skip_directories) = get_target_directories(\%config);
 468 display_configuration(\%config, $target_directories);
 469 my $file_map = {};
 470 get_file_map($target_map, $dirtree, $file_map, $config{'INSTALL_ZEBRA'} eq "yes" ? 1: 0);
 471
 472 my $pl_files = {
 473       'rewrite-config.PL' => [
 474          'blib/KOHA_CONF_DIR/koha-conf.xml',
 475          'blib/KOHA_CONF_DIR/koha-httpd.conf',
 476          'blib/MISC_DIR/koha-install-log'
 477          ],
 478           'fix-perl-path.PL' => [       # this script ensures the correct shebang line for the platform installed on...
 479                  'blib'
 480                  ]
 481 };
 482
 483 if ($config{'INSTALL_ZEBRA'} eq "yes") {
 484     push @{ $pl_files->{'rewrite-config.PL'} }, (
 485         'blib/ZEBRA_CONF_DIR/etc/passwd',
 486         'blib/ZEBRA_CONF_DIR/zebra-biblios.cfg',
 487         'blib/ZEBRA_CONF_DIR/zebra-authorities.cfg',
 488         'blib/ZEBRA_CONF_DIR/zebra-authorities-dom.cfg',
 489         'blib/ZEBRA_CONF_DIR/explain-authorities.xml',
 490         'blib/ZEBRA_CONF_DIR/explain-biblios.xml',
 491         'blib/ZEBRA_CONF_DIR/retrieval-info-auth-grs1.xml',
 492         'blib/ZEBRA_CONF_DIR/retrieval-info-auth-dom.xml',
 493     );
 494     push @{ $pl_files->{'rewrite-config.PL'} }, (
 495         'blib/SCRIPT_DIR/koha-zebra-ctl.sh',
 496         'blib/SCRIPT_DIR/koha-pazpar2-ctl.sh',
 497         'blib/SCRIPT_DIR/koha-zebraqueue-ctl.sh',
 498     );
 499     if ($config{'INSTALL_PAZPAR2'} eq 'yes') {
 500         push @{ $pl_files->{'rewrite-config.PL'} }, (
 501             'blib/PAZPAR2_CONF_DIR/koha-biblios.xml',
 502             'blib/PAZPAR2_CONF_DIR/pazpar2.xml'
 503         );
 504     }
 505     $config{'ZEBRA_AUTH_CFG'} = $config{'AUTH_INDEX_MODE'} eq 'dom' ? 'zebra-authorities-dom.cfg' : 'zebra-authorities.cfg';
 506     $config{'AUTH_RETRIEVAL_CFG'} =
 507         $config{'AUTH_INDEX_MODE'} eq 'dom' ? 'retrieval-info-auth-dom.xml' : 'retrieval-info-auth-grs1.xml';
 508 }
 509
 510 if ($config{'INSTALL_MODE'} ne "dev") {
 511     push @{ $pl_files->{'rewrite-config.PL'} }, (
 512         'blib/PERL_MODULE_DIR/C4/Context.pm',
 513         'blib/SCRIPT_NONDEV_DIR/kohalib.pl'
 514     );
 515 }
 516
 517 my %test_suite_override_dirs = (
 518     KOHA_CONF_DIR  => ['etc'],
 519     ZEBRA_CONF_DIR => ['etc', 'zebradb'],
 520     LOG_DIR        => ['var', 'log'],
 521     SCRIPT_DIR     => ['bin'],
 522     ZEBRA_LOCK_DIR => ['var', 'lock', 'zebradb'],
 523     ZEBRA_DATA_DIR => ['var', 'lib', 'zebradb'],
 524     ZEBRA_RUN_DIR  => ['var', 'run', 'zebradb'],
 525 );
 526
 527 WriteMakefile(
 528               NAME         => 'koha',
 529               #VERSION     => strftime('2.9.%Y%m%d%H',gmtime),
 530               VERSION_FROM => 'kohaversion.pl',
 531               ABSTRACT     => 'Award-winning integrated library system (ILS) and Web OPAC',
 532               AUTHOR       => 'Koha Developers <koha-devel@nongnu.org>',
 533               NO_META      => 1,
 534               PREREQ_PM => {
 535                             'Algorithm::CheckDigits'          => 0.50,
 536                             'Biblio::EndnoteStyle'             => 0.05,
 537                             'CGI'                              => 3.15,
 538                             'CGI::Carp'                        => 1.29,
 539                             'CGI::Session'                     => '4.10',
 540                             'Class::Factory::Util'             => 1.6,
 541                             'Class::Accessor'                  => 0.30,
 542                             'DBD::mysql'                       => 4.004,
 543                             'DBI'                              => 1.53,
 544                             'Data::ICal'                       => 0.13,
 545                             'Data::Dumper'                     => 2.121,
 546                             'Date::Calc'                       => 5.4,
 547                             'Date::ICal'                       => 1.72,
 548                             'Date::Manip'                      => 5.44,
 549                             'Digest::MD5'                      => 2.36,
 550                             'Email::Date'                      => 1.103,
 551                             'File::Temp'                       => 0.16,
 552                             'GD'                               => 2.39,    #optional
 553                             'GD::Barcode::UPCE'                => 1.1,
 554                             'Getopt::Long'                     => 2.35,
 555                             'Getopt::Std'                      => 1.05,
 556                             'HTML::Template::Pro'              => 0.69,
 557                             'HTML::Scrubber'                   => 0.08,
 558                             'HTTP::Cookies'                    => 1.39,
 559                             'HTTP::Request::Common'            => 1.26,
 560                             'LWP::Simple'                      => 1.41,
 561                             'LWP::UserAgent'                   => 2.033,
 562                             'Lingua::Stem'                     => 0.82,
 563                             'List::Util'                       => 1.18,
 564                             'List::MoreUtils'                  => 0.21,
 565                             'Locale::Language'                 => 2.07,
 566                             'MARC::Charset'                    => 0.98,
 567                             'MARC::Crosswalk::DublinCore'      => 0.02,
 568                             'MARC::File::XML'                  => 0.88,
 569                             'MARC::Record'                     => 2.00,
 570                             'MIME::Base64'                     => 3.07,
 571                             'MIME::Lite'                       => 3.00,
 572                             'MIME::QuotedPrint'                => 3.07,
 573                             'Mail::Sendmail'                   => 0.79,
 574                             'Net::LDAP'                        => 0.33, # optional
 575                             'Net::LDAP::Filter'                => 0.14, # optional
 576                             'Net::Z3950::ZOOM'                 => 1.16,
 577                             'PDF::API2'                        => 2.000,
 578                             'PDF::API2::Page'                  => 2.000,
 579                             'PDF::API2::Util'                  => 2.000,
 580                             'PDF::Reuse'                       => 0.33,
 581                             'PDF::Reuse::Barcode'              => 0.05,
 582                             'POE'                              => 0.9999,
 583                             'POSIX'                            => 1.09,
 584                             'Schedule::At'                     => 1.06,
 585                             'SMS::Send'                        => 0.05, # optional
 586                             'Term::ANSIColor'                  => 1.10,
 587                             'Test'                             => 1.25,
 588                             'Test::Harness'                    => 2.56,
 589                             'Test::More'                       => 0.62,
 590                             'Text::CSV'                        => 0.01,
 591                             'Text::CSV_XS'                     => 0.32,
 592                             'Text::Iconv'                      => 1.7,
 593                             'Text::Wrap'                       => 2005.082401,
 594                             'Time::HiRes'                      => 1.86,
 595                             'Time::localtime'                  => 1.02,
 596                             'Unicode::Normalize'               => 0.32,
 597                             'XML::Dumper'                      => 0.81,
 598                             'XML::LibXML'                      => 1.59,
 599                             'XML::LibXSLT'                     => 1.59,
 600                             'XML::SAX::ParserFactory'          => 1.01,
 601                             'XML::Simple'                      => 2.14,
 602                             'XML::RSS'                         => 1.31,
 603                             'YAML::Syck'                       => 0.71,
 604                         },
 605
 606               # File tree mapping
 607               PM => $file_map,
 608
 609               # Man pages generated from POD
 610               INSTALLMAN1DIR => File::Spec->catdir($target_directories->{'MAN_DIR'}, 'man1'),
 611               INSTALLMAN3DIR => File::Spec->catdir($target_directories->{'MAN_DIR'}, 'man3'),
 612
 613               PL_FILES => $pl_files,
 614 );
 615
 616 =head1 FUNCTIONS
 617
 618 =head2 hashdir
 619
 620 This function recurses through the directory structure and builds
 621 a hash of hashes containing the structure with arrays holding filenames.
 622 This directory hashing routine was taken from BrowserUK @ http://www.perlmonks.org/?node_id=219919
 623
 624 =cut
 625
 626 sub hashdir{
 627     my $dir = shift;
 628     opendir my $dh, $dir or die $!;
 629     my $tree = {}->{$dir} = {};
 630     while( my $file = readdir($dh) ) {
 631         next if $file =~ m/^\.{1,2}/ and $file !~ /^\.htaccess/; # .htaccess is a special case
 632         my $path = $dir .'/' . $file;
 633         $tree->{$file} = hashdir($path), next if -d $path;
 634         push @{$tree->{'.'}}, $file;
 635     }
 636     return $tree;
 637 }
 638
 639 =head2 get_file_map
 640
 641 This function combines the target_map and file hash to
 642 map each source file to its destination relative to
 643 the set of installation targets.
 644
 645 Output will be a hash mapping from each source file
 646 to its destination value, like this:
 647
 648 'mainpage.pl' => '$(INTRANET_CGI_DIR)/mainpage.pl'
 649
 650 =cut
 651
 652 sub get_file_map {
 653     my $target_map = shift;
 654     my $dirtree = shift;
 655     my $file_map = shift;
 656     my $install_zebra = shift;
 657     my $curr_path = @_ ? shift : ['.'];
 658
 659     # Traverse the directory tree.
 660     # For each file or directory, identify the
 661     # most specific match in the target_map
 662     foreach my $dir (sort keys %{ $dirtree }) {
 663         if ($dir eq '.') {
 664             # deal with files in directory
 665             foreach my $file (sort @{ $dirtree->{$dir} }) {
 666                 my $targetdir = undef;
 667                 my $matchlevel = undef;
 668                 # first, see if there is a match on this specific
 669                 # file in the target map
 670                 my $filepath = join("/", @$curr_path, $file);
 671                 if (exists $target_map->{$filepath}) {
 672                     $targetdir = $target_map->{$filepath};
 673                     $matchlevel = scalar(@$curr_path) + 1;
 674                 } else {
 675                     # no match on the specific file; look for
 676                     # a directory match
 677                     for (my $i = scalar(@$curr_path) - 1; $i >= 0; $i--)  {
 678                         my $dirpath = join("/", @$curr_path[0..$i]);
 679                         if (exists $target_map->{$dirpath}) {
 680                             $targetdir = $target_map->{$dirpath};
 681                             $matchlevel = $i + 1;
 682                             last;
 683                         }
 684                     }
 685                 }
 686                 if (defined $targetdir) {
 687                      _add_to_file_map($file_map, $targetdir, $curr_path, $file, $matchlevel, $install_zebra);
 688                 } else {
 689                     my $path = join("/", @$curr_path);
 690                     print "failed to map: $path/$file\n" if $DEBUG;
 691                 }
 692             }
 693         } else {
 694             # dealing with subdirectory
 695             push @$curr_path, $dir;
 696             get_file_map($target_map, $dirtree->{$dir}, $file_map, $install_zebra, $curr_path);
 697             pop @$curr_path;
 698         }
 699     }
 700 }
 701
 702 sub _add_to_file_map {
 703     my $file_map = shift;
 704     my $targetdir = shift;
 705     my $curr_path = shift;
 706     my $file = shift;
 707     my $matchlevel = shift;
 708     my $install_zebra = shift;
 709     my $dest_path = @_ ? shift : $curr_path;
 710
 711     # The target can be one of the following:
 712     # 1. scalar representing target symbol
 713     # 2. hash ref containing target and trimdir keys
 714     #
 715     # Consequently, this routine traverses this structure,
 716     # calling itself recursively, until it deals with
 717     # all of the scalar target symbols.
 718     if (ref $targetdir eq 'HASH') {
 719         my $subtarget = $targetdir->{target};
 720         if (exists $targetdir->{trimdir}) {
 721             # if we get here, we've specified that
 722             # rather than installing the file to
 723             # $(TARGET)/matching/dirs/subdirs/file,
 724             # we want to install it to
 725             # $(TARGET)/subdirs/file
 726             #
 727             # Note that this the only place where
 728             # $matchlevel is used.
 729             my @new_dest_path = @$dest_path;
 730             if ($targetdir->{trimdir} == -1)  {
 731                 splice @new_dest_path, 0, $matchlevel;
 732             } else {
 733                 splice @new_dest_path, 0, $targetdir->{trimdir};
 734             }
 735             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, $install_zebra, \@new_dest_path);
 736         } else {
 737             # actually getting here means that the
 738             # target was unnecessarily listed
 739             # as a hash, but we'll forgive that
 740             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, $install_zebra);
 741         }
 742     } elsif ($targetdir ne 'NONE' and $targetdir ne '') {
 743         my $source = File::Spec->catfile(@$curr_path, $file);
 744         my $destination = File::Spec->catfile('blib', $targetdir, @$dest_path, $file);
 745         #print "$source => $destination\n"; # DEBUG
 746         # quote spaces in file names
 747         # FIXME: this is of questionable portability and
 748         # probably depends on user's make recognizing this
 749         # quoting syntax -- probably better to remove
 750         # spaces and shell metacharacters from all file names
 751         $source =~ s/ /\\ /g;
 752         $destination =~ s/ /\\ /g;
 753
 754         $file_map->{$source} = $destination unless (!$install_zebra and $targetdir =~ /ZEBRA/);
 755     }
 756 }
 757
 758 =head2 get_install_log_values
 759
 760 Reads value from the Koha install log specified by
 761 --prev-install-log
 762
 763 =cut
 764
 765 sub get_install_log_values {
 766     my $install_log = shift;
 767     my $values = shift;
 768
 769     open LOG, "<$install_log" or die "Cannot open install log $install_log: $!\n";
 770     while (<LOG>) {
 771         chomp;
 772         next if /^#/ or /^\s*$/;
 773         next if /^=/;
 774         next unless m/=/;
 775         s/\s+$//g;
 776         my ($key, $value) = split /=/, $_, 2;
 777         $values->{$key} = $value;
 778     }
 779     close LOG;
 780
 781     print <<_EXPLAIN_INSTALL_LOG_;
 782 Reading values from install log $install_log.  You
 783 will be prompted only for settings that have been
 784 added since the last time you installed Koha.  To
 785 be prompted for all settings, run 'perl Makefile.PL'
 786 without the --prev-install-log option.
 787 _EXPLAIN_INSTALL_LOG_
 788 }
 789
 790 =head2 get_configuration
 791
 792 This prompts the user for various configuration options.
 793
 794 =cut
 795
 796 sub get_configuration {
 797   my $defaults = shift;
 798   my $valid_values = shift;
 799   my $install_log_values = shift;
 800   my %config = ();
 801
 802   my $msg = q(
 803 By default, Koha can be installed in one of three ways:
 804
 805 standard: Install files in conformance with the Filesystem
 806           Hierarchy Standard (FHS).  This is the default mode
 807           and should be used when installing a production
 808           Koha system.  On Unix systems, root access is
 809           needed to complete a standard installation.
 810
 811 single:   Install files under a single directory.  This option
 812           is useful for installing Koha without root access, e.g.,
 813           on a web host that allows CGI scripts and MySQL databases
 814           but requires the user to keep all files under the user's
 815           HOME directory.
 816
 817 dev:      Create a set of symbolic links and configuration files to
 818           allow Koha to run directly from the source distribution.
 819           This mode is useful for developers who want to run
 820           Koha from a git clone.
 821
 822 Installation mode);
 823     $msg .= _add_valid_values_disp('INSTALL_MODE', $valid_values);
 824     $config{'INSTALL_MODE'} = _get_value('INSTALL_MODE', $msg, $defaults->{'INSTALL_MODE'}, $valid_values, $install_log_values);
 825
 826     # set message and default value for INSTALL_BASE
 827     # depending on value of INSTALL_MODE
 828     my $install_base_default = $defaults->{'INSTALL_BASE'};
 829     if ($config{'INSTALL_MODE'} eq 'dev') {
 830         $msg = q(
 831 Please specify the directory in which to install Koha's
 832 active configuration files and (if applicable) the
 833 Zebra database.  Koha's CGI scripts and templates will
 834 be run from the current directory.
 835
 836 Configuration directory:);
 837         # FIXME - home directory portability consideration apply
 838         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha-dev" : "$defaults->{'INSTALL_BASE'}-dev";
 839     } elsif ($config{'INSTALL_MODE'} eq 'single') {
 840         $msg = "\nPlease specify the directory in which to install Koha";
 841         # FIXME -- we're assuming under a 'single' mode install
 842         # that user will likely want to install under the home
 843         # directory.  This is OK in and of itself, but we should
 844         # use File::HomeDir to locate the home directory portably.
 845         # This is deferred for now because File::HomeDir is not yet
 846         # core.
 847                 # --we must also keep this portable to the major OS's -fbcit
 848         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha" : $defaults->{'INSTALL_BASE'};
 849     } else {
 850         # must be standard
 851         $msg = q(
 852 Please specify the directory under which most Koha files
 853 will be installed.
 854
 855 Note that if you are planning in installing more than
 856 one instance of Koha, you may want to modify the last
 857 component of the directory path, which will be used
 858 as the package name in the FHS layout.
 859
 860 Base installation directory);
 861     }
 862     $config{'INSTALL_BASE'} = _get_value('INSTALL_BASE', $msg, $install_base_default, $valid_values, $install_log_values);
 863
 864     $config{'INSTALL_BASE'} = File::Spec->rel2abs($config{'INSTALL_BASE'});
 865         print "INSTALL_BASE=$config{'INSTALL_BASE'}\r\n" if $DEBUG;
 866     if ($config{'INSTALL_MODE'} eq "standard") {
 867         $msg = q(
 868 Since you are using the 'standard' install
 869 mode, you should run 'make install' as root.
 870 However, it is recommended that a non-root
 871 user (on Unix and Linux platforms) have
 872 ownership of Koha's files, including the
 873 Zebra indexes if applicable.
 874
 875 Please specify a user account.  This
 876 user account does not need to exist
 877 right now, but it needs to exist
 878 before you run 'make install'.  Please
 879 note that for security reasons, this
 880 user should not be the same as the user
 881 account Apache runs under.
 882
 883 User account);
 884         $config{'KOHA_USER'} = _get_value('KOHA_USER', $msg, $defaults->{'KOHA_USER'}, $valid_values, $install_log_values);
 885
 886         $msg = q(
 887 Please specify the group that should own
 888 Koha's files.  As above, this group need
 889 not exist right now, but should be created
 890 before you run 'make install'.
 891
 892 Group);
 893         $config{'KOHA_GROUP'} = _get_value('KOHA_GROUP', $msg, $defaults->{'KOHA_GROUP'}, $valid_values, $install_log_values);
 894     }
 895
 896     $msg = q(
 897 Please specify which database engine you will use
 898 to store data in Koha.  The choices are MySQL and
 899 PostgreSQL; please note that at the moment
 900 PostgreSQL support is highly experimental.
 901
 902 DBMS to use);
 903     $msg .= _add_valid_values_disp('DB_TYPE', $valid_values);
 904     $config{'DB_TYPE'} = _get_value('DB_TYPE', $msg, $defaults->{'DB_TYPE'}, $valid_values, $install_log_values);
 905
 906     $msg = q(
 907 Please specify the name or address of your
 908 database server.  Note that the database
 909 does not have to exist at this point, it
 910 can be created after running 'make install'
 911 and before you try using Koha for the first time.
 912
 913 Database server);
 914     $config{'DB_HOST'} = _get_value('DB_HOST', $msg, $defaults->{'DB_HOST'}, $valid_values, $install_log_values);
 915
 916     $msg = q(
 917 Please specify the port used to connect to the
 918 DMBS);
 919     my $db_port_default = $config{'DB_TYPE'} eq 'mysql' ? '3306' : '5432';
 920     $config{'DB_PORT'} = _get_value('DB_PORT', $msg, $db_port_default, $valid_values, $install_log_values);
 921
 922     $msg = q(
 923 Please specify the name of the database to be
 924 used by Koha);
 925     $config{'DB_NAME'} = _get_value('DB_NAME', $msg, $defaults->{'DB_NAME'}, $valid_values, $install_log_values);
 926
 927     $msg = q(
 928 Please specify the user that owns the database to be
 929 used by Koha);
 930     $config{'DB_USER'} = _get_value('DB_USER', $msg, $defaults->{'DB_USER'}, $valid_values, $install_log_values);
 931
 932     $msg = q(
 933 Please specify the password of the user that owns the
 934 database to be used by Koha);
 935     $config{'DB_PASS'} = _get_value('DB_PASS', $msg, $defaults->{'DB_PASS'}, $valid_values, $install_log_values);
 936
 937     $msg = q(
 938 Koha can use the Zebra search engine for high-performance
 939 searching of bibliographic and authority records.  If you
 940 have installed the Zebra software and would like to use it,
 941 please answer 'yes' to the following question.  Otherwise,
 942 Koha will default to using its internal search engine.
 943
 944 Please note that if you choose *NOT* to install Zebra,
 945 koha-conf.xml will still contain some references to Zebra
 946 settings.  Those references will be ignored by Koha.
 947
 948 Install the Zebra configuration files?);
 949     $msg .= _add_valid_values_disp('INSTALL_ZEBRA', $valid_values);
 950     $config{'INSTALL_ZEBRA'} = _get_value('INSTALL_ZEBRA', $msg, $defaults->{'INSTALL_ZEBRA'}, $valid_values, $install_log_values);
 951
 952     if ($config{'INSTALL_ZEBRA'} eq 'yes') {
 953
 954         if (defined(my $zebra_path = find_zebra())) {
 955             $config{'PATH_TO_ZEBRA'} = $zebra_path;
 956             print qq(
 957 Found 'zebrasrv' and 'zebraidx' in $zebra_path.
 958 );
 959         } else {
 960             print q(
 961 Unable to find the Zebra programs 'zebrasrv' and 'zebraidx'
 962 in your PATH or in some of the usual places.  If you haven't
 963 installed Zebra yet, please do so and run Makefile.PL again.
 964
 965 );
 966         }
 967
 968         $msg = q(
 969 Since you've chosen to use Zebra with Koha,
 970 you must specify the primary MARC format of the
 971 records to be indexed by Zebra.
 972
 973 Koha provides Zebra configuration files for MARC 21
 974 and UNIMARC.
 975
 976 MARC format for Zebra indexing);
 977         $msg .= _add_valid_values_disp('ZEBRA_MARC_FORMAT', $valid_values);
 978         $config{'ZEBRA_MARC_FORMAT'} = _get_value('ZEBRA_MARC_FORMAT', $msg, $defaults->{'ZEBRA_MARC_FORMAT'}, $valid_values, $install_log_values);
 979         $msg = q(
 980 Koha supplies Zebra configuration files tuned for
 981 searching either English (en) or French (fr) MARC
 982 records.
 983
 984 Primary language for Zebra indexing);
 985         $msg .= _add_valid_values_disp('ZEBRA_LANGUAGE', $valid_values);
 986         $config{'ZEBRA_LANGUAGE'} = _get_value('ZEBRA_LANGUAGE', $msg, $defaults->{'ZEBRA_LANGUAGE'}, $valid_values, $install_log_values);
 987
 988         $msg = q(
 989 Koha can use one of  two different indexing modes
 990 for the MARC authorities records:
 991
 992 grs1 - uses the Zebra GRS-1 filter, available
 993        for legacy support
 994 dom  - uses the DOM XML filter; offers improved
 995        functionality.
 996
 997 Authorities indexing mode);
 998         $msg .= _add_valid_values_disp('AUTH_INDEX_MODE', $valid_values);
 999         $config{'AUTH_INDEX_MODE'} = _get_value('AUTH_INDEX_MODE', $msg, $defaults->{'AUTH_INDEX_MODE'}, $valid_values, $install_log_values);
1000
1001         $msg = q(
1002 Please specify Zebra database user);
1003         $config{'ZEBRA_USER'} = _get_value('ZEBRA_USER', $msg, $defaults->{'ZEBRA_USER'}, $valid_values, $install_log_values);
1004
1005         $msg = q(
1006 Please specify the Zebra database password);
1007         $config{'ZEBRA_PASS'} = _get_value('ZEBRA_PASS', $msg, $defaults->{'ZEBRA_PASS'}, $valid_values, $install_log_values);
1008
1009         $msg = q(
1010 Since you've chosen to use Zebra, you can enable the SRU/
1011 Z39.50 Server if you so choose, but you must specify a
1012 few configuration options for it.
1013
1014 Please note that if you choose *NOT* to configure SRU,
1015 koha-conf.xml will still contain some references to SRU
1016 settings.  Those references will be ignored by Koha.
1017
1018 Install the SRU configuration files?);
1019         $msg .= _add_valid_values_disp('INSTALL_SRU', $valid_values);
1020         $config{'INSTALL_SRU'} = _get_value('INSTALL_SRU', $msg, $defaults->{'INSTALL_SRU'}, $valid_values, $install_log_values);
1021
1022         if ($config{'INSTALL_SRU'} eq 'yes') {
1023             $msg = q(
1024 Since you've chosen to configure SRU, you must
1025 specify the host and port(s) that the SRU
1026 Servers (bibliographic and authority) should run on.
1027 );
1028             $msg = q(
1029 SRU Database host?);
1030             $config{'ZEBRA_SRU_HOST'} = _get_value('ZEBRA_SRU_HOST', $msg, $defaults->{'ZEBRA_SRU_HOST'}, $valid_values, $install_log_values);
1031
1032             $msg = q(
1033 SRU port for bibliographic data?);
1034             $config{'ZEBRA_SRU_BIBLIOS_PORT'} = _get_value('ZEBRA_SRU_BIBLIOS_PORT', $msg, $defaults->{'ZEBRA_SRU_BIBLIOS_PORT'}, $valid_values, $install_log_values);
1035
1036             $msg = q(
1037 SRU port for authority data?);
1038             $config{'ZEBRA_SRU_AUTHORITIES_PORT'} = _get_value('ZEBRA_SRU_AUTHORITIES_PORT', $msg, $defaults->{'ZEBRA_SRU_AUTHORITIES_PORT'}, $valid_values, $install_log_values);
1039
1040         }
1041
1042         $msg = q(
1043 Since you've chosen to use Zebra, you can also choose to
1044 install PazPar2, which is a metasearch tool.  With PazPar2,
1045 Koha can perform on-the-fly merging of bibliographic
1046 records during searching, allowing for FRBRization of
1047 the results list.
1048
1049 Install the PazPar2 configuration files?);
1050         $msg .= _add_valid_values_disp('INSTALL_PAZPAR2', $valid_values);
1051         $config{'INSTALL_PAZPAR2'} = _get_value('INSTALL_PAZPAR2', $msg, $defaults->{'INSTALL_PAZPAR2'}, $valid_values, $install_log_values);
1052
1053         if ($config{'INSTALL_PAZPAR2'} eq 'yes') {
1054             $msg = q(
1055 Since you've chosen to configure PazPar2, you must
1056 specify the host and port(s) that PazPar2
1057 uses:
1058 );
1059             $msg = q(
1060 Zebra bibliographic server host?);
1061             $config{'MERGE_SERVER_HOST'} = _get_value('MERGE_SERVER_HOST', $msg, $defaults->{'MERGE_SERVER_HOST'}, $valid_values, $install_log_values);
1062
1063             $msg = q(
1064 Zebra bibliographic port for PazPar2 to use?);
1065             $config{'MERGE_SERVER_PORT'} = _get_value('MERGE_SERVER_PORT', $msg, $defaults->{'MERGE_SERVER_PORT'}, $valid_values, $install_log_values);
1066
1067             $msg = q(
1068 PazPar2 host?);
1069             $config{'PAZPAR2_HOST'} = _get_value('PAZPAR2_HOST', $msg, $defaults->{'PAZPAR2_HOST'}, $valid_values, $install_log_values);
1070
1071             $msg = q(
1072 PazPar2 port?);
1073             $config{'PAZPAR2_PORT'} = _get_value('PAZPAR2_PORT', $msg, $defaults->{'PAZPAR2_PORT'}, $valid_values, $install_log_values);
1074
1075         }
1076     }
1077
1078   $msg = q(
1079 Would you like to run the database-dependent test suite?);
1080   $msg .= _add_valid_values_disp( 'RUN_DATABASE_TESTS', $valid_values );
1081     $config{'RUN_DATABASE_TESTS'} = _get_value( 'RUN_DATABASE_TESTS', $msg, $defaults->{'RUN_DATABASE_TESTS'}, $valid_values, $install_log_values );
1082
1083   if ( $config{'RUN_DATABASE_TESTS'} eq 'yes' ) {
1084       $config{'TEST_DB_TYPE'} = $config{'DB_TYPE'};
1085       $config{'TEST_DB_HOST'} = $config{'DB_HOST'};
1086       $msg = q(TEST DATABASE
1087
1088 THE DATA IN THIS DATABASE WILL BE DESTROYED during the process of
1089 testing. Please don't do this on your production database. It is not
1090 reversable.
1091
1092 YOU WILL SUFFER DATA LOSS if you run this test suite on your test
1093 database. You are better off not running this optional test suite than
1094 doing it in a database that you don't want to lose.
1095
1096 Please specify the name of the test database to be
1097 used by Koha);
1098
1099       $config{'TEST_DB_NAME'} = _get_value('TEST_DB_NAME', $msg, $defaults->{'TEST_DB_NAME'}, $valid_values, $install_log_values);
1100       while ( $config{'TEST_DB_NAME'} eq $config{'DB_NAME'} ) {
1101           $msg = q(Please do not use the same database for testing as you do for production. You run the severe risk of data loss.);
1102           $config{'TEST_DB_NAME'} = _get_value('TEST_DB_NAME', $msg, $defaults->{'TEST_DB_NAME'}, $valid_values, $install_log_values);
1103       }
1104
1105       $msg = q(
1106 Please specify the user that owns the database to be
1107 used by Koha);
1108     $config{'TEST_DB_USER'} = _get_value('TEST_DB_USER', $msg, $defaults->{'TEST_DB_USER'}, $valid_values, $install_log_values);
1109
1110       $msg = q(
1111 Please specify the password of the user that owns the
1112 database to be used by Koha);
1113       $config{'TEST_DB_PASS'} = _get_value('TEST_DB_PASS', $msg, $defaults->{'TEST_DB_PASS'}, $valid_values, $install_log_values);
1114   }
1115
1116     print "\n\n";
1117
1118     # add version number
1119     my $version = "no_version_found";
1120     eval {
1121         require 'kohaversion.pl';
1122         $version = kohaversion();
1123     };
1124     $config{'KOHA_INSTALLED_VERSION'} = $version;
1125
1126     return %config;
1127 }
1128
1129 sub _add_valid_values_disp {
1130     my $key = shift;
1131     my $valid_values = shift;
1132
1133     my $disp = "";
1134     if (exists $valid_values->{$key}) {
1135         $disp = " (" . join(", ", sort keys %{ $valid_values->{$key} }) . ")";
1136     }
1137     return $disp;
1138 }
1139
1140 sub _get_value {
1141     my $key = shift;
1142     my $msg = shift;
1143     my $default = shift;
1144     my $valid_values = shift;
1145     my $install_log_values = shift;
1146
1147     # take value from install log if present
1148     if (exists $install_log_values{$key}) {
1149         return $install_log_values{$key};
1150     }
1151
1152     # override default value from environment
1153     if (exists $ENV{$key}) {
1154         $default = $ENV{$key};
1155         $msg .= " (default from environment)";
1156     }
1157
1158     my $val = prompt($msg, $default);
1159
1160     while (exists $valid_values->{$key} and
1161            $val ne $default and
1162            not exists $valid_values->{$key}->{$val}) {
1163         my $retry_msg = "Value '$val' is not a valid option.\n";
1164         $retry_msg .= "Please enter a value";
1165         $retry_msg .= _add_valid_values_disp($key, $valid_values);
1166         $val = prompt($retry_msg, $default);
1167     }
1168     return $val;
1169 }
1170
1171 =head2 get_target_directories
1172
1173 Creates a hash mapping from symbols for installation target
1174 directories to actual directory paths.
1175
1176 Also returns a hash indicating targets for which
1177 files need not be copied -- this is used for the 'dev'
1178 mode installation, where some files are installed in place.
1179
1180 =cut
1181
1182 sub get_target_directories {
1183     my $config = shift;
1184
1185     my $base = $config->{'INSTALL_BASE'};
1186     my $mode = $config->{'INSTALL_MODE'};
1187
1188     # get last component of install base directory
1189     # to treat as package name
1190     my ($volume, $directories, $file) = File::Spec->splitpath($base, 1);
1191
1192     my @basedir = File::Spec->splitdir($directories);
1193
1194         # for Win32 we need to prepend the volume to the directory path
1195         if ( $^O eq 'MSWin32' ) { shift @basedir; unshift @basedir, $volume; }
1196         elsif ( $^O eq 'cygwin' ) { shift @basedir; unshift @basedir, 'c:'; }   # in a cygwin environment, $volume is returned empty
1197
1198     my $package = pop @basedir;
1199
1200
1201     my %dirmap = ();
1202     my %skipdirs = ();
1203     if ($mode eq 'single') {
1204         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
1205         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
1206         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
1207         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
1208         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
1209         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
1210         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1211         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
1212         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
1213         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'pazpar2');
1214         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1215         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1216         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1217         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1218         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1219         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
1220         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
1221         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
1222         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
1223     } elsif ($mode eq 'dev') {
1224         my $curdir = File::Spec->rel2abs(File::Spec->curdir());
1225         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir($curdir);
1226         $skipdirs{'INTRANET_CGI_DIR'} = 1;
1227         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
1228         $skipdirs{'INTRANET_TMPL_DIR'} = 1;
1229         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
1230         $skipdirs{'INTRANET_WWW_DIR'} = 1;
1231         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir($curdir);
1232         $skipdirs{'OPAC_CGI_DIR'} = 1;
1233         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
1234         $skipdirs{'OPAC_TMPL_DIR'} = 1;
1235         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
1236         $skipdirs{'OPAC_WWW_DIR'} = 1;
1237         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir($curdir);
1238         $skipdirs{'PERL_MODULE_DIR'} = 1;
1239         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
1240         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
1241         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'pazpar2');
1242         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1243         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1244         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1245         $skipdirs{'SCRIPT_NONDEV_DIR'} = 1;
1246         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1247         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1248         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
1249         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
1250         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
1251         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
1252     } else {
1253         # mode is standard, i.e., 'fhs'
1254         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
1255         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
1256         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
1257         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
1258         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
1259         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
1260         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1261         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package);
1262         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'zebradb');
1263         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'pazpar2');
1264         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1265         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1266         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1267         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1268         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1269         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package, 'zebradb');
1270         $dirmap{'LOG_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'log', $package);
1271         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'zebradb');
1272         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'run', $package, 'zebradb');
1273     }
1274
1275     _get_env_overrides(\%dirmap);
1276     _get_argv_overrides(\%dirmap);
1277
1278     return \%dirmap, \%skipdirs;
1279 }
1280
1281 =head2 get_test_dir
1282
1283 Map a directory target to the corresponding path for
1284 the test suite.
1285
1286 =cut
1287
1288 sub get_test_dir {
1289     my ($dirname) = @_;
1290
1291     my @basedir = (File::Spec->rel2abs(File::Spec->curdir()), 't', 'run');
1292     if (exists $test_suite_override_dirs{$dirname}) {
1293         return File::Spec->catdir(@basedir, @{ $test_suite_override_dirs{$dirname} });
1294     } else {
1295         return;
1296     }
1297
1298 }
1299
1300 sub _get_env_overrides {
1301     my $dirmap = shift;
1302
1303     foreach my $key (keys %$dirmap) {
1304         if (exists $ENV{$key}) {
1305             $dirmap->{$key} = $ENV{$key};
1306             print "Setting $key from environment\n";
1307         }
1308     }
1309 }
1310
1311 sub _get_argv_overrides {
1312     my $dirmap = shift;
1313
1314     my @new_argv = ();
1315     for (my $i = 0; $i <= $#ARGV; $i++) {
1316         if ($ARGV[$i] =~ /^([^=]+)=([^=]+)$/ and exists $dirmap->{$1}) {
1317             $dirmap->{$1} = $2;
1318         } else {
1319             push @new_argv, $ARGV[$i];
1320         }
1321     }
1322     @ARGV = @new_argv;
1323 }
1324
1325 sub display_configuration {
1326     my $config = shift;
1327     my $dirmap = shift;
1328     print "\n\nKoha will be installed with the following configuration parameters:\n\n";
1329     foreach my $key (sort keys %$config) {
1330         print sprintf("%-25.25s%s\n", $key, $config->{$key});
1331     }
1332
1333     print "\nand in the following directories:\n\n";
1334     foreach my $key (sort keys %$dirmap) {
1335         print sprintf("%-25.25s%s\n", $key, $dirmap->{$key});
1336     }
1337     print "\n\nTo change any configuration setting, please run\n";
1338     print "perl Makefile.PL again.  To override one of the target\n";
1339     print "directories, you can do so on the command line like this:\n";
1340     print "\nperl Makefile.PL PERL_MODULE_DIR=/usr/share/perl/5.8\n\n";
1341     print "You can also set different default values for parameters\n";
1342     print "or override directory locations by using environment variables.\n";
1343     print "\nFor example:\n\n";
1344     print "export DB_USER=my_koha\n";
1345     print "perl Makefile.PL\n";
1346     print "\nor\n\n";
1347     print "DB_USER=my_koha DOC_DIR=/usr/local/info perl Makefile.PL\n\n";
1348     print "If installing on a Win32 platform, be sure to use:\n";
1349     print "'dmake -x MAXLINELENGTH=300000'\n\n";
1350 }
1351
1352 =head2 find_zebra
1353
1354 Attempt to find Zebra - check user's PATH and
1355 a few other directories for zebrasrv and zebraidx.
1356
1357 FIXME: doesn't handle Win32
1358
1359 =cut
1360
1361 sub find_zebra {
1362     my @search_dirs = map {
1363                             my $abs = File::Spec->rel2abs($_);
1364                             my ($toss, $directories);
1365                             ($toss, $directories, $toss) = File::Spec->splitpath($abs, 1);
1366                             $directories;
1367                         }  split /:/, $ENV{PATH};
1368     push @search_dirs, qw(/usr/local/bin /opt/local/bin /usr/bin);
1369     my @zebrasrv_dirs = grep { -x File::Spec->catpath('', $_, 'zebrasrv') } @search_dirs;
1370     return unless @zebrasrv_dirs;
1371     # verify that directory that contains zebrasrv also contains zebraidx
1372     foreach my $dir (@zebrasrv_dirs) {
1373         return $dir if -x File::Spec->catpath('', $dir, 'zebraidx');
1374     }
1375     return;
1376 }
1377
1378 package MY;
1379
1380 # This will have to be reworked in order to accommodate Win32...
1381
1382 sub test {
1383     my $self = shift;
1384     my $test = $self->SUPER::test(@_);
1385     $test =~ s!\$\(INST_LIB\)!blib/PERL_MODULE_DIR!g;
1386
1387     # set KOHA_CONF
1388     $test =~ s!\$\(FULLPERLRUN\)!KOHA_CONF=blib/KOHA_CONF_DIR/koha-conf.xml \$(FULLPERLRUN)!g;
1389     return $test;
1390 }
1391
1392 sub install {
1393     my $self = shift;
1394     my $install = "";
1395     # NOTE: we're *not* doing this: my $install = $self->SUPER::install(@_);
1396     # This means that we're completely overriding EU::MM's default
1397     # installation and uninstallation targets.
1398
1399 # If installation is on Win32, we need to do permissions different from *nix
1400     if ( $^O =~ /darwin|linux|cygwin|freebsd/ ) { # this value needs to be verified for each platform and modified accordingly
1401             foreach my $key (sort keys %$target_directories) {
1402                     $install .= qq(
1403 KOHA_INST_$key = blib/$key
1404 KOHA_DEST_$key = $target_directories->{$key}
1405 )                       unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1406                 }
1407                 $install .= qq(
1408 install :: all install_koha set_koha_ownership set_koha_permissions warn_koha_env_vars
1409 \t\$(NOECHO) \$(NOOP)
1410 );
1411                         $install .= "install_koha ::\n";
1412                         $install .= "\t\$(NOECHO) umask 022; \$(MOD_INSTALL) \\\n";
1413                         foreach my $key (sort keys %$target_directories) {
1414                                 $install .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1415                                         unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1416                         }
1417                         $install .= "\t\t\$(INST_MAN1DIR) \$(DESTINSTALLMAN1DIR) \\\n";
1418                         $install .= "\t\t\$(INST_MAN3DIR) \$(DESTINSTALLMAN3DIR)\n";
1419
1420                         $install .= "\n";
1421                         $install .= "set_koha_ownership ::\n";
1422                         if ($config{'INSTALL_MODE'} eq 'standard' and $config{'KOHA_USER'} ne "root") {
1423                                 foreach my $key (sort keys %$target_directories) {
1424                                         $install .= "\t\$(NOECHO) chown -R $config{'KOHA_USER'}:$config{'KOHA_GROUP'} \$(KOHA_DEST_$key)\n"
1425                                                 unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1426                                 }
1427                         } else {
1428                                 $install .= "\t\t\$(NOECHO) \$(NOOP)\n\n";
1429                         }
1430
1431                         $install .= "\n";
1432                         $install .= "set_koha_permissions ::\n";
1433                         # This is necessary because EU::MM installs files
1434                         # as either 0444 or 0555, and we want the owner
1435                         # of Koha's files to have write permission by default.
1436                         foreach my $key (sort keys %$target_directories) {
1437                                 $install .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_$key)\n"
1438                                         unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1439                         }
1440         }
1441         elsif ($^O eq 'MSWin32' ) {     # On Win32, the install probably needs to be done under the user account koha will be running as...
1442                                                                 # We can attempt some creative things with command line utils such as CACLS which allows permission
1443                                                                 # management from Win32 cmd.exe, but permissions really only apply to NTFS.
1444             foreach my $key (sort keys %$target_directories) {
1445                     $install .= qq(
1446 KOHA_INST_$key = blib/$key
1447 KOHA_DEST_$key = $target_directories->{$key}
1448 )                       unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1449                 }
1450                 $install .= qq(
1451 install :: all install_koha warn_koha_env_vars
1452 \t\$(NOECHO) \$(NOOP)
1453 );
1454                 $install .= "install_koha ::\n";
1455                 $install .= "\t\$(MOD_INSTALL) \\\n";
1456                 foreach my $key (sort keys %$target_directories) {
1457                         $install .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1458                                 unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or exists $skip_directories->{$key};
1459                 }
1460         }
1461         $install .= "\n";
1462
1463     $install .= "warn_koha_env_vars ::\n";
1464     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1465     $install .= "\t\$(NOECHO) \$(ECHO) Koha\\'s files have now been installed. \n";
1466     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1467     $install .= "\t\$(NOECHO) \$(ECHO) In order to use Koha\\'s command-line batch jobs,\n";
1468     $install .= "\t\$(NOECHO) \$(ECHO) you should set the following environment variables:\n";
1469     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1470     $install .= "\t\$(NOECHO) \$(ECHO) export KOHA_CONF=\$(KOHA_DEST_KOHA_CONF_DIR)/koha-conf.xml\n";
1471     $install .= "\t\$(NOECHO) \$(ECHO) export PERL5LIB=$target_directories->{'PERL_MODULE_DIR'}\n";
1472     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1473     $install .= "\t\$(NOECHO) \$(ECHO) For other post-installation tasks, please consult the README.\n";
1474     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1475
1476     if ($config{'INSTALL_ZEBRA'} eq "yes") {
1477         $install .= _update_zebra_conf_target();
1478     }
1479
1480     $install .= upgrade();
1481
1482     return $install;
1483 }
1484
1485 =head2 _update_zebra_conf_target
1486
1487 Add an installation target for updating
1488 Zebra's configuration files.
1489
1490 =cut
1491
1492 sub _update_zebra_conf_target {
1493
1494     my $target = "\nupdate_zebra_conf ::\n";
1495     $target .= "\tumask 022; \$(MOD_INSTALL) \\\n";
1496     $target .= "\t\t\$(KOHA_INST_ZEBRA_CONF_DIR) \$(KOHA_DEST_ZEBRA_CONF_DIR) \n";
1497     $target .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_ZEBRA_CONF_DIR)\n" unless $^O eq "MSWin32";
1498     $target .= "\tumask 022; \$(MOD_INSTALL) \\\n";
1499     $target .= "\t\t\$(KOHA_INST_PAZPAR2_CONF_DIR) \$(KOHA_DEST_PAZPAR2_CONF_DIR) \n";
1500     $target .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_PAZPAR2_CONF_DIR)\n" unless $^O eq "MSWin32";
1501
1502     return $target;
1503 }
1504
1505 sub upgrade {
1506     my $upgrade = "";
1507
1508     my $backup_suffix;
1509     if (exists $install_log_values{'KOHA_INSTALLED_VERSION'}) {
1510         my $version = $install_log_values{'KOHA_INSTALLED_VERSION'};
1511         $version =~ s/\./_/g;
1512         $backup_suffix = "_koha_$version";
1513     } else {
1514         $backup_suffix = "_upgrade_backup";
1515     }
1516
1517     $upgrade .= qq/
1518 MOD_BACKUP = \$(ABSPERLRUN) -Minstall_misc::UpgradeBackup -e 'backup_changed_files({\@ARGV}, '$backup_suffix', '\''\$(VERBINST)'\'', '\''\$(UNINST)'\'');' --
1519
1520 upgrade :: make_upgrade_backup install
1521 \t\$(NOECHO) \$(NOOP)
1522 make_upgrade_backup ::
1523 \t\$(NOECHO) umask 022; \$(MOD_BACKUP) \\
1524 /;
1525     foreach my $key (qw/KOHA_CONF_DIR INTRANET_TMPL_DIR INTRANET_WWW_DIR OPAC_TMPL_DIR OPAC_WWW_DIR
1526                      PAZPAR2_CONF_DIR ZEBRA_CONF_DIR/) {
1527         $upgrade .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1528             unless ($config{'INSTALL_ZEBRA'} ne "yes" and $key =~ /ZEBRA/) or
1529                    exists $skip_directories->{$key} or
1530                    not exists $target_directories->{$key};
1531     }
1532     $upgrade =~ s/\\\n$/\n/;
1533
1534     return $upgrade;
1535 }
1536
1537 sub postamble {
1538     # put directory mappings into Makefile
1539     # so that Make will export as environment
1540     # variables -- this is for the use of
1541     # rewrite-confg.PL
1542
1543     # quote '$' in the two password parameters
1544     my %config = %config;
1545     $config{'DB_PASS'} =~ s/\$/\$\$/g;
1546     if ($config{'INSTALL_ZEBRA'} eq "yes") {
1547         $config{'ZEBRA_PASS'} =~ s/\$/\$\$/g;
1548     }
1549
1550     my $env;
1551         # Hereagain, we must alter syntax per platform...
1552         if ( $^O eq 'MSWin32' ) {
1553                 # NOTE: it is imperative that there be no whitespaces in ENV=value...
1554                 $env = join("\n", map { "__${_}__=$target_directories->{$_}" } keys %$target_directories);
1555                 $env .= "\n\n";
1556                 $env .= join("\n", map { "__${_}__=$config{$_}" } keys %config);
1557         }
1558     else {
1559                 $env = join("\n", map { "export __${_}__ := $target_directories->{$_}" } keys %$target_directories);
1560                 $env .= "\n\n";
1561                 $env .= join("\n", map { "export __${_}__ := $config{$_}" } keys %config);
1562         }
1563
1564     if ( $config{'RUN_DATABASE_TESTS'} eq 'yes' ) {
1565         if ( open( my $confhandle, '>', 't/test-config.txt' ) ) {
1566             print $confhandle "# This configuration file lets the t/Makefile prepare a test koha-conf.xml file.\n";
1567             print $confhandle "# It is generated by the top-level Makefile.PL.\n";
1568             print $confhandle "# It is separate from the standard koha-conf.xml so that you can edit this by hand and test with different configurations.\n";
1569
1570             # these directories will be relocated to the 't' directory
1571             foreach my $dirname ( keys %$target_directories ) {
1572                 my $dir = $target_directories->{$dirname};
1573                 if ( exists $test_suite_override_dirs{$dirname} ) {
1574                     $dir = main::get_test_dir($dirname);
1575                 }
1576                 print $confhandle "$dirname = $dir\n"
1577             }
1578             print $confhandle "\n";
1579
1580             print $confhandle join( "\n", map { "$_ = $config{$_}" } keys( %config ) ), "\n";
1581             close( $confhandle );
1582         } else {
1583             warn 'unable to open conf file for database dependent tests: $!';
1584         }
1585
1586     }
1587     return "$env\n";
1588 }
1589
1590
1591 __END__
1592
1593
1594 =head1 SEE ALSO
1595
1596 ExtUtils::MakeMaker(3)
1597
1598 =head1 AUTHORS
1599
1600 MJ Ray mjr at phonecoop.coop
1601 Galen Charlton galen.charlton at liblime.com
1602
1603 =cut
1604 FIXME: deal with .htaccess