plugins/plugins-upload.pl

   1 #!/usr/bin/perl
   2
   3 #
   4 # This file is part of Koha.
   5 #
   6 # Koha is free software; you can redistribute it and/or modify it
   7 # under the terms of the GNU General Public License as published by
   8 # the Free Software Foundation; either version 3 of the License, or
   9 # (at your option) any later version.
  10 #
  11 # Koha is distributed in the hope that it will be useful, but
  12 # WITHOUT ANY WARRANTY; without even the implied warranty of
  13 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  14 # GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License
  17 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  18
  19 use strict;
  20 use warnings;
  21
  22 use Archive::Extract;
  23 use File::Temp;
  24 use File::Copy;
  25 use CGI qw ( -utf8 );
  26
  27 use C4::Context;
  28 use C4::Auth;
  29 use C4::Output;
  30 use C4::Members;
  31 use C4::Debug;
  32 use Koha::Plugins;
  33
  34 my $plugins_enabled = C4::Context->preference('UseKohaPlugins') && C4::Context->config("enable_plugins");
  35
  36 my $input = new CGI;
  37
  38 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  39     {   template_name => ($plugins_enabled) ? "plugins/plugins-upload.tt" : "plugins/plugins-disabled.tt",
  40         query         => $input,
  41         type          => "intranet",
  42         authnotrequired => 0,
  43         flagsrequired   => { plugins => 'manage' },
  44         debug           => 1,
  45     }
  46 );
  47
  48 my $uploadfilename = $input->param('uploadfile');
  49 my $uploadfile     = $input->upload('uploadfile');
  50 my $op             = $input->param('op');
  51
  52 my ( $total, $handled, @counts, $tempfile, $tfh );
  53
  54 my %errors;
  55
  56 if ($plugins_enabled) {
  57     if ( ( $op eq 'Upload' ) && $uploadfile ) {
  58         my $plugins_dir = C4::Context->config("pluginsdir");
  59
  60         my $dirname = File::Temp::tempdir( CLEANUP => 1 );
  61         $debug and warn "dirname = $dirname";
  62
  63         my $filesuffix;
  64         $filesuffix = $1 if $uploadfilename =~ m/(\..+)$/i;
  65         ( $tfh, $tempfile ) = File::Temp::tempfile( SUFFIX => $filesuffix, UNLINK => 1 );
  66
  67         $debug and warn "tempfile = $tempfile";
  68
  69         $errors{'NOTKPZ'} = 1 if ( $uploadfilename !~ /\.kpz$/i );
  70         $errors{'NOWRITETEMP'}    = 1 unless ( -w $dirname );
  71         $errors{'NOWRITEPLUGINS'} = 1 unless ( -w $plugins_dir );
  72         $errors{'EMPTYUPLOAD'}    = 1 unless ( length($uploadfile) > 0 );
  73
  74         if (%errors) {
  75             $template->param( ERRORS => [ \%errors ] );
  76         } else {
  77             while (<$uploadfile>) {
  78                 print $tfh $_;
  79             }
  80             close $tfh;
  81
  82             my $ae = Archive::Extract->new( archive => $tempfile, type => 'zip' );
  83             unless ( $ae->extract( to => $plugins_dir ) ) {
  84                 warn "ERROR: " . $ae->error;
  85                 $errors{'UZIPFAIL'} = $uploadfilename;
  86                 $template->param( ERRORS => [ \%errors ] );
  87                 output_html_with_http_headers $input, $cookie, $template->output;
  88                 exit;
  89             }
  90         }
  91     } elsif ( ( $op eq 'Upload' ) && !$uploadfile ) {
  92         warn "Problem uploading file or no file uploaded.";
  93     }
  94
  95     if ( $uploadfile && !%errors && !$template->param('ERRORS') ) {
  96         print $input->redirect("/cgi-bin/koha/plugins/plugins-home.pl");
  97     } else {
  98         output_html_with_http_headers $input, $cookie, $template->output;
  99     }
 100
 101 } else {
 102     output_html_with_http_headers $input, $cookie, $template->output;
 103 }