acqui/orderreceive.pl

   1 #!/usr/bin/perl
   2
   3
   4 #script to receive orders
   5 #written by chris@katipo.co.nz 24/2/2000
   6
   7 # Copyright 2000-2002 Katipo Communications
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 =head1 NAME
  25
  26 orderreceive.pl
  27
  28 =head1 DESCRIPTION
  29
  30 This script shows all order already receive and all pendings orders.
  31 It permit to write a new order as 'received'.
  32
  33 =head1 CGI PARAMETERS
  34
  35 =over 4
  36
  37 =item booksellerid
  38
  39 to know on what supplier this script has to display receive order.
  40
  41 =item invoiceid
  42
  43 the id of this invoice.
  44
  45 =item freight
  46
  47 =item biblio
  48
  49 The biblionumber of this order.
  50
  51 =item datereceived
  52
  53 =item catview
  54
  55 =item gst
  56
  57 =back
  58
  59 =cut
  60
  61 use strict;
  62 use warnings;
  63
  64 use CGI qw ( -utf8 );
  65 use C4::Context;
  66 use C4::Acquisition;
  67 use C4::Auth;
  68 use C4::Output;
  69 use C4::Budgets qw/ GetBudget GetBudgetHierarchy CanUserUseBudget GetBudgetPeriods /;
  70 use C4::Members;
  71 use C4::Items;
  72 use C4::Biblio;
  73 use C4::Suggestions;
  74 use C4::Koha;
  75
  76 use Koha::Acquisition::Booksellers;
  77 use Koha::Acquisition::Orders;
  78 use Koha::DateUtils qw( dt_from_string );
  79 use Koha::ItemTypes;
  80 use Koha::Patrons;
  81
  82 my $input      = new CGI;
  83
  84 my $dbh          = C4::Context->dbh;
  85 my $invoiceid    = $input->param('invoiceid');
  86 my $invoice      = GetInvoice($invoiceid);
  87 my $booksellerid   = $invoice->{booksellerid};
  88 my $freight      = $invoice->{shipmentcost};
  89 my $ordernumber  = $input->param('ordernumber');
  90
  91 my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
  92 my $results;
  93 $results = SearchOrders({
  94     ordernumber => $ordernumber
  95 }) if $ordernumber;
  96
  97 my ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
  98     {
  99         template_name   => "acqui/orderreceive.tt",
 100         query           => $input,
 101         type            => "intranet",
 102         authnotrequired => 0,
 103         flagsrequired   => {acquisition => 'order_receive'},
 104         debug           => 1,
 105     }
 106 );
 107
 108 unless ( $results and @$results) {
 109     output_html_with_http_headers $input, $cookie, $template->output;
 110     exit;
 111 }
 112
 113 # prepare the form for receiving
 114 my $order = $results->[0];
 115 my $basket = Koha::Acquisition::Orders->find( $ordernumber )->basket;
 116
 117 # Check if ACQ framework exists
 118 my $acq_fw = GetMarcStructure( 1, 'ACQ', { unsafe => 1 } );
 119 unless($acq_fw) {
 120     $template->param('NoACQframework' => 1);
 121 }
 122
 123 my $AcqCreateItem = $basket->effective_create_items;
 124 if ($AcqCreateItem eq 'receiving') {
 125     $template->param(
 126         AcqCreateItemReceiving => 1,
 127         UniqueItemFields => C4::Context->preference('UniqueItemFields'),
 128     );
 129 } elsif ($AcqCreateItem eq 'ordering') {
 130     my $fw = ($acq_fw) ? 'ACQ' : '';
 131     my @itemnumbers = GetItemnumbersFromOrder($order->{ordernumber});
 132     my @items;
 133     foreach (@itemnumbers) {
 134         my $item = GetItem($_);
 135         my $descriptions;
 136         $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({frameworkcode => $fw, kohafield => 'items.notforloan', authorised_value => $item->{notforloan} });
 137         $item->{notforloan} = $descriptions->{lib} // '';
 138
 139         $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({frameworkcode => $fw, kohafield => 'items.restricted', authorised_value => $item->{restricted} });
 140         $item->{restricted} = $descriptions->{lib} // '';
 141
 142         $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({frameworkcode => $fw, kohafield => 'items.location', authorised_value => $item->{location} });
 143         $item->{location} = $descriptions->{lib} // '';
 144
 145         $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({frameworkcode => $fw, kohafield => 'items.collection', authorised_value => $item->{collection} });
 146         $item->{collection} = $descriptions->{lib} // '';
 147
 148         $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({frameworkcode => $fw, kohafield => 'items.materials', authorised_value => $item->{materials} });
 149         $item->{materials} = $descriptions->{lib} // '';
 150
 151         my $itemtype = Koha::ItemTypes->find( $item->{itype} );
 152         if (defined $itemtype) {
 153             $item->{itemtype} = $itemtype->description; # FIXME Should not it be translated_description?
 154         }
 155         push @items, $item;
 156     }
 157     $template->param(items => \@items);
 158 }
 159
 160 $order->{quantityreceived} = '' if $order->{quantityreceived} == 0;
 161
 162 my $unitprice = $order->{unitprice};
 163 my ( $rrp, $ecost );
 164 if ( $bookseller->invoiceincgst ) {
 165     $rrp = $order->{rrp_tax_included};
 166     $ecost = $order->{ecost_tax_included};
 167     unless ( $unitprice != 0 and defined $unitprice) {
 168         $unitprice = $order->{ecost_tax_included};
 169     }
 170 } else {
 171     $rrp = $order->{rrp_tax_excluded};
 172     $ecost = $order->{ecost_tax_excluded};
 173     unless ( $unitprice != 0 and defined $unitprice) {
 174         $unitprice = $order->{ecost_tax_excluded};
 175     }
 176 }
 177
 178 my $tax_rate;
 179 if( defined $order->{tax_rate_on_receiving} ) {
 180     $tax_rate = $order->{tax_rate_on_receiving} + 0.0;
 181 } else {
 182     $tax_rate = $order->{tax_rate_on_ordering} + 0.0;
 183 }
 184
 185 my $suggestion = GetSuggestionInfoFromBiblionumber($order->{biblionumber});
 186
 187 my $authorisedby = $order->{authorisedby};
 188 my $authorised_patron = Koha::Patrons->find( $authorisedby );
 189
 190 my $budget = GetBudget( $order->{budget_id} );
 191
 192 my $datereceived = $order->{datereceived} ? dt_from_string( $order->{datereceived} ) : dt_from_string;
 193
 194 # get option values for gist syspref
 195 my @gst_values = map {
 196     option => $_ + 0.0
 197 }, split( '\|', C4::Context->preference("gist") );
 198
 199 $template->param(
 200     AcqCreateItem         => $AcqCreateItem,
 201     count                 => 1,
 202     biblionumber          => $order->{'biblionumber'},
 203     ordernumber           => $order->{'ordernumber'},
 204     subscriptionid        => $order->{subscriptionid},
 205     booksellerid          => $order->{'booksellerid'},
 206     freight               => $freight,
 207     name                  => $bookseller->name,
 208     title                 => $order->{'title'},
 209     author                => $order->{'author'},
 210     copyrightdate         => $order->{'copyrightdate'},
 211     isbn                  => $order->{'isbn'},
 212     seriestitle           => $order->{'seriestitle'},
 213     bookfund              => $budget->{budget_name},
 214     quantity              => $order->{'quantity'},
 215     quantityreceivedplus1 => $order->{'quantityreceived'} + 1,
 216     quantityreceived      => $order->{'quantityreceived'},
 217     rrp                   => $rrp,
 218     ecost                 => $ecost,
 219     unitprice             => $unitprice,
 220     tax_rate              => $tax_rate,
 221     memberfirstname       => $authorised_patron->firstname || "",
 222     membersurname         => $authorised_patron->surname || "",
 223     invoiceid             => $invoice->{invoiceid},
 224     invoice               => $invoice->{invoicenumber},
 225     datereceived          => $datereceived,
 226     order_internalnote    => $order->{order_internalnote},
 227     order_vendornote      => $order->{order_vendornote},
 228     suggestionid          => $suggestion->{suggestionid},
 229     surnamesuggestedby    => $suggestion->{surnamesuggestedby},
 230     firstnamesuggestedby  => $suggestion->{firstnamesuggestedby},
 231     gst_values            => \@gst_values,
 232 );
 233
 234 my $patron = Koha::Patrons->find( $loggedinuser )->unblessed;
 235 my @budget_loop;
 236 my $periods = GetBudgetPeriods( );
 237 foreach my $period (@$periods) {
 238     if ($period->{'budget_period_id'} == $budget->{'budget_period_id'}) {
 239         $template->{'VARS'}->{'budget_period_description'} = $period->{'budget_period_description'};
 240     }
 241     next if $period->{'budget_period_locked'} || !$period->{'budget_period_description'};
 242     my $budget_hierarchy = GetBudgetHierarchy( $period->{'budget_period_id'} );
 243     my @funds;
 244     foreach my $r ( @{$budget_hierarchy} ) {
 245         next unless ( CanUserUseBudget( $patron, $r, $userflags ) );
 246         if ( !defined $r->{budget_amount} || $r->{budget_amount} == 0 ) {
 247             next;
 248         }
 249         push @funds,
 250           {
 251             b_id  => $r->{budget_id},
 252             b_txt => $r->{budget_name},
 253             b_sel => ( $r->{budget_id} == $order->{budget_id} ) ? 1 : 0,
 254           };
 255     }
 256
 257     @funds = sort { uc( $a->{b_txt} ) cmp uc( $b->{b_txt} ) } @funds;
 258
 259     push @budget_loop,
 260       {
 261         'id'          => $period->{'budget_period_id'},
 262         'description' => $period->{'budget_period_description'},
 263         'funds'       => \@funds
 264       };
 265 }
 266
 267 $template->{'VARS'}->{'budget_loop'} = \@budget_loop;
 268
 269 my $op = $input->param('op');
 270 if ($op and $op eq 'edit'){
 271     $template->param(edit   =>   1);
 272 }
 273 output_html_with_http_headers $input, $cookie, $template->output;