C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Carp;
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember changepassword);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use C4::Members::Messaging;
  30 use C4::Auth qw(checkpw_internal);
  31 use Koha::AuthUtils qw(hash_password);
  32 use List::MoreUtils qw( any );
  33 use Net::LDAP;
  34 use Net::LDAP::Filter;
  35
  36 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  37
  38 BEGIN {
  39         require Exporter;
  40     $VERSION = 3.07.00.049;     # set the version for version checking
  41         @ISA    = qw(Exporter);
  42         @EXPORT = qw( checkpw_ldap );
  43 }
  44
  45 # Redefine checkpw_ldap:
  46 # connect to LDAP (named or anonymous)
  47 # ~ retrieves $userid from KOHA_CONF mapping
  48 # ~ then compares $password with userPassword
  49 # ~ then gets the LDAP entry
  50 # ~ and calls the memberadd if necessary
  51
  52 sub ldapserver_error {
  53         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  54 }
  55
  56 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  57 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  58 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  59 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  60 my $base      = $ldap->{base}           or die ldapserver_error('base');
  61 $ldapname     = $ldap->{user}           ;
  62 $ldappassword = $ldap->{pass}           ;
  63 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  64 my @mapkeys = keys %mapping;
  65 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  66 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  67 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  68
  69 my %config = (
  70         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  71     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  72        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  73 );
  74
  75 sub description {
  76         my $result = shift or return;
  77         return "LDAP error #" . $result->code
  78                         . ": " . $result->error_name . "\n"
  79                         . "# " . $result->error_text . "\n";
  80 }
  81
  82 sub search_method {
  83     my $db     = shift or return;
  84     my $userid = shift or return;
  85         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  86         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  87         my $search = $db->search(
  88                   base => $base,
  89                 filter => $filter,
  90                 # attrs => ['*'],
  91     );
  92     die "LDAP search failed to return object : " . $search->error if $search->code;
  93
  94         my $count = $search->count;
  95         if ($search->code > 0) {
  96                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
  97                 return 0;
  98         }
  99         if ($count != 1) {
 100                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
 101                 return 0;
 102         }
 103     return $search;
 104 }
 105
 106 sub checkpw_ldap {
 107     my ($dbh, $userid, $password) = @_;
 108     my @hosts = split(',', $prefhost);
 109     my $db = Net::LDAP->new(\@hosts);
 110     unless ( $db ) {
 111         warn "LDAP connexion failed";
 112         return 0;
 113     }
 114
 115         #$debug and $db->debug(5);
 116     my $userldapentry;
 117
 118     if ( $ldap->{auth_by_bind} ) {
 119         my $principal_name;
 120         if ( $ldap->{anonymous_bind} ) {
 121
 122             # Perform an anonymous bind
 123             my $res = $db->bind;
 124             if ( $res->code ) {
 125                 warn "Anonymous LDAP bind failed: " . description($res);
 126                 return 0;
 127             }
 128
 129             # Perform a LDAP search for the given username
 130             my $search = search_method( $db, $userid )
 131               or return 0;    # warnings are in the sub
 132             $userldapentry = $search->shift_entry;
 133             $principal_name = $userldapentry->dn;
 134         }
 135         else {
 136             $principal_name = $ldap->{principal_name};
 137             if ( $principal_name and $principal_name =~ /\%/ ) {
 138                 $principal_name = sprintf( $principal_name, $userid );
 139             }
 140             else {
 141                 $principal_name = $userid;
 142             }
 143         }
 144
 145         # Perform a LDAP bind for the given username using the matched DN
 146         my $res = $db->bind( $principal_name, password => $password );
 147         if ( $res->code ) {
 148             warn "LDAP bind failed as kohauser $userid: " . description($res);
 149             return -1;
 150         }
 151         if ( !defined($userldapentry)
 152             && ( $config{update} or $config{replicate} ) )
 153         {
 154             my $search = search_method( $db, $userid ) or return 0;
 155             $userldapentry = $search->shift_entry;
 156         }
 157     } else {
 158                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 159                 if ($res->code) {               # connection refused
 160                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 161                         return 0;
 162                 }
 163         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 164         $userldapentry = $search->shift_entry;
 165                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
 166                 if ($cmpmesg->code != 6) {
 167                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
 168                         return -1;
 169                 }
 170         }
 171
 172     # To get here, LDAP has accepted our user's login attempt.
 173     # But we still have work to do.  See perldoc below for detailed breakdown.
 174
 175     my (%borrower);
 176         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 177
 178     if (( $borrowernumber and $config{update}   ) or
 179         (!$borrowernumber and $config{replicate})   ) {
 180         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 181         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 182     }
 183
 184     if ($borrowernumber) {
 185         if ($config{update}) { # A1, B1
 186             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 187             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 188         } else { # C1, D1
 189             # maybe update just the password?
 190                 return(1, $cardnumber, $local_userid);
 191         }
 192     } elsif ($config{replicate}) { # A2, C2
 193         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
 194         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 195    } else {
 196         return 0;   # B2, D2
 197     }
 198     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 199         my @extended_patron_attributes;
 200         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 201             my $code = $attribute_type->{code};
 202             if ( exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) { # skip empty values
 203                 push @extended_patron_attributes, { code => $code, value => $borrower{$code} };
 204             }
 205         }
 206         #Check before add
 207         my @unique_attr;
 208         foreach my $attr ( @extended_patron_attributes ) {
 209             if (C4::Members::Attributes::CheckUniqueness($attr->{code}, $attr->{value}, $borrowernumber)) {
 210                 push @unique_attr, $attr;
 211             } else {
 212                 warn "ERROR_extended_unique_id_failed $attr->{code} $attr->{value}";
 213             }
 214         }
 215         C4::Members::Attributes::SetBorrowerAttributes($borrowernumber, \@unique_attr);
 216     }
 217 return(1, $cardnumber, $userid);
 218 }
 219
 220 # Pass LDAP entry object and local cardnumber (userid).
 221 # Returns borrower hash.
 222 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 223 # Ensure that mandatory fields are correctly filled!
 224 #
 225 sub ldap_entry_2_hash {
 226         my $userldapentry = shift;
 227         my %borrower = ( cardnumber => shift );
 228         my %memberhash;
 229         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 230         if ($debug) {
 231                 foreach (keys %$userldapentry) {
 232                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 233                 }
 234         }
 235         my $x = $userldapentry->{attrs} or return;
 236         foreach (keys %$x) {
 237                 $memberhash{$_} = join ' ', @{$x->{$_}};
 238                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 239         }
 240         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 241                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 242         foreach my $key (keys %mapping) {
 243                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 244                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 245                 unless (defined $data) {
 246                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 247                 }
 248                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 249         }
 250         $borrower{initials} = $memberhash{initials} ||
 251                 ( substr($borrower{'firstname'},0,1)
 252                 . substr($borrower{ 'surname' },0,1)
 253                 . " ");
 254
 255         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 256         my $dbh = C4::Context->dbh;
 257         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 258         $sth->execute( uc($borrower{'categorycode'}) );
 259         unless ( my $row = $sth->fetchrow_hashref ) {
 260                 my $default = $mapping{'categorycode'}->{content};
 261                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 262                 $borrower{'categorycode'} = $default
 263         }
 264
 265         return %borrower;
 266 }
 267
 268 sub exists_local {
 269         my $arg = shift;
 270         my $dbh = C4::Context->dbh;
 271         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 272
 273         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 274         $sth->execute($arg);
 275         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 276         ($sth->rows == 1) and return $sth->fetchrow;
 277
 278         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 279         $sth->execute($arg);
 280         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 281         ($sth->rows == 1) and return $sth->fetchrow;
 282         return 0;
 283 }
 284
 285 sub _do_changepassword {
 286     my ($userid, $borrowerid, $password) = @_;
 287
 288     my $digest = hash_password($password);
 289
 290     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 291     changepassword($userid, $borrowerid, $digest);
 292
 293     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 294     return $cardnum if $ok;
 295
 296     warn "Password mismatch after update to borrowernumber=$borrowerid";
 297     return;
 298 }
 299
 300 sub update_local {
 301     my $userid     = shift or croak "No userid";
 302     my $password   = shift or croak "No password";
 303     my $borrowerid = shift or croak "No borrowerid";
 304     my $borrower   = shift or croak "No borrower record";
 305
 306     my @keys = keys %$borrower;
 307     my $dbh = C4::Context->dbh;
 308     my $query = "UPDATE  borrowers\nSET     " .
 309         join(',', map {"$_=?"} @keys) .
 310         "\nWHERE   borrowernumber=? ";
 311     my $sth = $dbh->prepare($query);
 312     if ($debug) {
 313         print STDERR $query, "\n",
 314             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 315         print STDERR "\nuserid = $userid\n";
 316     }
 317     $sth->execute(
 318         ((map {$borrower->{$_}} @keys), $borrowerid)
 319     );
 320
 321     # MODIFY PASSWORD/LOGIN if password was mapped
 322     _do_changepassword($userid, $borrowerid, $password) if $borrower->{'password'};
 323 }
 324
 325 1;
 326 __END__
 327
 328 =head1 NAME
 329
 330 C4::Auth - Authenticates Koha users
 331
 332 =head1 SYNOPSIS
 333
 334   use C4::Auth_with_ldap;
 335
 336 =head1 LDAP Configuration
 337
 338     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 339         working LDAP servers.
 340         To use it :
 341            * Modify ldapserver element in KOHA_CONF
 342            * Establish field mapping in <mapping> element.
 343
 344         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 345         the username would match the "uid" field, and the password should match the "userpassword" field.
 346
 347         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 348         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 349
 350         mysql> show COLUMNS from borrowers;
 351                 +---------------------+--------------+------+-----+---------+----------------+
 352                 | Field               | Type         | Null | Key | Default | Extra          |
 353                 +---------------------+--------------+------+-----+---------+----------------+
 354                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 355                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 356                 | surname             | mediumtext   | NO   |     | NULL    |                |
 357                 | firstname           | text         | YES  |     | NULL    |                |
 358                 | title               | mediumtext   | YES  |     | NULL    |                |
 359                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 360                 | initials            | text         | YES  |     | NULL    |                |
 361                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 362                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 363                 | address             | mediumtext   | NO   |     | NULL    |                |
 364                 | address2            | text         | YES  |     | NULL    |                |
 365                 | city                | mediumtext   | NO   |     | NULL    |                |
 366                 | state               | mediumtext   | YES  |     | NULL    |                |
 367                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 368                 | country             | text         | YES  |     | NULL    |                |
 369                 | email               | mediumtext   | YES  |     | NULL    |                |
 370                 | phone               | text         | YES  |     | NULL    |                |
 371                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 372                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 373                 | emailpro            | text         | YES  |     | NULL    |                |
 374                 | phonepro            | text         | YES  |     | NULL    |                |
 375                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 376                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 377                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 378                 | B_address2          | text         | YES  |     | NULL    |                |
 379                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 380                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 381                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 382                 | B_country           | text         | YES  |     | NULL    |                |
 383                 | B_email             | text         | YES  |     | NULL    |                |
 384                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 385                 | dateofbirth         | date         | YES  |     | NULL    |                |
 386                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 387                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 388                 | dateenrolled        | date         | YES  |     | NULL    |                |
 389                 | dateexpiry          | date         | YES  |     | NULL    |                |
 390                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 391                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 392                 | debarred            | date         | YES  |     | NULL    |                |
 393                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 394                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 395                 | contactfirstname    | text         | YES  |     | NULL    |                |
 396                 | contacttitle        | text         | YES  |     | NULL    |                |
 397                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 398                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 399                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 400                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 401                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 402                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 403                 | password            | varchar(30)  | YES  |     | NULL    |                |
 404                 | flags               | int(11)      | YES  |     | NULL    |                |
 405                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 406                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 407                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 408                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 409                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 410                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 411                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 412                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 413                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 414                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 415                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 416                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 417                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 418                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 419                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 420                 | privacy             | int(11)      | NO   |     | 1       |                |
 421                 +---------------------+--------------+------+-----+---------+----------------+
 422                 66 rows in set (0.00 sec)
 423                 Where Null="NO", the field is required.
 424
 425 =head1 KOHA_CONF and field mapping
 426
 427 Example XML stanza for LDAP configuration in KOHA_CONF.
 428
 429  <config>
 430   ...
 431   <useldapserver>1</useldapserver>
 432   <!-- LDAP SERVER (optional) -->
 433   <ldapserver id="ldapserver">
 434     <hostname>localhost</hostname>
 435     <base>dc=metavore,dc=com</base>
 436     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 437     <pass>metavore</pass>          <!-- password, if not anonymous -->
 438     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 439     <update>1</update>             <!-- update existing users in Koha database -->
 440     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 441                                         password comparison, e.g., to use Active Directory -->
 442     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 443                                             an anonymous bind, even when auth_by_bind is on -->
 444     <principal_name>%s@my_domain.com</principal_name>
 445                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 446                                         Not used with anonymous_bind. -->
 447
 448     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 449       <firstname    is="givenname"      ></firstname>
 450       <surname      is="sn"             ></surname>
 451       <address      is="postaladdress"  ></address>
 452       <city         is="l"              >Athens, OH</city>
 453       <zipcode      is="postalcode"     ></zipcode>
 454       <branchcode   is="branch"         >MAIN</branchcode>
 455       <userid       is="uid"            ></userid>
 456       <password     is="userpassword"   ></password>
 457       <email        is="mail"           ></email>
 458       <categorycode is="employeetype"   >PT</categorycode>
 459       <phone        is="telephonenumber"></phone>
 460     </mapping>
 461   </ldapserver>
 462  </config>
 463
 464 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 465 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 466 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 467 patron).
 468
 469 =head1 CONFIGURATION
 470
 471 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 472 your configuration and the presence of a matching Koha user in your local DB:
 473
 474                          LOCAL_USER
 475  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 476    A1      1       1        1      OK : We're updating them anyway.
 477    A2      1       1        0      OK : We're adding them anyway.
 478    B1      1       0        1      OK : We update them.
 479    B2      1       0        0     FAIL: We cannot add new user.
 480    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 481    C2      0       1        0      OK : We add the new user.
 482    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 483    D2      0       0        0     FAIL: We cannot add new user.
 484
 485 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 486 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 487 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 488
 489 If you choose NOT to update local users, the borrowers table will not be affected at all.
 490 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 491 the local table never contained the LDAP values.
 492
 493 =head2 auth_by_bind
 494
 495 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 496
 497 =head2 principal_name
 498
 499 Provides an optional sprintf-style format for manipulating the userid before the bind.
 500 Even though the userPrincipalName is one intended target, any uniquely identifying
 501 attribute that the server allows to be used for binding could be used.
 502
 503 Currently, principal_name only operates when auth_by_bind is enabled.
 504
 505 =head2 Active Directory
 506
 507 The auth_by_bind and principal_name settings are recommended for Active Directory.
 508
 509 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 510 we would typically under openldap.  Instead of:
 511
 512     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 513
 514 We might get:
 515
 516     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 517
 518 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 519 in Koha userids.  But the userPrincipalName should be consistent, something like:
 520
 521     userPrincipalName: barnes.7@my_company.com
 522
 523 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 524 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 525 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 526 like this:
 527     <principal_name>%s@core.my_company.com</principal_name>
 528
 529 The user of the previous example, barnes.7, would then attempt to bind as:
 530     barnes.7@core.my_company.com
 531
 532 =head1 SEE ALSO
 533
 534 CGI(3)
 535
 536 Net::LDAP()
 537
 538 XML::Simple()
 539
 540 Digest::MD5(3)
 541
 542 sprintf()
 543
 544 =cut
 545
 546 # For reference, here's an important difference in the data structure we rely on.
 547 # ========================================
 548 # Using attrs instead of {asn}->attributes
 549 # ========================================
 550 #
 551 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 552 #       LDAP key: ->{             cn}->{           sss} = sss
 553 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 554 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 555 #
 556 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 557 #       LDAP key: ->{      givenname}->{Steve} = Steve
 558 #