C4/Barcodes/ValueBuilder.pm

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2008-2010 Foundations Bible College
   4 # Parts copyright 2012 C & P Bibliography Services
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 package C4::Barcodes::ValueBuilder::incremental;
  22
  23 use Modern::Perl;
  24 use C4::Context;
  25
  26 sub get_barcode {
  27     my ($args) = @_;
  28     my $nextnum;
  29     # not the best, two catalogers could add the same barcode easily this way :/
  30     my $query = "select max(abs(barcode)) from items";
  31     my $sth = C4::Context->dbh->prepare($query);
  32     $sth->execute();
  33     while (my ($count)= $sth->fetchrow_array) {
  34         $nextnum = $count;
  35     }
  36     $nextnum++;
  37     return $nextnum;
  38 }
  39
  40 1;
  41
  42 package C4::Barcodes::ValueBuilder::hbyymmincr;
  43 use C4::Context;
  44
  45 sub get_barcode {
  46     my ($args) = @_;
  47     my $nextnum = 0;
  48     my $year = substr($args->{year}, -2);
  49     my $month = $args->{mon};
  50     my $query = "SELECT MAX(CAST(SUBSTRING(barcode,-4) AS signed)) AS number FROM items WHERE barcode REGEXP ?";
  51     my $sth = C4::Context->dbh->prepare($query);
  52     $sth->execute("^[-a-zA-Z]{1,}$year$month");
  53     while (my ($count)= $sth->fetchrow_array) {
  54         $nextnum = $count if $count;
  55         $nextnum = 0 if $nextnum == 9999; # this sequence only allows for cataloging 9999 items per month
  56     }
  57     $nextnum++;
  58     $nextnum = sprintf("%0*d", "4",$nextnum);
  59     $nextnum = $year . $month . $nextnum;
  60     my $scr = "
  61         var form = document.getElementById('f');
  62         if ( !form ) {
  63             form = document.getElementById('serials_edit');
  64         }
  65         if ( !form ) {
  66             form = document.getElementById('Aform');
  67         }
  68         for (i=0 ; i<form.field_value.length ; i++) {
  69             if (form.tag[i].value == '$args->{loctag}' && form.subfield[i].value == '$args->{locsubfield}') {
  70                 fnum = i;
  71             }
  72         }
  73     if (\$('#' + id).val() == '') {
  74         \$('#' + id).val(form.field_value[fnum].value + '$nextnum');
  75     }
  76     ";
  77     return $nextnum, $scr;
  78 }
  79
  80
  81 package C4::Barcodes::ValueBuilder::annual;
  82 use C4::Context;
  83
  84 sub get_barcode {
  85     my ($args) = @_;
  86     my $nextnum;
  87     my $query = "select max(cast( substring_index(barcode, '-',-1) as signed)) from items where barcode like ?";
  88     my $sth=C4::Context->dbh->prepare($query);
  89     $sth->execute($args->{year} . '-%');
  90     while (my ($count)= $sth->fetchrow_array) {
  91         $nextnum = $count if $count;
  92     }
  93     $nextnum++;
  94     $nextnum = sprintf("%0*d", "4",$nextnum);
  95     $nextnum = "$args->{year}-$nextnum";
  96     return $nextnum;
  97 }
  98
  99 1;
 100
 101
 102 =head1 Barcodes::ValueBuilder
 103
 104 This module is intended as a shim to ease the eventual transition from
 105 having all barcode-related code in the value builder plugin .pl file
 106 to using C4::Barcodes. Since the shift will require a rather significant
 107 amount of refactoring, this module will return value builder-formatted
 108 results, at first by merely running the code that was formerly in the
 109 barcodes.pl value builder, but later by using C4::Barcodes.
 110
 111 =cut
 112
 113 1;