tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use strict;
  44 use warnings;
  45 use CGI qw ( -utf8 );
  46 use C4::Auth;
  47 use C4::Context;
  48 use C4::Output;
  49 use C4::Branch; # GetBranches
  50 use C4::Letters;
  51 use C4::Members::Attributes;
  52
  53 # $protected_letters = protected_letters()
  54 # - return a hashref of letter_codes representing letters that should never be deleted
  55 sub protected_letters {
  56     my $dbh = C4::Context->dbh;
  57     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  58     return { map { $_->[0] => 1 } @{$codes} };
  59 }
  60
  61 our $input       = new CGI;
  62 my $searchfield = $input->param('searchfield');
  63 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  64 our $branchcode  = $input->param('branchcode');
  65 my $code        = $input->param('code');
  66 my $module      = $input->param('module') || '';
  67 my $content     = $input->param('content');
  68 my $op          = $input->param('op') || '';
  69 my $dbh = C4::Context->dbh;
  70
  71 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  72     {
  73         template_name   => 'tools/letter.tt',
  74         query           => $input,
  75         type            => 'intranet',
  76         authnotrequired => 0,
  77         flagsrequired   => { tools => 'edit_notices' },
  78         debug           => 1,
  79     }
  80 );
  81
  82 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  83   ?  C4::Context->userenv()->{'branch'}
  84   : undef;
  85 # we show only the TMPL_VAR names $op
  86
  87 $template->param(
  88     independant_branch => $my_branch,
  89         script_name => $script_name,
  90   searchfield => $searchfield,
  91     branchcode => $branchcode,
  92         action => $script_name
  93 );
  94
  95 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
  96     add_validate();
  97     $op = q{}; # we return to the default screen for the next operation
  98 }
  99 if ($op eq 'copy_form') {
 100     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 101     my $branchcode = $input->param('branchcode') || q||;
 102     add_form($oldbranchcode, $module, $code);
 103     $template->param(
 104         oldbranchcode => $oldbranchcode,
 105         branchcode => $branchcode,
 106         branchloop => _branchloop($branchcode),
 107         copying => 1,
 108         modify => 0,
 109     );
 110 }
 111 elsif ( $op eq 'add_form' ) {
 112     add_form($branchcode, $module, $code);
 113 }
 114 elsif ( $op eq 'delete_confirm' ) {
 115     delete_confirm($branchcode, $module, $code);
 116 }
 117 elsif ( $op eq 'delete_confirmed' ) {
 118     delete_confirmed($branchcode, $module, $code);
 119     $op = q{}; # next operation is to return to default screen
 120 }
 121 else {
 122     default_display($branchcode,$searchfield);
 123 }
 124
 125 # Do this last as delete_confirmed resets
 126 if ($op) {
 127     $template->param($op  => 1);
 128 } else {
 129     $template->param(no_op_set => 1);
 130 }
 131
 132 output_html_with_http_headers $input, $cookie, $template->output;
 133
 134 sub add_form {
 135     my ( $branchcode,$module, $code ) = @_;
 136
 137     my $letters;
 138     # if code has been passed we can identify letter and its an update action
 139     if ($code) {
 140         $letters = C4::Letters::GetLetterTemplates(
 141             {
 142                 branchcode => $branchcode,
 143                 module     => $module,
 144                 code       => $code,
 145             }
 146         );
 147     }
 148
 149     my $message_transport_types = GetMessageTransportTypes();
 150     my @letter_loop;
 151     if ($letters) {
 152         $template->param(
 153             modify     => 1,
 154             code       => $code,
 155             branchcode => $branchcode,
 156         );
 157         my $first_flag = 1;
 158         # The letter name is contained into each mtt row.
 159         # So we can only sent the first one to the template.
 160         for my $mtt ( @$message_transport_types ) {
 161             # The letter_name
 162             if ( $first_flag and $letters->{$mtt}{name} ) {
 163                 $template->param(
 164                     letter_name=> $letters->{$mtt}{name},
 165                 );
 166                 $first_flag = 0;
 167             }
 168
 169             push @letter_loop, {
 170                 message_transport_type => $mtt,
 171                 is_html    => $letters->{$mtt}{is_html},
 172                 title      => $letters->{$mtt}{title},
 173                 content    => $letters->{$mtt}{content}//'',
 174             };
 175         }
 176     }
 177     else { # initialize the new fields
 178         for my $mtt ( @$message_transport_types ) {
 179             push @letter_loop, {
 180                 message_transport_type => $mtt,
 181             }
 182         }
 183         $template->param(
 184             branchcode => $branchcode,
 185             module     => $module,
 186         );
 187         $template->param( adding => 1 );
 188     }
 189
 190     $template->param(
 191         letters => \@letter_loop,
 192     );
 193
 194     my $field_selection;
 195     push @{$field_selection}, add_fields('branches');
 196     if ($module eq 'reserves') {
 197         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'items');
 198     }
 199     elsif ( $module eq 'acquisition' ) {
 200         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 201     }
 202     elsif ($module eq 'claimacquisition') {
 203         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'biblioitems');
 204     }
 205     elsif ($module eq 'claimissues') {
 206         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription');
 207         push @{$field_selection},
 208         {
 209             value => q{},
 210             text => '---BIBLIO---'
 211         };
 212         foreach(qw(title author serial)) {
 213             push @{$field_selection}, {value => "biblio.$_", text => ucfirst $_ };
 214         }
 215     }
 216     elsif ($module eq 'suggestions') {
 217         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 218     }
 219     else {
 220         push @{$field_selection}, add_fields('biblio','biblioitems'),
 221             add_fields('items'),
 222             {value => 'items.content', text => 'items.content'},
 223             {value => 'items.fine',    text => 'items.fine'},
 224             add_fields('borrowers');
 225         if ($module eq 'circulation') {
 226             push @{$field_selection}, add_fields('opac_news');
 227
 228         }
 229
 230         if ( $module eq 'circulation' && $code eq "CHECKIN" ) {
 231             push @{$field_selection}, add_fields('old_issues');
 232         } else {
 233             push @{$field_selection}, add_fields('issues');
 234         }
 235     }
 236
 237     $template->param(
 238         module     => $module,
 239         branchloop => _branchloop($branchcode),
 240         SQLfieldname => $field_selection,
 241     );
 242     return;
 243 }
 244
 245 sub add_validate {
 246     my $dbh        = C4::Context->dbh;
 247     my $branchcode    = $input->param('branchcode') || '';
 248     my $module        = $input->param('module');
 249     my $oldmodule     = $input->param('oldmodule');
 250     my $code          = $input->param('code');
 251     my $name          = $input->param('name');
 252     my @mtt           = $input->param('message_transport_type');
 253     my @title         = $input->param('title');
 254     my @content       = $input->param('content');
 255     for my $mtt ( @mtt ) {
 256         my $is_html = $input->param("is_html_$mtt");
 257         my $title   = shift @title;
 258         my $content = shift @content;
 259         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt);
 260
 261         # getletter can return the default letter even if we pass a branchcode
 262         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 263         if ( $letter and $branchcode ne $letter->{branchcode} ) {
 264             $letter = undef;
 265         }
 266         unless ( $title and $content ) {
 267             # Delete this mtt if no title or content given
 268             delete_confirmed( $branchcode, $oldmodule, $code, $mtt );
 269             next;
 270         }
 271         elsif ( $letter and $letter->{message_transport_type} eq $mtt ) {
 272             $dbh->do(
 273                 q{
 274                     UPDATE letter
 275                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?
 276                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ?
 277                 },
 278                 undef,
 279                 $branchcode, $module, $name, $is_html || 0, $title, $content,
 280                 $branchcode, $oldmodule, $code, $mtt
 281             );
 282         } else {
 283             $dbh->do(
 284                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type) VALUES (?,?,?,?,?,?,?,?)},
 285                 undef,
 286                 $branchcode, $module, $code, $name, $is_html || 0, $title, $content, $mtt
 287             );
 288         }
 289     }
 290     # set up default display
 291     default_display($branchcode);
 292     return 1;
 293 }
 294
 295 sub delete_confirm {
 296     my ($branchcode, $module, $code) = @_;
 297     my $dbh = C4::Context->dbh;
 298     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 299     my @values = values %$letter;
 300     $template->param(
 301         letter => $letter,
 302     );
 303     return;
 304 }
 305
 306 sub delete_confirmed {
 307     my ($branchcode, $module, $code, $mtt) = @_;
 308     C4::Letters::DelLetter(
 309         {
 310             branchcode => $branchcode,
 311             module     => $module,
 312             code       => $code,
 313             mtt        => $mtt
 314         }
 315     );
 316     # setup default display for screen
 317     default_display($branchcode);
 318     return;
 319 }
 320
 321 sub retrieve_letters {
 322     my ($branchcode, $searchstring) = @_;
 323
 324     $branchcode = $my_branch if $branchcode && $my_branch;
 325
 326     my $dbh = C4::Context->dbh;
 327     my ($sql, @where, @args);
 328     $sql = "SELECT branchcode, module, code, name, branchname
 329             FROM letter
 330             LEFT OUTER JOIN branches USING (branchcode)
 331     ";
 332     if ($searchstring && $searchstring=~m/(\S+)/) {
 333         $searchstring = $1 . q{%};
 334         push @where, 'code LIKE ?';
 335         push @args, $searchstring;
 336     }
 337     elsif ($branchcode) {
 338         push @where, 'branchcode = ?';
 339         push @args, $branchcode || '';
 340     }
 341     elsif ($my_branch) {
 342         push @where, "(branchcode = ? OR branchcode = '')";
 343         push @args, $my_branch;
 344     }
 345
 346     $sql .= " WHERE ".join(" AND ", @where) if @where;
 347     $sql .= " GROUP BY branchcode,module,code";
 348     $sql .= " ORDER BY module, code, branchcode";
 349
 350     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 351 }
 352
 353 sub default_display {
 354     my ($branchcode, $searchfield) = @_;
 355
 356     if ( $searchfield  ) {
 357         $template->param( search      => 1 );
 358     }
 359     my $results = retrieve_letters($branchcode,$searchfield);
 360
 361     my $loop_data = [];
 362     my $protected_letters = protected_letters();
 363     foreach my $row (@{$results}) {
 364         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 365         push @{$loop_data}, $row;
 366
 367     }
 368
 369     $template->param(
 370         letter => $loop_data,
 371         branchloop => _branchloop($branchcode),
 372     );
 373 }
 374
 375 sub _branchloop {
 376     my ($branchcode) = @_;
 377
 378     my $branches = GetBranches();
 379     my @branchloop;
 380     for my $thisbranch (sort { $branches->{$a}->{branchname} cmp $branches->{$b}->{branchname} } keys %$branches) {
 381         push @branchloop, {
 382             value      => $thisbranch,
 383             selected   => $branchcode && $thisbranch eq $branchcode,
 384             branchname => $branches->{$thisbranch}->{'branchname'},
 385         };
 386     }
 387
 388     return \@branchloop;
 389 }
 390
 391 sub add_fields {
 392     my @tables = @_;
 393     my @fields = ();
 394
 395     for my $table (@tables) {
 396         push @fields, get_columns_for($table);
 397
 398     }
 399     return @fields;
 400 }
 401
 402 sub get_columns_for {
 403     my $table = shift;
 404 # FIXME untranslateable
 405     my %column_map = (
 406         aqbooksellers => '---BOOKSELLERS---',
 407         aqorders      => '---ORDERS---',
 408         serial        => '---SERIALS---',
 409         reserves      => '---HOLDS---',
 410         suggestions   => '---SUGGESTIONS---',
 411     );
 412     my @fields = ();
 413     if (exists $column_map{$table} ) {
 414         push @fields, {
 415             value => q{},
 416             text  => $column_map{$table} ,
 417         };
 418     }
 419     else {
 420         my $tlabel = '---' . uc $table;
 421         $tlabel.= '---';
 422         push @fields, {
 423             value => q{},
 424             text  => $tlabel,
 425         };
 426     }
 427
 428     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 429     my $table_prefix = $table . q|.|;
 430     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 431     for my $row (@{$rows}) {
 432         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 433         push @fields, {
 434             value => $table_prefix . $row->{Field},
 435             text  => $table_prefix . $row->{Field},
 436         }
 437     }
 438     if ($table eq 'borrowers') {
 439         if ( my $attributes = C4::Members::Attributes::GetAttributes() ) {
 440             foreach (@$attributes) {
 441                 push @fields, {
 442                     value => "borrower-attribute:$_",
 443                     text  => "attribute:$_",
 444                 }
 445             }
 446         }
 447     }
 448     return @fields;
 449 }