admin/library_groups.pl

   1 #! /usr/bin/perl
   2
   3 # Copyright 2016 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use CGI qw ( -utf8 );
  22 use C4::Context;
  23 use C4::Auth;
  24 use C4::Output;
  25
  26 use Koha::Libraries;
  27 use Koha::Library::Group;
  28 use Koha::Library::Groups;
  29
  30 my $cgi = new CGI;
  31
  32 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  33     {
  34         template_name   => "admin/library_groups.tt",
  35         query           => $cgi,
  36         type            => "intranet",
  37         authnotrequired => 0,
  38         flagsrequired   => { parameters => 'manage_libraries' },
  39         debug           => 1,
  40     }
  41 );
  42
  43 my $action = $cgi->param('action') || q{};
  44 my @messages;
  45
  46 if ( $action eq 'add' ) {
  47     my $parent_id   = $cgi->param('parent_id')   || undef;
  48     my $title       = $cgi->param('title')       || undef;
  49     my $description = $cgi->param('description') || undef;
  50     my $branchcode  = $cgi->param('branchcode')  || undef;
  51     my $ft_hide_patron_info    = $cgi->param('ft_hide_patron_info')    || 0;
  52     my $ft_search_groups_opac  = $cgi->param('ft_search_groups_opac')  || 0;
  53     my $ft_search_groups_staff = $cgi->param('ft_search_groups_staff') || 0;
  54     my $ft_local_hold_group = $cgi->param('ft_local_hold_group') || 0;
  55
  56     if ( !$branchcode && Koha::Library::Groups->search( { title => $title } )->count() ) {
  57         $template->param( error_duplicate_title => $title );
  58     }
  59     else {
  60         my $group = eval {
  61             Koha::Library::Group->new(
  62                 {
  63                     parent_id              => $parent_id,
  64                     title                  => $title,
  65                     description            => $description,
  66                     ft_hide_patron_info    => $ft_hide_patron_info,
  67                     ft_search_groups_opac  => $ft_search_groups_opac,
  68                     ft_search_groups_staff => $ft_search_groups_staff,
  69                     ft_local_hold_group    => $ft_local_hold_group,
  70                     branchcode             => $branchcode,
  71                 }
  72             )->store();
  73         };
  74         if ($@) {
  75             push @messages, { type => 'alert', code => 'error_on_insert' };
  76         }
  77         else {
  78             $template->param( added => $group );
  79         }
  80     }
  81 }
  82 elsif ( $action eq 'edit' ) {
  83     my $id          = $cgi->param('id')          || undef;
  84     my $title       = $cgi->param('title')       || undef;
  85     my $description = $cgi->param('description') || undef;
  86     my $ft_hide_patron_info    = $cgi->param('ft_hide_patron_info')    || 0;
  87     my $ft_search_groups_opac  = $cgi->param('ft_search_groups_opac')  || 0;
  88     my $ft_search_groups_staff = $cgi->param('ft_search_groups_staff') || 0;
  89     my $ft_local_hold_group = $cgi->param('ft_local_hold_group') || 0;
  90
  91     if ($id) {
  92         my $group = Koha::Library::Groups->find($id);
  93
  94         $group->set(
  95             {
  96                 title       => $title,
  97                 description => $description,
  98                 ft_hide_patron_info      => $ft_hide_patron_info,
  99                 ft_search_groups_opac    => $ft_search_groups_opac,
 100                 ft_search_groups_staff   => $ft_search_groups_staff,
 101                 ft_local_hold_group   => $ft_local_hold_group,
 102             }
 103         )->store();
 104
 105         $template->param( edited => $group );
 106     }
 107 }
 108 elsif ( $action eq 'delete' ) {
 109     my $id = $cgi->param('id');
 110
 111     my $group = Koha::Library::Groups->find($id);
 112
 113     if ($group) {
 114         $group->delete();
 115         $template->param(
 116             deleted => {
 117                 title   => $group->title(),
 118                 library => $group->library()
 119                 ? $group->library()->branchname
 120                 : undef
 121             }
 122         );
 123     }
 124 }
 125
 126 my $root_groups = Koha::Library::Groups->get_root_groups();
 127
 128 $template->param( root_groups => $root_groups, messages => \@messages, );
 129
 130 output_html_with_http_headers $cgi, $cookie, $template->output;