koha-tmpl/intranet-tmpl/prog/en/xslt/UNIMARCslimUtils.xsl

   1 <?xml version='1.0'?>
   2
   3 <!DOCTYPE stylesheet [<!ENTITY nbsp "&#160;" >]>
   4
   5 <xsl:stylesheet version="1.0"
   6   xmlns:marc="http://www.loc.gov/MARC21/slim"
   7   xmlns:items="http://www.koha-community.org/items"
   8   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   9   exclude-result-prefixes="marc items">
  10
  11   <xsl:template name="datafield">
  12     <xsl:param name="tag"/>
  13     <xsl:param name="ind1"><xsl:text> </xsl:text></xsl:param>
  14     <xsl:param name="ind2"><xsl:text> </xsl:text></xsl:param>
  15     <xsl:param name="subfields"/>
  16     <xsl:element name="datafield">
  17       <xsl:attribute name="tag">
  18         <xsl:value-of select="$tag"/>
  19       </xsl:attribute>
  20       <xsl:attribute name="ind1">
  21         <xsl:value-of select="$ind1"/>
  22       </xsl:attribute>
  23       <xsl:attribute name="ind2">
  24        <xsl:value-of select="$ind2"/>
  25          </xsl:attribute>
  26        <xsl:copy-of select="$subfields"/>
  27     </xsl:element>
  28   </xsl:template>
  29
  30   <xsl:template name="tag_210">
  31     <li>
  32       <strong>Publication: </strong>
  33       <xsl:for-each select="marc:datafield[@tag=210]">
  34         <span>
  35           <xsl:call-template name="addClassRtl" />
  36           <xsl:value-of select="marc:subfield[@code='a']"/>
  37           <xsl:if test="marc:subfield[@code='b']">
  38             <xsl:if test="marc:subfield[@code='a']">, </xsl:if>
  39             <xsl:value-of select="marc:subfield[@code='b']"/>
  40           </xsl:if>
  41           <xsl:if test="marc:subfield[@code='a' or @code='b']">
  42             <xsl:if test="marc:subfield[@code='a']"> : </xsl:if>
  43             <xsl:value-of select="marc:subfield[@code='c']"/>
  44           </xsl:if>
  45           <xsl:if test="marc:subfield[@code='d']">
  46             <xsl:if test="marc:subfield[@code='a' or @code='c']">, </xsl:if>
  47             <xsl:value-of select="marc:subfield[@code='d']"/>
  48           </xsl:if>
  49           <xsl:if test="marc:subfield[@code='e']">
  50             <xsl:if test="marc:subfield[@code='a' or @code='c' or @code='d']"> — </xsl:if>
  51             <xsl:value-of select="marc:subfield[@code='e']"/>
  52           </xsl:if>
  53           <xsl:if test="marc:subfield[@code='g']">
  54             <xsl:if test="marc:subfield[@code='e']"> : </xsl:if>
  55             <xsl:value-of select="marc:subfield[@code='g']"/>
  56           </xsl:if>
  57           <xsl:if test="marc:subfield[@code='h']">
  58             <xsl:if test="marc:subfield[@code='e' or @code='g']">, </xsl:if>
  59             <xsl:value-of select="marc:subfield[@code='h']"/>
  60           </xsl:if>
  61           <xsl:if test="not (position() = last())">
  62             <xsl:text> • </xsl:text>
  63           </xsl:if>
  64         </span>
  65       </xsl:for-each>
  66     </li>
  67   </xsl:template>
  68
  69         <xsl:template name="tag_215">
  70     <xsl:for-each select="marc:datafield[@tag=215]">
  71       <li>
  72         <strong>Description: </strong>
  73         <xsl:if test="marc:subfield[@code='a']">
  74           <xsl:value-of select="marc:subfield[@code='a']"/>
  75         </xsl:if>
  76         <xsl:if test="marc:subfield[@code='c']"> :
  77           <xsl:value-of select="marc:subfield[@code='c']"/>
  78         </xsl:if>
  79         <xsl:if test="marc:subfield[@code='d']"> ;
  80           <xsl:value-of select="marc:subfield[@code='d']"/>
  81         </xsl:if>
  82         <xsl:if test="marc:subfield[@code='e']"> +
  83           <xsl:value-of select="marc:subfield[@code='e']"/>
  84         </xsl:if>
  85       </li>
  86     </xsl:for-each>
  87   </xsl:template>
  88
  89         <xsl:template name="tag_4xx">
  90     <xsl:for-each select="marc:datafield[@tag=464 or @tag=461]">
  91         <li>
  92         <strong>Linked with: </strong>
  93         <span>
  94           <xsl:call-template name="addClassRtl" />
  95           <xsl:if test="marc:subfield[@code='t']">
  96             <xsl:value-of select="marc:subfield[@code='t']"/>
  97           </xsl:if>
  98           <xsl:if test="marc:subfield[@code='e']"> :
  99             <xsl:value-of select="marc:subfield[@code='e']"/>
 100           </xsl:if>
 101           <xsl:if test="marc:subfield[@code='f']"> /
 102             <xsl:value-of select="marc:subfield[@code='f']"/>
 103           </xsl:if>
 104           <xsl:if test="marc:subfield[@code='v']">,
 105             <xsl:value-of select="marc:subfield[@code='v']"/>
 106           </xsl:if>
 107         </span>
 108       </li>
 109     </xsl:for-each>
 110   </xsl:template>
 111
 112         <xsl:template name="subfieldSelect">
 113                 <xsl:param name="codes"/>
 114                 <xsl:param name="delimeter"><xsl:text> </xsl:text></xsl:param>
 115                 <xsl:param name="subdivCodes"/>
 116                 <xsl:param name="subdivDelimiter"/>
 117                 <xsl:variable name="str">
 118                         <xsl:for-each select="marc:subfield">
 119                                 <xsl:if test="contains($codes, @code)">
 120                     <xsl:if test="contains($subdivCodes, @code)">
 121                         <xsl:value-of select="$subdivDelimiter"/>
 122                     </xsl:if>
 123                                         <xsl:value-of select="text()"/><xsl:value-of select="$delimeter"/>
 124                                 </xsl:if>
 125                         </xsl:for-each>
 126                 </xsl:variable>
 127                 <xsl:value-of select="substring($str,1,string-length($str)-string-length($delimeter))"/>
 128         </xsl:template>
 129
 130         <xsl:template name="buildSpaces">
 131                 <xsl:param name="spaces"/>
 132                 <xsl:param name="char"><xsl:text> </xsl:text></xsl:param>
 133                 <xsl:if test="$spaces>0">
 134                         <xsl:value-of select="$char"/>
 135                         <xsl:call-template name="buildSpaces">
 136                                 <xsl:with-param name="spaces" select="$spaces - 1"/>
 137                                 <xsl:with-param name="char" select="$char"/>
 138                         </xsl:call-template>
 139                 </xsl:if>
 140         </xsl:template>
 141
 142   <xsl:template name="buildBiblioDefaultViewURL">
 143       <xsl:param name="IntranetBiblioDefaultView"/>
 144       <xsl:choose>
 145           <xsl:when test="$IntranetBiblioDefaultView='normal'">
 146               <xsl:text>/cgi-bin/koha/catalogue/detail.pl?biblionumber=</xsl:text>
 147           </xsl:when>
 148           <xsl:when test="$IntranetBiblioDefaultView='isbd'">
 149               <xsl:text>/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=</xsl:text>
 150           </xsl:when>
 151           <xsl:when test="$IntranetBiblioDefaultView='labeled_marc'">
 152               <xsl:text>/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=</xsl:text>
 153           </xsl:when>
 154           <xsl:when test="$IntranetBiblioDefaultView='marc'">
 155               <xsl:text>/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=</xsl:text>
 156           </xsl:when>
 157           <xsl:otherwise>
 158               <xsl:text>/cgi-bin/koha/catalogue/detail.pl?biblionumber=</xsl:text>
 159           </xsl:otherwise>
 160       </xsl:choose>
 161   </xsl:template>
 162
 163         <xsl:template name="chopSpecialCharacters">
 164         <xsl:param name="title" />
 165         <xsl:variable name="ntitle"
 166              select="translate($title, '&#x0098;&#x009C;&#xC29C;&#xC29B;&#xC298;&#xC288;&#xC289;','')"/>
 167         <xsl:value-of select="$ntitle" />
 168     </xsl:template>
 169
 170
 171         <xsl:template name="chopPunctuation">
 172                 <xsl:param name="chopString"/>
 173                 <xsl:variable name="length" select="string-length($chopString)"/>
 174                 <xsl:choose>
 175                         <xsl:when test="$length=0"/>
 176                         <xsl:when test="contains('.:,;/ ', substring($chopString,$length,1))">
 177                                 <xsl:call-template name="chopPunctuation">
 178                                         <xsl:with-param name="chopString" select="substring($chopString,1,$length - 1)"/>
 179                                 </xsl:call-template>
 180                         </xsl:when>
 181                         <xsl:when test="not($chopString)"/>
 182                         <xsl:otherwise><xsl:value-of select="$chopString"/></xsl:otherwise>
 183                 </xsl:choose>
 184     <xsl:text> </xsl:text>
 185         </xsl:template>
 186
 187         <xsl:template name="addClassRtl">
 188     <xsl:variable name="lang" select="marc:subfield[@code='7']" />
 189     <xsl:if test="$lang = 'ha' or $lang = 'Hebrew' or $lang = 'fa' or $lang = 'Arabe'">
 190       <xsl:attribute name="class">rtl</xsl:attribute>
 191     </xsl:if>
 192   </xsl:template>
 193
 194   <xsl:template name="tag_title">
 195     <xsl:param name="tag" />
 196     <xsl:param name="label" />
 197     <xsl:if test="marc:datafield[@tag=$tag]">
 198       <li>
 199         <strong><xsl:value-of select="$label"/>: </strong>
 200         <xsl:for-each select="marc:datafield[@tag=$tag]">
 201           <xsl:value-of select="marc:subfield[@code='a']" />
 202           <xsl:if test="marc:subfield[@code='d']">
 203             <xsl:text> : </xsl:text>
 204             <xsl:value-of select="marc:subfield[@code='e']"/>
 205           </xsl:if>
 206           <xsl:if test="marc:subfield[@code='e']">
 207             <xsl:for-each select="marc:subfield[@code='e']">
 208               <xsl:text> </xsl:text>
 209               <xsl:value-of select="."/>
 210             </xsl:for-each>
 211           </xsl:if>
 212           <xsl:if test="marc:subfield[@code='f']">
 213             <xsl:text> / </xsl:text>
 214             <xsl:value-of select="marc:subfield[@code='f']"/>
 215           </xsl:if>
 216           <xsl:if test="marc:subfield[@code='h']">
 217             <xsl:text>, </xsl:text>
 218             <xsl:value-of select="marc:subfield[@code='h']"/>
 219           </xsl:if>
 220           <xsl:if test="marc:subfield[@code='i']">
 221             <xsl:text>, </xsl:text>
 222             <xsl:value-of select="marc:subfield[@code='i']"/>
 223           </xsl:if>
 224           <xsl:if test="marc:subfield[@code='v']">
 225             <xsl:text>, </xsl:text>
 226             <xsl:value-of select="marc:subfield[@code='v']"/>
 227           </xsl:if>
 228           <xsl:if test="marc:subfield[@code='x']">
 229             <xsl:text>, </xsl:text>
 230             <xsl:value-of select="marc:subfield[@code='x']"/>
 231           </xsl:if>
 232           <xsl:if test="marc:subfield[@code='z']">
 233             <xsl:text>, </xsl:text>
 234             <xsl:value-of select="marc:subfield[@code='z']"/>
 235           </xsl:if>
 236         </xsl:for-each>
 237       </li>
 238     </xsl:if>
 239   </xsl:template>
 240
 241
 242   <xsl:template name="tag_subject">
 243     <xsl:param name="tag" />
 244     <xsl:param name="label" />
 245     <xsl:if test="marc:datafield[@tag=$tag]">
 246       <li>
 247         <strong><xsl:value-of select="$label"/>: </strong>
 248         <xsl:for-each select="marc:datafield[@tag=$tag]">
 249           <a>
 250             <xsl:choose>
 251               <xsl:when test="marc:subfield[@code=9]">
 252                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=an:<xsl:value-of select="marc:subfield[@code=9]"/></xsl:attribute>
 253               </xsl:when>
 254               <xsl:otherwise>
 255                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=su:<xsl:value-of select="marc:subfield[@code='a']"/></xsl:attribute>
 256               </xsl:otherwise>
 257             </xsl:choose>
 258             <xsl:call-template name="chopPunctuation">
 259               <xsl:with-param name="chopString">
 260                 <xsl:call-template name="subfieldSelect">
 261                     <xsl:with-param name="codes">abcdjpvxyz</xsl:with-param>
 262                     <xsl:with-param name="subdivCodes">jpxyz</xsl:with-param>
 263                     <xsl:with-param name="subdivDelimiter">-- </xsl:with-param>
 264                 </xsl:call-template>
 265               </xsl:with-param>
 266             </xsl:call-template>
 267           </a>
 268           <xsl:if test="not (position()=last())">
 269             <xsl:text> | </xsl:text>
 270           </xsl:if>
 271         </xsl:for-each>
 272       </li>
 273     </xsl:if>
 274   </xsl:template>
 275
 276
 277   <xsl:template name="tag_7xx">
 278     <xsl:param name="tag" />
 279     <xsl:param name="label" />
 280     <xsl:if test="marc:datafield[@tag=$tag]">
 281       <li>
 282         <strong><xsl:value-of select="$label" />: </strong>
 283         <xsl:for-each select="marc:datafield[@tag=$tag]">
 284           <span>
 285             <xsl:call-template name="addClassRtl" />
 286             <a>
 287               <xsl:choose>
 288                 <xsl:when test="marc:subfield[@code=9]">
 289                   <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=an:<xsl:value-of select="marc:subfield[@code=9]"/></xsl:attribute>
 290                 </xsl:when>
 291                 <xsl:otherwise>
 292                   <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=au:<xsl:value-of select="marc:subfield[@code='a']"/><xsl:text> </xsl:text><xsl:value-of select="marc:subfield[@code='b']"/></xsl:attribute>
 293                 </xsl:otherwise>
 294               </xsl:choose>
 295               <xsl:if test="marc:subfield[@code='a']">
 296                 <xsl:value-of select="marc:subfield[@code='a']"/>
 297               </xsl:if>
 298               <xsl:if test="marc:subfield[@code='b']">
 299                 <xsl:text>, </xsl:text>
 300                 <xsl:value-of select="marc:subfield[@code='b']"/>
 301               </xsl:if>
 302               <xsl:if test="marc:subfield[@code='c']">
 303                 <xsl:text>, </xsl:text>
 304                 <xsl:value-of select="marc:subfield[@code='c']"/>
 305               </xsl:if>
 306               <xsl:if test="marc:subfield[@code='d']">
 307                 <xsl:text> </xsl:text>
 308                 <xsl:value-of select="marc:subfield[@code='d']"/>
 309               </xsl:if>
 310               <xsl:if test="marc:subfield[@code='f']">
 311                 <span dir="ltr">
 312                 <xsl:text> (</xsl:text>
 313                 <xsl:value-of select="marc:subfield[@code='f']"/>
 314                 <xsl:text>)</xsl:text>
 315                 </span>
 316               </xsl:if>
 317               <xsl:if test="marc:subfield[@code='g']">
 318                 <xsl:text> </xsl:text>
 319                 <xsl:value-of select="marc:subfield[@code='g']"/>
 320               </xsl:if>
 321               <xsl:if test="marc:subfield[@code='p']">
 322                 <xsl:text> </xsl:text>
 323                 <xsl:value-of select="marc:subfield[@code='p']"/>
 324               </xsl:if>
 325             </a>
 326           </span>
 327           <xsl:if test="not (position() = last())">
 328             <xsl:text> ; </xsl:text>
 329           </xsl:if>
 330         </xsl:for-each>
 331       </li>
 332     </xsl:if>
 333   </xsl:template>
 334
 335 </xsl:stylesheet>