koha-tmpl/intranet-tmpl/prog/en/xslt/NORMARCslimUtils.xsl

   1 <?xml version='1.0'?>
   2 <xsl:stylesheet version="1.0" xmlns:marc="http://www.loc.gov/MARC21/slim" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
   3         <xsl:template name="datafield">
   4                 <xsl:param name="tag"/>
   5                 <xsl:param name="ind1"><xsl:text> </xsl:text></xsl:param>
   6                 <xsl:param name="ind2"><xsl:text> </xsl:text></xsl:param>
   7                 <xsl:param name="subfields"/>
   8                 <xsl:element name="datafield">
   9                         <xsl:attribute name="tag">
  10                                 <xsl:value-of select="$tag"/>
  11                         </xsl:attribute>
  12                         <xsl:attribute name="ind1">
  13                                 <xsl:value-of select="$ind1"/>
  14                         </xsl:attribute>
  15                         <xsl:attribute name="ind2">
  16                                 <xsl:value-of select="$ind2"/>
  17                         </xsl:attribute>
  18                         <xsl:copy-of select="$subfields"/>
  19                 </xsl:element>
  20         </xsl:template>
  21
  22         <xsl:template name="subfieldSelect">
  23                 <xsl:param name="codes"/>
  24                 <xsl:param name="delimeter"><xsl:text> </xsl:text></xsl:param>
  25                 <xsl:param name="subdivCodes"/>
  26                 <xsl:param name="subdivDelimiter"/>
  27         <xsl:param name="prefix"/>
  28         <xsl:param name="suffix"/>
  29                 <xsl:variable name="str">
  30                         <xsl:for-each select="marc:subfield">
  31                                 <xsl:if test="contains($codes, @code)">
  32                     <xsl:if test="contains($subdivCodes, @code)">
  33                         <xsl:value-of select="$subdivDelimiter"/>
  34                     </xsl:if>
  35                                         <xsl:value-of select="$prefix"/><xsl:value-of select="text()"/><xsl:value-of select="$suffix"/><xsl:value-of select="$delimeter"/>
  36                                 </xsl:if>
  37                         </xsl:for-each>
  38                 </xsl:variable>
  39                 <xsl:value-of select="substring($str,1,string-length($str)-string-length($delimeter))"/>
  40         </xsl:template>
  41
  42         <xsl:template name="buildSpaces">
  43                 <xsl:param name="spaces"/>
  44                 <xsl:param name="char"><xsl:text> </xsl:text></xsl:param>
  45                 <xsl:if test="$spaces>0">
  46                         <xsl:value-of select="$char"/>
  47                         <xsl:call-template name="buildSpaces">
  48                                 <xsl:with-param name="spaces" select="$spaces - 1"/>
  49                                 <xsl:with-param name="char" select="$char"/>
  50                         </xsl:call-template>
  51                 </xsl:if>
  52         </xsl:template>
  53
  54         <xsl:template name="chopPunctuation">
  55                 <xsl:param name="chopString"/>
  56                 <xsl:variable name="length" select="string-length($chopString)"/>
  57                 <xsl:choose>
  58                         <xsl:when test="$length=0"/>
  59                         <xsl:when test="contains('.:,;/ ', substring($chopString,$length,1))">
  60                                 <xsl:call-template name="chopPunctuation">
  61                                         <xsl:with-param name="chopString" select="substring($chopString,1,$length - 1)"/>
  62                                 </xsl:call-template>
  63                         </xsl:when>
  64                         <xsl:when test="not($chopString)"/>
  65                         <xsl:otherwise><xsl:value-of select="$chopString"/></xsl:otherwise>
  66                 </xsl:choose>
  67 <xsl:text> </xsl:text>
  68         </xsl:template>
  69
  70         <!-- Function extractControlNumber is used to extract the control number (record number) from MARC tags 773/80/85 [etc.] subfield $w.
  71              Parameter: control number string.
  72              Assumes LOC convention: (OrgCode)recordNumber.
  73              If OrgCode is not present, return full string.
  74              Additionally, handle various brackets/parentheses. Chop leading and trailing spaces.
  75         -->
  76         <xsl:template name="extractControlNumber">
  77             <xsl:param name="subfieldW"/>
  78             <xsl:variable name="tranW" select="translate($subfieldW,']})&gt;','))))')"/>
  79             <xsl:choose>
  80               <xsl:when test="contains($tranW,')')">
  81                 <xsl:value-of select="normalize-space(translate(substring-after($tranW,')'),'[]{}()&lt;&gt;',''))"/>
  82               </xsl:when>
  83               <xsl:otherwise>
  84                 <xsl:value-of select="normalize-space($subfieldW)"/>
  85               </xsl:otherwise>
  86             </xsl:choose>
  87         </xsl:template>
  88
  89 <xsl:template name="nameABCDQ">
  90 <xsl:call-template name="chopPunctuation">
  91 <xsl:with-param name="chopString">
  92 <xsl:call-template name="subfieldSelect">
  93 <xsl:with-param name="codes">aq</xsl:with-param>
  94 </xsl:call-template>
  95 </xsl:with-param>
  96 <xsl:with-param name="punctuation">
  97 <xsl:text>:,;/ </xsl:text>
  98 </xsl:with-param>
  99 </xsl:call-template>
 100 <xsl:call-template name="termsOfAddress"/>
 101 </xsl:template>
 102
 103 <xsl:template name="nameABCDN">
 104 <xsl:for-each select="marc:subfield[@code='a']">
 105 <xsl:call-template name="chopPunctuation">
 106 <xsl:with-param name="chopString" select="."/>
 107 </xsl:call-template>
 108 </xsl:for-each>
 109 <xsl:for-each select="marc:subfield[@code='b']">
 110 <xsl:value-of select="."/>
 111 </xsl:for-each>
 112 <xsl:if test="marc:subfield[@code='c'] or marc:subfield[@code='d'] or marc:subfield[@code='n']">
 113 <xsl:call-template name="subfieldSelect">
 114 <xsl:with-param name="codes">cdn</xsl:with-param>
 115 </xsl:call-template>
 116 </xsl:if>
 117 </xsl:template>
 118
 119 <xsl:template name="nameACDEQ">
 120 <xsl:call-template name="subfieldSelect">
 121 <xsl:with-param name="codes">acdeq</xsl:with-param>
 122 </xsl:call-template>
 123 </xsl:template>
 124
 125 <xsl:template name="termsOfAddress">
 126 <xsl:if test="marc:subfield[@code='b' or @code='c']">
 127 <xsl:call-template name="chopPunctuation">
 128 <xsl:with-param name="chopString">
 129 <xsl:call-template name="subfieldSelect">
 130 <xsl:with-param name="codes">bc</xsl:with-param>
 131 </xsl:call-template>
 132 </xsl:with-param>
 133 </xsl:call-template>
 134 </xsl:if>
 135 </xsl:template>
 136
 137     <!-- Function m880Select:  Display Alternate Graphic Representation (MARC 880) for selected latin "base"tags
 138         - should be called immediately before the corresonding latin tags are processed
 139         - tags in right-to-left languages are displayed floating right
 140         * Parameter:
 141            + basetags: display these tags if found in linkage section ( subfield 6) of tag 880
 142            + codes: display these subfields codes
 143         * Options:
 144             - class: wrap output in <span class="$class">...</span>
 145             - label: prefix each(!) tag with label $label
 146             - bibno: link to biblionumber $bibno
 147             - index: build a search link using index $index with subfield $a as key; if subfield $9 is present use index 'an' with key $9 instead.
 148          * Limitations:
 149             - displays every field on a separate line (to switch between rtl and ltr)
 150          * Pitfalls:
 151            (!) output might be empty
 152     -->
 153     <xsl:template name="m880Select">
 154          <xsl:param name="basetags"/> <!-- e.g.  100,700,110,710 -->
 155         <xsl:param name="codes"/> <!-- e.g. abc  -->
 156         <xsl:param name="class"/> <!-- e.g. results_summary -->
 157         <xsl:param name="label"/> <!-- e.g.  Edition -->
 158         <xsl:param name="bibno"/>
 159         <xsl:param name="index"/> <!-- e.g.  au -->
 160
 161         <xsl:for-each select="marc:datafield[@tag=880]">
 162             <xsl:variable name="code6" select="marc:subfield[@code=6]"/>
 163             <xsl:if test="contains(string($basetags), substring($code6,1,3))">
 164                 <span>
 165                     <xsl:if test="boolean($class)">
 166                         <xsl:attribute name="class"><xsl:value-of select="$class"/></xsl:attribute>
 167                     </xsl:if>
 168                     <xsl:choose>
 169                         <!-- display right-to-left tags floating right of their left-to-right counterparts -->
 170                         <xsl:when test="substring($code6,10,2) ='/r'">
 171                             <xsl:attribute name="style">display:block; text-align:right; float:right; width:50%; padding-left:20px</xsl:attribute>
 172                             <xsl:attribute name="dir">rtl</xsl:attribute>
 173                         </xsl:when>
 174                         <xsl:otherwise>
 175                             <xsl:attribute name="style">display:block; </xsl:attribute>
 176                         </xsl:otherwise>
 177                     </xsl:choose>
 178                     <xsl:if test="boolean($label)">
 179                         <span class="label">
 180                             <xsl:value-of select="$label"/>
 181                         </span>
 182                     </xsl:if>
 183                     <xsl:variable name="str">
 184                         <xsl:for-each select="marc:subfield">
 185                             <xsl:if test="contains($codes, @code)">
 186                                 <xsl:value-of select="text()"/>
 187                                 <xsl:text> </xsl:text>
 188                             </xsl:if>
 189                         </xsl:for-each>
 190                     </xsl:variable>
 191                     <xsl:choose>
 192                         <xsl:when test="boolean($bibno)">
 193                             <a>
 194                                 <xsl:attribute name="href">/cgi-bin/koha/opac-detail.pl?biblionumber=<xsl:value-of  select="$bibno"/></xsl:attribute>
 195                                 <xsl:value-of select="$str"/>
 196                             </a>
 197                         </xsl:when>
 198                        <xsl:when test="boolean($index) and boolean(marc:subfield[@code=9])">
 199                             <a>
 200                                 <xsl:attribute name="href">/cgi-bin/koha/opac-search.pl?q=an:<xsl:value-of  select="marc:subfield[@code=9]"/></xsl:attribute>
 201                                   <xsl:value-of select="$str"/>
 202                             </a>
 203                         </xsl:when>
 204                         <xsl:when test="boolean($index)">
 205                             <a>
 206                                 <xsl:attribute name="href">/cgi-bin/koha/opac-search.pl?q=<xsl:value-of  select="$index"/>:<xsl:value-of  select="marc:subfield[@code='a']"/></xsl:attribute>
 207                                 <xsl:value-of select="$str"/>
 208                             </a>
 209                         </xsl:when>
 210                         <xsl:otherwise>
 211                             <xsl:value-of select="$str"/>
 212                         </xsl:otherwise>
 213                     </xsl:choose>
 214                 </span>
 215             </xsl:if>
 216         </xsl:for-each>
 217
 218     </xsl:template>
 219
 220 </xsl:stylesheet>
 221
 222 <!-- Stylus Studio meta-information - (c)1998-2002 eXcelon Corp.
 223 <metaInformation>
 224 <scenarios/><MapperInfo srcSchemaPath="" srcSchemaRoot="" srcSchemaPathIsRelative="yes" srcSchemaInterpretAsXML="no" destSchemaPath="" destSchemaRoot="" destSchemaPathIsRelative="yes" destSchemaInterpretAsXML="no"/>
 225 </metaInformation>
 226 -->