koha-tmpl/intranet-tmpl/prog/en/xslt/NORMARCslim2intranetDetail.xsl

   1 <?xml version="1.0" encoding="UTF-8"?>
   2 <!-- $Id: MARC21slim2DC.xsl,v 1.1 2003/01/06 08:20:27 adam Exp $ -->
   3 <xsl:stylesheet version="1.0"
   4   xmlns:marc="http://www.loc.gov/MARC21/slim"
   5   xmlns:items="http://www.koha-community.org/items"
   6   xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
   7   exclude-result-prefixes="marc items">
   8     <xsl:import href="NORMARCslimUtils.xsl"/>
   9     <xsl:output method = "html" indent="yes" omit-xml-declaration = "yes" encoding="UTF-8"/>
  10     <xsl:template match="/">
  11             <xsl:apply-templates/>
  12     </xsl:template>
  13
  14     <xsl:template match="marc:record">
  15
  16         <!-- Sysprefs -->
  17         <xsl:variable name="UseControlNumber" select="marc:sysprefs/marc:syspref[@name='UseControlNumber']"/>
  18         <xsl:variable name="OPACBaseURL" select="marc:sysprefs/marc:syspref[@name='OPACBaseURL']"/>
  19         <xsl:variable name="SubjectModifier"><xsl:if test="marc:sysprefs/marc:syspref[@name='TraceCompleteSubfields']='1'">,complete-subfield</xsl:if></xsl:variable>
  20         <xsl:variable name="TraceSubjectSubdivisions" select="marc:sysprefs/marc:syspref[@name='TraceSubjectSubdivisions']"/>
  21         <xsl:variable name="TracingQuotesLeft">
  22           <xsl:choose>
  23             <xsl:when test="marc:sysprefs/marc:syspref[@name='UseICU']='1'">{</xsl:when>
  24             <xsl:otherwise>"</xsl:otherwise>
  25           </xsl:choose>
  26         </xsl:variable>
  27         <xsl:variable name="TracingQuotesRight">
  28           <xsl:choose>
  29             <xsl:when test="marc:sysprefs/marc:syspref[@name='UseICU']='1'">}</xsl:when>
  30             <xsl:otherwise>"</xsl:otherwise>
  31           </xsl:choose>
  32         </xsl:variable>
  33         <xsl:variable name="DisplayOPACiconsXSLT" select="marc:sysprefs/marc:syspref[@name='DisplayOPACiconsXSLT']"/>
  34
  35         <xsl:variable name="leader" select="marc:leader"/>
  36         <xsl:variable name="leader6" select="substring($leader,7,1)"/>
  37         <xsl:variable name="leader7" select="substring($leader,8,1)"/>
  38         <xsl:variable name="controlField008" select="marc:controlfield[@tag=008]"/>
  39         <xsl:variable name="field019b" select="marc:datafield[@tag=019]/marc:subfield[@code='b']"/>
  40         <xsl:variable name="biblionumber" select="marc:datafield[@tag=999]/marc:subfield[@code='c']"/>
  41         <xsl:variable name="typeOf008">
  42             <!-- The logic here should be exactly the same for NORMARCslim2intranetDetail.xsl, NORMARCslim2intranetResults.xsl, NORMARCslim2OPACDetail.xsl and NORMARCslim2OPACResults.xsl -->
  43             <xsl:choose>
  44                 <xsl:when test="$field019b='b' or $field019b='k' or $field019b='l' or $leader6='b'">Mon</xsl:when>
  45                 <xsl:when test="$field019b='e' or contains($field019b,'ec') or contains($field019b,'ed') or contains($field019b,'ee') or contains($field019b,'ef') or $leader6='g'">FV</xsl:when>
  46                 <xsl:when test="$field019b='c' or $field019b='d' or contains($field019b,'da') or contains($field019b,'db') or contains($field019b,'dc') or contains($field019b,'dd') or contains($field019b,'dg') or contains($field019b,'dh') or contains($field019b,'di') or contains($field019b,'dj') or contains($field019b,'dk') or $leader6='c' or $leader6='d' or $leader6='i' or $leader6='j'">Mus</xsl:when>
  47                 <xsl:when test="$field019b='a' or contains($field019b,'ab') or contains($field019b,'aj') or $leader6='e' or $leader6='f'">Kar</xsl:when>
  48                 <xsl:when test="$field019b='f' or $field019b='i' or contains($field019b,'ib') or contains($field019b,'ic') or contains($field019b,'fd') or contains($field019b,'ff') or contains($field019b,'fi') or $leader6='k'">gra</xsl:when>
  49                 <xsl:when test="$field019b='g' or contains($field019b,'gb') or contains($field019b,'gd') or contains($field019b,'ge') or $leader6='m'">Fil</xsl:when>
  50                 <xsl:when test="$leader6='o'">kom</xsl:when>
  51                 <xsl:when test="$field019b='h' or $leader6='r'">trd</xsl:when>
  52                 <xsl:when test="$field019b='j' or $leader6='a'">
  53                     <xsl:choose>
  54                         <xsl:when test="$leader7='a' or $leader7='c' or $leader7='m' or $leader7='p'">Mon</xsl:when>
  55                         <xsl:when test="$field019b='j' or $leader7='b' or $leader7='s'">Per</xsl:when>
  56                     </xsl:choose>
  57                 </xsl:when>
  58             </xsl:choose>
  59         </xsl:variable>
  60
  61         <!-- Tittel og ansvarsopplysninger -->
  62         <xsl:if test="marc:datafield[@tag=245]">
  63         <h1>
  64             <xsl:for-each select="marc:datafield[@tag=245]">
  65                     <xsl:call-template name="subfieldSelect">
  66                         <xsl:with-param name="codes">a</xsl:with-param>
  67                     </xsl:call-template>
  68                     <xsl:if test="marc:subfield[@code='b']">
  69                         <xsl:text> : </xsl:text>
  70                         <xsl:call-template name="subfieldSelect">
  71                             <xsl:with-param name="codes">b</xsl:with-param>
  72                         </xsl:call-template>
  73                     </xsl:if>
  74                     <xsl:if test="marc:subfield[@code='h']">
  75                         <xsl:text> </xsl:text>
  76                         (<xsl:call-template name="subfieldSelect">
  77                             <xsl:with-param name="codes">h</xsl:with-param>
  78                         </xsl:call-template>)
  79                     </xsl:if>
  80                     <xsl:text> </xsl:text>
  81                     <xsl:call-template name="subfieldSelect">
  82                         <xsl:with-param name="codes">np</xsl:with-param>
  83                     </xsl:call-template>
  84             </xsl:for-each>
  85         </h1>
  86         </xsl:if>
  87
  88         <!-- Author Statement -->
  89                 <!-- 245$9 is Koha authority number -->
  90         <xsl:choose>
  91         <xsl:when test="marc:datafield[@tag=100] or marc:datafield[@tag=110] or marc:datafield[@tag=111] or marc:datafield[@tag=700] or marc:datafield[@tag=710] or marc:datafield[@tag=711]">
  92         <h5 class="author">av
  93         <xsl:for-each select="marc:datafield[@tag=100 or @tag=700]">
  94         <a>
  95         <xsl:choose>
  96             <xsl:when test="marc:subfield[@code=9]">
  97                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=an:<xsl:value-of select="marc:subfield[@code=9]"/></xsl:attribute>
  98             </xsl:when>
  99             <xsl:otherwise>
 100             <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=au:<xsl:value-of select="marc:subfield[@code='a']"/></xsl:attribute>
 101             </xsl:otherwise>
 102         </xsl:choose>
 103         <xsl:call-template name="nameABCDQ"/></a>
 104         <xsl:choose>
 105         <xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 106         </xsl:for-each>
 107
 108         <xsl:for-each select="marc:datafield[@tag=110 or @tag=710]">
 109         <a>
 110         <xsl:choose>
 111             <xsl:when test="marc:subfield[@code=9]">
 112                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=an:<xsl:value-of select="marc:subfield[@code=9]"/></xsl:attribute>
 113             </xsl:when>
 114             <xsl:otherwise>
 115             <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=au:<xsl:value-of select="marc:subfield[@code='a']"/></xsl:attribute>
 116             </xsl:otherwise>
 117         </xsl:choose>
 118         <xsl:call-template name="nameABCDN"/></a>
 119         <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 120         </xsl:for-each>
 121
 122         <xsl:for-each select="marc:datafield[@tag=111 or @tag=711]">
 123         <a>
 124         <xsl:choose>
 125             <xsl:when test="marc:subfield[@code=9]">
 126                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=an:<xsl:value-of select="marc:subfield[@code=9]"/></xsl:attribute>
 127             </xsl:when>
 128             <xsl:otherwise>
 129             <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=au:<xsl:value-of select="marc:subfield[@code='a']"/></xsl:attribute>
 130             </xsl:otherwise>
 131         </xsl:choose>
 132         <xsl:call-template name="nameACDEQ"/></a>
 133         <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 134
 135         </xsl:for-each>
 136         </h5>
 137         </xsl:when>
 138         </xsl:choose>
 139
 140
 141         <xsl:if test="$typeOf008!=''">
 142         <span class="results_summary">
 143             <span class="label">Materialtype: </span>
 144             <xsl:choose>
 145                 <xsl:when test="$typeOf008='Mon'"><img src="/intranet-tmpl/prog/img/famfamfam/BK.png" alt="Bok" title="Bok"/> Bok</xsl:when>
 146                 <xsl:when test="$typeOf008='Per'"><img src="/intranet-tmpl/prog/img/famfamfam/AR.png" alt="Periodika" title="Periodika"/> Periodika</xsl:when>
 147                 <xsl:when test="$typeOf008='Fil'"><img src="/intranet-tmpl/prog/img/famfamfam/CF.png" alt="Fil" title="Fil"/> Fil</xsl:when>
 148                 <xsl:when test="$typeOf008='Kar'"><img src="/intranet-tmpl/prog/img/famfamfam/MP.png" alt="Kart" title="Kart"/> Kart</xsl:when>
 149                 <xsl:when test="$typeOf008='FV'"><img  src="/intranet-tmpl/prog/img/famfamfam/VM.png" alt="Film og video" title="Film og video"/> Film og video</xsl:when>
 150                 <xsl:when test="$typeOf008='Mus'"><img src="/intranet-tmpl/prog/img/famfamfam/PR.png" alt="Musikktrykk og lydopptak" title="Musikktrykk og lydopptak"/> Musikk</xsl:when>
 151                 <xsl:when test="$typeOf008='gra'"><img src="/intranet-tmpl/prog/img/famfamfam/GR.png" alt="Grafisk materiale" title="Grafisk materiale"/> Grafisk materiale</xsl:when>
 152                 <xsl:when test="$typeOf008='kom'"><img src="/intranet-tmpl/prog/img/famfamfam/MX.png" alt="Kombidokumenter" title="Kombidokumenter"/> Kombidokumenter</xsl:when>
 153                 <xsl:when test="$typeOf008='trd'"><img src="/intranet-tmpl/prog/img/famfamfam/TD.png" alt="Tre-dimensjonale gjenstander" title="Tre-dimensjonale gjenstander"/> Tre-dimensjonale gjenstander</xsl:when>
 154             </xsl:choose>
 155         </span>
 156         </xsl:if>
 157
 158         <!--Series -->
 159         <xsl:if test="marc:datafield[@tag=440 or @tag=490]">
 160                 <span class="results_summary"><span class="label">Series: </span>
 161                 <xsl:for-each select="marc:datafield[@tag=440]">
 162                      <a href="/cgi-bin/koha/catalogue/search.pl?q=se:{marc:subfield[@code='a']}">
 163                     <xsl:call-template name="chopPunctuation">
 164                                     <xsl:with-param name="chopString">
 165                                         <xsl:call-template name="subfieldSelect">
 166                                             <xsl:with-param name="codes">av</xsl:with-param>
 167                                         </xsl:call-template>
 168                                     </xsl:with-param>
 169                                 </xsl:call-template>
 170                                 </a>
 171                             <xsl:text> </xsl:text><xsl:call-template name="part"/>
 172                     <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 173                 </xsl:for-each>
 174
 175                 <xsl:for-each select="marc:datafield[@tag=490][@ind1=0]">
 176                      <a href="/cgi-bin/koha/catalogue/search.pl?q=se:{marc:subfield[@code='a']}">
 177                                 <xsl:call-template name="chopPunctuation">
 178                                     <xsl:with-param name="chopString">
 179                                         <xsl:call-template name="subfieldSelect">
 180                                             <xsl:with-param name="codes">av</xsl:with-param>
 181                                         </xsl:call-template>
 182                                     </xsl:with-param>
 183                                 </xsl:call-template>
 184                     </a>
 185                             <xsl:call-template name="part"/>
 186                 <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 187                 </xsl:for-each>
 188                 </span>
 189         </xsl:if>
 190
 191         <!-- Analytics -->
 192         <xsl:if test="$leader7='s' or $leader7='c'">
 193         <span class="results_summary analytics"><span class="label">Analytics: </span>
 194             <a>
 195             <xsl:choose>
 196             <xsl:when test="$UseControlNumber = '1' and marc:controlfield[@tag=001]">
 197                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=rcn:<xsl:value-of select="marc:controlfield[@tag=001]"/>+and+(bib-level:a+or+bib-level:b)</xsl:attribute>
 198             </xsl:when>
 199             <xsl:otherwise>
 200                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=Host-item:<xsl:value-of select="translate(marc:datafield[@tag=245]/marc:subfield[@code='a'], '/', '')"/></xsl:attribute>
 201             </xsl:otherwise>
 202             </xsl:choose>
 203             <xsl:text>Show analytics</xsl:text>
 204             </a>
 205         </span>
 206         </xsl:if>
 207
 208         <!-- 773 - Links from child to parent -->
 209         <xsl:if test="marc:datafield[@tag=773]">
 210         <xsl:for-each select="marc:datafield[@tag=773]">
 211         <xsl:if test="@ind1=0">
 212         <span class="results_summary in"><span class="label">
 213         <xsl:choose>
 214         <xsl:when test="@ind2=' '">
 215             In:
 216         </xsl:when>
 217         <xsl:when test="@ind2=8">
 218             <xsl:if test="marc:subfield[@code='i']">
 219                 <xsl:value-of select="marc:subfield[@code='i']"/>
 220             </xsl:if>
 221         </xsl:when>
 222         </xsl:choose>
 223         </span>
 224                 <xsl:variable name="f773">
 225                     <xsl:call-template name="chopPunctuation"><xsl:with-param name="chopString"><xsl:call-template name="subfieldSelect">
 226                         <xsl:with-param name="codes">at</xsl:with-param>
 227                     </xsl:call-template></xsl:with-param></xsl:call-template>
 228                 </xsl:variable>
 229             <xsl:choose>
 230                 <xsl:when test="$UseControlNumber = '1' and marc:subfield[@code='w']">
 231                     <a><xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=Control-number:<xsl:call-template name="extractControlNumber"><xsl:with-param name="subfieldW" select="marc:subfield[@code='w']"/></xsl:call-template></xsl:attribute>
 232                         <xsl:value-of select="translate($f773, '()', '')"/>
 233                     </a>
 234                     <xsl:if test="marc:subfield[@code='g']"><xsl:text> </xsl:text><xsl:value-of select="marc:subfield[@code='g']"/></xsl:if>
 235                 </xsl:when>
 236                 <xsl:when test="marc:subfield[@code='0']">
 237                     <a><xsl:attribute name="href">/cgi-bin/koha/catalogue/detail.pl?biblionumber=<xsl:value-of select="marc:subfield[@code='0']"/></xsl:attribute>
 238                         <xsl:value-of select="$f773"/>
 239                     </a>
 240                 </xsl:when>
 241                 <xsl:otherwise>
 242                     <a><xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=ti,phr:<xsl:value-of select="translate($f773, '()', '')"/></xsl:attribute>
 243                         <xsl:value-of select="$f773"/>
 244                     </a>
 245                     <xsl:if test="marc:subfield[@code='g']"><xsl:text> </xsl:text><xsl:value-of select="marc:subfield[@code='g']"/></xsl:if>
 246                 </xsl:otherwise>
 247             </xsl:choose>
 248         </span>
 249         <xsl:if test="marc:subfield[@code='n']">
 250             <span class="results_summary"><xsl:value-of select="marc:subfield[@code='n']"/></span>
 251         </xsl:if>
 252         </xsl:if>
 253         </xsl:for-each>
 254         </xsl:if>
 255
 256         <!-- Publisher Statement -->
 257
 258         <xsl:if test="marc:datafield[@tag=260]">
 259         <span class="results_summary"><span class="label">Utgiver: </span>
 260             <xsl:for-each select="marc:datafield[@tag=260]">
 261                 <xsl:call-template name="chopPunctuation">
 262                   <xsl:with-param name="chopString">
 263                     <xsl:call-template name="subfieldSelect">
 264                         <xsl:with-param name="codes">bcg</xsl:with-param>
 265                     </xsl:call-template>
 266                    </xsl:with-param>
 267                </xsl:call-template>
 268                     <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 269             </xsl:for-each>
 270         </span>
 271         </xsl:if>
 272
 273         <!-- Edition Statement -->
 274
 275         <xsl:if test="marc:datafield[@tag=250]">
 276         <span class="results_summary"><span class="label">Utgave: </span>
 277             <xsl:for-each select="marc:datafield[@tag=250]">
 278                 <xsl:call-template name="chopPunctuation">
 279                   <xsl:with-param name="chopString">
 280                     <xsl:call-template name="subfieldSelect">
 281                         <xsl:with-param name="codes">ab</xsl:with-param>
 282                     </xsl:call-template>
 283                    </xsl:with-param>
 284                </xsl:call-template>
 285                     <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 286             </xsl:for-each>
 287         </span>
 288         </xsl:if>
 289
 290         <!-- Description -->
 291
 292         <xsl:if test="marc:datafield[@tag=300]">
 293         <span class="results_summary"><span class="label">Beskrivelse: </span>
 294             <xsl:for-each select="marc:datafield[@tag=300]">
 295                 <xsl:call-template name="chopPunctuation">
 296                   <xsl:with-param name="chopString">
 297                     <xsl:call-template name="subfieldSelect">
 298                         <xsl:with-param name="codes">abceg</xsl:with-param>
 299                     </xsl:call-template>
 300                    </xsl:with-param>
 301                </xsl:call-template>
 302                     <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 303             </xsl:for-each>
 304         </span>
 305        </xsl:if>
 306
 307        <abbr class="unapi-id" title="koha:biblionumber:{marc:datafield[@tag=999]/marc:subfield[@code='c']}" ><!-- unAPI --></abbr>
 308
 309        <xsl:if test="marc:datafield[@tag=020]">
 310         <span class="results_summary"><span class="label">ISBN: </span>
 311         <xsl:for-each select="marc:datafield[@tag=020]">
 312         <xsl:variable name="isbn" select="marc:subfield[@code='a']"/>
 313                 <xsl:value-of select="marc:subfield[@code='a']"/>
 314                 <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 315         </xsl:for-each>
 316         </span>
 317         </xsl:if>
 318
 319         <xsl:if test="marc:datafield[@tag=022]">
 320         <span class="results_summary"><span class="label">ISSN: </span>
 321         <xsl:for-each select="marc:datafield[@tag=022]">
 322                 <xsl:value-of select="marc:subfield[@code='a']"/>
 323                 <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 324         </xsl:for-each>
 325         </span>
 326         </xsl:if>
 327
 328         <!-- Other Title  Statement -->
 329
 330         <xsl:if test="marc:datafield[@tag=246]">
 331         <span class="results_summary"><span class="label">Parallelltittel: </span>
 332             <xsl:for-each select="marc:datafield[@tag=246]">
 333                 <xsl:call-template name="chopPunctuation">
 334                   <xsl:with-param name="chopString">
 335                     <xsl:call-template name="subfieldSelect">
 336                         <xsl:with-param name="codes">abhfgnp</xsl:with-param>
 337                     </xsl:call-template>
 338                    </xsl:with-param>
 339                </xsl:call-template>
 340                     <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 341             </xsl:for-each>
 342         </span>
 343        </xsl:if>
 344
 345         <!-- Uniform Title  Statement -->
 346
 347         <xsl:if test="marc:datafield[@tag=130]|marc:datafield[@tag=240]|marc:datafield[@tag=730][@ind2!=2]">
 348         <span class="results_summary"><span class="label">Standardtittel: </span>
 349         <xsl:for-each select="marc:datafield[@tag=130]|marc:datafield[@tag=240]|marc:datafield[@tag=730][@ind2!=2]">
 350             <xsl:variable name="str">
 351                 <xsl:for-each select="marc:subfield">
 352                     <xsl:if test="(contains('adfklmor',@code) and (not(../marc:subfield[@code='n' or @code='p']) or (following-sibling::marc:subfield[@code='n' or @code='p'])))">
 353                         <xsl:value-of select="text()"/>
 354                         <xsl:text> </xsl:text>
 355                      </xsl:if>
 356                 </xsl:for-each>
 357             </xsl:variable>
 358             <xsl:call-template name="chopPunctuation">
 359                 <xsl:with-param name="chopString">
 360                     <xsl:value-of select="substring($str,1,string-length($str)-1)"/>
 361
 362                 </xsl:with-param>
 363             </xsl:call-template>
 364             <xsl:choose><xsl:when test="position()=last()"><xsl:text>.</xsl:text></xsl:when><xsl:otherwise><xsl:text>; </xsl:text></xsl:otherwise></xsl:choose>
 365         </xsl:for-each>
 366         </span>
 367         </xsl:if>
 368
 369         <!-- Subjects -->
 370
 371         <xsl:if test="marc:datafield[substring(@tag, 1, 1) = '6']">
 372             <span class="results_summary subjects"><span class="label">Emne(r): </span>
 373             <xsl:for-each select="marc:datafield[substring(@tag, 1, 1) = '6']">
 374             <a>
 375             <xsl:choose>
 376             <!-- Will implement this later
 377                 <xsl:when test="marc:subfield[@code=9] and $UseAuthoritiesForTracings='1'">
 378                     <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=an:<xsl:value-of select="marc:subfield[@code=9]"/></xsl:attribute>
 379                 </xsl:when>
 380             -->
 381             <xsl:when test="$TraceSubjectSubdivisions='1'">
 382                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=<xsl:call-template name="subfieldSelect">
 383                         <xsl:with-param name="codes">abcdvxyz</xsl:with-param>
 384                         <xsl:with-param name="delimeter"> AND </xsl:with-param>
 385                         <xsl:with-param name="prefix">(su<xsl:value-of select="$SubjectModifier"/>:<xsl:value-of select="$TracingQuotesLeft"/></xsl:with-param>
 386                         <xsl:with-param name="suffix"><xsl:value-of select="$TracingQuotesRight"/>)</xsl:with-param>
 387                     </xsl:call-template>
 388                 </xsl:attribute>
 389             </xsl:when>
 390             <xsl:otherwise>
 391                 <xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=su<xsl:value-of select="$SubjectModifier"/>:<xsl:value-of select="$TracingQuotesLeft"/><xsl:value-of select="marc:subfield[@code='a']"/><xsl:value-of select="$TracingQuotesRight"/></xsl:attribute>
 392             </xsl:otherwise>
 393             </xsl:choose>
 394             <xsl:call-template name="chopPunctuation">
 395                 <xsl:with-param name="chopString">
 396                     <xsl:call-template name="subfieldSelect">
 397                         <xsl:with-param name="codes">abcdvxyz</xsl:with-param>
 398                         <xsl:with-param name="subdivCodes">vxyz</xsl:with-param>
 399                         <xsl:with-param name="subdivDelimiter">-- </xsl:with-param>
 400                     </xsl:call-template>
 401                 </xsl:with-param>
 402             </xsl:call-template>
 403             </a>
 404             <xsl:choose>
 405             <xsl:when test="position()=last()"></xsl:when>
 406             <xsl:otherwise> | </xsl:otherwise>
 407             </xsl:choose>
 408
 409             </xsl:for-each>
 410             </span>
 411         </xsl:if>
 412
 413         <xsl:if test="marc:datafield[@tag=856]">
 414         <span class="results_summary"><span class="label">Nettbasert ressurs: </span>
 415         <xsl:for-each select="marc:datafield[@tag=856]">
 416             <a><xsl:attribute name="href"><xsl:value-of select="marc:subfield[@code='u']"/></xsl:attribute>
 417         <xsl:choose>
 418             <xsl:when test="marc:subfield[@code='y' or @code='3' or @code='z']">
 419                     <xsl:call-template name="subfieldSelect">
 420                         <xsl:with-param name="codes">y3z</xsl:with-param>
 421                     </xsl:call-template>
 422             </xsl:when>
 423         <xsl:when test="not(marc:subfield[@code='y']) and not(marc:subfield[@code='3']) and not(marc:subfield[@code='z'])">
 424         Klikk her for tilgang
 425         </xsl:when>
 426         </xsl:choose>
 427         </a>
 428             <xsl:choose>
 429             <xsl:when test="position()=last()"></xsl:when>
 430             <xsl:otherwise> | </xsl:otherwise>
 431             </xsl:choose>
 432         </xsl:for-each>
 433         </span>
 434         </xsl:if>
 435
 436         <!-- NORMARC does not define indicators for 505
 437         <xsl:if test="marc:datafield[@tag=505]">
 438         <xsl:for-each select="marc:datafield[@tag=505]">
 439         <span class="results_summary"><span class="label">
 440         <xsl:choose>
 441         <xsl:when test="@ind1=0">
 442             Contents:
 443         </xsl:when>
 444         <xsl:when test="@ind1=1">
 445             Incomplete contents:
 446         </xsl:when>
 447         <xsl:when test="@ind1=1">
 448             Partial contents:
 449         </xsl:when>
 450         </xsl:choose>
 451         </span>
 452         <xsl:choose>
 453         <xsl:when test="@ind2=0">
 454             <xsl:for-each select="marc:subfield[@code='t']">
 455                 <xsl:value-of select="marc:subfield[@code=t]"/> <xsl:value-of select="marc:subfield[@code=r]"/>
 456             </xsl:for-each>
 457         </xsl:when>
 458         <xsl:otherwise>
 459             <xsl:call-template name="subfieldSelect">
 460                 <xsl:with-param name="codes">au</xsl:with-param>
 461             </xsl:call-template>
 462         </xsl:otherwise>
 463         </xsl:choose>
 464         </span>
 465         </xsl:for-each>
 466         </xsl:if>
 467         -->
 468         <xsl:if test="marc:datafield[@tag=505]">
 469                 <xsl:call-template name="subfieldSelect">
 470                 <xsl:with-param name="codes">a</xsl:with-param>
 471             </xsl:call-template>
 472                 </xsl:if>
 473
 474         <!-- 780 -->
 475         <xsl:if test="marc:datafield[@tag=780]">
 476         <xsl:for-each select="marc:datafield[@tag=780]">
 477         <span class="results_summary"><span class="label">
 478         <xsl:choose>
 479                 <xsl:when test="@ind2=0">
 480                     Fortsettelse av:
 481                 </xsl:when>
 482                 <xsl:when test="@ind2=1">
 483                     Delvis fortsettelse av:
 484                 </xsl:when>
 485                 <xsl:when test="@ind2=2">
 486                     Avløser:
 487                 </xsl:when>
 488                 <xsl:when test="@ind2=3">
 489                     Avløser delvis:
 490                 </xsl:when>
 491                 <xsl:when test="@ind2=4">
 492                     Sammenslåing av: ... ; og ...
 493                 </xsl:when>
 494                 <xsl:when test="@ind2=5">
 495                     Har tatt opp:
 496                 </xsl:when>
 497                 <xsl:when test="@ind2=6">
 498                     Har delvis tatt opp:
 499                 </xsl:when>
 500                 <xsl:when test="@ind2=7">
 501                     Utskilt fra:
 502                 </xsl:when>
 503         </xsl:choose>
 504         </span>
 505                 <xsl:variable name="f780">
 506                     <xsl:call-template name="subfieldSelect">
 507                         <xsl:with-param name="codes">a_t</xsl:with-param>
 508                     </xsl:call-template>
 509                 </xsl:variable>
 510              <a><xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=<xsl:value-of select="translate($f780, '()', '')"/></xsl:attribute>
 511                 <xsl:value-of select="translate($f780, '()', '')"/>
 512             </a>
 513         </span>
 514
 515         <xsl:choose>
 516         <xsl:when test="@ind1=0">
 517             <span class="results_summary"><xsl:value-of select="marc:subfield[@code='n']"/></span>
 518         </xsl:when>
 519         </xsl:choose>
 520
 521         </xsl:for-each>
 522         </xsl:if>
 523
 524         <!-- 785 -->
 525         <xsl:if test="marc:datafield[@tag=785]">
 526         <xsl:for-each select="marc:datafield[@tag=785]">
 527         <span class="results_summary"><span class="label">
 528         <xsl:choose>
 529                 <xsl:when test="@ind2=0">
 530                     Fortsettelse i:
 531                 </xsl:when>
 532                 <xsl:when test="@ind2=1">
 533                     Fortsettes delvis i:
 534                 </xsl:when>
 535                 <xsl:when test="@ind2=2">
 536                     Avløst av:
 537                 </xsl:when>
 538                 <xsl:when test="@ind2=3">
 539                     Delvis avløst av:
 540                 </xsl:when>
 541                 <xsl:when test="@ind2=4">
 542                     Gått inn i:
 543                 </xsl:when>
 544                 <xsl:when test="@ind2=5">
 545                     Delvis gått inn i:
 546                 </xsl:when>
 547                 <xsl:when test="@ind2=6">
 548                     Fortsettes av: ...; og ...
 549                 </xsl:when>
 550                 <xsl:when test="@ind2=7">
 551                         Slått sammen med: .., til: ...
 552                 </xsl:when>
 553         </xsl:choose>
 554         </span>
 555                    <xsl:variable name="f785">
 556                     <xsl:call-template name="subfieldSelect">
 557                         <xsl:with-param name="codes">a_t</xsl:with-param>
 558                     </xsl:call-template>
 559                 </xsl:variable>
 560
 561                 <a><xsl:attribute name="href">/cgi-bin/koha/catalogue/search.pl?q=<xsl:value-of select="translate($f785, '()', '')"/></xsl:attribute>
 562                 <xsl:value-of select="translate($f785, '()', '')"/>
 563             </a>
 564
 565         </span>
 566         </xsl:for-each>
 567         </xsl:if>
 568
 569         <!-- This will only work if the OPACBaseURL syspref is set. -->
 570         <xsl:if test="string-length($OPACBaseURL) > 0">
 571         <p>OPAC View: <a>
 572                       <xsl:attribute name="href">http://<xsl:value-of select="$OPACBaseURL"/>/cgi-bin/koha/opac-detail.pl?biblionumber=<xsl:value-of select="$biblionumber"/></xsl:attribute>
 573                       <xsl:attribute name="target">_blank</xsl:attribute>
 574                       Open in new window
 575                       </a></p>
 576          </xsl:if>
 577
 578     </xsl:template>
 579
 580     <xsl:template name="part">
 581         <xsl:variable name="partNumber">
 582             <xsl:call-template name="specialSubfieldSelect">
 583                 <xsl:with-param name="axis">n</xsl:with-param>
 584                 <xsl:with-param name="anyCodes">n</xsl:with-param>
 585                 <xsl:with-param name="afterCodes">fghkdlmor</xsl:with-param>
 586             </xsl:call-template>
 587         </xsl:variable>
 588         <xsl:variable name="partName">
 589             <xsl:call-template name="specialSubfieldSelect">
 590                 <xsl:with-param name="axis">p</xsl:with-param>
 591                 <xsl:with-param name="anyCodes">p</xsl:with-param>
 592                 <xsl:with-param name="afterCodes">fghkdlmor</xsl:with-param>
 593             </xsl:call-template>
 594         </xsl:variable>
 595         <xsl:if test="string-length(normalize-space($partNumber))">
 596                 <xsl:call-template name="chopPunctuation">
 597                     <xsl:with-param name="chopString" select="$partNumber"/>
 598                 </xsl:call-template>
 599         </xsl:if>
 600         <xsl:if test="string-length(normalize-space($partName))">
 601                 <xsl:call-template name="chopPunctuation">
 602                     <xsl:with-param name="chopString" select="$partName"/>
 603                 </xsl:call-template>
 604         </xsl:if>
 605     </xsl:template>
 606
 607     <xsl:template name="specialSubfieldSelect">
 608         <xsl:param name="anyCodes"/>
 609         <xsl:param name="axis"/>
 610         <xsl:param name="beforeCodes"/>
 611         <xsl:param name="afterCodes"/>
 612         <xsl:variable name="str">
 613             <xsl:for-each select="marc:subfield">
 614                 <xsl:if test="contains($anyCodes, @code)      or (contains($beforeCodes,@code) and following-sibling::marc:subfield[@code=$axis])      or (contains($afterCodes,@code) and preceding-sibling::marc:subfield[@code=$axis])">
 615                     <xsl:value-of select="text()"/>
 616                     <xsl:text> </xsl:text>
 617                 </xsl:if>
 618             </xsl:for-each>
 619         </xsl:variable>
 620         <xsl:value-of select="substring($str,1,string-length($str)-1)"/>
 621     </xsl:template>
 622 </xsl:stylesheet>