C4/Auth_with_shibboleth.pm

   1 package C4::Auth_with_shibboleth;
   2
   3 # Copyright 2014 PTFS Europe
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use C4::Debug;
  23 use C4::Context;
  24 use Koha::AuthUtils qw(get_script_name);
  25 use Koha::Database;
  26 use Koha::Patrons;
  27 use C4::Members::Messaging;
  28 use Carp;
  29 use CGI;
  30
  31 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  32
  33 BEGIN {
  34     require Exporter;
  35     $debug   = $ENV{DEBUG};
  36     @ISA     = qw(Exporter);
  37     @EXPORT =
  38       qw(shib_ok logout_shib login_shib_url checkpw_shib get_login_shib);
  39 }
  40
  41 # Check that shib config is not malformed
  42 sub shib_ok {
  43     my $config = _get_shib_config();
  44
  45     if ($config) {
  46         return 1;
  47     }
  48
  49     return 0;
  50 }
  51
  52 # Logout from Shibboleth
  53 sub logout_shib {
  54     my ($query) = @_;
  55     my $uri = _get_uri();
  56     print $query->redirect( $uri . "/Shibboleth.sso/Logout?return=$uri" );
  57 }
  58
  59 # Returns Shibboleth login URL with callback to the requesting URL
  60 sub login_shib_url {
  61     my ($query) = @_;
  62
  63     my $param = _get_uri() . get_script_name();
  64     if ( $query->query_string() ) {
  65         $param = $param . '%3F' . $query->query_string();
  66     }
  67     my $uri = _get_uri() . "/Shibboleth.sso/Login?target=$param";
  68     return $uri;
  69 }
  70
  71 # Returns shibboleth user login
  72 sub get_login_shib {
  73
  74 # In case of a Shibboleth authentication, we expect a shibboleth user attribute
  75 # to contain the login match point of the shibboleth-authenticated user. This match
  76 # point is configured in koha-conf.xml
  77
  78 # Shibboleth attributes are mapped into http environmement variables, so we're getting
  79 # the match point of the user this way
  80
  81     # Get shibboleth config
  82     my $config = _get_shib_config();
  83
  84     my $matchAttribute = $config->{mapping}->{ $config->{matchpoint} }->{is};
  85     $debug and warn $matchAttribute . " value: " . $ENV{$matchAttribute};
  86
  87     return $ENV{$matchAttribute} || '';
  88 }
  89
  90 # Checks for password correctness
  91 # In our case : does the given attribute match one of our users ?
  92 sub checkpw_shib {
  93     $debug and warn "checkpw_shib";
  94
  95     my ( $match ) = @_;
  96     my $config = _get_shib_config();
  97     $debug and warn "User Shibboleth-authenticated as: $match";
  98
  99     # Does the given shibboleth attribute value ($match) match a valid koha user ?
 100     my $borrower =
 101       Koha::Database->new()->schema()->resultset('Borrower')
 102       ->find( { $config->{matchpoint} => $match } );
 103     if ( defined($borrower) ) {
 104         return ( 1, $borrower->get_column('cardnumber'), $borrower->get_column('userid') );
 105     }
 106
 107     if ( $config->{'autocreate'} ) {
 108         return _autocreate( $config, $match );
 109     } else {
 110         # If we reach this point, the user is not a valid koha user
 111          $debug and warn "User with $config->{matchpoint} of $match is not a valid Koha user";
 112         return 0;
 113     }
 114 }
 115
 116 sub _autocreate {
 117     my ( $config, $match ) = @_;
 118
 119     my %borrower = ( $config->{matchpoint} => $match );
 120
 121     while ( my ( $key, $entry ) = each %{$config->{'mapping'}} ) {
 122         $borrower{$key} = ( $entry->{'is'} && $ENV{ $entry->{'is'} } ) || $entry->{'content'} || '';
 123     }
 124
 125     my $patron = Koha::Patron->new( \%borrower )->store;
 126     C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $patron->borrowernumber, categorycode => $patron->categorycode } );
 127
 128     return ( 1, $patron->cardnumber, $patron->userid );
 129 }
 130
 131 sub _get_uri {
 132
 133     my $protocol = "https://";
 134     my $interface = C4::Context->interface;
 135     $debug and warn "shibboleth interface: " . $interface;
 136
 137     my $uri;
 138     if ( $interface eq 'intranet' ) {
 139
 140         $uri = C4::Context->preference('staffClientBaseURL') // '';
 141         if ($uri eq '') {
 142             $debug and warn 'staffClientBaseURL not set!';
 143         }
 144     } else {
 145         $uri = C4::Context->preference('OPACBaseURL') // '';
 146         if ($uri eq '') {
 147             $debug and warn 'OPACBaseURL not set!';
 148         }
 149     }
 150
 151     if ($uri =~ /(.*):\/\/(.*)/) {
 152         my $oldprotocol = $1;
 153         if ($oldprotocol ne 'https') {
 154             $debug
 155                 and warn
 156                   'Shibboleth requires OPACBaseURL/staffClientBaseURL to use the https protocol!';
 157         }
 158         $uri = $2;
 159     }
 160     my $return = $protocol . $uri;
 161     return $return;
 162 }
 163
 164 sub _get_shib_config {
 165     my $config = C4::Context->config('shibboleth');
 166
 167     if ( !$config ) {
 168         carp 'shibboleth config not defined';
 169         return 0;
 170     }
 171
 172     if ( $config->{matchpoint}
 173         && defined( $config->{mapping}->{ $config->{matchpoint} }->{is} ) )
 174     {
 175         if ($debug) {
 176             warn "koha borrower field to match: " . $config->{matchpoint};
 177             warn "shibboleth attribute to match: "
 178               . $config->{mapping}->{ $config->{matchpoint} }->{is};
 179         }
 180         return $config;
 181     }
 182     else {
 183         if ( !$config->{matchpoint} ) {
 184             carp 'shibboleth matchpoint not defined';
 185         }
 186         else {
 187             carp 'shibboleth matchpoint not mapped';
 188         }
 189         return 0;
 190     }
 191 }
 192
 193 1;
 194 __END__
 195
 196 =head1 NAME
 197
 198 C4::Auth_with_shibboleth
 199
 200 =head1 SYNOPSIS
 201
 202 use C4::Auth_with_shibboleth;
 203
 204 =head1 DESCRIPTION
 205
 206 This module is specific to Shibboleth authentication in koha and relies heavily upon the native shibboleth service provider package in your operating system.
 207
 208 =head1 CONFIGURATION
 209
 210 To use this type of authentication these additional packages are required:
 211
 212 =over
 213
 214 =item *
 215
 216 libapache2-mod-shib2
 217
 218 =item *
 219
 220 libshibsp5:amd64
 221
 222 =item *
 223
 224 shibboleth-sp2-schemas
 225
 226 =back
 227
 228 We let the native shibboleth service provider packages handle all the complexities of shibboleth negotiation for us, and configuring this is beyond the scope of this documentation.
 229
 230 But to sum up, to get shibboleth working in koha, as a minimum you will need to:
 231
 232 =over
 233
 234 =item 1.
 235
 236 Create some metadata for your koha instance (if you're in a single instance setup then the default metadata available at https://youraddress.com/Shibboleth.sso/Metadata should be adequate)
 237
 238 =item 2.
 239
 240 Swap metadata with your Identidy Provider (IdP)
 241
 242 =item 3.
 243
 244 Map their attributes to what you want to see in koha
 245
 246 =item 4.
 247
 248 Tell apache that we wish to allow koha to authenticate via shibboleth.
 249
 250 This is as simple as adding the below to your virtualhost config:
 251
 252  <Location />
 253    AuthType shibboleth
 254    Require shibboleth
 255  </Location>
 256
 257 =item 5.
 258
 259 Configure koha to listen for shibboleth environment variables.
 260
 261 This is as simple as enabling B<useshibboleth> in koha-conf.xml:
 262
 263  <useshibboleth>1</useshibboleth>
 264
 265 =item 6.
 266
 267 Map shibboleth attributes to koha fields, and configure authentication match point in koha-conf.xml.
 268
 269  <shibboleth>
 270    <matchpoint>userid</matchpoint> <!-- koha borrower field to match upon -->
 271    <mapping>
 272      <userid is="eduPersonID"></userid> <!-- koha borrower field to shibboleth attribute mapping -->
 273    </mapping>
 274  </shibboleth>
 275
 276 Note: The minimum you need here is a <matchpoint> block, containing a valid column name from the koha borrowers table, and a <mapping> block containing a relation between the chosen matchpoint and the shibboleth attribute name.
 277
 278 =back
 279
 280 It should be as simple as that; you should now be able to login via shibboleth in the opac.
 281
 282 If you need more help configuring your B<S>ervice B<P>rovider to authenticate against a chosen B<Id>entity B<P>rovider then it might be worth taking a look at the community wiki L<page|http://wiki.koha-community.org/wiki/Shibboleth_Configuration>
 283
 284 =head1 FUNCTIONS
 285
 286 =head2 logout_shib
 287
 288 Sends a logout signal to the native shibboleth service provider and then logs out of koha.  Depending upon the native service provider configuration and identity provider capabilities this may or may not perform a single sign out action.
 289
 290   logout_shib($query);
 291
 292 =head2 login_shib_url
 293
 294 Given a query, this will return a shibboleth login url with return code to page with given given query.
 295
 296   my $shibLoginURL = login_shib_url($query);
 297
 298 =head2 get_login_shib
 299
 300 Returns the shibboleth login attribute should it be found present in the http session
 301
 302   my $shib_login = get_login_shib();
 303
 304 =head2 checkpw_shib
 305
 306 Given a shib_login attribute, this routine checks for a matching local user and if found returns true, their cardnumber and their userid.  If a match is not found, then this returns false.
 307
 308   my ( $retval, $retcard, $retuserid ) = C4::Auth_with_shibboleth::checkpw_shib( $shib_login );
 309
 310 =head2 _get_uri
 311
 312   _get_uri();
 313
 314 A sugar function to that simply returns the current page URI with appropriate protocol attached
 315
 316 This routine is NOT exported
 317
 318 =head2 _get_shib_config
 319
 320   my $config = _get_shib_config();
 321
 322 A sugar function that checks for a valid shibboleth configuration, and if found returns a hashref of it's contents
 323
 324 This routine is NOT exported
 325
 326 =head2 _autocreate
 327
 328   my ( $retval, $retcard, $retuserid ) = _autocreate( $config, $match );
 329
 330 Given a shibboleth attribute reference and a userid this internal routine will add the given user to Koha and return their user credentials.
 331
 332 This routine is NOT exported
 333
 334 =head1 SEE ALSO
 335
 336 =cut