catalogue/search.pl

   1 #!/usr/bin/perl
   2 # Script to perform searching
   3 # For documentation try 'perldoc /path/to/search'
   4 #
   5 # Copyright 2006 LibLime
   6 # Copyright 2010 BibLibre
   7 #
   8 # This file is part of Koha
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 NAME
  24
  25 search - a search script for finding records in a Koha system (Version 3)
  26
  27 =head1 OVERVIEW
  28
  29 This script utilizes a new search API for Koha 3. It is designed to be
  30 simple to use and configure, yet capable of performing feats like stemming,
  31 field weighting, relevance ranking, support for multiple  query language
  32 formats (CCL, CQL, PQF), full support for the bib1 attribute set, extended
  33 attribute sets defined in Zebra profiles, access to the full range of Z39.50
  34 and SRU query options, federated searches on Z39.50/SRU targets, etc.
  35
  36 The API as represented in this script is mostly sound, even if the individual
  37 functions in Search.pm and Koha.pm need to be cleaned up. Of course, you are
  38 free to disagree :-)
  39
  40 I will attempt to describe what is happening at each part of this script.
  41 -- Joshua Ferraro <jmf AT liblime DOT com>
  42
  43 =head2 INTRO
  44
  45 This script performs two functions:
  46
  47 =over
  48
  49 =item 1. interacts with Koha to retrieve and display the results of a search
  50
  51 =item 2. loads the advanced search page
  52
  53 =back
  54
  55 These two functions share many of the same variables and modules, so the first
  56 task is to load what they have in common and determine which template to use.
  57 Once determined, proceed to only load the variables and procedures necessary
  58 for that function.
  59
  60 =head2 LOADING ADVANCED SEARCH PAGE
  61
  62 This is fairly straightforward, and I won't go into detail ;-)
  63
  64 =head2 PERFORMING A SEARCH
  65
  66 If we're performing a search, this script  performs three primary
  67 operations:
  68
  69 =over
  70
  71 =item 1. builds query strings (yes, plural)
  72
  73 =item 2. perform the search and return the results array
  74
  75 =item 3. build the HTML for output to the template
  76
  77 =back
  78
  79 There are several additional secondary functions performed that I will
  80 not cover in detail.
  81
  82 =head3 1. Building Query Strings
  83
  84 There are several types of queries needed in the process of search and retrieve:
  85
  86 =over
  87
  88 =item 1 $query - the fully-built query passed to zebra
  89
  90 This is the most complex query that needs to be built. The original design goal
  91 was to use a custom CCL2PQF query parser to translate an incoming CCL query into
  92 a multi-leaf query to pass to Zebra. It needs to be multi-leaf to allow field
  93 weighting, koha-specific relevance ranking, and stemming. When I have a chance
  94 I'll try to flesh out this section to better explain.
  95
  96 This query incorporates query profiles that aren't compatible with most non-Zebra
  97 Z39.50 targets to accomplish the field weighting and relevance ranking.
  98
  99 =item 2 $simple_query - a simple query that doesn't contain the field weighting,
 100 stemming, etc., suitable to pass off to other search targets
 101
 102 This query is just the user's query expressed in CCL CQL, or PQF for passing to a
 103 non-zebra Z39.50 target (one that doesn't support the extended profile that Zebra does).
 104
 105 =item 3 $query_cgi - passed to the template / saved for future refinements of
 106 the query (by user)
 107
 108 This is a simple string that completely expresses the query as a CGI string that
 109 can be used for future refinements of the query or as a part of a history feature.
 110
 111 =item 4 $query_desc - Human search description - what the user sees in search
 112 feedback area
 113
 114 This is a simple string that is human readable. It will contain '=', ',', etc.
 115
 116 =back
 117
 118 =head3 2. Perform the Search
 119
 120 This section takes the query strings and performs searches on the named servers,
 121 including the Koha Zebra server, stores the results in a deeply nested object,
 122 builds 'faceted results', and returns these objects.
 123
 124 =head3 3. Build HTML
 125
 126 The final major section of this script takes the objects collected thusfar and
 127 builds the HTML for output to the template and user.
 128
 129 =head3 Additional Notes
 130
 131 Not yet completed...
 132
 133 =cut
 134
 135 use Modern::Perl;
 136
 137 ## STEP 1. Load things that are used in both search page and
 138 # results page and decide which template to load, operations
 139 # to perform, etc.
 140
 141 ## load Koha modules
 142 use C4::Context;
 143 use C4::Output;
 144 use C4::Auth qw(:DEFAULT get_session);
 145 use C4::Search;
 146 use C4::Languages qw(getLanguages);
 147 use C4::Koha;
 148 use URI::Escape;
 149 use POSIX qw(ceil floor);
 150 use C4::Search::History;
 151
 152 use Koha::ItemTypes;
 153 use Koha::Library::Groups;
 154 use Koha::Patrons;
 155 use Koha::SearchEngine::Search;
 156 use Koha::SearchEngine::QueryBuilder;
 157 use Koha::Virtualshelves;
 158 use Koha::SearchFields;
 159
 160 use URI::Escape;
 161
 162 my $DisplayMultiPlaceHold = C4::Context->preference("DisplayMultiPlaceHold");
 163 # create a new CGI object
 164 # FIXME: no_undef_params needs to be tested
 165 use CGI qw('-no_undef_params' -utf8 );
 166 my $cgi = new CGI;
 167
 168 # decide which template to use
 169 my $template_name;
 170 my $template_type;
 171 my @params = $cgi->multi_param("limit");
 172 if ((@params>=1) || ($cgi->param("q")) || ($cgi->param('multibranchlimit')) || ($cgi->param('limit-yr')) ) {
 173     $template_name = 'catalogue/results.tt';
 174     $template_type = 'results';
 175 }
 176 else {
 177     $template_name = 'catalogue/advsearch.tt';
 178     $template_type = 'advsearch';
 179 }
 180 # load the template
 181 my ($template, $borrowernumber, $cookie) = get_template_and_user({
 182     template_name => $template_name,
 183     query => $cgi,
 184     type => "intranet",
 185     authnotrequired => 0,
 186     flagsrequired   => { catalogue => 1 },
 187     }
 188 );
 189
 190 my $lang = C4::Languages::getlanguage($cgi);
 191
 192 if (C4::Context->preference("marcflavour") eq "UNIMARC" ) {
 193     $template->param('UNIMARC' => 1);
 194 }
 195
 196 if($cgi->cookie("holdfor")){
 197     my $holdfor_patron = Koha::Patrons->find( $cgi->cookie("holdfor") );
 198     $template->param(
 199         holdfor => $cgi->cookie("holdfor"),
 200         holdfor_surname => $holdfor_patron->surname,
 201         holdfor_firstname => $holdfor_patron->firstname,
 202         holdfor_cardnumber => $holdfor_patron->cardnumber,
 203     );
 204 }
 205
 206 if($cgi->cookie("holdforclub")){
 207     my $holdfor_club = Koha::Clubs->find( $cgi->cookie("holdforclub") );
 208     $template->param(
 209         holdforclub => $cgi->cookie("holdforclub"),
 210         holdforclub_name => $holdfor_club->name,
 211     );
 212 }
 213
 214 if($cgi->cookie("searchToOrder")){
 215     my ( $basketno, $vendorid ) = split( /\//, $cgi->cookie("searchToOrder") );
 216     $template->param(
 217         searchtoorder_basketno => $basketno,
 218         searchtoorder_vendorid => $vendorid
 219     );
 220 }
 221
 222 # get biblionumbers stored in the cart
 223 my @cart_list;
 224
 225 if($cgi->cookie("intranet_bib_list")){
 226     my $cart_list = $cgi->cookie("intranet_bib_list");
 227     @cart_list = split(/\//, $cart_list);
 228 }
 229
 230 my @search_groups =
 231   Koha::Library::Groups->get_search_groups( { interface => 'staff' } );
 232 @search_groups = sort { $a->title cmp $b->title } @search_groups;
 233
 234 $template->param(
 235     selected_branchcode => ( C4::Context->IsSuperLibrarian ? C4::Context->userenv : '' ),
 236     search_groups    => \@search_groups,
 237 );
 238
 239 # load the Type stuff
 240 my $types = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 241 my $advancedsearchesloop = prepare_adv_search_types($types);
 242 $template->param(advancedsearchesloop => $advancedsearchesloop);
 243
 244 $template->param( searchid => scalar $cgi->param('searchid'), );
 245
 246 # The following should only be loaded if we're bringing up the advanced search template
 247 if ( $template_type eq 'advsearch' ) {
 248
 249     # load the servers (used for searching -- to do federated searching, etc.)
 250     my $primary_servers_loop;# = displayPrimaryServers();
 251     $template->param(outer_servers_loop =>  $primary_servers_loop,);
 252
 253     my $secondary_servers_loop;
 254     $template->param(outer_sup_servers_loop => $secondary_servers_loop,);
 255
 256     # set the default sorting
 257     if (   C4::Context->preference('defaultSortField')
 258         && C4::Context->preference('defaultSortOrder') ) {
 259         my $default_sort_by =
 260             C4::Context->preference('defaultSortField') . '_'
 261           . C4::Context->preference('defaultSortOrder');
 262         $template->param( sort_by => $default_sort_by  );
 263     }
 264
 265     # determine what to display next to the search boxes (ie, boolean option
 266     # shouldn't appear on the first one, scan indexes should, adding a new
 267     # box should only appear on the last, etc.
 268     my @search_boxes_array;
 269     my $search_boxes_count = 3; # begin with 3 boxes
 270     # FIXME: all this junk can be done in TMPL using __first__ and __last__
 271     for (my $i=1;$i<=$search_boxes_count;$i++) {
 272         # if it's the first one, don't display boolean option, but show scan indexes
 273         if ($i==1) {
 274             push @search_boxes_array, {scan_index => 1};
 275         }
 276         # if it's the last one, show the 'add field' box
 277         elsif ($i==$search_boxes_count) {
 278             push @search_boxes_array,
 279                 {
 280                 boolean => 1,
 281                 add_field => 1,
 282                 };
 283         }
 284         else {
 285             push @search_boxes_array,
 286                 {
 287                 boolean => 1,
 288                 };
 289         }
 290
 291     }
 292     $template->param(uc(C4::Context->preference("marcflavour")) => 1,
 293                       search_boxes_loop => \@search_boxes_array);
 294
 295     # load the language limits (for search)
 296     my $languages_limit_loop = getLanguages($lang, 1);
 297     $template->param(search_languages_loop => $languages_limit_loop,);
 298
 299     # Expanded search options in advanced search:
 300     # use the global setting by default, but let the user override it
 301     {
 302         my $expanded = $cgi->param('expanded_options');
 303         $expanded = C4::Context->preference("expandedSearchOption") || 0
 304             if !defined($expanded) || $expanded !~ /^0|1$/;
 305         $template->param( expanded_options => $expanded );
 306     }
 307
 308     $template->param(virtualshelves => C4::Context->preference("virtualshelves"));
 309
 310     output_html_with_http_headers $cgi, $cookie, $template->output;
 311     exit;
 312 }
 313
 314 ### OK, if we're this far, we're performing a search, not just loading the advanced search page
 315
 316 # Fetch the paramater list as a hash in scalar context:
 317 #  * returns paramater list as tied hash ref
 318 #  * we can edit the values by changing the key
 319 #  * multivalued CGI paramaters are returned as a packaged string separated by "\0" (null)
 320 my $params = $cgi->Vars;
 321 # Params that can have more than one value
 322 # sort by is used to sort the query
 323 # in theory can have more than one but generally there's just one
 324 my @sort_by;
 325 my $default_sort_by;
 326 if (   C4::Context->preference('defaultSortField')
 327     && C4::Context->preference('defaultSortOrder') ) {
 328     $default_sort_by =
 329         C4::Context->preference('defaultSortField') . '_'
 330       . C4::Context->preference('defaultSortOrder');
 331 }
 332
 333 @sort_by = $cgi->multi_param('sort_by');
 334 $sort_by[0] = $default_sort_by unless $sort_by[0];
 335 foreach my $sort (@sort_by) {
 336     $template->param($sort => 1) if $sort;
 337 }
 338 $template->param('sort_by' => $sort_by[0]);
 339
 340 # Use the servers defined, or just search our local catalog(default)
 341 my @servers = $cgi->multi_param('server');
 342 unless (@servers) {
 343     #FIXME: this should be handled using Context.pm
 344     @servers = ("biblioserver");
 345     # @servers = C4::Context->config("biblioserver");
 346 }
 347 # operators include boolean and proximity operators and are used
 348 # to evaluate multiple operands
 349 my @operators = map uri_unescape($_), $cgi->multi_param('op');
 350
 351 # indexes are query qualifiers, like 'title', 'author', etc. They
 352 # can be single or multiple parameters separated by comma: kw,right-Truncation
 353 my @indexes = map uri_unescape($_), $cgi->multi_param('idx');
 354
 355 # if a simple index (only one)  display the index used in the top search box
 356 if ($indexes[0] && (!$indexes[1] || $params->{'scan'})) {
 357     my $idx = "ms_".$indexes[0];
 358     $idx =~ s/\,/comma/g;  # template toolkit doesn't like variables with a , in it
 359     $idx =~ s/-/dash/g;  # template toolkit doesn't like variables with a dash in it
 360     $template->param($idx => 1);
 361 }
 362
 363 # an operand can be a single term, a phrase, or a complete ccl query
 364 my @operands = map uri_unescape($_), $cgi->multi_param('q');
 365
 366 # if a simple search, display the value in the search box
 367 if ($operands[0] && !$operands[1]) {
 368     my $ms_query = $operands[0];
 369     $ms_query =~ s/ #\S+//;
 370     $template->param(ms_value => $ms_query);
 371 }
 372
 373 # limits are use to limit to results to a pre-defined category such as branch or language
 374 my @limits = map uri_unescape($_), $cgi->multi_param('limit');
 375 my @nolimits = map uri_unescape($_), $cgi->multi_param('nolimit');
 376 my %is_nolimit = map { $_ => 1 } @nolimits;
 377 @limits = grep { not $is_nolimit{$_} } @limits;
 378
 379 if($params->{'multibranchlimit'}) {
 380     my $search_group = Koha::Library::Groups->find( $params->{multibranchlimit} );
 381     my @libraries = $search_group->all_libraries;
 382     my $multibranch = '('.join( " OR ", map { '(homebranch: ' . $_->branchcode .')' } @libraries ) .')';
 383     push @limits, $multibranch if ($multibranch ne  '()');
 384 }
 385
 386 my $available;
 387 foreach my $limit(@limits) {
 388     if ($limit =~/available/) {
 389         $available = 1;
 390     }
 391 }
 392 $template->param(available => $available);
 393
 394 # append year limits if they exist
 395 my $limit_yr;
 396 my $limit_yr_value;
 397 if ($params->{'limit-yr'}) {
 398     if ($params->{'limit-yr'} =~ /\d{4}/) {
 399         $limit_yr = "yr,st-numeric=$params->{'limit-yr'}";
 400         $limit_yr_value = $params->{'limit-yr'};
 401     }
 402     push @limits,$limit_yr;
 403     #FIXME: Should return a error to the user, incorect date format specified
 404 }
 405
 406 # convert indexes and operands to corresponding parameter names for the z3950 search
 407 # $ %z3950p will be a hash ref if the indexes are present (advacned search), otherwise undef
 408 my $z3950par;
 409 my $indexes2z3950 = {
 410     kw=>'title', au=>'author', 'au,phr'=>'author', nb=>'isbn', ns=>'issn',
 411     'lcn,phr'=>'dewey', su=>'subject', 'su,phr'=>'subject',
 412     ti=>'title', 'ti,phr'=>'title', se=>'title'
 413 };
 414 for (my $ii = 0; $ii < @operands; ++$ii)
 415 {
 416     my $name = $indexes2z3950->{$indexes[$ii] || 'kw'};
 417     if (defined $name && defined $operands[$ii])
 418     {
 419         $z3950par ||= {};
 420         $z3950par->{$name} = $operands[$ii] if !exists $z3950par->{$name};
 421     }
 422 }
 423
 424
 425 # Params that can only have one value
 426 my $scan = $params->{'scan'};
 427 my $count = C4::Context->preference('numSearchResults') || 20;
 428 my $results_per_page = $params->{'count'} || $count;
 429 my $offset = $params->{'offset'} || 0;
 430 my $whole_record = $params->{'whole_record'} || 0;
 431 $offset = 0 if $offset < 0;
 432 my $page = $cgi->param('page') || 1;
 433 #my $offset = ($page-1)*$results_per_page;
 434
 435 # Define some global variables
 436 my ( $error,$query,$simple_query,$query_cgi,$query_desc,$limit,$limit_cgi,$limit_desc,$query_type);
 437
 438 my $builder = Koha::SearchEngine::QueryBuilder->new(
 439     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 440 my $searcher = Koha::SearchEngine::Search->new(
 441     { index => $Koha::SearchEngine::BIBLIOS_INDEX } );
 442
 443 ## I. BUILD THE QUERY
 444 (
 445     $error,             $query, $simple_query, $query_cgi,
 446     $query_desc,        $limit, $limit_cgi,    $limit_desc,
 447     $query_type
 448   )
 449   = $builder->build_query_compat( \@operators, \@operands, \@indexes, \@limits,
 450     \@sort_by, $scan, $lang, { weighted_fields => !$cgi->param('advsearch'), whole_record => $whole_record });
 451
 452 $template->param( search_query => $query ) if C4::Context->preference('DumpSearchQueryTemplate');
 453
 454 ## parse the query_cgi string and put it into a form suitable for <input>s
 455 my @query_inputs;
 456 my $scan_index_to_use;
 457 my $scan_search_term_to_use;
 458
 459 if ($query_cgi) {
 460     for my $this_cgi ( split('&', $query_cgi) ) {
 461         next unless $this_cgi;
 462         $this_cgi =~ m/(.*?)=(.*)/;
 463         my $input_name = $1;
 464         my $input_value = $2;
 465         push @query_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape( $input_value ) ) };
 466         if ($input_name eq 'idx') {
 467             # The form contains multiple fields, so take the first value as the scan index
 468             $scan_index_to_use = $input_value unless $scan_index_to_use;
 469         }
 470         if (!defined $scan_search_term_to_use && $input_name eq 'q') {
 471             $scan_search_term_to_use = Encode::decode_utf8( uri_unescape( $input_value ));
 472         }
 473     }
 474 }
 475
 476 $template->param ( QUERY_INPUTS => \@query_inputs,
 477                    scan_index_to_use => $scan_index_to_use,
 478                    scan_search_term_to_use => $scan_search_term_to_use );
 479
 480 ## parse the limit_cgi string and put it into a form suitable for <input>s
 481 my @limit_inputs;
 482 if ($limit_cgi) {
 483     for my $this_cgi ( split('&', $limit_cgi) ) {
 484         next unless $this_cgi;
 485         # handle special case limit-yr
 486         if ($this_cgi =~ /yr,st-numeric/) {
 487             push @limit_inputs, { input_name => 'limit-yr', input_value => $limit_yr_value };
 488             next;
 489         }
 490         $this_cgi =~ m/(.*=)(.*)/;
 491         my $input_name = $1;
 492         my $input_value = $2;
 493         $input_name =~ s/=$//;
 494         push @limit_inputs, { input_name => $input_name, input_value => Encode::decode_utf8( uri_unescape($input_value) ) };
 495     }
 496 }
 497 $template->param ( LIMIT_INPUTS => \@limit_inputs );
 498
 499 ## II. DO THE SEARCH AND GET THE RESULTS
 500 my $total = 0; # the total results for the whole set
 501 my $facets; # this object stores the faceted results that display on the left-hand of the results page
 502 my $results_hashref;
 503
 504 eval {
 505     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 506     ( $error, $results_hashref, $facets ) = $searcher->search_compat(
 507         $query,            $simple_query, \@sort_by,       \@servers,
 508         $results_per_page, $offset,       undef,           $itemtypes,
 509         $query_type,       $scan
 510     );
 511 };
 512
 513 if ($@ || $error) {
 514     $template->param(query_error => $error.$@);
 515     output_html_with_http_headers $cgi, $cookie, $template->output;
 516     exit;
 517 }
 518
 519 # At this point, each server has given us a result set
 520 # now we build that set for template display
 521 my @sup_results_array;
 522 for (my $i=0;$i<@servers;$i++) {
 523     my $server = $servers[$i];
 524     if ($server =~/biblioserver/) { # this is the local bibliographic server
 525         my $hits = $results_hashref->{$server}->{"hits"} // 0;
 526         my $page = $cgi->param('page') || 0;
 527         my @newresults = searchResults({ 'interface' => 'intranet' }, $query_desc, $hits, $results_per_page, $offset, $scan,
 528                                        $results_hashref->{$server}->{"RECORDS"});
 529         $total = $total + $hits;
 530
 531         # Search history
 532         if (C4::Context->preference('EnableSearchHistory')) {
 533             unless ( $offset ) {
 534                 my $path_info = $cgi->url(-path_info=>1);
 535                 my $query_cgi_history = $cgi->url(-query=>1);
 536                 $query_cgi_history =~ s/^$path_info\?//;
 537                 $query_cgi_history =~ s/;/&/g;
 538                 my $query_desc_history = $query_desc;
 539                 $query_desc_history .= ", $limit_desc"
 540                     if $limit_desc;
 541
 542                 C4::Search::History::add({
 543                     userid => $borrowernumber,
 544                     sessionid => $cgi->cookie("CGISESSID"),
 545                     query_desc => $query_desc_history,
 546                     query_cgi => $query_cgi_history,
 547                     total => $total,
 548                     type => "biblio",
 549                 });
 550             }
 551             $template->param( EnableSearchHistory => 1 );
 552         }
 553
 554         ## If there's just one result, redirect to the detail page unless doing an index scan
 555         if ($total == 1 && !$scan) {
 556             my $biblionumber = $newresults[0]->{biblionumber};
 557             my $defaultview = C4::Context->preference('IntranetBiblioDefaultView');
 558             my $views = { C4::Search::enabled_staff_search_views };
 559             if ($defaultview eq 'isbd' && $views->{can_view_ISBD}) {
 560                 print $cgi->redirect("/cgi-bin/koha/catalogue/ISBDdetail.pl?biblionumber=$biblionumber");
 561             } elsif  ($defaultview eq 'marc' && $views->{can_view_MARC}) {
 562                 print $cgi->redirect("/cgi-bin/koha/catalogue/MARCdetail.pl?biblionumber=$biblionumber");
 563             } elsif  ($defaultview eq 'labeled_marc' && $views->{can_view_labeledMARC}) {
 564                 print $cgi->redirect("/cgi-bin/koha/catalogue/labeledMARCdetail.pl?biblionumber=$biblionumber");
 565             } else {
 566                 print $cgi->redirect("/cgi-bin/koha/catalogue/detail.pl?biblionumber=$biblionumber");
 567             }
 568             exit;
 569         }
 570
 571         # set up parameters if user wishes to re-run the search
 572         # as a Z39.50 search
 573         $template->param (z3950_search_params => C4::Search::z3950_search_args($z3950par || $query_desc));
 574
 575         if ($hits) {
 576             $template->param(total => $hits);
 577             if ($limit_cgi) {
 578                 my $limit_cgi_not_availablity = $limit_cgi;
 579                 $limit_cgi_not_availablity =~ s/&limit=available//g;
 580                 $template->param(limit_cgi_not_availablity => $limit_cgi_not_availablity);
 581             }
 582             $template->param(limit_cgi => $limit_cgi);
 583             $template->param(query_cgi => $query_cgi);
 584             $template->param(query_desc => $query_desc);
 585             $template->param(limit_desc => $limit_desc);
 586             $template->param(offset     => $offset);
 587             $template->param(DisplayMultiPlaceHold => $DisplayMultiPlaceHold);
 588             if ($query_desc || $limit_desc) {
 589                 $template->param(searchdesc => 1);
 590             }
 591             $template->param(results_per_page =>  $results_per_page);
 592             # must define a value for size if not present in DB
 593             # in order to avoid problems generated by the default size value in TT
 594             foreach my $line (@newresults) {
 595                 if ( not exists $line->{'size'} ) { $line->{'size'} = "" }
 596                 # while we're checking each line, see if item is in the cart
 597                 if ( grep {$_ eq $line->{'biblionumber'}} @cart_list) {
 598                     $line->{'incart'} = 1;
 599                 }
 600             }
 601             $template->param(SEARCH_RESULTS => \@newresults);
 602             ## FIXME: add a global function for this, it's better than the current global one
 603             ## Build the page numbers on the bottom of the page
 604             my @page_numbers;
 605             my $max_result_window = $searcher->max_result_window;
 606             my $hits_to_paginate = ($max_result_window && $max_result_window < $hits) ? $max_result_window : $hits;
 607             $template->param( hits_to_paginate => $hits_to_paginate );
 608             # total number of pages there will be
 609             my $pages = ceil($hits_to_paginate / $results_per_page);
 610             my $last_page_offset = ( $pages -1 ) * $results_per_page;
 611             # default page number
 612             my $current_page_number = 1;
 613             $current_page_number = ($offset / $results_per_page + 1) if $offset;
 614             my $previous_page_offset;
 615             if ( $offset >= $results_per_page ) {
 616                 $previous_page_offset = $offset - $results_per_page;
 617             }
 618             my $next_page_offset = $offset + $results_per_page;
 619             # If we're within the first 10 pages, keep it simple
 620             #warn "current page:".$current_page_number;
 621             if ($current_page_number < 10) {
 622                 # just show the first 10 pages
 623                 # Loop through the pages
 624                 my $pages_to_show = 10;
 625                 $pages_to_show = $pages if $pages<10;
 626                 for (my $i=1; $i<=$pages_to_show;$i++) {
 627                     # the offset for this page
 628                     my $this_offset = (($i*$results_per_page)-$results_per_page);
 629                     # the page number for this page
 630                     my $this_page_number = $i;
 631                     # put it in the array
 632                     push @page_numbers,
 633                       { offset    => $this_offset,
 634                         pg        => $this_page_number,
 635                         # it should only be highlighted if it's the current page
 636                         highlight => $this_page_number == $current_page_number,
 637                         sort_by   => join ' ', @sort_by
 638                       };
 639
 640                 }
 641
 642             }
 643
 644             # now, show twenty pages, with the current one smack in the middle
 645             else {
 646                 for (my $i=$current_page_number; $i<=($current_page_number + 20 );$i++) {
 647                     my $this_offset = ((($i-9)*$results_per_page)-$results_per_page);
 648                     my $this_page_number = $i-9;
 649                     if ( $this_page_number <= $pages ) {
 650                         push @page_numbers,
 651                           { offset    => $this_offset,
 652                             pg        => $this_page_number,
 653                             highlight => $this_page_number == $current_page_number,
 654                             sort_by   => join ' ', @sort_by
 655                           };
 656                     }
 657                 }
 658             }
 659             # FIXME: no previous_page_offset when pages < 2
 660             $template->param(   PAGE_NUMBERS => \@page_numbers,
 661                                 last_page_offset => $last_page_offset,
 662                                 previous_page_offset => $previous_page_offset) unless $pages < 2;
 663             $template->param(   next_page_offset => $next_page_offset) unless $pages eq $current_page_number;
 664         }
 665
 666
 667         # no hits
 668         else {
 669             $template->param(searchdesc => 1,query_desc => $query_desc,limit_desc => $limit_desc);
 670         }
 671
 672     } # end of the if local
 673
 674     # asynchronously search the authority server
 675     elsif ($server =~/authorityserver/) { # this is the local authority server
 676         my @inner_sup_results_array;
 677         for my $sup_record ( @{$results_hashref->{$server}->{"RECORDS"}} ) {
 678             my $marc_record_object = C4::Search::new_record_from_zebra(
 679                 'authorityserver',
 680                 $sup_record
 681             );
 682             # warn "Authority Found: ".$marc_record_object->as_formatted();
 683             push @inner_sup_results_array, {
 684                 'title' => $marc_record_object->field(100)->subfield('a'),
 685                 'link' => "&amp;idx=an&amp;q=".$marc_record_object->field('001')->as_string(),
 686             };
 687         }
 688         push @sup_results_array, {  servername => $server,
 689                                     inner_sup_results_loop => \@inner_sup_results_array} if @inner_sup_results_array;
 690     }
 691     # FIXME: can add support for other targets as needed here
 692     $template->param(           outer_sup_results_loop => \@sup_results_array);
 693 } #/end of the for loop
 694 #$template->param(FEDERATED_RESULTS => \@results_array);
 695
 696 my $gotonumber = $cgi->param('gotoNumber');
 697 if ( $gotonumber && ( $gotonumber eq 'last' || $gotonumber eq 'first' ) ) {
 698     $template->{'VARS'}->{'gotoNumber'} = $gotonumber;
 699 }
 700 $template->{'VARS'}->{'gotoPage'}   = 'detail.pl';
 701 my $gotopage = $cgi->param('gotoPage');
 702 $template->{'VARS'}->{'gotoPage'} = $gotopage
 703   if $gotopage && $gotopage =~ m/^(ISBD|labeledMARC|MARC|more)?detail.pl$/;
 704
 705 for my $facet ( @$facets ) {
 706     for my $entry ( @{ $facet->{facets} } ) {
 707         my $index = $entry->{type_link_value};
 708         my $value = $entry->{facet_link_value};
 709         $entry->{active} = grep { $_->{input_value} eq qq{$index:$value} } @limit_inputs;
 710     }
 711 }
 712
 713 $template->param(
 714             #classlist => $classlist,
 715             total => $total,
 716             opacfacets => 1,
 717             facets_loop => $facets,
 718             displayFacetCount=> C4::Context->preference('displayFacetCount')||0,
 719             scan => $scan,
 720             search_error => $error,
 721 );
 722
 723 if ($query_desc || $limit_desc) {
 724     $template->param(searchdesc => 1);
 725 }
 726
 727 # VI. BUILD THE TEMPLATE
 728
 729 my $some_private_shelves = Koha::Virtualshelves->get_some_shelves(
 730     {
 731         borrowernumber => $borrowernumber,
 732         add_allowed    => 1,
 733         category       => 1,
 734     }
 735 );
 736 my $some_public_shelves = Koha::Virtualshelves->get_some_shelves(
 737     {
 738         borrowernumber => $borrowernumber,
 739         add_allowed    => 1,
 740         category       => 2,
 741     }
 742 );
 743
 744
 745 $template->param(
 746     add_to_some_private_shelves => $some_private_shelves,
 747     add_to_some_public_shelves  => $some_public_shelves,
 748 );
 749
 750 output_html_with_http_headers $cgi, $cookie, $template->output;
 751
 752
 753 =head2 prepare_adv_search_types
 754
 755     my $type = C4::Context->preference("AdvancedSearchTypes") || "itemtypes";
 756     my @advanced_search_types = prepare_adv_search_types($type);
 757
 758 Different types can be searched for in the advanced search. This takes the
 759 system preference that defines these types and parses it into an arrayref for
 760 the template.
 761
 762 "itemtypes" is handled specially, as itemtypes aren't an authorised value.
 763 It also accounts for the "item-level_itypes" system preference.
 764
 765 =cut
 766
 767 sub prepare_adv_search_types {
 768     my ($types) = @_;
 769
 770     my @advanced_search_types = split( /\|/, $types );
 771
 772     # the index parameter is different for item-level itemtypes
 773     my $itype_or_itemtype =
 774       ( C4::Context->preference("item-level_itypes") ) ? 'itype' : 'itemtype';
 775     my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 776
 777     my ( $cnt, @result );
 778     foreach my $advanced_srch_type (@advanced_search_types) {
 779         $advanced_srch_type =~ s/^\s*//;
 780         $advanced_srch_type =~ s/\s*$//;
 781         if ( $advanced_srch_type eq 'itemtypes' ) {
 782
 783        # itemtype is a special case, since it's not defined in authorized values
 784             my @itypesloop;
 785             foreach my $thisitemtype (
 786                 sort {
 787                     $itemtypes->{$a}->{'translated_description'}
 788                       cmp $itemtypes->{$b}->{'translated_description'}
 789                 } keys %$itemtypes
 790               )
 791             {
 792                 my %row = (
 793                     number      => $cnt++,
 794                     ccl         => "$itype_or_itemtype,phr",
 795                     code        => $thisitemtype,
 796                     description => $itemtypes->{$thisitemtype}->{'translated_description'},
 797                     imageurl    => getitemtypeimagelocation(
 798                         'intranet', $itemtypes->{$thisitemtype}->{'imageurl'}
 799                     ),
 800                 );
 801                 push @itypesloop, \%row;
 802             }
 803             my %search_code = (
 804                 advanced_search_type => $advanced_srch_type,
 805                 code_loop            => \@itypesloop
 806             );
 807             push @result, \%search_code;
 808         }
 809         else {
 810             # covers all the other cases: non-itemtype authorized values
 811             my $advsearchtypes = GetAuthorisedValues($advanced_srch_type);
 812             my @authvalueloop;
 813             for my $thisitemtype (@$advsearchtypes) {
 814                 my %row = (
 815                     number      => $cnt++,
 816                     ccl         => $advanced_srch_type,
 817                     code        => $thisitemtype->{authorised_value},
 818                     description => $thisitemtype->{'lib'},
 819                     imageurl    => getitemtypeimagelocation(
 820                         'intranet', $thisitemtype->{'imageurl'}
 821                     ),
 822                 );
 823                 push @authvalueloop, \%row;
 824             }
 825             my %search_code = (
 826                 advanced_search_type => $advanced_srch_type,
 827                 code_loop            => \@authvalueloop
 828             );
 829             push @result, \%search_code;
 830         }
 831     }
 832     return \@result;
 833 }