opac/opac-ics.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2007 Liblime Ltd
   4
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 # This script builds an ICalendar file (rfc 2445) for use in programs such as Ical
  21
  22 use Modern::Perl;
  23
  24 use CGI qw ( -utf8 );
  25 use Data::ICal;
  26 use Data::ICal::Entry::Event;
  27 use DateTime;
  28 use DateTime::Format::ICal;
  29 use DateTime::Event::ICal;
  30 use URI;
  31
  32 use C4::Auth;
  33 use C4::Koha;
  34 use C4::Circulation;
  35 use C4::Members;
  36 use Koha::DateUtils;
  37
  38 my $query = CGI->new;
  39 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  40     {
  41         template_name   => "opac-ics.tt",
  42         query           => $query,
  43         type            => "opac",
  44         debug           => 1,
  45     }
  46 );
  47
  48 # Create Calendar
  49 my $calendar = Data::ICal->new();
  50
  51 my $patron = Koha::Patrons->find( $borrowernumber );
  52 my $pending_checkouts = $patron->pending_checkouts;
  53
  54 while ( my $c = $pending_checkouts->next ) {
  55     my $issue = $c->unblessed_all_relateds;
  56     my $vevent = Data::ICal::Entry::Event->new();
  57     my $timestamp = dt_from_string(undef,undef,"UTC"); #Get current time in UTC
  58     # Send some values to the template to generate summary and description
  59     $issue->{overdue} = $c->is_overdue;
  60     $template->param(
  61         overdue => $issue->{'overdue'},
  62         title   => $issue->{'title'},
  63         barcode => $issue->{'barcode'},
  64     );
  65     # Catch the result of the template and split on newline
  66     my ($summary,$description) = split /\n/, $template->output;
  67     my $datestart;
  68     if ($issue->{'overdue'} && $issue->{'overdue'} == 1) {
  69         # Not much use adding an event in the past for a book that is overdue
  70         # so we set datestart = now
  71         $datestart = $timestamp;
  72     } else {
  73         $datestart = dt_from_string($issue->{'date_due'});
  74         $datestart->set_time_zone('UTC');
  75     }
  76     # Create a UID that includes the issue number and the domain
  77     my $domain = '';
  78     my $baseurl = C4::Context->preference('OPACBaseURL');
  79     if ( $baseurl ne '' ) {
  80         my $url = URI->new($baseurl);
  81         $domain = $url->host;
  82     } else {
  83         warn "Make sure the systempreference OPACBaseURL is set!";
  84     }
  85     my $uid = 'issue-' . $issue->{'issue_id'} . '@' . $domain;
  86     # Create the event
  87     $vevent->add_properties(
  88         summary     => $summary,
  89         description => $description,
  90         dtstamp     => DateTime::Format::ICal->format_datetime($timestamp),
  91         dtstart     => DateTime::Format::ICal->format_datetime($datestart),
  92         uid         => $uid,
  93     );
  94     # Add it to the calendar
  95     $calendar->add_entry($vevent);
  96 }
  97
  98 print $query->header(
  99     -type       => 'application/octet-stream',
 100     -attachment => 'koha.ics'
 101 );
 102
 103 print $calendar->as_string;