opac/opac-renew.pl

   1 #!/usr/bin/perl
   2
   3 #written 18/1/2000 by chris@katipo.co.nz
   4 # adapted for use in the hlt opac by finlay@katipo.co.nz 29/11/2002
   5 # script to renew items from the web
   6 # Parts Copyright 2010,2011 Catalyst IT
   7
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use strict;
  25 use warnings;
  26
  27 use CGI qw ( -utf8 );
  28 use C4::Circulation;
  29 use C4::Auth;
  30 use C4::Context;
  31 use C4::Items;
  32 use C4::Members;
  33 use Date::Calc qw( Today Date_to_Days );
  34 my $query = new CGI;
  35
  36 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  37         {
  38         template_name   => "opac-user.tt",
  39         query           => $query,
  40         type            => "opac",
  41         authnotrequired => 0,
  42         flagsrequired   => { borrow => 1 },
  43         debug           => 1,
  44         }
  45 );
  46 my @items = $query->param('item');
  47
  48 my $opacrenew = C4::Context->preference("OpacRenewalAllowed");
  49
  50 my $errorstring = q{};
  51 my $renewed     = q{};
  52
  53 my $member_details = GetMemberDetails($borrowernumber);
  54
  55 if (   $member_details->{'BlockExpiredPatronOpacActions'}
  56     && $member_details->{'is_expired'} )
  57 {
  58     $errorstring = 'card_expired';
  59 }
  60 else {
  61     my @renewed;
  62     for my $itemnumber (@items) {
  63         my ( $status, $error ) =
  64           CanBookBeRenewed( $borrowernumber, $itemnumber );
  65         if ( $status == 1 && $opacrenew == 1 ) {
  66             my $renewalbranch = C4::Context->preference('OpacRenewalBranch');
  67             my $branchcode;
  68             if ( $renewalbranch eq 'itemhomebranch' ) {
  69                 my $item = GetItem($itemnumber);
  70                 $branchcode = $item->{'homebranch'};
  71             }
  72             elsif ( $renewalbranch eq 'patronhomebranch' ) {
  73                 my $borrower = GetMemberDetails($borrowernumber);
  74                 $branchcode = $borrower->{'branchcode'};
  75             }
  76             elsif ( $renewalbranch eq 'checkoutbranch' ) {
  77                 my $issue = GetOpenIssue($itemnumber);
  78                 $branchcode = $issue->{'branchcode'};
  79             }
  80             elsif ( $renewalbranch eq 'NULL' ) {
  81                 $branchcode = '';
  82             }
  83             else {
  84                 $branchcode = 'OPACRenew';
  85             }
  86             AddRenewal( $borrowernumber, $itemnumber, $branchcode );
  87             push( @renewed, $itemnumber );
  88         }
  89         else {
  90             $errorstring .= $error . "|";
  91         }
  92     }
  93     $renewed = join( ':', @renewed );
  94 }
  95
  96 print $query->redirect("/cgi-bin/koha/opac-user.pl?renew_error=$errorstring&renewed=$renewed");
  97