acqui/basket.pl

   1 #!/usr/bin/perl
   2
   3 #script to show display basket of orders
   4 #written by chris@katipo.co.nz 24/2/2000
   5
   6 # Copyright 2000-2002 Katipo Communications
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it under the
  11 # terms of the GNU General Public License as published by the Free Software
  12 # Foundation; either version 2 of the License, or (at your option) any later
  13 # version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  16 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  17 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  18 #
  19 # You should have received a copy of the GNU General Public License along with
  20 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  21 # Suite 330, Boston, MA  02111-1307 USA
  22
  23 use strict;
  24 use C4::Auth;
  25 use C4::Koha;
  26 use C4::Output;
  27 use CGI;
  28 use C4::Acquisition;
  29 use C4::Bookfund;
  30 use C4::Bookseller;
  31 use C4::Dates qw/format_date/;
  32
  33 use vars qw($debug);
  34
  35 BEGIN {
  36     $debug = $ENV{DEBUG} || 1;
  37 }
  38
  39 =head1 NAME
  40
  41 basket.pl
  42
  43 =head1 DESCRIPTION
  44
  45  This script display all informations about basket for the supplier given
  46  on input arg. Moreover, it allow to add a new order for this supplier from
  47  an existing record, a suggestion or from a new record.
  48
  49 =head1 CGI PARAMETERS
  50
  51 =over 4
  52
  53 =item $basketno
  54
  55 this parameter seems to be unused.
  56
  57 =item supplierid
  58
  59 the supplier this script have to display the basket.
  60
  61 =item order
  62
  63 =back
  64
  65 =cut
  66
  67 my $query        = new CGI;
  68 my $basketno     = $query->param('basketno');
  69 my $booksellerid = $query->param('supplierid');
  70 my $order        = $query->param('order');
  71 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  72     {
  73         template_name   => "acqui/basket.tmpl",
  74         query           => $query,
  75         type            => "intranet",
  76         authnotrequired => 0,
  77         flagsrequired   => { acquisition => 1 },
  78         debug           => 1,
  79     }
  80 );
  81
  82 my $basket = GetBasket($basketno);
  83
  84 # FIXME : the query->param('supplierid') below is probably useless. The bookseller is always known from the basket
  85 # if no booksellerid in parameter, get it from basket
  86 # warn "=>".$basket->{booksellerid};
  87 $booksellerid = $basket->{booksellerid} unless $booksellerid;
  88 my ($bookseller) = GetBookSellerFromId($booksellerid);
  89
  90 if ( !$bookseller ) {
  91     $template->param( NO_BOOKSELLER => 1 );
  92 }
  93 else {
  94
  95     # get librarian branch...
  96     if ( C4::Context->preference("IndependantBranches") ) {
  97         my $userenv = C4::Context->userenv;
  98         unless ( $userenv->{flags} == 1 ) {
  99             my $validtest = ( $basket->{creationdate} eq '' )
 100               || ( $userenv->{branch} eq $basket->{branch} )
 101               || ( $userenv->{branch} eq '' )
 102               || ( $basket->{branch}  eq '' );
 103             unless ($validtest) {
 104                 print $query->redirect("../mainpage.pl");
 105                 exit 1;
 106             }
 107         }
 108     }
 109
 110     # if new basket, pre-fill infos
 111     $basket->{creationdate} = ""            unless ( $basket->{creationdate} );
 112     $basket->{authorisedby} = $loggedinuser unless ( $basket->{authorisedby} );
 113     $debug
 114       and warn sprintf
 115       "loggedinuser: $loggedinuser; creationdate: %s; authorisedby: %s",
 116       $basket->{creationdate}, $basket->{authorisedby};
 117
 118     my @results = GetOrders( $basketno, $order );
 119     my $count = scalar @results;
 120
 121     my $line_total;     # total of each line
 122     my $sub_total;      # total of line totals
 123     my $gist;           # GST
 124     my $grand_total;    # $subttotal + $gist
 125     my $toggle = 0;
 126
 127     # my $line_total_est; # total of each line
 128     my $sub_total_est;      # total of line totals
 129     my $sub_total_rrp;      # total of line totals
 130     my $gist_est;           # GST
 131     my $grand_total_est;    # $subttotal + $gist
 132
 133     my $qty_total;
 134     my @books_loop;
 135     for ( my $i = 0 ; $i < $count ; $i++ ) {
 136         my $rrp = $results[$i]->{'listprice'};
 137         $rrp = ConvertCurrency( $results[$i]->{'currency'}, $rrp );
 138         $sub_total_rrp += $results[$i]->{'quantity'} * $results[$i]->{'rrp'};
 139         $line_total = $results[$i]->{'quantity'} * $results[$i]->{'ecost'};
 140         $sub_total += $line_total;
 141         $qty_total += $results[$i]->{'quantity'};
 142         my %line;
 143         %line = %{ $results[$i] };
 144
 145         if ( $toggle == 0 ) {
 146             $line{color} = '#EEEEEE';
 147             $toggle = 1;
 148         }
 149         else {
 150             $line{color} = 'white';
 151             $toggle = 0;
 152         }
 153         $line{order_received} =
 154           ( $results[$i]->{'quantity'} eq $results[$i]->{'quantityreceived'} );
 155         $line{publishercode} = $results[$i]->{'publishercode'};
 156         $line{basketno}      = $basketno;
 157         $line{i}             = $i;
 158         $line{rrp}           = sprintf( "%.2f", $line{'rrp'} );
 159         $line{ecost}         = sprintf( "%.2f", $line{'ecost'} );
 160         $line{line_total}    = sprintf( "%.2f", $line_total );
 161         $line{odd}           = $i % 2;
 162         push @books_loop, \%line;
 163     }
 164     my $prefgist = C4::Context->preference("gist");
 165     $gist            = sprintf( "%.2f", $sub_total * $prefgist );
 166     $grand_total     = $sub_total;
 167     $grand_total_est = $sub_total_est;
 168     unless ( $bookseller->{'listincgst'} ) {
 169         $grand_total += $gist;
 170         $grand_total_est += sprintf( "%.2f", $sub_total_est * $prefgist );
 171     }
 172     my $grand_total_rrp = sprintf( "%.2f", $sub_total_rrp );
 173     $gist_est = sprintf( "%.2f", $sub_total_est * $prefgist );
 174     $template->param(
 175         basketno         => $basketno,
 176         creationdate     => format_date( $basket->{creationdate} ),
 177         authorisedby     => $basket->{authorisedby},
 178         authorisedbyname => $basket->{authorisedbyname},
 179         closedate        => format_date( $basket->{closedate} ),
 180         active           => $bookseller->{'active'},
 181         booksellerid     => $bookseller->{'id'},
 182         name             => $bookseller->{'name'},
 183         address1         => $bookseller->{'address1'},
 184         address2         => $bookseller->{'address2'},
 185         address3         => $bookseller->{'address3'},
 186         address4         => $bookseller->{'address4'},
 187         entrydate        => format_date( $results[0]->{'entrydate'} ),
 188         books_loop       => \@books_loop,
 189         count            => $count,
 190         sub_total        => sprintf( "%.2f", $sub_total ),
 191         gist             => $gist,
 192         grand_total      => sprintf( "%.2f", $grand_total ),
 193         sub_total_est    => $sub_total_est,
 194         gist_est         => $gist_est,
 195         grand_total_est  => $grand_total_est,
 196         grand_total_rrp  => $grand_total_rrp,
 197         currency         => $bookseller->{'listprice'},
 198         qty_total        => $qty_total,
 199         GST              => $prefgist,
 200     );
 201 }
 202 output_html_with_http_headers $query, $cookie, $template->output;