tools/letter.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 =head1 tools/letter.pl
  21
  22  ALGO :
  23  this script use an $op to know what to do.
  24  if $op is empty or none of the values listed below,
  25         - the default screen is built (with all or filtered (if search string is set) records).
  26         - the   user can click on add, modify or delete record.
  27     - filtering is done on the code field
  28  if $op=add_form
  29         - if primary key (module + code) exists, this is a modification,so we read the required record
  30         - builds the add/modify form
  31  if $op=add_validate
  32         - the user has just send data, so we create/modify the record
  33  if $op=delete_form
  34         - we show the record selected and ask for confirmation
  35  if $op=delete_confirm
  36         - we delete the designated record
  37
  38 =cut
  39
  40 # TODO This script drives the CRUD operations on the letter table
  41 # The DB interaction should be handled by calls to C4/Letters.pm
  42
  43 use Modern::Perl;
  44 use CGI qw ( -utf8 );
  45 use C4::Auth;
  46 use C4::Context;
  47 use C4::Output;
  48 use C4::Letters;
  49
  50 use Koha::Patron::Attribute::Types;
  51
  52 # $protected_letters = protected_letters()
  53 # - return a hashref of letter_codes representing letters that should never be deleted
  54 sub protected_letters {
  55     my $dbh = C4::Context->dbh;
  56     my $codes = $dbh->selectall_arrayref(q{SELECT DISTINCT letter_code FROM message_transports});
  57     return { map { $_->[0] => 1 } @{$codes} };
  58 }
  59
  60 our $input       = new CGI;
  61 my $searchfield = $input->param('searchfield');
  62 my $script_name = '/cgi-bin/koha/tools/letter.pl';
  63 our $branchcode  = $input->param('branchcode');
  64 $branchcode = '' if defined $branchcode and $branchcode eq '*';
  65 my $code        = $input->param('code');
  66 my $module      = $input->param('module') || '';
  67 my $content     = $input->param('content');
  68 my $op          = $input->param('op') || '';
  69 my $redirect    = $input->param('redirect');
  70 my $section     = $input->param('section');
  71
  72 my $dbh = C4::Context->dbh;
  73
  74 our ( $template, $borrowernumber, $cookie, $staffflags ) = get_template_and_user(
  75     {
  76         template_name   => 'tools/letter.tt',
  77         query           => $input,
  78         type            => 'intranet',
  79         flagsrequired   => { tools => 'edit_notices' },
  80         debug           => 1,
  81     }
  82 );
  83
  84 our $my_branch = C4::Context->preference("IndependentBranches") && !$staffflags->{'superlibrarian'}
  85   ?  C4::Context->userenv()->{'branch'}
  86   : undef;
  87 # we show only the TMPL_VAR names $op
  88
  89 $template->param(
  90     independant_branch => $my_branch,
  91         script_name => $script_name,
  92   searchfield => $searchfield,
  93     branchcode => $branchcode,
  94     section => $section,
  95         action => $script_name
  96 );
  97
  98 if ( $op eq 'add_validate' or $op eq 'copy_validate' ) {
  99     add_validate();
 100     if( $redirect eq "just_save" ){
 101         print $input->redirect("/cgi-bin/koha/tools/letter.pl?op=add_form&branchcode=$branchcode&module=$module&code=$code&redirect=done&section=$section");
 102         exit;
 103     } else {
 104         $op = q{}; # we return to the default screen for the next operation
 105     }
 106 }
 107 if ($op eq 'copy_form') {
 108     my $oldbranchcode = $input->param('oldbranchcode') || q||;
 109     my $branchcode = $input->param('branchcode');
 110     add_form($oldbranchcode, $module, $code);
 111     $template->param(
 112         oldbranchcode => $oldbranchcode,
 113         branchcode => $branchcode,
 114         copying => 1,
 115         modify => 0,
 116     );
 117 }
 118 elsif ( $op eq 'add_form' ) {
 119     add_form($branchcode, $module, $code);
 120 }
 121 elsif ( $op eq 'delete_confirm' ) {
 122     delete_confirm($branchcode, $module, $code);
 123 }
 124 elsif ( $op eq 'delete_confirmed' ) {
 125     delete_confirmed($branchcode, $module, $code);
 126     $op = q{}; # next operation is to return to default screen
 127 }
 128 else {
 129     default_display($branchcode,$searchfield);
 130 }
 131
 132 # Do this last as delete_confirmed resets
 133 if ($op) {
 134     $template->param($op  => 1);
 135 } else {
 136     $template->param(no_op_set => 1);
 137 }
 138
 139 output_html_with_http_headers $input, $cookie, $template->output;
 140
 141 sub add_form {
 142     my ( $branchcode,$module, $code ) = @_;
 143
 144     my $letters;
 145     # if code has been passed we can identify letter and its an update action
 146     if ($code) {
 147         $letters = C4::Letters::GetLetterTemplates(
 148             {
 149                 branchcode => $branchcode,
 150                 module     => $module,
 151                 code       => $code,
 152             }
 153         );
 154     }
 155
 156     my $message_transport_types = GetMessageTransportTypes();
 157     my $templates = { map { $_ => { message_transport_type => $_ } } sort @$message_transport_types };
 158     my %letters = ( default => { templates => $templates } );
 159
 160     if ( C4::Context->preference('TranslateNotices') ) {
 161         my $translated_languages =
 162           C4::Languages::getTranslatedLanguages( 'opac',
 163             C4::Context->preference('template') );
 164         for my $language (@$translated_languages) {
 165             for my $sublanguage( @{ $language->{sublanguages_loop} } ) {
 166                 if ( $language->{plural} ) {
 167                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 168                         description => $sublanguage->{native_description}
 169                           . ' '
 170                           . $sublanguage->{region_description} . ' ('
 171                           . $sublanguage->{rfc4646_subtag} . ')',
 172                         templates => { %$templates },
 173                     };
 174                 }
 175                 else {
 176                     $letters{ $sublanguage->{rfc4646_subtag} } = {
 177                         description => $sublanguage->{native_description}
 178                           . ' ('
 179                           . $sublanguage->{rfc4646_subtag} . ')',
 180                         templates => { %$templates },
 181                     };
 182                 }
 183             }
 184         }
 185         $template->param( languages => $translated_languages );
 186     }
 187     if ($letters) {
 188         $template->param(
 189             modify     => 1,
 190             code       => $code,
 191         );
 192         my $first_flag_name = 1;
 193         my $lang;
 194         # The letter name is contained into each mtt row.
 195         # So we can only sent the first one to the template.
 196         for my $letter ( @$letters ) {
 197             # The letter_name
 198             if ( $first_flag_name and $letter->{name} ) {
 199                 $template->param(
 200                     letter_name=> $letter->{name},
 201                 );
 202                 $first_flag_name = 0;
 203             }
 204
 205             my $lang = $letter->{lang};
 206             my $mtt = $letter->{message_transport_type};
 207             $letters{ $lang }{templates}{$mtt} = {
 208                 message_transport_type => $letter->{message_transport_type},
 209                 is_html    => $letter->{is_html},
 210                 title      => $letter->{title},
 211                 content    => $letter->{content} // '',
 212             };
 213         }
 214     }
 215     else {
 216         $template->param( adding => 1 );
 217     }
 218
 219     $template->param(
 220         letters => \%letters,
 221     );
 222
 223     my $field_selection;
 224     push @{$field_selection}, add_fields('branches');
 225     if ($module eq 'reserves') {
 226         push @{$field_selection}, add_fields('borrowers', 'reserves', 'biblio', 'biblioitems', 'items');
 227     }
 228     elsif ( $module eq 'acquisition' ) {
 229         push @{$field_selection}, add_fields('aqbooksellers', 'aqorders', 'biblio', 'items');
 230     }
 231     elsif ($module eq 'claimacquisition' || $module eq 'orderacquisition') {
 232         push @{$field_selection}, add_fields('aqbooksellers', 'aqbasket', 'aqorders', 'biblio', 'biblioitems');
 233     }
 234     elsif ($module eq 'claimissues') {
 235         push @{$field_selection}, add_fields('aqbooksellers', 'serial', 'subscription', 'biblio', 'biblioitems');
 236     }
 237     elsif ($module eq 'serial') {
 238         push @{$field_selection}, add_fields('branches', 'biblio', 'biblioitems', 'borrowers', 'subscription', 'serial');
 239     }
 240     elsif ($module eq 'suggestions') {
 241         push @{$field_selection}, add_fields('suggestions', 'borrowers', 'biblio');
 242     }
 243     else {
 244         push @{$field_selection}, add_fields('biblio','biblioitems'),
 245             add_fields('items'),
 246             {value => 'items.content', text => 'items.content'},
 247             {value => 'items.fine',    text => 'items.fine'},
 248             add_fields('borrowers');
 249         if ($module eq 'circulation') {
 250             push @{$field_selection}, add_fields('opac_news');
 251
 252         }
 253
 254         if ( $module eq 'circulation' and $code and $code eq "CHECKIN" ) {
 255             push @{$field_selection}, add_fields('old_issues');
 256         } else {
 257             push @{$field_selection}, add_fields('issues');
 258         }
 259
 260         if ( $module eq 'circulation' and $code and $code =~ /^AR_/  ) {
 261             push @{$field_selection}, add_fields('article_requests');
 262         }
 263
 264         if ( $module eq 'members' and $code and $code eq 'PROBLEM_REPORT' ) {
 265             push @{$field_selection}, add_fields('problem_reports');
 266         }
 267     }
 268
 269     my $preview_is_available = 0;
 270
 271     if ($code) {
 272         $preview_is_available = grep {$_ eq $code } qw( CHECKIN CHECKOUT HOLD_SLIP );
 273     }
 274
 275     $template->param(
 276         module     => $module,
 277         SQLfieldnames => $field_selection,
 278         branchcode => $branchcode,
 279         preview_is_available => $preview_is_available,
 280     );
 281     return;
 282 }
 283
 284 sub add_validate {
 285     my $dbh        = C4::Context->dbh;
 286     my $branchcode    = $input->param('branchcode');
 287     my $module        = $input->param('module');
 288     my $oldmodule     = $input->param('oldmodule');
 289     my $code          = $input->param('code');
 290     my $name          = $input->param('name');
 291     my @mtt           = $input->multi_param('message_transport_type');
 292     my @title         = $input->multi_param('title');
 293     my @content       = $input->multi_param('content');
 294     my @lang          = $input->multi_param('lang');
 295     for my $mtt ( @mtt ) {
 296         my $lang = shift @lang;
 297         my $is_html = $input->param("is_html_$mtt\_$lang");
 298         my $title   = shift @title;
 299         my $content = shift @content;
 300         my $letter = C4::Letters::getletter( $oldmodule, $code, $branchcode, $mtt, $lang );
 301
 302         # getletter can return the default letter even if we pass a branchcode
 303         # If we got the default one and we needed the specific one, we didn't get the one we needed!
 304         if ( $letter and $branchcode and $branchcode ne $letter->{branchcode} ) {
 305             $letter = undef;
 306         }
 307         unless ( $title and $content ) {
 308             # Delete this mtt if no title or content given
 309             delete_confirmed( $branchcode, $oldmodule, $code, $mtt, $lang );
 310             next;
 311         }
 312         elsif ( $letter and $letter->{message_transport_type} eq $mtt and $letter->{lang} eq $lang ) {
 313             $dbh->do(
 314                 q{
 315                     UPDATE letter
 316                     SET branchcode = ?, module = ?, name = ?, is_html = ?, title = ?, content = ?, lang = ?
 317                     WHERE branchcode = ? AND module = ? AND code = ? AND message_transport_type = ? AND lang = ?
 318                 },
 319                 undef,
 320                 $branchcode || '', $module, $name, $is_html || 0, $title, $content, $lang,
 321                 $branchcode, $oldmodule, $code, $mtt, $lang
 322             );
 323         } else {
 324             $dbh->do(
 325                 q{INSERT INTO letter (branchcode,module,code,name,is_html,title,content,message_transport_type, lang) VALUES (?,?,?,?,?,?,?,?,?)},
 326                 undef,
 327                 $branchcode || '', $module, $code, $name, $is_html || 0, $title, $content, $mtt, $lang
 328             );
 329         }
 330     }
 331     # set up default display
 332     default_display($branchcode);
 333     return 1;
 334 }
 335
 336 sub delete_confirm {
 337     my ($branchcode, $module, $code) = @_;
 338     my $dbh = C4::Context->dbh;
 339     my $letter = C4::Letters::getletter($module, $code, $branchcode);
 340     my @values = values %$letter;
 341     $template->param(
 342         letter => $letter,
 343     );
 344     return;
 345 }
 346
 347 sub delete_confirmed {
 348     my ($branchcode, $module, $code, $mtt, $lang) = @_;
 349     C4::Letters::DelLetter(
 350         {
 351             branchcode => $branchcode || '',
 352             module     => $module,
 353             code       => $code,
 354             mtt        => $mtt,
 355             lang       => $lang,
 356         }
 357     );
 358     # setup default display for screen
 359     default_display($branchcode);
 360     return;
 361 }
 362
 363 sub retrieve_letters {
 364     my ($branchcode, $searchstring) = @_;
 365
 366     $branchcode = $my_branch if $branchcode && $my_branch;
 367
 368     my $dbh = C4::Context->dbh;
 369     my ($sql, @where, @args);
 370     $sql = "SELECT branchcode, module, code, name, branchname
 371             FROM letter
 372             LEFT OUTER JOIN branches USING (branchcode)
 373     ";
 374     if ($searchstring && $searchstring=~m/(\S+)/) {
 375         $searchstring = $1 . q{%};
 376         push @where, 'code LIKE ?';
 377         push @args, $searchstring;
 378     }
 379     elsif ($branchcode) {
 380         push @where, 'branchcode = ?';
 381         push @args, $branchcode || '';
 382     }
 383     elsif ($my_branch) {
 384         push @where, "(branchcode = ? OR branchcode = '')";
 385         push @args, $my_branch;
 386     }
 387
 388     $sql .= " WHERE ".join(" AND ", @where) if @where;
 389     $sql .= " GROUP BY branchcode,module,code,name,branchname";
 390
 391     $sql .= " ORDER BY module, code, branchcode";
 392
 393     return $dbh->selectall_arrayref($sql, { Slice => {} }, @args);
 394 }
 395
 396 sub default_display {
 397     my ($branchcode, $searchfield) = @_;
 398
 399     unless ( defined $branchcode ) {
 400         if ( C4::Context->preference('DefaultToLoggedInLibraryNoticesSlips') ) {
 401             $branchcode = C4::Context::mybranch();
 402         }
 403     }
 404
 405     if ( $searchfield  ) {
 406         $template->param( search      => 1 );
 407     }
 408     my $results = retrieve_letters($branchcode,$searchfield);
 409
 410     my $loop_data = [];
 411     my $protected_letters = protected_letters();
 412     foreach my $row (@{$results}) {
 413         $row->{protected} = !$row->{branchcode} && $protected_letters->{ $row->{code} };
 414         push @{$loop_data}, $row;
 415
 416     }
 417
 418     $template->param(
 419         letter => $loop_data,
 420         branchcode => $branchcode,
 421     );
 422 }
 423
 424 sub add_fields {
 425     my @tables = @_;
 426     my @fields = ();
 427
 428     for my $table (@tables) {
 429         push @fields, get_columns_for($table);
 430
 431     }
 432     return @fields;
 433 }
 434
 435 sub get_columns_for {
 436     my $table = shift;
 437 # FIXME untranslatable
 438     my %column_map = (
 439         aqbooksellers => '---BOOKSELLERS---',
 440         aqorders      => '---ORDERS---',
 441         serial        => '---SERIALS---',
 442         reserves      => '---HOLDS---',
 443         suggestions   => '---SUGGESTIONS---',
 444     );
 445     my @fields = ();
 446     if (exists $column_map{$table} ) {
 447         push @fields, {
 448             value => q{},
 449             text  => $column_map{$table} ,
 450         };
 451     }
 452     else {
 453         my $tlabel = '---' . uc $table;
 454         $tlabel.= '---';
 455         push @fields, {
 456             value => q{},
 457             text  => $tlabel,
 458         };
 459     }
 460
 461     my $sql = "SHOW COLUMNS FROM $table";# TODO not db agnostic
 462     my $table_prefix = $table . q|.|;
 463     my $rows = C4::Context->dbh->selectall_arrayref($sql, { Slice => {} });
 464     for my $row (@{$rows}) {
 465         next if $row->{'Field'} eq 'timestamp'; # this is really an irrelevant field and there may be other common fields that should be excluded from the list
 466         push @fields, {
 467             value => $table_prefix . $row->{Field},
 468             text  => $table_prefix . $row->{Field},
 469         }
 470     }
 471     if ($table eq 'borrowers') {
 472         my $attribute_types = Koha::Patron::Attribute::Types->search(
 473             {},
 474             { order_by => 'code' },
 475         );
 476         while ( my $at = $attribute_types->next ) {
 477             push @fields, {
 478                 value => "borrower-attribute:" . $at->code,
 479                 text  => "attribute:" . $at->code,
 480             }
 481         }
 482     }
 483     return @fields;
 484 }