C4/Reserves.pm

   1 package C4::Reserves;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #           2006 SAN Ouest Provence
   5 #           2007-2010 BibLibre Paul POULAIN
   6 #           2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23
  24 use strict;
  25 #use warnings; FIXME - Bug 2505
  26 use C4::Context;
  27 use C4::Biblio;
  28 use C4::Members;
  29 use C4::Items;
  30 use C4::Circulation;
  31 use C4::Accounts;
  32
  33 # for _koha_notify_reserve
  34 use C4::Members::Messaging;
  35 use C4::Members qw();
  36 use C4::Letters;
  37 use C4::Log;
  38
  39 use Koha::Biblios;
  40 use Koha::DateUtils;
  41 use Koha::Calendar;
  42 use Koha::Database;
  43 use Koha::Hold;
  44 use Koha::Old::Hold;
  45 use Koha::Holds;
  46 use Koha::Libraries;
  47 use Koha::IssuingRules;
  48 use Koha::Items;
  49 use Koha::ItemTypes;
  50 use Koha::Patrons;
  51
  52 use List::MoreUtils qw( firstidx any );
  53 use Carp;
  54 use Data::Dumper;
  55
  56 use vars qw(@ISA @EXPORT @EXPORT_OK %EXPORT_TAGS);
  57
  58 =head1 NAME
  59
  60 C4::Reserves - Koha functions for dealing with reservation.
  61
  62 =head1 SYNOPSIS
  63
  64   use C4::Reserves;
  65
  66 =head1 DESCRIPTION
  67
  68 This modules provides somes functions to deal with reservations.
  69
  70   Reserves are stored in reserves table.
  71   The following columns contains important values :
  72   - priority >0      : then the reserve is at 1st stage, and not yet affected to any item.
  73              =0      : then the reserve is being dealed
  74   - found : NULL       : means the patron requested the 1st available, and we haven't chosen the item
  75             T(ransit)  : the reserve is linked to an item but is in transit to the pickup branch
  76             W(aiting)  : the reserve is linked to an item, is at the pickup branch, and is waiting on the hold shelf
  77             F(inished) : the reserve has been completed, and is done
  78   - itemnumber : empty : the reserve is still unaffected to an item
  79                  filled: the reserve is attached to an item
  80   The complete workflow is :
  81   ==== 1st use case ====
  82   patron request a document, 1st available :                      P >0, F=NULL, I=NULL
  83   a library having it run "transfertodo", and clic on the list
  84          if there is no transfer to do, the reserve waiting
  85          patron can pick it up                                    P =0, F=W,    I=filled
  86          if there is a transfer to do, write in branchtransfer    P =0, F=T,    I=filled
  87            The pickup library receive the book, it check in       P =0, F=W,    I=filled
  88   The patron borrow the book                                      P =0, F=F,    I=filled
  89
  90   ==== 2nd use case ====
  91   patron requests a document, a given item,
  92     If pickup is holding branch                                   P =0, F=W,   I=filled
  93     If transfer needed, write in branchtransfer                   P =0, F=T,    I=filled
  94         The pickup library receive the book, it checks it in      P =0, F=W,    I=filled
  95   The patron borrow the book                                      P =0, F=F,    I=filled
  96
  97 =head1 FUNCTIONS
  98
  99 =cut
 100
 101 BEGIN {
 102     require Exporter;
 103     @ISA = qw(Exporter);
 104     @EXPORT = qw(
 105         &AddReserve
 106
 107         &GetReserveStatus
 108
 109         &GetOtherReserves
 110
 111         &ModReserveFill
 112         &ModReserveAffect
 113         &ModReserve
 114         &ModReserveStatus
 115         &ModReserveCancelAll
 116         &ModReserveMinusPriority
 117         &MoveReserve
 118
 119         &CheckReserves
 120         &CanBookBeReserved
 121         &CanItemBeReserved
 122         &CanReserveBeCanceledFromOpac
 123         &CancelExpiredReserves
 124
 125         &AutoUnsuspendReserves
 126
 127         &IsAvailableForItemLevelRequest
 128
 129         &AlterPriority
 130         &ToggleLowestPriority
 131
 132         &ReserveSlip
 133         &ToggleSuspend
 134         &SuspendAll
 135
 136         &GetReservesControlBranch
 137
 138         IsItemOnHoldAndFound
 139
 140         GetMaxPatronHoldsForRecord
 141     );
 142     @EXPORT_OK = qw( MergeHolds );
 143 }
 144
 145 =head2 AddReserve
 146
 147     AddReserve($branch,$borrowernumber,$biblionumber,$bibitems,$priority,$resdate,$expdate,$notes,$title,$checkitem,$found)
 148
 149 Adds reserve and generates HOLDPLACED message.
 150
 151 The following tables are available witin the HOLDPLACED message:
 152
 153     branches
 154     borrowers
 155     biblio
 156     biblioitems
 157     items
 158     reserves
 159
 160 =cut
 161
 162 sub AddReserve {
 163     my (
 164         $branch,   $borrowernumber, $biblionumber, $bibitems,
 165         $priority, $resdate,        $expdate,      $notes,
 166         $title,    $checkitem,      $found,        $itemtype
 167     ) = @_;
 168
 169     $resdate = output_pref( { str => dt_from_string( $resdate ), dateonly => 1, dateformat => 'iso' })
 170         or output_pref({ dt => dt_from_string, dateonly => 1, dateformat => 'iso' });
 171
 172     $expdate = output_pref({ str => $expdate, dateonly => 1, dateformat => 'iso' });
 173
 174     if ( C4::Context->preference('AllowHoldDateInFuture') ) {
 175
 176         # Make room in reserves for this before those of a later reserve date
 177         $priority = _ShiftPriorityByDateAndPriority( $biblionumber, $resdate, $priority );
 178     }
 179
 180     my $waitingdate;
 181
 182     # If the reserv had the waiting status, we had the value of the resdate
 183     if ( $found eq 'W' ) {
 184         $waitingdate = $resdate;
 185     }
 186
 187     # Don't add itemtype limit if specific item is selected
 188     $itemtype = undef if $checkitem;
 189
 190     # updates take place here
 191     my $hold = Koha::Hold->new(
 192         {
 193             borrowernumber => $borrowernumber,
 194             biblionumber   => $biblionumber,
 195             reservedate    => $resdate,
 196             branchcode     => $branch,
 197             priority       => $priority,
 198             reservenotes   => $notes,
 199             itemnumber     => $checkitem,
 200             found          => $found,
 201             waitingdate    => $waitingdate,
 202             expirationdate => $expdate,
 203             itemtype       => $itemtype,
 204         }
 205     )->store();
 206
 207     logaction( 'HOLDS', 'CREATE', $hold->id, Dumper($hold->unblessed) )
 208         if C4::Context->preference('HoldsLog');
 209
 210     my $reserve_id = $hold->id();
 211
 212     # add a reserve fee if needed
 213     if ( C4::Context->preference('HoldFeeMode') ne 'any_time_is_collected' ) {
 214         my $reserve_fee = GetReserveFee( $borrowernumber, $biblionumber );
 215         ChargeReserveFee( $borrowernumber, $reserve_fee, $title );
 216     }
 217
 218     _FixPriority({ biblionumber => $biblionumber});
 219
 220     # Send e-mail to librarian if syspref is active
 221     if(C4::Context->preference("emailLibrarianWhenHoldIsPlaced")){
 222         my $patron = Koha::Patrons->find( $borrowernumber );
 223         my $library = $patron->library;
 224         if ( my $letter =  C4::Letters::GetPreparedLetter (
 225             module => 'reserves',
 226             letter_code => 'HOLDPLACED',
 227             branchcode => $branch,
 228             lang => $patron->lang,
 229             tables => {
 230                 'branches'    => $library->unblessed,
 231                 'borrowers'   => $patron->unblessed,
 232                 'biblio'      => $biblionumber,
 233                 'biblioitems' => $biblionumber,
 234                 'items'       => $checkitem,
 235                 'reserves'    => $hold->unblessed,
 236             },
 237         ) ) {
 238
 239             my $admin_email_address = $library->branchemail || C4::Context->preference('KohaAdminEmailAddress');
 240
 241             C4::Letters::EnqueueLetter(
 242                 {   letter                 => $letter,
 243                     borrowernumber         => $borrowernumber,
 244                     message_transport_type => 'email',
 245                     from_address           => $admin_email_address,
 246                     to_address           => $admin_email_address,
 247                 }
 248             );
 249         }
 250     }
 251
 252     return $reserve_id;
 253 }
 254
 255 =head2 CanBookBeReserved
 256
 257   $canReserve = &CanBookBeReserved($borrowernumber, $biblionumber)
 258   if ($canReserve eq 'OK') { #We can reserve this Item! }
 259
 260 See CanItemBeReserved() for possible return values.
 261
 262 =cut
 263
 264 sub CanBookBeReserved{
 265     my ($borrowernumber, $biblionumber) = @_;
 266
 267     my $items = GetItemnumbersForBiblio($biblionumber);
 268     #get items linked via host records
 269     my @hostitems = get_hostitemnumbers_of($biblionumber);
 270     if (@hostitems){
 271     push (@$items,@hostitems);
 272     }
 273
 274     my $canReserve;
 275     foreach my $item (@$items) {
 276         $canReserve = CanItemBeReserved( $borrowernumber, $item );
 277         return 'OK' if $canReserve eq 'OK';
 278     }
 279     return $canReserve;
 280 }
 281
 282 =head2 CanItemBeReserved
 283
 284   $canReserve = &CanItemBeReserved($borrowernumber, $itemnumber)
 285   if ($canReserve eq 'OK') { #We can reserve this Item! }
 286
 287 @RETURNS OK,              if the Item can be reserved.
 288          ageRestricted,   if the Item is age restricted for this borrower.
 289          damaged,         if the Item is damaged.
 290          cannotReserveFromOtherBranches, if syspref 'canreservefromotherbranches' is OK.
 291          tooManyReserves, if the borrower has exceeded his maximum reserve amount.
 292          notReservable,   if holds on this item are not allowed
 293
 294 =cut
 295
 296 sub CanItemBeReserved {
 297     my ( $borrowernumber, $itemnumber ) = @_;
 298
 299     my $dbh = C4::Context->dbh;
 300     my $ruleitemtype;    # itemtype of the matching issuing rule
 301     my $allowedreserves  = 0; # Total number of holds allowed across all records
 302     my $holds_per_record = 1; # Total number of holds allowed for this one given record
 303
 304     # we retrieve borrowers and items informations #
 305     # item->{itype} will come for biblioitems if necessery
 306     my $item       = GetItem($itemnumber);
 307     my $biblio     = Koha::Biblios->find( $item->{biblionumber} );
 308     my $patron = Koha::Patrons->find( $borrowernumber );
 309     my $borrower = $patron->unblessed;
 310
 311     # If an item is damaged and we don't allow holds on damaged items, we can stop right here
 312     return 'damaged'
 313       if ( $item->{damaged}
 314         && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 315
 316     # Check for the age restriction
 317     my ( $ageRestriction, $daysToAgeRestriction ) =
 318       C4::Circulation::GetAgeRestriction( $biblio->biblioitem->agerestriction, $borrower );
 319     return 'ageRestricted' if $daysToAgeRestriction && $daysToAgeRestriction > 0;
 320
 321     # Check that the patron doesn't have an item level hold on this item already
 322     return 'itemAlreadyOnHold'
 323       if Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->count();
 324
 325     my $controlbranch = C4::Context->preference('ReservesControlBranch');
 326
 327     my $querycount = q{
 328         SELECT count(*) AS count
 329           FROM reserves
 330      LEFT JOIN items USING (itemnumber)
 331      LEFT JOIN biblioitems ON (reserves.biblionumber=biblioitems.biblionumber)
 332      LEFT JOIN borrowers USING (borrowernumber)
 333          WHERE borrowernumber = ?
 334     };
 335
 336     my $branchcode  = "";
 337     my $branchfield = "reserves.branchcode";
 338
 339     if ( $controlbranch eq "ItemHomeLibrary" ) {
 340         $branchfield = "items.homebranch";
 341         $branchcode  = $item->{homebranch};
 342     }
 343     elsif ( $controlbranch eq "PatronLibrary" ) {
 344         $branchfield = "borrowers.branchcode";
 345         $branchcode  = $borrower->{branchcode};
 346     }
 347
 348     # we retrieve rights
 349     if ( my $rights = GetHoldRule( $borrower->{'categorycode'}, $item->{'itype'}, $branchcode ) ) {
 350         $ruleitemtype     = $rights->{itemtype};
 351         $allowedreserves  = $rights->{reservesallowed};
 352         $holds_per_record = $rights->{holds_per_record};
 353     }
 354     else {
 355         $ruleitemtype = '*';
 356     }
 357
 358     $item = Koha::Items->find( $itemnumber );
 359     my $holds = Koha::Holds->search(
 360         {
 361             borrowernumber => $borrowernumber,
 362             biblionumber   => $item->biblionumber,
 363             found          => undef, # Found holds don't count against a patron's holds limit
 364         }
 365     );
 366     if ( $holds->count() >= $holds_per_record ) {
 367         return "tooManyHoldsForThisRecord";
 368     }
 369
 370     # we retrieve count
 371
 372     $querycount .= "AND $branchfield = ?";
 373
 374     # If using item-level itypes, fall back to the record
 375     # level itemtype if the hold has no associated item
 376     $querycount .=
 377       C4::Context->preference('item-level_itypes')
 378       ? " AND COALESCE( items.itype, biblioitems.itemtype ) = ?"
 379       : " AND biblioitems.itemtype = ?"
 380       if ( $ruleitemtype ne "*" );
 381
 382     my $sthcount = $dbh->prepare($querycount);
 383
 384     if ( $ruleitemtype eq "*" ) {
 385         $sthcount->execute( $borrowernumber, $branchcode );
 386     }
 387     else {
 388         $sthcount->execute( $borrowernumber, $branchcode, $ruleitemtype );
 389     }
 390
 391     my $reservecount = "0";
 392     if ( my $rowcount = $sthcount->fetchrow_hashref() ) {
 393         $reservecount = $rowcount->{count};
 394     }
 395
 396     # we check if it's ok or not
 397     if ( $reservecount >= $allowedreserves ) {
 398         return 'tooManyReserves';
 399     }
 400
 401     my $circ_control_branch =
 402       C4::Circulation::_GetCircControlBranch( $item->unblessed(), $borrower );
 403     my $branchitemrule =
 404       C4::Circulation::GetBranchItemRule( $circ_control_branch, $item->itype );
 405
 406     if ( $branchitemrule->{holdallowed} == 0 ) {
 407         return 'notReservable';
 408     }
 409
 410     if (   $branchitemrule->{holdallowed} == 1
 411         && $borrower->{branchcode} ne $item->homebranch )
 412     {
 413         return 'cannotReserveFromOtherBranches';
 414     }
 415
 416     # If reservecount is ok, we check item branch if IndependentBranches is ON
 417     # and canreservefromotherbranches is OFF
 418     if ( C4::Context->preference('IndependentBranches')
 419         and !C4::Context->preference('canreservefromotherbranches') )
 420     {
 421         my $itembranch = $item->homebranch;
 422         if ( $itembranch ne $borrower->{branchcode} ) {
 423             return 'cannotReserveFromOtherBranches';
 424         }
 425     }
 426
 427     return 'OK';
 428 }
 429
 430 =head2 CanReserveBeCanceledFromOpac
 431
 432     $number = CanReserveBeCanceledFromOpac($reserve_id, $borrowernumber);
 433
 434     returns 1 if reserve can be cancelled by user from OPAC.
 435     First check if reserve belongs to user, next checks if reserve is not in
 436     transfer or waiting status
 437
 438 =cut
 439
 440 sub CanReserveBeCanceledFromOpac {
 441     my ($reserve_id, $borrowernumber) = @_;
 442
 443     return unless $reserve_id and $borrowernumber;
 444     my $reserve = Koha::Holds->find($reserve_id);
 445
 446     return 0 unless $reserve->borrowernumber == $borrowernumber;
 447     return 0 if ( $reserve->found eq 'W' ) or ( $reserve->found eq 'T' );
 448
 449     return 1;
 450
 451 }
 452
 453 =head2 GetOtherReserves
 454
 455   ($messages,$nextreservinfo)=$GetOtherReserves(itemnumber);
 456
 457 Check queued list of this document and check if this document must be transferred
 458
 459 =cut
 460
 461 sub GetOtherReserves {
 462     my ($itemnumber) = @_;
 463     my $messages;
 464     my $nextreservinfo;
 465     my ( undef, $checkreserves, undef ) = CheckReserves($itemnumber);
 466     if ($checkreserves) {
 467         my $iteminfo = GetItem($itemnumber);
 468         if ( $iteminfo->{'holdingbranch'} ne $checkreserves->{'branchcode'} ) {
 469             $messages->{'transfert'} = $checkreserves->{'branchcode'};
 470             #minus priorities of others reservs
 471             ModReserveMinusPriority(
 472                 $itemnumber,
 473                 $checkreserves->{'reserve_id'},
 474             );
 475
 476             #launch the subroutine dotransfer
 477             C4::Items::ModItemTransfer(
 478                 $itemnumber,
 479                 $iteminfo->{'holdingbranch'},
 480                 $checkreserves->{'branchcode'}
 481               ),
 482               ;
 483         }
 484
 485      #step 2b : case of a reservation on the same branch, set the waiting status
 486         else {
 487             $messages->{'waiting'} = 1;
 488             ModReserveMinusPriority(
 489                 $itemnumber,
 490                 $checkreserves->{'reserve_id'},
 491             );
 492             ModReserveStatus($itemnumber,'W');
 493         }
 494
 495         $nextreservinfo = $checkreserves->{'borrowernumber'};
 496     }
 497
 498     return ( $messages, $nextreservinfo );
 499 }
 500
 501 =head2 ChargeReserveFee
 502
 503     $fee = ChargeReserveFee( $borrowernumber, $fee, $title );
 504
 505     Charge the fee for a reserve (if $fee > 0)
 506
 507 =cut
 508
 509 sub ChargeReserveFee {
 510     my ( $borrowernumber, $fee, $title ) = @_;
 511     return if !$fee || $fee==0; # the last test is needed to include 0.00
 512     my $accquery = qq{
 513 INSERT INTO accountlines ( borrowernumber, accountno, date, amount, description, accounttype, amountoutstanding ) VALUES (?, ?, NOW(), ?, ?, 'Res', ?)
 514     };
 515     my $dbh = C4::Context->dbh;
 516     my $nextacctno = &getnextacctno( $borrowernumber );
 517     $dbh->do( $accquery, undef, ( $borrowernumber, $nextacctno, $fee, "Reserve Charge - $title", $fee ) );
 518 }
 519
 520 =head2 GetReserveFee
 521
 522     $fee = GetReserveFee( $borrowernumber, $biblionumber );
 523
 524     Calculate the fee for a reserve (if applicable).
 525
 526 =cut
 527
 528 sub GetReserveFee {
 529     my ( $borrowernumber, $biblionumber ) = @_;
 530     my $borquery = qq{
 531 SELECT reservefee FROM borrowers LEFT JOIN categories ON borrowers.categorycode = categories.categorycode WHERE borrowernumber = ?
 532     };
 533     my $issue_qry = qq{
 534 SELECT COUNT(*) FROM items
 535 LEFT JOIN issues USING (itemnumber)
 536 WHERE items.biblionumber=? AND issues.issue_id IS NULL
 537     };
 538     my $holds_qry = qq{
 539 SELECT COUNT(*) FROM reserves WHERE biblionumber=? AND borrowernumber<>?
 540     };
 541
 542     my $dbh = C4::Context->dbh;
 543     my ( $fee ) = $dbh->selectrow_array( $borquery, undef, ($borrowernumber) );
 544     my $hold_fee_mode = C4::Context->preference('HoldFeeMode') || 'not_always';
 545     if( $fee and $fee > 0 and $hold_fee_mode eq 'not_always' ) {
 546         # This is a reconstruction of the old code:
 547         # Compare number of items with items issued, and optionally check holds
 548         # If not all items are issued and there are no holds: charge no fee
 549         # NOTE: Lost, damaged, not-for-loan, etc. are just ignored here
 550         my ( $notissued, $reserved );
 551         ( $notissued ) = $dbh->selectrow_array( $issue_qry, undef,
 552             ( $biblionumber ) );
 553         if( $notissued ) {
 554             ( $reserved ) = $dbh->selectrow_array( $holds_qry, undef,
 555                 ( $biblionumber, $borrowernumber ) );
 556             $fee = 0 if $reserved == 0;
 557         }
 558     }
 559     return $fee;
 560 }
 561
 562 =head2 GetReserveStatus
 563
 564   $reservestatus = GetReserveStatus($itemnumber);
 565
 566 Takes an itemnumber and returns the status of the reserve placed on it.
 567 If several reserves exist, the reserve with the lower priority is given.
 568
 569 =cut
 570
 571 ## FIXME: I don't think this does what it thinks it does.
 572 ## It only ever checks the first reserve result, even though
 573 ## multiple reserves for that bib can have the itemnumber set
 574 ## the sub is only used once in the codebase.
 575 sub GetReserveStatus {
 576     my ($itemnumber) = @_;
 577
 578     my $dbh = C4::Context->dbh;
 579
 580     my ($sth, $found, $priority);
 581     if ( $itemnumber ) {
 582         $sth = $dbh->prepare("SELECT found, priority FROM reserves WHERE itemnumber = ? order by priority LIMIT 1");
 583         $sth->execute($itemnumber);
 584         ($found, $priority) = $sth->fetchrow_array;
 585     }
 586
 587     if(defined $found) {
 588         return 'Waiting'  if $found eq 'W' and $priority == 0;
 589         return 'Finished' if $found eq 'F';
 590     }
 591
 592     return 'Reserved' if $priority > 0;
 593
 594     return ''; # empty string here will remove need for checking undef, or less log lines
 595 }
 596
 597 =head2 CheckReserves
 598
 599   ($status, $reserve, $all_reserves) = &CheckReserves($itemnumber);
 600   ($status, $reserve, $all_reserves) = &CheckReserves(undef, $barcode);
 601   ($status, $reserve, $all_reserves) = &CheckReserves($itemnumber,undef,$lookahead);
 602
 603 Find a book in the reserves.
 604
 605 C<$itemnumber> is the book's item number.
 606 C<$lookahead> is the number of days to look in advance for future reserves.
 607
 608 As I understand it, C<&CheckReserves> looks for the given item in the
 609 reserves. If it is found, that's a match, and C<$status> is set to
 610 C<Waiting>.
 611
 612 Otherwise, it finds the most important item in the reserves with the
 613 same biblio number as this book (I'm not clear on this) and returns it
 614 with C<$status> set to C<Reserved>.
 615
 616 C<&CheckReserves> returns a two-element list:
 617
 618 C<$status> is either C<Waiting>, C<Reserved> (see above), or 0.
 619
 620 C<$reserve> is the reserve item that matched. It is a
 621 reference-to-hash whose keys are mostly the fields of the reserves
 622 table in the Koha database.
 623
 624 =cut
 625
 626 sub CheckReserves {
 627     my ( $item, $barcode, $lookahead_days, $ignore_borrowers) = @_;
 628     my $dbh = C4::Context->dbh;
 629     my $sth;
 630     my $select;
 631     if (C4::Context->preference('item-level_itypes')){
 632         $select = "
 633            SELECT items.biblionumber,
 634            items.biblioitemnumber,
 635            itemtypes.notforloan,
 636            items.notforloan AS itemnotforloan,
 637            items.itemnumber,
 638            items.damaged,
 639            items.homebranch,
 640            items.holdingbranch
 641            FROM   items
 642            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 643            LEFT JOIN itemtypes   ON items.itype   = itemtypes.itemtype
 644         ";
 645     }
 646     else {
 647         $select = "
 648            SELECT items.biblionumber,
 649            items.biblioitemnumber,
 650            itemtypes.notforloan,
 651            items.notforloan AS itemnotforloan,
 652            items.itemnumber,
 653            items.damaged,
 654            items.homebranch,
 655            items.holdingbranch
 656            FROM   items
 657            LEFT JOIN biblioitems ON items.biblioitemnumber = biblioitems.biblioitemnumber
 658            LEFT JOIN itemtypes   ON biblioitems.itemtype   = itemtypes.itemtype
 659         ";
 660     }
 661
 662     if ($item) {
 663         $sth = $dbh->prepare("$select WHERE itemnumber = ?");
 664         $sth->execute($item);
 665     }
 666     else {
 667         $sth = $dbh->prepare("$select WHERE barcode = ?");
 668         $sth->execute($barcode);
 669     }
 670     # note: we get the itemnumber because we might have started w/ just the barcode.  Now we know for sure we have it.
 671     my ( $biblio, $bibitem, $notforloan_per_itemtype, $notforloan_per_item, $itemnumber, $damaged, $item_homebranch, $item_holdingbranch ) = $sth->fetchrow_array;
 672
 673     return if ( $damaged && !C4::Context->preference('AllowHoldsOnDamagedItems') );
 674
 675     return unless $itemnumber; # bail if we got nothing.
 676
 677     # if item is not for loan it cannot be reserved either.....
 678     # except where items.notforloan < 0 :  This indicates the item is holdable.
 679     return if  ( $notforloan_per_item > 0 ) or $notforloan_per_itemtype;
 680
 681     # Find this item in the reserves
 682     my @reserves = _Findgroupreserve( $bibitem, $biblio, $itemnumber, $lookahead_days, $ignore_borrowers);
 683
 684     # $priority and $highest are used to find the most important item
 685     # in the list returned by &_Findgroupreserve. (The lower $priority,
 686     # the more important the item.)
 687     # $highest is the most important item we've seen so far.
 688     my $highest;
 689     if (scalar @reserves) {
 690         my $LocalHoldsPriority = C4::Context->preference('LocalHoldsPriority');
 691         my $LocalHoldsPriorityPatronControl = C4::Context->preference('LocalHoldsPriorityPatronControl');
 692         my $LocalHoldsPriorityItemControl = C4::Context->preference('LocalHoldsPriorityItemControl');
 693
 694         my $priority = 10000000;
 695         foreach my $res (@reserves) {
 696             if ( $res->{'itemnumber'} == $itemnumber && $res->{'priority'} == 0) {
 697                 if ($res->{'found'} eq 'W') {
 698                     return ( "Waiting", $res, \@reserves ); # Found it, it is waiting
 699                 } else {
 700                     return ( "Reserved", $res, \@reserves ); # Found determinated hold, e. g. the tranferred one
 701                 }
 702             } else {
 703                 my $patron;
 704                 my $iteminfo;
 705                 my $local_hold_match;
 706
 707                 if ($LocalHoldsPriority) {
 708                     $patron = Koha::Patrons->find( $res->{borrowernumber} );
 709                     $iteminfo = C4::Items::GetItem($itemnumber);
 710
 711                     my $local_holds_priority_item_branchcode =
 712                       $iteminfo->{$LocalHoldsPriorityItemControl};
 713                     my $local_holds_priority_patron_branchcode =
 714                       ( $LocalHoldsPriorityPatronControl eq 'PickupLibrary' )
 715                       ? $res->{branchcode}
 716                       : ( $LocalHoldsPriorityPatronControl eq 'HomeLibrary' )
 717                       ? $patron->branchcode
 718                       : undef;
 719                     $local_hold_match =
 720                       $local_holds_priority_item_branchcode eq
 721                       $local_holds_priority_patron_branchcode;
 722                 }
 723
 724                 # See if this item is more important than what we've got so far
 725                 if ( ( $res->{'priority'} && $res->{'priority'} < $priority ) || $local_hold_match ) {
 726                     $iteminfo ||= C4::Items::GetItem($itemnumber);
 727                     next if $res->{itemtype} && $res->{itemtype} ne _get_itype( $iteminfo );
 728                     $patron ||= Koha::Patrons->find( $res->{borrowernumber} );
 729                     my $branch = GetReservesControlBranch( $iteminfo, $patron->unblessed );
 730                     my $branchitemrule = C4::Circulation::GetBranchItemRule($branch,$iteminfo->{'itype'});
 731                     next if ($branchitemrule->{'holdallowed'} == 0);
 732                     next if (($branchitemrule->{'holdallowed'} == 1) && ($branch ne $patron->branchcode));
 733                     next if ( ($branchitemrule->{hold_fulfillment_policy} ne 'any') && ($res->{branchcode} ne $iteminfo->{ $branchitemrule->{hold_fulfillment_policy} }) );
 734                     $priority = $res->{'priority'};
 735                     $highest  = $res;
 736                     last if $local_hold_match;
 737                 }
 738             }
 739         }
 740     }
 741
 742     # If we get this far, then no exact match was found.
 743     # We return the most important (i.e. next) reservation.
 744     if ($highest) {
 745         $highest->{'itemnumber'} = $item;
 746         return ( "Reserved", $highest, \@reserves );
 747     }
 748
 749     return ( '' );
 750 }
 751
 752 =head2 CancelExpiredReserves
 753
 754   CancelExpiredReserves();
 755
 756 Cancels all reserves with an expiration date from before today.
 757
 758 =cut
 759
 760 sub CancelExpiredReserves {
 761     my $today = dt_from_string();
 762     my $cancel_on_holidays = C4::Context->preference('ExpireReservesOnHolidays');
 763     my $expireWaiting = C4::Context->preference('ExpireReservesMaxPickUpDelay');
 764
 765     my $dtf = Koha::Database->new->schema->storage->datetime_parser;
 766     my $params = { expirationdate => { '<', $dtf->format_date($today) } };
 767     $params->{found} = undef unless $expireWaiting;
 768
 769     # FIXME To move to Koha::Holds->search_expired (?)
 770     my $holds = Koha::Holds->search( $params );
 771
 772     while ( my $hold = $holds->next ) {
 773         my $calendar = Koha::Calendar->new( branchcode => $hold->branchcode );
 774
 775         next if !$cancel_on_holidays && $calendar->is_holiday( $today );
 776
 777         my $cancel_params = {};
 778         if ( $hold->found eq 'W' ) {
 779             $cancel_params->{charge_cancel_fee} = 1;
 780         }
 781         $hold->cancel( $cancel_params );
 782     }
 783 }
 784
 785 =head2 AutoUnsuspendReserves
 786
 787   AutoUnsuspendReserves();
 788
 789 Unsuspends all suspended reserves with a suspend_until date from before today.
 790
 791 =cut
 792
 793 sub AutoUnsuspendReserves {
 794     my $today = dt_from_string();
 795
 796     my @holds = Koha::Holds->search( { suspend_until => { '<' => $today->ymd() } } );
 797
 798     map { $_->suspend(0)->suspend_until(undef)->store() } @holds;
 799 }
 800
 801 =head2 ModReserve
 802
 803   ModReserve({ rank => $rank,
 804                reserve_id => $reserve_id,
 805                branchcode => $branchcode
 806                [, itemnumber => $itemnumber ]
 807                [, biblionumber => $biblionumber, $borrowernumber => $borrowernumber ]
 808               });
 809
 810 Change a hold request's priority or cancel it.
 811
 812 C<$rank> specifies the effect of the change.  If C<$rank>
 813 is 'W' or 'n', nothing happens.  This corresponds to leaving a
 814 request alone when changing its priority in the holds queue
 815 for a bib.
 816
 817 If C<$rank> is 'del', the hold request is cancelled.
 818
 819 If C<$rank> is an integer greater than zero, the priority of
 820 the request is set to that value.  Since priority != 0 means
 821 that the item is not waiting on the hold shelf, setting the
 822 priority to a non-zero value also sets the request's found
 823 status and waiting date to NULL.
 824
 825 The optional C<$itemnumber> parameter is used only when
 826 C<$rank> is a non-zero integer; if supplied, the itemnumber
 827 of the hold request is set accordingly; if omitted, the itemnumber
 828 is cleared.
 829
 830 B<FIXME:> Note that the forgoing can have the effect of causing
 831 item-level hold requests to turn into title-level requests.  This
 832 will be fixed once reserves has separate columns for requested
 833 itemnumber and supplying itemnumber.
 834
 835 =cut
 836
 837 sub ModReserve {
 838     my ( $params ) = @_;
 839
 840     my $rank = $params->{'rank'};
 841     my $reserve_id = $params->{'reserve_id'};
 842     my $branchcode = $params->{'branchcode'};
 843     my $itemnumber = $params->{'itemnumber'};
 844     my $suspend_until = $params->{'suspend_until'};
 845     my $borrowernumber = $params->{'borrowernumber'};
 846     my $biblionumber = $params->{'biblionumber'};
 847
 848     return if $rank eq "W";
 849     return if $rank eq "n";
 850
 851     return unless ( $reserve_id || ( $borrowernumber && ( $biblionumber || $itemnumber ) ) );
 852
 853     my $hold;
 854     unless ( $reserve_id ) {
 855         my $holds = Koha::Holds->search({ biblionumber => $biblionumber, borrowernumber => $borrowernumber, itemnumber => $itemnumber });
 856         return unless $holds->count; # FIXME Should raise an exception
 857         $hold = $holds->next;
 858         $reserve_id = $hold->reserve_id;
 859     }
 860
 861     $hold ||= Koha::Holds->find($reserve_id);
 862
 863     if ( $rank eq "del" ) {
 864         $hold->cancel;
 865     }
 866     elsif ($rank =~ /^\d+/ and $rank > 0) {
 867         logaction( 'HOLDS', 'MODIFY', $hold->reserve_id, Dumper($hold->unblessed) )
 868             if C4::Context->preference('HoldsLog');
 869
 870         $hold->set(
 871             {
 872                 priority    => $rank,
 873                 branchcode  => $branchcode,
 874                 itemnumber  => $itemnumber,
 875                 found       => undef,
 876                 waitingdate => undef
 877             }
 878         )->store();
 879
 880         if ( defined( $suspend_until ) ) {
 881             if ( $suspend_until ) {
 882                 $suspend_until = eval { dt_from_string( $suspend_until ) };
 883                 $hold->suspend_hold( $suspend_until );
 884             } else {
 885                 # If the hold is suspended leave the hold suspended, but convert it to an indefinite hold.
 886                 # If the hold is not suspended, this does nothing.
 887                 $hold->set( { suspend_until => undef } )->store();
 888             }
 889         }
 890
 891         _FixPriority({ reserve_id => $reserve_id, rank =>$rank });
 892     }
 893 }
 894
 895 =head2 ModReserveFill
 896
 897   &ModReserveFill($reserve);
 898
 899 Fill a reserve. If I understand this correctly, this means that the
 900 reserved book has been found and given to the patron who reserved it.
 901
 902 C<$reserve> specifies the reserve to fill. It is a reference-to-hash
 903 whose keys are fields from the reserves table in the Koha database.
 904
 905 =cut
 906
 907 sub ModReserveFill {
 908     my ($res) = @_;
 909     my $reserve_id = $res->{'reserve_id'};
 910
 911     my $hold = Koha::Holds->find($reserve_id);
 912
 913     # get the priority on this record....
 914     my $priority = $hold->priority;
 915
 916     # update the hold statuses, no need to store it though, we will be deleting it anyway
 917     $hold->set(
 918         {
 919             found    => 'F',
 920             priority => 0,
 921         }
 922     );
 923
 924     # FIXME Must call Koha::Hold->cancel ? => No, should call ->filled and add the correct log
 925     Koha::Old::Hold->new( $hold->unblessed() )->store();
 926
 927     $hold->delete();
 928
 929     if ( C4::Context->preference('HoldFeeMode') eq 'any_time_is_collected' ) {
 930         my $reserve_fee = GetReserveFee( $hold->borrowernumber, $hold->biblionumber );
 931         ChargeReserveFee( $hold->borrowernumber, $reserve_fee, $hold->biblio->title );
 932     }
 933
 934     # now fix the priority on the others (if the priority wasn't
 935     # already sorted!)....
 936     unless ( $priority == 0 ) {
 937         _FixPriority( { reserve_id => $reserve_id, biblionumber => $hold->biblionumber } );
 938     }
 939 }
 940
 941 =head2 ModReserveStatus
 942
 943   &ModReserveStatus($itemnumber, $newstatus);
 944
 945 Update the reserve status for the active (priority=0) reserve.
 946
 947 $itemnumber is the itemnumber the reserve is on
 948
 949 $newstatus is the new status.
 950
 951 =cut
 952
 953 sub ModReserveStatus {
 954
 955     #first : check if we have a reservation for this item .
 956     my ($itemnumber, $newstatus) = @_;
 957     my $dbh = C4::Context->dbh;
 958
 959     my $query = "UPDATE reserves SET found = ?, waitingdate = NOW() WHERE itemnumber = ? AND found IS NULL AND priority = 0";
 960     my $sth_set = $dbh->prepare($query);
 961     $sth_set->execute( $newstatus, $itemnumber );
 962
 963     if ( C4::Context->preference("ReturnToShelvingCart") && $newstatus ) {
 964       CartToShelf( $itemnumber );
 965     }
 966 }
 967
 968 =head2 ModReserveAffect
 969
 970   &ModReserveAffect($itemnumber,$borrowernumber,$diffBranchSend,$reserve_id);
 971
 972 This function affect an item and a status for a given reserve, either fetched directly
 973 by record_id, or by borrowernumber and itemnumber or biblionumber. If only biblionumber
 974 is given, only first reserve returned is affected, which is ok for anything but
 975 multi-item holds.
 976
 977 if $transferToDo is not set, then the status is set to "Waiting" as well.
 978 otherwise, a transfer is on the way, and the end of the transfer will
 979 take care of the waiting status
 980
 981 =cut
 982
 983 sub ModReserveAffect {
 984     my ( $itemnumber, $borrowernumber, $transferToDo, $reserve_id ) = @_;
 985     my $dbh = C4::Context->dbh;
 986
 987     # we want to attach $itemnumber to $borrowernumber, find the biblionumber
 988     # attached to $itemnumber
 989     my $sth = $dbh->prepare("SELECT biblionumber FROM items WHERE itemnumber=?");
 990     $sth->execute($itemnumber);
 991     my ($biblionumber) = $sth->fetchrow;
 992
 993     # get request - need to find out if item is already
 994     # waiting in order to not send duplicate hold filled notifications
 995
 996     my $hold;
 997     # Find hold by id if we have it
 998     $hold = Koha::Holds->find( $reserve_id ) if $reserve_id;
 999     # Find item level hold for this item if there is one
1000     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, itemnumber => $itemnumber } )->next();
1001     # Find record level hold if there is no item level hold
1002     $hold ||= Koha::Holds->search( { borrowernumber => $borrowernumber, biblionumber => $biblionumber } )->next();
1003
1004     return unless $hold;
1005
1006     my $already_on_shelf = $hold->found && $hold->found eq 'W';
1007
1008     $hold->itemnumber($itemnumber);
1009     $hold->set_waiting($transferToDo);
1010
1011     _koha_notify_reserve( $hold->reserve_id )
1012       if ( !$transferToDo && !$already_on_shelf );
1013
1014     _FixPriority( { biblionumber => $biblionumber } );
1015
1016     if ( C4::Context->preference("ReturnToShelvingCart") ) {
1017         CartToShelf($itemnumber);
1018     }
1019
1020     return;
1021 }
1022
1023 =head2 ModReserveCancelAll
1024
1025   ($messages,$nextreservinfo) = &ModReserveCancelAll($itemnumber,$borrowernumber);
1026
1027 function to cancel reserv,check other reserves, and transfer document if it's necessary
1028
1029 =cut
1030
1031 sub ModReserveCancelAll {
1032     my $messages;
1033     my $nextreservinfo;
1034     my ( $itemnumber, $borrowernumber ) = @_;
1035
1036     #step 1 : cancel the reservation
1037     my $holds = Koha::Holds->search({ itemnumber => $itemnumber, borrowernumber => $borrowernumber });
1038     return unless $holds->count;
1039     $holds->next->cancel;
1040
1041     #step 2 launch the subroutine of the others reserves
1042     ( $messages, $nextreservinfo ) = GetOtherReserves($itemnumber);
1043
1044     return ( $messages, $nextreservinfo );
1045 }
1046
1047 =head2 ModReserveMinusPriority
1048
1049   &ModReserveMinusPriority($itemnumber,$borrowernumber,$biblionumber)
1050
1051 Reduce the values of queued list
1052
1053 =cut
1054
1055 sub ModReserveMinusPriority {
1056     my ( $itemnumber, $reserve_id ) = @_;
1057
1058     #first step update the value of the first person on reserv
1059     my $dbh   = C4::Context->dbh;
1060     my $query = "
1061         UPDATE reserves
1062         SET    priority = 0 , itemnumber = ?
1063         WHERE  reserve_id = ?
1064     ";
1065     my $sth_upd = $dbh->prepare($query);
1066     $sth_upd->execute( $itemnumber, $reserve_id );
1067     # second step update all others reserves
1068     _FixPriority({ reserve_id => $reserve_id, rank => '0' });
1069 }
1070
1071 =head2 IsAvailableForItemLevelRequest
1072
1073   my $is_available = IsAvailableForItemLevelRequest($item_record,$borrower_record);
1074
1075 Checks whether a given item record is available for an
1076 item-level hold request.  An item is available if
1077
1078 * it is not lost AND
1079 * it is not damaged AND
1080 * it is not withdrawn AND
1081 * a waiting or in transit reserve is placed on
1082 * does not have a not for loan value > 0
1083
1084 Need to check the issuingrules onshelfholds column,
1085 if this is set items on the shelf can be placed on hold
1086
1087 Note that IsAvailableForItemLevelRequest() does not
1088 check if the staff operator is authorized to place
1089 a request on the item - in particular,
1090 this routine does not check IndependentBranches
1091 and canreservefromotherbranches.
1092
1093 =cut
1094
1095 sub IsAvailableForItemLevelRequest {
1096     my $item = shift;
1097     my $borrower = shift;
1098
1099     my $dbh = C4::Context->dbh;
1100     # must check the notforloan setting of the itemtype
1101     # FIXME - a lot of places in the code do this
1102     #         or something similar - need to be
1103     #         consolidated
1104     my $patron = Koha::Patrons->find( $borrower->{borrowernumber} );
1105     my $item_object = Koha::Items->find( $item->{itemnumber } );
1106     my $itemtype = $item_object->effective_itemtype;
1107     my $notforloan_per_itemtype
1108       = $dbh->selectrow_array("SELECT notforloan FROM itemtypes WHERE itemtype = ?",
1109                               undef, $itemtype);
1110
1111     return 0 if
1112         $notforloan_per_itemtype ||
1113         $item->{itemlost}        ||
1114         $item->{notforloan} > 0  ||
1115         $item->{withdrawn}        ||
1116         ($item->{damaged} && !C4::Context->preference('AllowHoldsOnDamagedItems'));
1117
1118     my $on_shelf_holds = Koha::IssuingRules->get_onshelfholds_policy( { item => $item_object, patron => $patron } );
1119
1120     if ( $on_shelf_holds == 1 ) {
1121         return 1;
1122     } elsif ( $on_shelf_holds == 2 ) {
1123         my @items =
1124           Koha::Items->search( { biblionumber => $item->{biblionumber} } );
1125
1126         my $any_available = 0;
1127
1128         foreach my $i (@items) {
1129
1130             my $circ_control_branch = C4::Circulation::_GetCircControlBranch( $i->unblessed(), $borrower );
1131             my $branchitemrule = C4::Circulation::GetBranchItemRule( $circ_control_branch, $i->itype );
1132
1133             $any_available = 1
1134               unless $i->itemlost
1135               || $i->notforloan > 0
1136               || $i->withdrawn
1137               || $i->onloan
1138               || IsItemOnHoldAndFound( $i->id )
1139               || ( $i->damaged
1140                 && !C4::Context->preference('AllowHoldsOnDamagedItems') )
1141               || Koha::ItemTypes->find( $i->effective_itemtype() )->notforloan
1142               || $branchitemrule->{holdallowed} == 1 && $borrower->{branchcode} ne $i->homebranch;
1143         }
1144
1145         return $any_available ? 0 : 1;
1146     } else { # on_shelf_holds == 0 "If any unavailable" (the description is rather cryptic and could still be improved)
1147         return $item->{onloan} || IsItemOnHoldAndFound( $item->{itemnumber} );
1148     }
1149 }
1150
1151 sub _get_itype {
1152     my $item = shift;
1153
1154     my $itype;
1155     if (C4::Context->preference('item-level_itypes')) {
1156         # We can't trust GetItem to honour the syspref, so safest to do it ourselves
1157         # When GetItem is fixed, we can remove this
1158         $itype = $item->{itype};
1159     }
1160     else {
1161         # XXX This is a bit dodgy. It relies on biblio itemtype column having different name.
1162         # So if we already have a biblioitems join when calling this function,
1163         # we don't need to access the database again
1164         $itype = $item->{itemtype};
1165     }
1166     unless ($itype) {
1167         my $dbh = C4::Context->dbh;
1168         my $query = "SELECT itemtype FROM biblioitems WHERE biblioitemnumber = ? ";
1169         my $sth = $dbh->prepare($query);
1170         $sth->execute($item->{biblioitemnumber});
1171         if (my $data = $sth->fetchrow_hashref()){
1172             $itype = $data->{itemtype};
1173         }
1174     }
1175     return $itype;
1176 }
1177
1178 =head2 AlterPriority
1179
1180   AlterPriority( $where, $reserve_id );
1181
1182 This function changes a reserve's priority up, down, to the top, or to the bottom.
1183 Input: $where is 'up', 'down', 'top' or 'bottom'. Biblionumber, Date reserve was placed
1184
1185 =cut
1186
1187 sub AlterPriority {
1188     my ( $where, $reserve_id ) = @_;
1189
1190     my $hold = Koha::Holds->find( $reserve_id );
1191     return unless $hold;
1192
1193     if ( $hold->cancellationdate ) {
1194         warn "I cannot alter the priority for reserve_id $reserve_id, the reserve has been cancelled (" . $hold->cancellationdate . ')';
1195         return;
1196     }
1197
1198     if ( $where eq 'up' || $where eq 'down' ) {
1199
1200       my $priority = $hold->priority;
1201       $priority = $where eq 'up' ? $priority - 1 : $priority + 1;
1202       _FixPriority({ reserve_id => $reserve_id, rank => $priority })
1203
1204     } elsif ( $where eq 'top' ) {
1205
1206       _FixPriority({ reserve_id => $reserve_id, rank => '1' })
1207
1208     } elsif ( $where eq 'bottom' ) {
1209
1210       _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1211
1212     }
1213     # FIXME Should return the new priority
1214 }
1215
1216 =head2 ToggleLowestPriority
1217
1218   ToggleLowestPriority( $borrowernumber, $biblionumber );
1219
1220 This function sets the lowestPriority field to true if is false, and false if it is true.
1221
1222 =cut
1223
1224 sub ToggleLowestPriority {
1225     my ( $reserve_id ) = @_;
1226
1227     my $dbh = C4::Context->dbh;
1228
1229     my $sth = $dbh->prepare( "UPDATE reserves SET lowestPriority = NOT lowestPriority WHERE reserve_id = ?");
1230     $sth->execute( $reserve_id );
1231
1232     _FixPriority({ reserve_id => $reserve_id, rank => '999999' });
1233 }
1234
1235 =head2 ToggleSuspend
1236
1237   ToggleSuspend( $reserve_id );
1238
1239 This function sets the suspend field to true if is false, and false if it is true.
1240 If the reserve is currently suspended with a suspend_until date, that date will
1241 be cleared when it is unsuspended.
1242
1243 =cut
1244
1245 sub ToggleSuspend {
1246     my ( $reserve_id, $suspend_until ) = @_;
1247
1248     $suspend_until = dt_from_string($suspend_until) if ($suspend_until);
1249
1250     my $hold = Koha::Holds->find( $reserve_id );
1251
1252     if ( $hold->is_suspended ) {
1253         $hold->resume()
1254     } else {
1255         $hold->suspend_hold( $suspend_until );
1256     }
1257 }
1258
1259 =head2 SuspendAll
1260
1261   SuspendAll(
1262       borrowernumber   => $borrowernumber,
1263       [ biblionumber   => $biblionumber, ]
1264       [ suspend_until  => $suspend_until, ]
1265       [ suspend        => $suspend ]
1266   );
1267
1268   This function accepts a set of hash keys as its parameters.
1269   It requires either borrowernumber or biblionumber, or both.
1270
1271   suspend_until is wholly optional.
1272
1273 =cut
1274
1275 sub SuspendAll {
1276     my %params = @_;
1277
1278     my $borrowernumber = $params{'borrowernumber'} || undef;
1279     my $biblionumber   = $params{'biblionumber'}   || undef;
1280     my $suspend_until  = $params{'suspend_until'}  || undef;
1281     my $suspend = defined( $params{'suspend'} ) ? $params{'suspend'} : 1;
1282
1283     $suspend_until = eval { dt_from_string($suspend_until) }
1284       if ( defined($suspend_until) );
1285
1286     return unless ( $borrowernumber || $biblionumber );
1287
1288     my $params;
1289     $params->{found}          = undef;
1290     $params->{borrowernumber} = $borrowernumber if $borrowernumber;
1291     $params->{biblionumber}   = $biblionumber if $biblionumber;
1292
1293     my @holds = Koha::Holds->search($params);
1294
1295     if ($suspend) {
1296         map { $_->suspend_hold($suspend_until) } @holds;
1297     }
1298     else {
1299         map { $_->resume() } @holds;
1300     }
1301 }
1302
1303
1304 =head2 _FixPriority
1305
1306   _FixPriority({
1307     reserve_id => $reserve_id,
1308     [rank => $rank,]
1309     [ignoreSetLowestRank => $ignoreSetLowestRank]
1310   });
1311
1312   or
1313
1314   _FixPriority({ biblionumber => $biblionumber});
1315
1316 This routine adjusts the priority of a hold request and holds
1317 on the same bib.
1318
1319 In the first form, where a reserve_id is passed, the priority of the
1320 hold is set to supplied rank, and other holds for that bib are adjusted
1321 accordingly.  If the rank is "del", the hold is cancelled.  If no rank
1322 is supplied, all of the holds on that bib have their priority adjusted
1323 as if the second form had been used.
1324
1325 In the second form, where a biblionumber is passed, the holds on that
1326 bib (that are not captured) are sorted in order of increasing priority,
1327 then have reserves.priority set so that the first non-captured hold
1328 has its priority set to 1, the second non-captured hold has its priority
1329 set to 2, and so forth.
1330
1331 In both cases, holds that have the lowestPriority flag on are have their
1332 priority adjusted to ensure that they remain at the end of the line.
1333
1334 Note that the ignoreSetLowestRank parameter is meant to be used only
1335 when _FixPriority calls itself.
1336
1337 =cut
1338
1339 sub _FixPriority {
1340     my ( $params ) = @_;
1341     my $reserve_id = $params->{reserve_id};
1342     my $rank = $params->{rank} // '';
1343     my $ignoreSetLowestRank = $params->{ignoreSetLowestRank};
1344     my $biblionumber = $params->{biblionumber};
1345
1346     my $dbh = C4::Context->dbh;
1347
1348     my $hold;
1349     if ( $reserve_id ) {
1350         $hold = Koha::Holds->find( $reserve_id );
1351         return unless $hold;
1352     }
1353
1354     unless ( $biblionumber ) { # FIXME This is a very weird API
1355         $biblionumber = $hold->biblionumber;
1356     }
1357
1358     if ( $rank eq "del" ) { # FIXME will crash if called without $hold
1359         $hold->cancel;
1360     }
1361     elsif ( $rank eq "W" || $rank eq "0" ) {
1362
1363         # make sure priority for waiting or in-transit items is 0
1364         my $query = "
1365             UPDATE reserves
1366             SET    priority = 0
1367             WHERE reserve_id = ?
1368             AND found IN ('W', 'T')
1369         ";
1370         my $sth = $dbh->prepare($query);
1371         $sth->execute( $reserve_id );
1372     }
1373     my @priority;
1374
1375     # get whats left
1376     my $query = "
1377         SELECT reserve_id, borrowernumber, reservedate
1378         FROM   reserves
1379         WHERE  biblionumber   = ?
1380           AND  ((found <> 'W' AND found <> 'T') OR found IS NULL)
1381         ORDER BY priority ASC
1382     ";
1383     my $sth = $dbh->prepare($query);
1384     $sth->execute( $biblionumber );
1385     while ( my $line = $sth->fetchrow_hashref ) {
1386         push( @priority,     $line );
1387     }
1388
1389     # To find the matching index
1390     my $i;
1391     my $key = -1;    # to allow for 0 to be a valid result
1392     for ( $i = 0 ; $i < @priority ; $i++ ) {
1393         if ( $reserve_id == $priority[$i]->{'reserve_id'} ) {
1394             $key = $i;    # save the index
1395             last;
1396         }
1397     }
1398
1399     # if index exists in array then move it to new position
1400     if ( $key > -1 && $rank ne 'del' && $rank > 0 ) {
1401         my $new_rank = $rank -
1402           1;    # $new_rank is what you want the new index to be in the array
1403         my $moving_item = splice( @priority, $key, 1 );
1404         splice( @priority, $new_rank, 0, $moving_item );
1405     }
1406
1407     # now fix the priority on those that are left....
1408     $query = "
1409         UPDATE reserves
1410         SET    priority = ?
1411         WHERE  reserve_id = ?
1412     ";
1413     $sth = $dbh->prepare($query);
1414     for ( my $j = 0 ; $j < @priority ; $j++ ) {
1415         $sth->execute(
1416             $j + 1,
1417             $priority[$j]->{'reserve_id'}
1418         );
1419     }
1420
1421     $sth = $dbh->prepare( "SELECT reserve_id FROM reserves WHERE lowestPriority = 1 ORDER BY priority" );
1422     $sth->execute();
1423
1424     unless ( $ignoreSetLowestRank ) {
1425       while ( my $res = $sth->fetchrow_hashref() ) {
1426         _FixPriority({
1427             reserve_id => $res->{'reserve_id'},
1428             rank => '999999',
1429             ignoreSetLowestRank => 1
1430         });
1431       }
1432     }
1433 }
1434
1435 =head2 _Findgroupreserve
1436
1437   @results = &_Findgroupreserve($biblioitemnumber, $biblionumber, $itemnumber, $lookahead, $ignore_borrowers);
1438
1439 Looks for a holds-queue based item-specific match first, then for a holds-queue title-level match, returning the
1440 first match found.  If neither, then we look for non-holds-queue based holds.
1441 Lookahead is the number of days to look in advance.
1442
1443 C<&_Findgroupreserve> returns :
1444 C<@results> is an array of references-to-hash whose keys are mostly
1445 fields from the reserves table of the Koha database, plus
1446 C<biblioitemnumber>.
1447
1448 =cut
1449
1450 sub _Findgroupreserve {
1451     my ( $bibitem, $biblio, $itemnumber, $lookahead, $ignore_borrowers) = @_;
1452     my $dbh   = C4::Context->dbh;
1453
1454     # TODO: consolidate at least the SELECT portion of the first 2 queries to a common $select var.
1455     # check for exact targeted match
1456     my $item_level_target_query = qq{
1457         SELECT reserves.biblionumber        AS biblionumber,
1458                reserves.borrowernumber      AS borrowernumber,
1459                reserves.reservedate         AS reservedate,
1460                reserves.branchcode          AS branchcode,
1461                reserves.cancellationdate    AS cancellationdate,
1462                reserves.found               AS found,
1463                reserves.reservenotes        AS reservenotes,
1464                reserves.priority            AS priority,
1465                reserves.timestamp           AS timestamp,
1466                biblioitems.biblioitemnumber AS biblioitemnumber,
1467                reserves.itemnumber          AS itemnumber,
1468                reserves.reserve_id          AS reserve_id,
1469                reserves.itemtype            AS itemtype
1470         FROM reserves
1471         JOIN biblioitems USING (biblionumber)
1472         JOIN hold_fill_targets USING (biblionumber, borrowernumber, itemnumber)
1473         WHERE found IS NULL
1474         AND priority > 0
1475         AND item_level_request = 1
1476         AND itemnumber = ?
1477         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1478         AND suspend = 0
1479         ORDER BY priority
1480     };
1481     my $sth = $dbh->prepare($item_level_target_query);
1482     $sth->execute($itemnumber, $lookahead||0);
1483     my @results;
1484     if ( my $data = $sth->fetchrow_hashref ) {
1485         push( @results, $data )
1486           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1487     }
1488     return @results if @results;
1489
1490     # check for title-level targeted match
1491     my $title_level_target_query = qq{
1492         SELECT reserves.biblionumber        AS biblionumber,
1493                reserves.borrowernumber      AS borrowernumber,
1494                reserves.reservedate         AS reservedate,
1495                reserves.branchcode          AS branchcode,
1496                reserves.cancellationdate    AS cancellationdate,
1497                reserves.found               AS found,
1498                reserves.reservenotes        AS reservenotes,
1499                reserves.priority            AS priority,
1500                reserves.timestamp           AS timestamp,
1501                biblioitems.biblioitemnumber AS biblioitemnumber,
1502                reserves.itemnumber          AS itemnumber,
1503                reserves.reserve_id          AS reserve_id,
1504                reserves.itemtype            AS itemtype
1505         FROM reserves
1506         JOIN biblioitems USING (biblionumber)
1507         JOIN hold_fill_targets USING (biblionumber, borrowernumber)
1508         WHERE found IS NULL
1509         AND priority > 0
1510         AND item_level_request = 0
1511         AND hold_fill_targets.itemnumber = ?
1512         AND reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1513         AND suspend = 0
1514         ORDER BY priority
1515     };
1516     $sth = $dbh->prepare($title_level_target_query);
1517     $sth->execute($itemnumber, $lookahead||0);
1518     @results = ();
1519     if ( my $data = $sth->fetchrow_hashref ) {
1520         push( @results, $data )
1521           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1522     }
1523     return @results if @results;
1524
1525     my $query = qq{
1526         SELECT reserves.biblionumber               AS biblionumber,
1527                reserves.borrowernumber             AS borrowernumber,
1528                reserves.reservedate                AS reservedate,
1529                reserves.waitingdate                AS waitingdate,
1530                reserves.branchcode                 AS branchcode,
1531                reserves.cancellationdate           AS cancellationdate,
1532                reserves.found                      AS found,
1533                reserves.reservenotes               AS reservenotes,
1534                reserves.priority                   AS priority,
1535                reserves.timestamp                  AS timestamp,
1536                reserves.itemnumber                 AS itemnumber,
1537                reserves.reserve_id                 AS reserve_id,
1538                reserves.itemtype                   AS itemtype
1539         FROM reserves
1540         WHERE reserves.biblionumber = ?
1541           AND (reserves.itemnumber IS NULL OR reserves.itemnumber = ?)
1542           AND reserves.reservedate <= DATE_ADD(NOW(),INTERVAL ? DAY)
1543           AND suspend = 0
1544           ORDER BY priority
1545     };
1546     $sth = $dbh->prepare($query);
1547     $sth->execute( $biblio, $itemnumber, $lookahead||0);
1548     @results = ();
1549     while ( my $data = $sth->fetchrow_hashref ) {
1550         push( @results, $data )
1551           unless any{ $data->{borrowernumber} eq $_ } @$ignore_borrowers ;
1552     }
1553     return @results;
1554 }
1555
1556 =head2 _koha_notify_reserve
1557
1558   _koha_notify_reserve( $hold->reserve_id );
1559
1560 Sends a notification to the patron that their hold has been filled (through
1561 ModReserveAffect, _not_ ModReserveFill)
1562
1563 The letter code for this notice may be found using the following query:
1564
1565     select distinct letter_code
1566     from message_transports
1567     inner join message_attributes using (message_attribute_id)
1568     where message_name = 'Hold_Filled'
1569
1570 This will probably sipmly be 'HOLD', but because it is defined in the database,
1571 it is subject to addition or change.
1572
1573 The following tables are availalbe witin the notice:
1574
1575     branches
1576     borrowers
1577     biblio
1578     biblioitems
1579     reserves
1580     items
1581
1582 =cut
1583
1584 sub _koha_notify_reserve {
1585     my $reserve_id = shift;
1586     my $hold = Koha::Holds->find($reserve_id);
1587     my $borrowernumber = $hold->borrowernumber;
1588
1589     my $patron = Koha::Patrons->find( $borrowernumber );
1590
1591     # Try to get the borrower's email address
1592     my $to_address = $patron->notice_email_address;
1593
1594     my $messagingprefs = C4::Members::Messaging::GetMessagingPreferences( {
1595             borrowernumber => $borrowernumber,
1596             message_name => 'Hold_Filled'
1597     } );
1598
1599     my $library = Koha::Libraries->find( $hold->branchcode )->unblessed;
1600
1601     my $admin_email_address = $library->{branchemail} || C4::Context->preference('KohaAdminEmailAddress');
1602
1603     my %letter_params = (
1604         module => 'reserves',
1605         branchcode => $hold->branchcode,
1606         lang => $patron->lang,
1607         tables => {
1608             'branches'       => $library,
1609             'borrowers'      => $patron->unblessed,
1610             'biblio'         => $hold->biblionumber,
1611             'biblioitems'    => $hold->biblionumber,
1612             'reserves'       => $hold->unblessed,
1613             'items'          => $hold->itemnumber,
1614         },
1615     );
1616
1617     my $notification_sent = 0; #Keeping track if a Hold_filled message is sent. If no message can be sent, then default to a print message.
1618     my $send_notification = sub {
1619         my ( $mtt, $letter_code ) = (@_);
1620         return unless defined $letter_code;
1621         $letter_params{letter_code} = $letter_code;
1622         $letter_params{message_transport_type} = $mtt;
1623         my $letter =  C4::Letters::GetPreparedLetter ( %letter_params );
1624         unless ($letter) {
1625             warn "Could not find a letter called '$letter_params{'letter_code'}' for $mtt in the 'reserves' module";
1626             return;
1627         }
1628
1629         C4::Letters::EnqueueLetter( {
1630             letter => $letter,
1631             borrowernumber => $borrowernumber,
1632             from_address => $admin_email_address,
1633             message_transport_type => $mtt,
1634         } );
1635     };
1636
1637     while ( my ( $mtt, $letter_code ) = each %{ $messagingprefs->{transports} } ) {
1638         next if (
1639                ( $mtt eq 'email' and not $to_address ) # No email address
1640             or ( $mtt eq 'sms'   and not $patron->smsalertnumber ) # No SMS number
1641             or ( $mtt eq 'phone' and C4::Context->preference('TalkingTechItivaPhoneNotification') ) # Notice is handled by TalkingTech_itiva_outbound.pl
1642         );
1643
1644         &$send_notification($mtt, $letter_code);
1645         $notification_sent++;
1646     }
1647     #Making sure that a print notification is sent if no other transport types can be utilized.
1648     if (! $notification_sent) {
1649         &$send_notification('print', 'HOLD');
1650     }
1651
1652 }
1653
1654 =head2 _ShiftPriorityByDateAndPriority
1655
1656   $new_priority = _ShiftPriorityByDateAndPriority( $biblionumber, $reservedate, $priority );
1657
1658 This increments the priority of all reserves after the one
1659 with either the lowest date after C<$reservedate>
1660 or the lowest priority after C<$priority>.
1661
1662 It effectively makes room for a new reserve to be inserted with a certain
1663 priority, which is returned.
1664
1665 This is most useful when the reservedate can be set by the user.  It allows
1666 the new reserve to be placed before other reserves that have a later
1667 reservedate.  Since priority also is set by the form in reserves/request.pl
1668 the sub accounts for that too.
1669
1670 =cut
1671
1672 sub _ShiftPriorityByDateAndPriority {
1673     my ( $biblio, $resdate, $new_priority ) = @_;
1674
1675     my $dbh = C4::Context->dbh;
1676     my $query = "SELECT priority FROM reserves WHERE biblionumber = ? AND ( reservedate > ? OR priority > ? ) ORDER BY priority ASC LIMIT 1";
1677     my $sth = $dbh->prepare( $query );
1678     $sth->execute( $biblio, $resdate, $new_priority );
1679     my $min_priority = $sth->fetchrow;
1680     # if no such matches are found, $new_priority remains as original value
1681     $new_priority = $min_priority if ( $min_priority );
1682
1683     # Shift the priority up by one; works in conjunction with the next SQL statement
1684     $query = "UPDATE reserves
1685               SET priority = priority+1
1686               WHERE biblionumber = ?
1687               AND borrowernumber = ?
1688               AND reservedate = ?
1689               AND found IS NULL";
1690     my $sth_update = $dbh->prepare( $query );
1691
1692     # Select all reserves for the biblio with priority greater than $new_priority, and order greatest to least
1693     $query = "SELECT borrowernumber, reservedate FROM reserves WHERE priority >= ? AND biblionumber = ? ORDER BY priority DESC";
1694     $sth = $dbh->prepare( $query );
1695     $sth->execute( $new_priority, $biblio );
1696     while ( my $row = $sth->fetchrow_hashref ) {
1697         $sth_update->execute( $biblio, $row->{borrowernumber}, $row->{reservedate} );
1698     }
1699
1700     return $new_priority;  # so the caller knows what priority they wind up receiving
1701 }
1702
1703 =head2 MoveReserve
1704
1705   MoveReserve( $itemnumber, $borrowernumber, $cancelreserve )
1706
1707 Use when checking out an item to handle reserves
1708 If $cancelreserve boolean is set to true, it will remove existing reserve
1709
1710 =cut
1711
1712 sub MoveReserve {
1713     my ( $itemnumber, $borrowernumber, $cancelreserve ) = @_;
1714
1715     my $lookahead = C4::Context->preference('ConfirmFutureHolds'); #number of days to look for future holds
1716     my ( $restype, $res, $all_reserves ) = CheckReserves( $itemnumber, undef, $lookahead );
1717     return unless $res;
1718
1719     my $biblionumber     =  $res->{biblionumber};
1720
1721     if ($res->{borrowernumber} == $borrowernumber) {
1722         ModReserveFill($res);
1723     }
1724     else {
1725         # warn "Reserved";
1726         # The item is reserved by someone else.
1727         # Find this item in the reserves
1728
1729         my $borr_res;
1730         foreach (@$all_reserves) {
1731             $_->{'borrowernumber'} == $borrowernumber or next;
1732             $_->{'biblionumber'}   == $biblionumber   or next;
1733
1734             $borr_res = $_;
1735             last;
1736         }
1737
1738         if ( $borr_res ) {
1739             # The item is reserved by the current patron
1740             ModReserveFill($borr_res);
1741         }
1742
1743         if ( $cancelreserve eq 'revert' ) { ## Revert waiting reserve to priority 1
1744             RevertWaitingStatus({ itemnumber => $itemnumber });
1745         }
1746         elsif ( $cancelreserve eq 'cancel' || $cancelreserve ) { # cancel reserves on this item
1747             my $hold = Koha::Holds->find( $res->{reserve_id} );
1748             $hold->cancel;
1749         }
1750     }
1751 }
1752
1753 =head2 MergeHolds
1754
1755   MergeHolds($dbh,$to_biblio, $from_biblio);
1756
1757 This shifts the holds from C<$from_biblio> to C<$to_biblio> and reorders them by the date they were placed
1758
1759 =cut
1760
1761 sub MergeHolds {
1762     my ( $dbh, $to_biblio, $from_biblio ) = @_;
1763     my $sth = $dbh->prepare(
1764         "SELECT count(*) as reserve_count FROM reserves WHERE biblionumber = ?"
1765     );
1766     $sth->execute($from_biblio);
1767     if ( my $data = $sth->fetchrow_hashref() ) {
1768
1769         # holds exist on old record, if not we don't need to do anything
1770         $sth = $dbh->prepare(
1771             "UPDATE reserves SET biblionumber = ? WHERE biblionumber = ?");
1772         $sth->execute( $to_biblio, $from_biblio );
1773
1774         # Reorder by date
1775         # don't reorder those already waiting
1776
1777         $sth = $dbh->prepare(
1778 "SELECT * FROM reserves WHERE biblionumber = ? AND (found <> ? AND found <> ? OR found is NULL) ORDER BY reservedate ASC"
1779         );
1780         my $upd_sth = $dbh->prepare(
1781 "UPDATE reserves SET priority = ? WHERE biblionumber = ? AND borrowernumber = ?
1782         AND reservedate = ? AND (itemnumber = ? or itemnumber is NULL) "
1783         );
1784         $sth->execute( $to_biblio, 'W', 'T' );
1785         my $priority = 1;
1786         while ( my $reserve = $sth->fetchrow_hashref() ) {
1787             $upd_sth->execute(
1788                 $priority,                    $to_biblio,
1789                 $reserve->{'borrowernumber'}, $reserve->{'reservedate'},
1790                 $reserve->{'itemnumber'}
1791             );
1792             $priority++;
1793         }
1794     }
1795 }
1796
1797 =head2 RevertWaitingStatus
1798
1799   RevertWaitingStatus({ itemnumber => $itemnumber });
1800
1801   Reverts a 'waiting' hold back to a regular hold with a priority of 1.
1802
1803   Caveat: Any waiting hold fixed with RevertWaitingStatus will be an
1804           item level hold, even if it was only a bibliolevel hold to
1805           begin with. This is because we can no longer know if a hold
1806           was item-level or bib-level after a hold has been set to
1807           waiting status.
1808
1809 =cut
1810
1811 sub RevertWaitingStatus {
1812     my ( $params ) = @_;
1813     my $itemnumber = $params->{'itemnumber'};
1814
1815     return unless ( $itemnumber );
1816
1817     my $dbh = C4::Context->dbh;
1818
1819     ## Get the waiting reserve we want to revert
1820     my $query = "
1821         SELECT * FROM reserves
1822         WHERE itemnumber = ?
1823         AND found IS NOT NULL
1824     ";
1825     my $sth = $dbh->prepare( $query );
1826     $sth->execute( $itemnumber );
1827     my $reserve = $sth->fetchrow_hashref();
1828
1829     ## Increment the priority of all other non-waiting
1830     ## reserves for this bib record
1831     $query = "
1832         UPDATE reserves
1833         SET
1834           priority = priority + 1
1835         WHERE
1836           biblionumber =  ?
1837         AND
1838           priority > 0
1839     ";
1840     $sth = $dbh->prepare( $query );
1841     $sth->execute( $reserve->{'biblionumber'} );
1842
1843     ## Fix up the currently waiting reserve
1844     $query = "
1845     UPDATE reserves
1846     SET
1847       priority = 1,
1848       found = NULL,
1849       waitingdate = NULL
1850     WHERE
1851       reserve_id = ?
1852     ";
1853     $sth = $dbh->prepare( $query );
1854     $sth->execute( $reserve->{'reserve_id'} );
1855     _FixPriority( { biblionumber => $reserve->{biblionumber} } );
1856 }
1857
1858 =head2 ReserveSlip
1859
1860   ReserveSlip($branchcode, $borrowernumber, $biblionumber)
1861
1862 Returns letter hash ( see C4::Letters::GetPreparedLetter ) or undef
1863
1864 The letter code will be HOLD_SLIP, and the following tables are
1865 available within the slip:
1866
1867     reserves
1868     branches
1869     borrowers
1870     biblio
1871     biblioitems
1872     items
1873
1874 =cut
1875
1876 sub ReserveSlip {
1877     my ($branch, $borrowernumber, $biblionumber) = @_;
1878
1879 #   return unless ( C4::Context->boolean_preference('printreserveslips') );
1880     my $patron = Koha::Patrons->find( $borrowernumber );
1881
1882     my $hold = Koha::Holds->search({biblionumber => $biblionumber, borrowernumber => $borrowernumber })->next;
1883     return unless $hold;
1884     my $reserve = $hold->unblessed;
1885
1886     return  C4::Letters::GetPreparedLetter (
1887         module => 'circulation',
1888         letter_code => 'HOLD_SLIP',
1889         branchcode => $branch,
1890         lang => $patron->lang,
1891         tables => {
1892             'reserves'    => $reserve,
1893             'branches'    => $reserve->{branchcode},
1894             'borrowers'   => $reserve->{borrowernumber},
1895             'biblio'      => $reserve->{biblionumber},
1896             'biblioitems' => $reserve->{biblionumber},
1897             'items'       => $reserve->{itemnumber},
1898         },
1899     );
1900 }
1901
1902 =head2 GetReservesControlBranch
1903
1904   my $reserves_control_branch = GetReservesControlBranch($item, $borrower);
1905
1906   Return the branchcode to be used to determine which reserves
1907   policy applies to a transaction.
1908
1909   C<$item> is a hashref for an item. Only 'homebranch' is used.
1910
1911   C<$borrower> is a hashref to borrower. Only 'branchcode' is used.
1912
1913 =cut
1914
1915 sub GetReservesControlBranch {
1916     my ( $item, $borrower ) = @_;
1917
1918     my $reserves_control = C4::Context->preference('ReservesControlBranch');
1919
1920     my $branchcode =
1921         ( $reserves_control eq 'ItemHomeLibrary' ) ? $item->{'homebranch'}
1922       : ( $reserves_control eq 'PatronLibrary' )   ? $borrower->{'branchcode'}
1923       :                                              undef;
1924
1925     return $branchcode;
1926 }
1927
1928 =head2 CalculatePriority
1929
1930     my $p = CalculatePriority($biblionumber, $resdate);
1931
1932 Calculate priority for a new reserve on biblionumber, placing it at
1933 the end of the line of all holds whose start date falls before
1934 the current system time and that are neither on the hold shelf
1935 or in transit.
1936
1937 The reserve date parameter is optional; if it is supplied, the
1938 priority is based on the set of holds whose start date falls before
1939 the parameter value.
1940
1941 After calculation of this priority, it is recommended to call
1942 _ShiftPriorityByDateAndPriority. Note that this is currently done in
1943 AddReserves.
1944
1945 =cut
1946
1947 sub CalculatePriority {
1948     my ( $biblionumber, $resdate ) = @_;
1949
1950     my $sql = q{
1951         SELECT COUNT(*) FROM reserves
1952         WHERE biblionumber = ?
1953         AND   priority > 0
1954         AND   (found IS NULL OR found = '')
1955     };
1956     #skip found==W or found==T (waiting or transit holds)
1957     if( $resdate ) {
1958         $sql.= ' AND ( reservedate <= ? )';
1959     }
1960     else {
1961         $sql.= ' AND ( reservedate < NOW() )';
1962     }
1963     my $dbh = C4::Context->dbh();
1964     my @row = $dbh->selectrow_array(
1965         $sql,
1966         undef,
1967         $resdate ? ($biblionumber, $resdate) : ($biblionumber)
1968     );
1969
1970     return @row ? $row[0]+1 : 1;
1971 }
1972
1973 =head2 IsItemOnHoldAndFound
1974
1975     my $bool = IsItemFoundHold( $itemnumber );
1976
1977     Returns true if the item is currently on hold
1978     and that hold has a non-null found status ( W, T, etc. )
1979
1980 =cut
1981
1982 sub IsItemOnHoldAndFound {
1983     my ($itemnumber) = @_;
1984
1985     my $rs = Koha::Database->new()->schema()->resultset('Reserve');
1986
1987     my $found = $rs->count(
1988         {
1989             itemnumber => $itemnumber,
1990             found      => { '!=' => undef }
1991         }
1992     );
1993
1994     return $found;
1995 }
1996
1997 =head2 GetMaxPatronHoldsForRecord
1998
1999 my $holds_per_record = ReservesControlBranch( $borrowernumber, $biblionumber );
2000
2001 For multiple holds on a given record for a given patron, the max
2002 number of record level holds that a patron can be placed is the highest
2003 value of the holds_per_record rule for each item if the record for that
2004 patron. This subroutine finds and returns the highest holds_per_record
2005 rule value for a given patron id and record id.
2006
2007 =cut
2008
2009 sub GetMaxPatronHoldsForRecord {
2010     my ( $borrowernumber, $biblionumber ) = @_;
2011
2012     my $patron = Koha::Patrons->find($borrowernumber);
2013     my @items = Koha::Items->search( { biblionumber => $biblionumber } );
2014
2015     my $controlbranch = C4::Context->preference('ReservesControlBranch');
2016
2017     my $categorycode = $patron->categorycode;
2018     my $branchcode;
2019     $branchcode = $patron->branchcode if ( $controlbranch eq "PatronLibrary" );
2020
2021     my $max = 0;
2022     foreach my $item (@items) {
2023         my $itemtype = $item->effective_itemtype();
2024
2025         $branchcode = $item->homebranch if ( $controlbranch eq "ItemHomeLibrary" );
2026
2027         my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2028         my $holds_per_record = $rule ? $rule->{holds_per_record} : 0;
2029         $max = $holds_per_record if $holds_per_record > $max;
2030     }
2031
2032     return $max;
2033 }
2034
2035 =head2 GetHoldRule
2036
2037 my $rule = GetHoldRule( $categorycode, $itemtype, $branchcode );
2038
2039 Returns the matching hold related issuingrule fields for a given
2040 patron category, itemtype, and library.
2041
2042 =cut
2043
2044 sub GetHoldRule {
2045     my ( $categorycode, $itemtype, $branchcode ) = @_;
2046
2047     my $dbh = C4::Context->dbh;
2048
2049     my $sth = $dbh->prepare(
2050         q{
2051          SELECT categorycode, itemtype, branchcode, reservesallowed, holds_per_record
2052            FROM issuingrules
2053           WHERE (categorycode in (?,'*') )
2054             AND (itemtype IN (?,'*'))
2055             AND (branchcode IN (?,'*'))
2056        ORDER BY categorycode DESC,
2057                 itemtype     DESC,
2058                 branchcode   DESC
2059         }
2060     );
2061
2062     $sth->execute( $categorycode, $itemtype, $branchcode );
2063
2064     return $sth->fetchrow_hashref();
2065 }
2066
2067 =head1 AUTHOR
2068
2069 Koha Development Team <http://koha-community.org/>
2070
2071 =cut
2072
2073 1;