Koha/Objects.pm

   1 package Koha::Objects;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use Koha::Database;
  25
  26 =head1 NAME
  27
  28 Koha::Objects - Koha Object set base class
  29
  30 =head1 SYNOPSIS
  31
  32     use Koha::Objects;
  33     my @objects = Koha::Objects->search({ borrowernumber => $borrowernumber});
  34
  35 =head1 DESCRIPTION
  36
  37 This class must be subclassed.
  38
  39 =head1 API
  40
  41 =head2 Class Methods
  42
  43 =cut
  44
  45 =head3 Koha::Objects->new();
  46
  47 my $object = Koha::Objects->new();
  48
  49 =cut
  50
  51 sub new {
  52     my ($class) = @_;
  53     my $self = {};
  54
  55     bless( $self, $class );
  56 }
  57
  58 =head3 Koha::Objects->_new_from_dbic();
  59
  60 my $object = Koha::Objects->_new_from_dbic( $resultset );
  61
  62 =cut
  63
  64 sub _new_from_dbic {
  65     my ( $class, $resultset ) = @_;
  66     my $self = { _resultset => $resultset };
  67
  68     bless( $self, $class );
  69 }
  70
  71 =head3 Koha::Objects->find();
  72
  73 my $object = Koha::Objects->find($id);
  74 my $object = Koha::Objects->find( { keypart1 => $keypart1, keypart2 => $keypart2 } );
  75
  76 =cut
  77
  78 sub find {
  79     my ( $self, $id ) = @_;
  80
  81     return unless defined($id);
  82
  83     my $result = $self->_resultset()->find($id);
  84
  85     return unless $result;
  86
  87     my $object = $self->object_class()->_new_from_dbic( $result );
  88
  89     return $object;
  90 }
  91
  92 =head3 Koha::Objects->find_or_create();
  93
  94 my $object = Koha::Objects->find_or_create( $attrs );
  95
  96 =cut
  97
  98 sub find_or_create {
  99     my ( $self, $params ) = @_;
 100
 101     my $result = $self->_resultset->find_or_create($params);
 102
 103     return unless $result;
 104
 105     my $object = $self->object_class->_new_from_dbic($result);
 106
 107     return $object;
 108 }
 109
 110 =head3 Koha::Objects->search();
 111
 112 my @objects = Koha::Objects->search($params);
 113
 114 =cut
 115
 116 sub search {
 117     my ( $self, $params, $attributes ) = @_;
 118
 119     if (wantarray) {
 120         my @dbic_rows = $self->_resultset()->search($params, $attributes);
 121
 122         return $self->_wrap(@dbic_rows);
 123
 124     }
 125     else {
 126         my $class = ref($self) ? ref($self) : $self;
 127         my $rs = $self->_resultset()->search($params, $attributes);
 128
 129         return $class->_new_from_dbic($rs);
 130     }
 131 }
 132
 133 =head3 search_related
 134
 135     my @objects = Koha::Objects->search_related( $rel_name, $cond?, \%attrs? );
 136     my $objects = Koha::Objects->search_related( $rel_name, $cond?, \%attrs? );
 137
 138 Searches the specified relationship, optionally specifying a condition and attributes for matching records.
 139
 140 =cut
 141
 142 sub search_related {
 143     my ( $self, $rel_name, @params ) = @_;
 144
 145     return if !$rel_name;
 146     if (wantarray) {
 147         my @dbic_rows = $self->_resultset()->search_related($rel_name, @params);
 148         return if !@dbic_rows;
 149         my $object_class = _get_objects_class( $dbic_rows[0]->result_class );
 150
 151         eval "require $object_class";
 152         return _wrap( $object_class, @dbic_rows );
 153
 154     } else {
 155         my $rs = $self->_resultset()->search_related($rel_name, @params);
 156         return if !$rs;
 157         my $object_class = _get_objects_class( $rs->result_class );
 158
 159         eval "require $object_class";
 160         return _new_from_dbic( $object_class, $rs );
 161     }
 162 }
 163
 164 =head3 Koha::Objects->next();
 165
 166 my $object = Koha::Objects->next();
 167
 168 Returns the next object that is part of this set.
 169 Returns undef if there are no more objects to return.
 170
 171 =cut
 172
 173 sub next {
 174     my ( $self ) = @_;
 175
 176     my $result = $self->_resultset()->next();
 177     return unless $result;
 178
 179     my $object = $self->object_class()->_new_from_dbic( $result );
 180
 181     return $object;
 182 }
 183
 184 =head3 Koha::Objects->as_list();
 185
 186 Koha::Objects->as_list();
 187
 188 Returns an arrayref of the objects in this set.
 189
 190 =cut
 191
 192 sub as_list {
 193     my ( $self ) = @_;
 194
 195     my @dbic_rows = $self->_resultset()->all();
 196
 197     my @objects = $self->_wrap(@dbic_rows);
 198
 199     return wantarray ? @objects : \@objects;
 200 }
 201
 202 =head3 Koha::Objects->unblessed
 203
 204 Returns an unblessed representation of objects.
 205
 206 =cut
 207
 208 sub unblessed {
 209     my ($self) = @_;
 210
 211     return [ map { $_->unblessed } $self->as_list ];
 212 }
 213
 214 =head3 Koha::Objects->_wrap
 215
 216 wraps the DBIC object in a corresponding Koha object
 217
 218 =cut
 219
 220 sub _wrap {
 221     my ( $self, @dbic_rows ) = @_;
 222
 223     my @objects = map { $self->object_class->_new_from_dbic( $_ ) } @dbic_rows;
 224
 225     return @objects;
 226 }
 227
 228 =head3 Koha::Objects->_resultset
 229
 230 Returns the internal resultset or creates it if undefined
 231
 232 =cut
 233
 234 sub _resultset {
 235     my ($self) = @_;
 236
 237     if ( ref($self) ) {
 238         $self->{_resultset} ||=
 239           Koha::Database->new()->schema()->resultset( $self->_type() );
 240
 241         return $self->{_resultset};
 242     }
 243     else {
 244         return Koha::Database->new()->schema()->resultset( $self->_type() );
 245     }
 246 }
 247
 248 sub _get_objects_class {
 249     my ( $type ) = @_;
 250     return unless $type;
 251
 252     if( $type->can('koha_objects_class') ) {
 253         return $type->koha_objects_class;
 254     }
 255     $type =~ s|Schema::Result::||;
 256     return "${type}s";
 257 }
 258
 259 =head3 columns
 260
 261 my @columns = Koha::Objects->columns
 262
 263 Return the table columns
 264
 265 =cut
 266
 267 sub columns {
 268     my ( $class ) = @_;
 269     return Koha::Database->new->schema->resultset( $class->_type )->result_source->columns;
 270 }
 271
 272 =head3 AUTOLOAD
 273
 274 The autoload method is used call DBIx::Class method on a resultset.
 275
 276 Important: If you plan to use one of the DBIx::Class methods you must provide
 277 relevant tests in t/db_dependent/Koha/Objects.t
 278 Currently count, pager, reset, update and delete are covered.
 279
 280 =cut
 281
 282 sub AUTOLOAD {
 283     my ( $self, @params ) = @_;
 284
 285     my @known_methods = qw( count pager reset update delete result_class );
 286     my $method = our $AUTOLOAD;
 287     $method =~ s/.*:://;
 288
 289     carp "The method $method is not covered by tests" and return unless grep {/^$method$/} @known_methods;
 290     my $r = eval { $self->_resultset->$method(@params) };
 291     if ( $@ ) {
 292         carp "No method $method found for " . ref($self) . " " . $@;
 293         return
 294     }
 295     return $r;
 296 }
 297
 298 =head3 _type
 299
 300 The _type method must be set for all child classes.
 301 The value returned by it should be the DBIC resultset name.
 302 For example, for holds, _type should return 'Reserve'.
 303
 304 =cut
 305
 306 sub _type { }
 307
 308 =head3 object_class
 309
 310 This method must be set for all child classes.
 311 The value returned by it should be the name of the Koha
 312 object class that is returned by this class.
 313 For example, for holds, object_class should return 'Koha::Hold'.
 314
 315 =cut
 316
 317 sub object_class { }
 318
 319 sub DESTROY { }
 320
 321 =head1 AUTHOR
 322
 323 Kyle M Hall <kyle@bywatersolutions.com>
 324
 325 =cut
 326
 327 1;