svc/checkouts

   1 #!/usr/bin/perl
   2
   3 # Copyright 2014 ByWater Solutions
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI;
  23 use JSON qw(to_json);
  24
  25 use C4::Auth qw(check_cookie_auth haspermission get_session);
  26 use C4::Circulation qw(GetIssuingCharges CanBookBeRenewed GetRenewCount GetSoonestRenewDate);
  27 use C4::Overdues qw(GetFine);
  28 use C4::Context;
  29
  30 use Koha::AuthorisedValues;
  31 use Koha::DateUtils;
  32 use Koha::ItemTypes;
  33
  34 my $input = CGI->new;
  35
  36 my ( $auth_status, $sessionID ) =
  37   check_cookie_auth( $input->cookie('CGISESSID'));
  38
  39 my $session   = get_session($sessionID);
  40 my $userid   = $session->param('id');
  41
  42 unless (haspermission($userid, { circulate => 'circulate_remaining_permissions' })
  43     || haspermission($userid, { borrowers => 'edit_borrowers' })) {
  44     exit 0;
  45 }
  46
  47 my @sort_columns = qw/date_due title itype issuedate branchcode itemcallnumber/;
  48
  49 my @borrowernumber   = $input->multi_param('borrowernumber');
  50 my $offset           = $input->param('iDisplayStart');
  51 my $results_per_page = $input->param('iDisplayLength') || -1;
  52
  53 my $sorting_column = $input->param('iSortCol_0') || q{};
  54 $sorting_column = ( $sorting_column && $sort_columns[$sorting_column] ) ? $sort_columns[$sorting_column] : 'issuedate';
  55
  56 my $sorting_direction = $input->param('sSortDir_0') || q{};
  57 $sorting_direction = $sorting_direction eq 'asc' ? 'asc' : 'desc';
  58
  59 $results_per_page = undef if ( $results_per_page == -1 );
  60
  61 binmode STDOUT, ":encoding(UTF-8)";
  62 print $input->header( -type => 'text/plain', -charset => 'UTF-8' );
  63
  64 my @parameters;
  65 my $sql = '
  66     SELECT
  67         issues.issuedate,
  68         issues.date_due,
  69         issues.date_due < now() as date_due_overdue,
  70         issues.timestamp,
  71
  72         issues.onsite_checkout,
  73
  74         biblio.biblionumber,
  75         biblio.title,
  76         biblio.subtitle,
  77         biblio.medium,
  78         biblio.part_number,
  79         biblio.part_name,
  80         biblio.author,
  81
  82         items.itemnumber,
  83         items.barcode,
  84         branches2.branchname AS homebranch,
  85         items.itemnotes,
  86         items.itemnotes_nonpublic,
  87         items.itemcallnumber,
  88         items.copynumber,
  89         items.replacementprice,
  90
  91         issues.branchcode,
  92         branches.branchname,
  93
  94         items.itype,
  95         biblioitems.itemtype,
  96
  97         items.ccode AS collection,
  98
  99         borrowers.borrowernumber,
 100         borrowers.surname,
 101         borrowers.firstname,
 102         borrowers.cardnumber,
 103
 104         items.itemlost,
 105         items.damaged,
 106         items.location,
 107         items.enumchron,
 108         items.materials,
 109
 110         DATEDIFF( issues.issuedate, CURRENT_DATE() ) AS not_issued_today,
 111
 112         return_claims.id AS return_claim_id,
 113         return_claims.notes AS return_claim_notes,
 114         return_claims.created_on AS return_claim_created_on,
 115         return_claims.updated_on AS return_claim_updated_on
 116
 117     FROM issues
 118         LEFT JOIN items USING ( itemnumber )
 119         LEFT JOIN biblio USING ( biblionumber )
 120         LEFT JOIN biblioitems USING ( biblionumber )
 121         LEFT JOIN borrowers USING ( borrowernumber )
 122         LEFT JOIN branches ON ( issues.branchcode = branches.branchcode )
 123         LEFT JOIN branches branches2 ON ( items.homebranch = branches2.branchcode )
 124         LEFT JOIN return_claims USING ( issue_id )
 125     WHERE issues.borrowernumber
 126 ';
 127
 128 if ( @borrowernumber == 1 ) {
 129     $sql .= '= ?';
 130 }
 131 else {
 132     $sql .= ' IN (' . join( ',', ('?') x @borrowernumber ) . ') ';
 133 }
 134 push( @parameters, @borrowernumber );
 135
 136 $sql .= " ORDER BY $sorting_column $sorting_direction ";
 137
 138 my $dbh = C4::Context->dbh();
 139 my $sth = $dbh->prepare($sql);
 140 $sth->execute(@parameters);
 141
 142 my $item_level_itypes = C4::Context->preference('item-level_itypes');
 143 my $claims_returned_lost_value = C4::Context->preference('ClaimReturnedLostValue');
 144 my $confirm_parts_required = C4::Context->preference("CircConfirmItemParts");
 145
 146 my $itemtypes = { map { $_->{itemtype} => $_->{translated_description} } @{ Koha::ItemTypes->search_with_localization->unblessed } };
 147
 148 my @checkouts_today;
 149 my @checkouts_previous;
 150 while ( my $c = $sth->fetchrow_hashref() ) {
 151     my ($charge) = GetIssuingCharges( $c->{itemnumber}, $c->{borrowernumber} );
 152     my $fine = GetFine( $c->{itemnumber}, $c->{borrowernumber} );
 153
 154     my ( $can_renew, $can_renew_error ) =
 155       CanBookBeRenewed( $c->{borrowernumber}, $c->{itemnumber} );
 156     my $can_renew_date =
 157       $can_renew_error && $can_renew_error eq 'too_soon'
 158       ? output_pref(
 159         {
 160             dt => GetSoonestRenewDate( $c->{borrowernumber}, $c->{itemnumber} ),
 161             as_due_date => 1
 162         }
 163       )
 164       : undef;
 165
 166     my (
 167         $renewals_count,
 168         $renewals_allowed,
 169         $renewals_remaining,
 170         $unseen_count,
 171         $unseen_allowed,
 172         $unseen_remaining
 173     ) =
 174       GetRenewCount( $c->{borrowernumber}, $c->{itemnumber} );
 175
 176     my ( $itemtype, $recordtype, $type_for_stat );
 177     $itemtype      = $itemtypes->{ $c->{itype} }    if $c->{itype};
 178     $recordtype    = $itemtypes->{ $c->{itemtype} } if $c->{itemtype};
 179     $type_for_stat = $item_level_itypes ? $itemtype : $recordtype;
 180
 181     my $location;
 182     if ( $c->{location} ) {
 183         my $av = Koha::AuthorisedValues->get_description_by_koha_field(
 184             { kohafield => 'items.location', authorised_value => $c->{location} } );
 185         $location = $av->{lib} ? $av->{lib} : '';
 186     }
 187     my $collection;
 188     if ( $c->{collection} ) {
 189         my $av = Koha::AuthorisedValues->get_description_by_koha_field(
 190             { kohafield => 'items.ccode', authorised_value => $c->{collection} } );
 191         $collection = $av->{lib} ? $av->{lib} : '';
 192     }
 193     my $lost;
 194     my $claims_returned;
 195     if ( $c->{itemlost} ) {
 196         my $av = Koha::AuthorisedValues->get_description_by_koha_field(
 197             { kohafield => 'items.itemlost', authorised_value => $c->{itemlost} } );
 198         $lost            = $av->{lib} ? $av->{lib} : '';
 199         $claims_returned = $c->{itemlost} eq $claims_returned_lost_value;
 200     }
 201     my $damaged;
 202     if ( $c->{damaged} ) {
 203         my $av = Koha::AuthorisedValues->get_description_by_koha_field(
 204             { kohafield => 'items.damaged', authorised_value => $c->{damaged} } );
 205         $damaged = $av->{lib} ? $av->{lib} : '';
 206     }
 207     my $materials;
 208     if ( $c->{materials} && $confirm_parts_required ) {
 209         my $descriptions = Koha::AuthorisedValues->get_description_by_koha_field({frameworkcode => '', kohafield =>'items.materials', authorised_value => $c->{materials} });
 210         $materials = $descriptions->{lib} // $c->{materials};
 211     }
 212     my @subtitles = split(/ \| /, $c->{'subtitle'} // '' );
 213     my $checkout = {
 214         DT_RowId             => $c->{itemnumber} . '-' . $c->{borrowernumber},
 215         title                => $c->{title},
 216         subtitle             => \@subtitles,
 217         medium               => $c->{medium} // '',
 218         part_number          => $c->{part_number} // '',
 219         part_name            => $c->{part_name} // '',
 220         author               => $c->{author},
 221         barcode              => $c->{barcode},
 222         type_for_stat          => $type_for_stat || q{},
 223         itemtype_description   => $itemtype || q{},
 224         recordtype_description => $recordtype || q{},
 225         collection           => $collection,
 226         location             => $location,
 227         homebranch           => $c->{homebranch},
 228         itemnotes            => $c->{itemnotes},
 229         itemnotes_nonpublic  => $c->{itemnotes_nonpublic},
 230         branchcode           => $c->{branchcode},
 231         branchname           => $c->{branchname},
 232         itemcallnumber       => $c->{itemcallnumber} || q{},
 233         copynumber           => $c->{copynumber} || q{},
 234         charge         => $charge,
 235         fine           => $fine,
 236         price          => $c->{replacementprice} || q{},
 237         can_renew      => $can_renew,
 238         can_renew_error     => $can_renew_error,
 239         can_renew_date      => $can_renew_date,
 240         itemnumber          => $c->{itemnumber},
 241         borrowernumber      => $c->{borrowernumber},
 242         biblionumber        => $c->{biblionumber},
 243         issuedate           => $c->{issuedate},
 244         date_due            => $c->{date_due},
 245         date_due_overdue    => $c->{date_due_overdue} ? JSON::true : JSON::false,
 246         timestamp           => $c->{timestamp},
 247         onsite_checkout     => $c->{onsite_checkout},
 248         enumchron           => $c->{enumchron},
 249         renewals_count      => $renewals_count,
 250         renewals_allowed    => $renewals_allowed,
 251         renewals_remaining  => $renewals_remaining,
 252         unseen_count        => $unseen_count,
 253         unseen_allowed      => $unseen_allowed,
 254         unseen_remaining    => $unseen_remaining,
 255
 256         return_claim_id         => $c->{return_claim_id},
 257         return_claim_notes      => $c->{return_claim_notes},
 258         return_claim_created_on => $c->{return_claim_created_on},
 259         return_claim_updated_on => $c->{return_claim_updated_on},
 260         return_claim_created_on_formatted => $c->{return_claim_created_on} ? output_pref({ dt => dt_from_string( $c->{return_claim_created_on} ) }) : undef,
 261         return_claim_updated_on_formatted => $c->{return_claim_updated_on} ? output_pref({ dt => dt_from_string( $c->{return_claim_updated_on} ) }) : undef,
 262
 263         issuedate_formatted => output_pref(
 264             {
 265                 dt          => dt_from_string( $c->{issuedate} ),
 266                 as_due_date => 1
 267             }
 268         ),
 269         date_due_formatted => output_pref(
 270             {
 271                 dt          => dt_from_string( $c->{date_due} ),
 272                 as_due_date => 1
 273             }
 274         ),
 275         lost    => $lost,
 276         claims_returned => $claims_returned,
 277         damaged => $damaged,
 278         materials => $materials,
 279         borrower => {
 280             surname    => $c->{surname},
 281             firstname  => $c->{firstname},
 282             cardnumber => $c->{cardnumber},
 283         },
 284         issued_today => !$c->{not_issued_today},
 285     };
 286
 287     if ( $c->{not_issued_today} ) {
 288         push( @checkouts_previous, $checkout );
 289     }
 290     else {
 291         push( @checkouts_today, $checkout );
 292     }
 293 }
 294
 295
 296 @checkouts_today = sort { $a->{timestamp} cmp $b->{timestamp} } @checkouts_today;    # latest to earliest
 297 @checkouts_today = reverse(@checkouts_today)
 298   if ( C4::Context->preference('todaysIssuesDefaultSortOrder') eq 'desc' );      # earliest to latest
 299
 300 @checkouts_previous =
 301   sort { $a->{date_due} cmp $b->{date_due} || $a->{timestamp} cmp $b->{timestamp} }
 302   @checkouts_previous;                                                               # latest to earliest
 303 @checkouts_previous = reverse(@checkouts_previous)
 304   if ( C4::Context->preference('previousIssuesDefaultSortOrder') eq 'desc' );    # earliest to latest
 305
 306 my @checkouts = ( @checkouts_today, @checkouts_previous );
 307
 308 my $i = 1;
 309 map { $_->{sort_order} = $i++ } @checkouts;
 310
 311
 312 my $data;
 313 $data->{'iTotalRecords'}        = scalar @checkouts;
 314 $data->{'iTotalDisplayRecords'} = scalar @checkouts;
 315 $data->{'sEcho'}                = $input->param('sEcho') || undef;
 316 $data->{'aaData'}               = \@checkouts;
 317
 318 print to_json($data);