installer/install.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright (C) YEAR  YOURNAME-OR-YOUREMPLOYER
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21 use diagnostics;
  22
  23 use C4::InstallAuth;
  24 use CGI qw ( -utf8 );
  25 use POSIX qw(strftime);
  26
  27 use C4::Context;
  28 use C4::Output;
  29 use C4::Templates;
  30 use C4::Languages qw(getAllLanguages getTranslatedLanguages);
  31 use C4::Installer;
  32 use C4::Installer::PerlModules;
  33
  34 use Koha;
  35
  36 my $query = CGI->new;
  37 my $step  = $query->param('step');
  38
  39 my $language = $query->param('language');
  40 my ( $template, $loggedinuser, $cookie );
  41
  42 my $all_languages = getAllLanguages();
  43
  44 if ( defined($language) ) {
  45     C4::Templates::setlanguagecookie( $query, $language, "install.pl?step=1" );
  46 }
  47 ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  48     {
  49         template_name => "installer/step" . ( $step ? $step : 1 ) . ".tt",
  50         query         => $query,
  51         type          => "intranet",
  52         debug           => 1,
  53     }
  54 );
  55
  56 my $installer = C4::Installer->new();
  57 my %info;
  58 $info{'dbname'} = C4::Context->config("database");
  59 $info{'dbms'}   = (
  60       C4::Context->config("db_scheme")
  61     ? C4::Context->config("db_scheme")
  62     : "mysql"
  63 );
  64 $info{'hostname'} = C4::Context->config("hostname");
  65 $info{'port'}     = C4::Context->config("port");
  66 $info{'user'}     = C4::Context->config("user");
  67 $info{'password'} = C4::Context->config("pass");
  68 $info{'tls'} = C4::Context->config("tls");
  69     if ($info{'tls'} && $info{'tls'} eq 'yes'){
  70         $info{'ca'} = C4::Context->config('ca');
  71         $info{'cert'} = C4::Context->config('cert');
  72         $info{'key'} = C4::Context->config('key');
  73         $info{'tlsoptions'} = ";mysql_ssl=1;mysql_ssl_client_key=".$info{key}.";mysql_ssl_client_cert=".$info{cert}.";mysql_ssl_ca_file=".$info{ca};
  74         $info{'tlscmdline'} =  " --ssl-cert ". $info{cert} . " --ssl-key " . $info{key} . " --ssl-ca ".$info{ca}." "
  75     }
  76
  77 my $dbh = DBI->connect(
  78     "DBI:$info{dbms}:dbname=$info{dbname};host=$info{hostname}"
  79       . ( $info{port} ? ";port=$info{port}" : "" )
  80       . ( $info{tlsoptions} ? $info{tlsoptions} : "" ),
  81     $info{'user'}, $info{'password'}
  82 );
  83
  84 if ( $step && $step == 1 ) {
  85
  86     #First Step (for both fresh installations and upgrades)
  87     #Checking ALL perl Modules and services needed are installed.
  88     #Whenever there is an error, adding a report to the page
  89     my $op = $query->param('op') || 'noop';
  90     $template->param( language      => 1 );
  91     my $checkmodule = 1;
  92     $template->param( 'checkmodule' => 1 )
  93       ; # we start with the assumption that there are no problems and set this to 0 if there are
  94
  95     unless ( $] >= 5.010000 ) {    # Bug 7375
  96         $template->param( problems => 1, perlversion => 1, checkmodule => 0 );
  97         $checkmodule = 0;
  98     }
  99
 100     my $perl_modules = C4::Installer::PerlModules->new;
 101     $perl_modules->versions_info;
 102
 103     my $missing_modules = $perl_modules->get_attr('missing_pm');
 104     my $upgrade_modules = $perl_modules->get_attr('upgrade_pm');
 105     if ( scalar(@$missing_modules) || scalar(@$upgrade_modules) ) {
 106         my @missing  = ();
 107         my @upgrade = ();
 108         foreach (@$missing_modules) {
 109             my ( $module, $stats ) = each %$_;
 110             $checkmodule = 0 if $stats->{'required'};
 111             push(
 112                 @missing,
 113                 {
 114                     name    => $module,
 115                     min_version => $stats->{'min_ver'},
 116                     max_version => $stats->{'max_ver'},
 117                     require => $stats->{'required'}
 118                 }
 119             );
 120         }
 121         foreach (@$upgrade_modules) {
 122             my ( $module, $stats ) = each %$_;
 123             $checkmodule = 0 if $stats->{'required'};
 124             push(
 125                 @upgrade,
 126                 {
 127                     name    => $module,
 128                     min_version => $stats->{'min_ver'},
 129                     max_version => $stats->{'max_ver'},
 130                     require => $stats->{'required'}
 131                 }
 132             );
 133         }
 134         @missing = sort { $a->{'name'} cmp $b->{'name'} } @missing;
 135         @upgrade = sort { $a->{'name'} cmp $b->{'name'} } @upgrade;
 136         $template->param(
 137             missing_modules => \@missing,
 138             upgrade_modules => \@upgrade,
 139             checkmodule     => $checkmodule,
 140             op              => $op
 141         );
 142     }
 143 }
 144 elsif ( $step && $step == 2 ) {
 145
 146     #STEP 2 Check Database connection and access
 147
 148     $template->param(%info);
 149     my $checkdb = $query->param("checkdb");
 150     $template->param( 'dbconnection' => $checkdb );
 151     if ($checkdb) {
 152         if ($dbh) {
 153
 154             # Can connect to the mysql
 155             $template->param( "checkdatabaseaccess" => 1 );
 156             if ( $info{dbms} eq "mysql" ) {
 157
 158                 #Check if database created
 159                 my $rv = $dbh->do("SHOW DATABASES LIKE \'$info{dbname}\'");
 160                 if ( $rv == 1 ) {
 161                     $template->param( 'checkdatabasecreated' => 1 );
 162                 }
 163
 164                 # Check if user have all necessary grants on this database.
 165                 # CURRENT_USER is ANSI SQL, and doesn't require mysql table
 166                 # privileges, making the % check pointless, since they
 167                 # couldn't even check GRANTS if they couldn't connect.
 168                 my $rq = $dbh->prepare('SHOW GRANTS FOR CURRENT_USER');
 169                 $rq->execute;
 170                 my $grantaccess;
 171                 while ( my ($line) = $rq->fetchrow ) {
 172                     my $dbname = $info{dbname};
 173                     if ( $line =~ m/^GRANT (.*?) ON `$dbname`\.\*/
 174                         || index( $line, '*.*' ) > 0 )
 175                     {
 176                         $grantaccess = 1
 177                           if (
 178                             index( $line, 'ALL PRIVILEGES' ) > 0
 179                             || (   ( index( $line, 'SELECT' ) > 0 )
 180                                 && ( index( $line, 'INSERT' ) > 0 )
 181                                 && ( index( $line, 'UPDATE' ) > 0 )
 182                                 && ( index( $line, 'DELETE' ) > 0 )
 183                                 && ( index( $line, 'CREATE' ) > 0 )
 184                                 && ( index( $line, 'DROP' ) > 0 ) )
 185                           );
 186                     }
 187                 }
 188                 $template->param( "checkgrantaccess" => $grantaccess );
 189             }    # End mysql connect check...
 190
 191             elsif ( $info{dbms} eq "Pg" ) {
 192
 193                 # Check if database has been created...
 194                 my $rv = $dbh->do(
 195 "SELECT * FROM pg_catalog.pg_database WHERE datname = \'$info{dbname}\';"
 196                 );
 197                 if ( $rv == 1 ) {
 198                     $template->param( 'checkdatabasecreated' => 1 );
 199                 }
 200
 201                 # Check if user has all necessary grants on this database...
 202                 my $rq = $dbh->do(
 203                     "SELECT u.usesuper
 204             FROM pg_catalog.pg_user as u
 205             WHERE u.usename = \'$info{user}\';"
 206                 );
 207                 if ( $rq == 1 ) {
 208                     $template->param( "checkgrantaccess" => 1 );
 209                 }
 210             }    # End Pg connect check...
 211         }
 212         else {
 213             $template->param( "error" => DBI::err, "message" => DBI::errstr );
 214         }
 215     }
 216 }
 217 elsif ( $step && $step == 3 ) {
 218
 219     # STEP 3 : database setup
 220
 221     my $op = $query->param('op');
 222     if ( $op && $op eq 'finished' ) {
 223         #
 224         # we have finished, just redirect to mainpage.
 225         #
 226         print $query->redirect("/cgi-bin/koha/mainpage.pl");
 227         exit;
 228     }
 229     elsif ( $op && $op eq 'finish' ) {
 230         $installer->set_version_syspref();
 231
 232         my $langchoice = $query->param('fwklanguage');
 233         $langchoice = $query->cookie('KohaOpacLanguage') unless ($langchoice);
 234         $langchoice =~ s/[^a-zA-Z_-]*//g;
 235         $installer->set_languages_syspref($langchoice);
 236
 237 # Installation is finished.
 238 # We just deny anybody access to install
 239 # And we redirect people to mainpage.
 240 # The installer will have to relogin since we do not pass cookie to redirection.
 241         $template->param( "$op" => 1 );
 242     }
 243
 244     elsif ( $op && $op eq 'addframeworks' ) {
 245
 246         # 1ST install, 3rd sub-step : insert the SQL files the user has selected
 247         my $langchoice = $query->param('fwklanguage');
 248         $langchoice = $query->cookie('KohaOpacLanguage') unless ($langchoice);
 249         $langchoice =~ s/[^a-zA-Z_-]*//g;
 250
 251         my ( $fwk_language, $list ) =
 252           $installer->load_sql_in_order( $langchoice, $all_languages,
 253             $query->multi_param('framework') );
 254         $template->param(
 255             "fwklanguage" => $fwk_language,
 256             "list"        => $list
 257         );
 258         use Koha::SearchEngine::Elasticsearch;
 259         Koha::SearchEngine::Elasticsearch->reset_elasticsearch_mappings;
 260         $template->param( "$op" => 1 );
 261     }
 262     elsif ( $op && $op eq 'selectframeworks' ) {
 263 #
 264 #
 265 # 1ST install, 2nd sub-step : show the user the sql datas they can insert in the database.
 266 #
 267 #
 268 # (note that the term "selectframeworks is not correct. The user can select various files, not only frameworks)
 269
 270 #Framework Selection
 271 #sql data for import are supposed to be located in installer/data/<language>/<level>
 272 # Where <language> is en|fr or any international abbreviation (provided language hash is updated... This will be a problem with internationlisation.)
 273 # Where <level> is a category of requirement : required, recommended optional
 274 # level should contain :
 275 #   SQL File for import With a readable name.
 276 #   txt File that explains what this SQL File is meant for.
 277 # Could be VERY useful to have A Big file for a kind of library.
 278 # But could also be useful to have some Authorised values data set prepared here.
 279 # Framework Selection is achieved through checking boxes.
 280         my $langchoice = $query->param('fwklanguage');
 281         $langchoice = $query->cookie('KohaOpacLanguage') unless ($langchoice);
 282         $langchoice =~ s/[^a-zA-Z_-]*//g;
 283         my $marcflavour = $query->param('marcflavour');
 284         if ($marcflavour) {
 285             $installer->set_marcflavour_syspref($marcflavour);
 286         }
 287         $marcflavour = C4::Context->preference('marcflavour')
 288           unless ($marcflavour);
 289
 290         #Insert into database the selected marcflavour
 291         undef $/;
 292         my ( $marc_defaulted_to_en, $fwklist ) =
 293           $installer->marc_framework_sql_list( $langchoice, $marcflavour );
 294         $template->param( 'en_marc_frameworks' => $marc_defaulted_to_en );
 295         $template->param( "frameworksloop"     => $fwklist );
 296         $template->param( "marcflavour"        => ucfirst($marcflavour) );
 297
 298         my ( $sample_defaulted_to_en, $levellist ) =
 299           $installer->sample_data_sql_list($langchoice);
 300         $template->param( "en_sample_data" => $sample_defaulted_to_en );
 301         $template->param( "levelloop"      => $levellist );
 302         $template->param( "$op"            => 1 );
 303
 304     }
 305     elsif ( $op && $op eq 'choosemarc' ) {
 306         #
 307         #
 308         # 1ST install, 2nd sub-step : show the user the marcflavour available.
 309         #
 310         #
 311
 312 #Choose Marc Flavour
 313 #sql data are supposed to be located in installer/data/<dbms>/<language>/marcflavour/marcflavourname
 314 # Where <dbms> is database type according to DBD syntax
 315 # Where <language> is en|fr or any international abbreviation (provided language hash is updated... This will be a problem with internationlisation.)
 316 # Where <level> is a category of requirement : required, recommended optional
 317 # level should contain :
 318 #   SQL File for import With a readable name.
 319 #   txt File that explains what this SQL File is meant for.
 320 # Could be VERY useful to have A Big file for a kind of library.
 321 # But could also be useful to have some Authorised values data set prepared here.
 322 # Marcflavour Selection is achieved through radiobuttons.
 323         my $langchoice = $query->param('fwklanguage');
 324
 325         $langchoice = $query->cookie('KohaOpacLanguage') unless ($langchoice);
 326         $langchoice =~ s/[^a-zA-Z_-]*//g;
 327         my $dir =
 328           C4::Context->config('intranetdir')
 329           . "/installer/data/$info{dbms}/$langchoice/marcflavour";
 330         unless ( opendir( MYDIR, $dir ) ) {
 331             if ( $langchoice eq 'en' ) {
 332                 warn "cannot open MARC frameworks directory $dir";
 333             }
 334             else {
 335                 # if no translated MARC framework is available,
 336                 # default to English
 337                 $dir = C4::Context->config('intranetdir')
 338                   . "/installer/data/$info{dbms}/en/marcflavour";
 339                 opendir( MYDIR, $dir )
 340                   or warn "cannot open English MARC frameworks directory $dir";
 341             }
 342         }
 343         my @listdir = grep { !/^\./ && -d "$dir/$_" } readdir(MYDIR);
 344         closedir MYDIR;
 345         my $marcflavour = C4::Context->preference("marcflavour");
 346         my @flavourlist;
 347         foreach my $marc (@listdir) {
 348              my %cell=(
 349                  "label"=> ucfirst($marc),
 350                   "code"=>uc($marc),
 351                "checked"=> defined($marcflavour) ? uc($marc) eq $marcflavour : 0);
 352 #             $cell{"description"}= do { local $/ = undef; open INPUT "<$dir/$marc.txt"||"";<INPUT> };
 353              push @flavourlist, \%cell;
 354         }
 355         $template->param( "flavourloop" => \@flavourlist );
 356         $template->param( "$op"         => 1 );
 357     }
 358     elsif ( $op && $op eq 'importdatastructure' ) {
 359         #
 360         #
 361         # 1st install, 1st "sub-step" : import kohastructure
 362         #
 363         #
 364         my $error = $installer->load_db_schema();
 365         $template->param(
 366             "error" => $error,
 367             "$op"   => 1,
 368         );
 369     }
 370     elsif ( $op && $op eq 'updatestructure' ) {
 371         #
 372         # Not 1st install, the only sub-step : update database
 373         #
 374         #Do updatedatabase And report
 375
 376         if ( !defined $ENV{PERL5LIB} ) {
 377             my $find = "C4/Context.pm";
 378             my $path = $INC{$find};
 379             $path =~ s/\Q$find\E//;
 380             $ENV{PERL5LIB} = "$path:$path/installer";
 381             warn "# plack? inserted PERL5LIB $ENV{PERL5LIB}\n";
 382         }
 383
 384         my $now         = POSIX::strftime( "%Y-%m-%dT%H:%M:%S", localtime() );
 385         my $logdir      = C4::Context->config('logdir');
 386         my $dbversion   = C4::Context->preference('Version');
 387         my $kohaversion = Koha::version;
 388         $kohaversion =~ s/(.*\..*)\.(.*)\.(.*)/$1$2$3/;
 389
 390         my $filename_suffix = join '_', $now, $dbversion, $kohaversion;
 391         my ( $logfilepath, $logfilepath_errors ) = (
 392             chk_log( $logdir, "updatedatabase_$filename_suffix" ),
 393             chk_log( $logdir, "updatedatabase-error_$filename_suffix" )
 394         );
 395
 396         my $cmd = C4::Context->config("intranetdir")
 397           . "/installer/data/$info{dbms}/updatedatabase.pl >> $logfilepath 2>> $logfilepath_errors";
 398
 399         system($cmd );
 400
 401         my $fh;
 402         open( $fh, "<:encoding(utf-8)", $logfilepath )
 403           or die "Cannot open log file $logfilepath: $!";
 404         my @report = <$fh>;
 405         close $fh;
 406         if (@report) {
 407             $template->param( update_report =>
 408                   [ map { { line => $_ =~ s/\t/&emsp;&emsp;/gr } } split( /\n/, join( '', @report ) ) ]
 409             );
 410             $template->param( has_update_succeeds => 1 );
 411         }
 412         else {
 413             eval { `rm $logfilepath` };
 414         }
 415         open( $fh, "<:encoding(utf-8)", $logfilepath_errors )
 416           or die "Cannot open log file $logfilepath_errors: $!";
 417         @report = <$fh>;
 418         close $fh;
 419         if (@report) {
 420             $template->param( update_errors =>
 421                   [ map { { line => $_ } } split( /\n/, join( '', @report ) ) ]
 422             );
 423             $template->param( has_update_errors => 1 );
 424             warn
 425 "The following errors were returned while attempting to run the updatedatabase.pl script:\n";
 426             foreach my $line (@report) { warn "$line\n"; }
 427         }
 428         else {
 429             eval { `rm $logfilepath_errors` };
 430         }
 431         $template->param( $op => 1 );
 432     }
 433     else {
 434 #
 435 # check whether it's a 1st install or an update
 436 #
 437 #Check if there are enough tables.
 438 # Paul has cleaned up tables so reduced the count
 439 #I put it there because it implied a data import if condition was not satisfied.
 440         my $dbh = DBI->connect(
 441                 "DBI:$info{dbms}:dbname=$info{dbname};host=$info{hostname}"
 442                 . ( $info{port} ? ";port=$info{port}" : "" )
 443                 . ( $info{tlsoptions} ? $info{tlsoptions} : "" ),
 444                 $info{'user'}, $info{'password'}
 445         );
 446         my $rq;
 447         if ( $info{dbms} eq 'mysql' ) { $rq = $dbh->prepare("SHOW TABLES"); }
 448         elsif ( $info{dbms} eq 'Pg' ) {
 449             $rq = $dbh->prepare(
 450                 "SELECT *
 451                 FROM information_schema.tables
 452                 WHERE table_schema='public' and table_type='BASE TABLE';"
 453             );
 454         }
 455         $rq->execute;
 456         my $data = $rq->fetchall_arrayref( {} );
 457         my $count = scalar(@$data);
 458         #
 459         # we don't have tables, propose DB import
 460         #
 461         if ( $count < 70 ) {
 462             $template->param( "count" => $count, "proposeimport" => 1 );
 463         }
 464         else {
 465            #
 466            # we have tables, propose to select files to upload or updatedatabase
 467            #
 468             $template->param( "count" => $count, "default" => 1 );
 469      #
 470      # 1st part of step 3 : check if there is a databaseversion systempreference
 471      # if there is, then we just need to upgrade
 472      # if there is none, then we need to install the database
 473      #
 474             if ( C4::Context->preference('Version') ) {
 475                 my $dbversion = C4::Context->preference('Version');
 476                 $dbversion =~ /(.*)\.(..)(..)(...)/;
 477                 $dbversion = "$1.$2.$3.$4";
 478                 $template->param(
 479                     "upgrading"   => 1,
 480                     "dbversion"   => $dbversion,
 481                     "kohaversion" => Koha::version(),
 482                 );
 483             }
 484         }
 485     }
 486 }
 487 else {
 488
 489     # LANGUAGE SELECTION page by default
 490     # using opendir + language Hash
 491     my $languages_loop = getTranslatedLanguages('intranet');
 492     $template->param( installer_languages_loop => $languages_loop );
 493     if ($dbh) {
 494         my $rq =
 495           $dbh->prepare(
 496             "SELECT * from systempreferences WHERE variable='Version'");
 497         if ( $rq->execute ) {
 498             my ($version) = $rq->fetchrow;
 499             if ($version) {
 500                 print $query->redirect(
 501                     "/cgi-bin/koha/installer/install.pl?step=3");
 502                 exit;
 503             }
 504         }
 505     }
 506 }
 507 output_html_with_http_headers $query, $cookie, $template->output;
 508
 509 sub chk_log {    #returns a logfile in $dir or - if that failed - in temp dir
 510     my ( $dir, $name ) = @_;
 511     my $fn = $dir . '/' . $name . '.log';
 512     if ( !open my $fh, '>', $fn ) {
 513         $name .= '_XXXX';
 514         require File::Temp;
 515         ( $fh, $fn ) =
 516           File::Temp::tempfile( $name, TMPDIR => 1, SUFFIX => '.log' );
 517
 518         #if this should not work, let croak take over
 519     }
 520     return $fn;
 521 }