acqui/booksellers.pl

   1 #!/usr/bin/perl
   2
   3 #script to show suppliers and orders
   4
   5 # Copyright 2000-2002 Katipo Communications
   6 # Copyright 2008-2009 BibLibre SARL
   7 # Copyright 2010 PTFS Europe
   8 #
   9 # This file is part of Koha.
  10 #
  11 # Koha is free software; you can redistribute it and/or modify it
  12 # under the terms of the GNU General Public License as published by
  13 # the Free Software Foundation; either version 3 of the License, or
  14 # (at your option) any later version.
  15 #
  16 # Koha is distributed in the hope that it will be useful, but
  17 # WITHOUT ANY WARRANTY; without even the implied warranty of
  18 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  19 # GNU General Public License for more details.
  20 #
  21 # You should have received a copy of the GNU General Public License
  22 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  23
  24 =head1 NAME
  25
  26 booksellers.pl
  27
  28 =head1 DESCRIPTION
  29
  30 this script displays the list of suppliers & baskets like C<$supplier> given on input arg.
  31 thus, this page brings differents features like to display supplier's details,
  32 to add an order for a specific supplier or to just add a new supplier.
  33
  34 =head1 CGI PARAMETERS
  35
  36 =over 4
  37
  38 =item supplier
  39
  40 C<$supplier> is the string with which we search for a supplier
  41
  42 =back
  43
  44 =over 4
  45
  46 =item id or booksellerid
  47
  48 The id of the supplier whose baskets we will display
  49
  50 =back
  51
  52 =cut
  53
  54 use strict;
  55 use warnings;
  56 use C4::Auth;
  57 use C4::Biblio;
  58 use C4::Budgets;
  59 use C4::Output;
  60 use CGI qw ( -utf8 );
  61
  62 use C4::Acquisition qw/ GetBasketsInfosByBookseller CanUserManageBasket /;
  63 use C4::Context;
  64
  65 use Koha::Acquisition::Booksellers;
  66 use Koha::Patrons;
  67
  68 my $query = CGI->new;
  69 my ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
  70     {   template_name   => 'acqui/booksellers.tt',
  71         query           => $query,
  72         type            => 'intranet',
  73         authnotrequired => 0,
  74         flagsrequired   => { acquisition => '*' },
  75         debug           => 1,
  76     }
  77 );
  78
  79 #parameters
  80 my $supplier = $query->param('supplier');
  81 my $booksellerid = $query->param('booksellerid');
  82 my $allbaskets= $query->param('allbaskets')||0;
  83 my @suppliers;
  84
  85 if ($booksellerid) {
  86     push @suppliers, scalar Koha::Acquisition::Booksellers->find( $booksellerid );
  87 } else {
  88     @suppliers = Koha::Acquisition::Booksellers->search(
  89                         { name => { -like => "%$supplier%" } },
  90                         { order_by => { -asc => 'name' } } );
  91 }
  92
  93 my $supplier_count = @suppliers;
  94 if ( $supplier_count == 1 ) {
  95     $template->param(
  96         supplier_name => $suppliers[0]->name,
  97         booksellerid  => $suppliers[0]->id,
  98         basketcount   => $suppliers[0]->baskets->count,
  99         active        => $suppliers[0]->active,
 100     );
 101 }
 102
 103 my $uid;
 104 # FIXME This script should only be accessed by a valid logged in patron
 105 if ($loggedinuser) {
 106     # FIXME Should not be needed, logged in patron should be cached
 107     $uid = Koha::Patrons->find( $loggedinuser )->userid;
 108 }
 109
 110 my $userenv = C4::Context::userenv;
 111 my $viewbaskets = C4::Context->preference('AcqViewBaskets');
 112
 113 my $userbranch = $userenv->{branch};
 114
 115 my $budgets = GetBudgetHierarchy;
 116 my $has_budgets = 0;
 117 foreach my $r (@{$budgets}) {
 118     if (!defined $r->{budget_amount} || $r->{budget_amount} == 0) {
 119         next;
 120     }
 121     next unless (CanUserUseBudget($loggedinuser, $r, $userflags));
 122
 123     $has_budgets = 1;
 124     last;
 125 }
 126
 127 #build result page
 128 my $loop_suppliers = [];
 129
 130 for my $vendor (@suppliers) {
 131     my $baskets = GetBasketsInfosByBookseller( $vendor->id, $allbaskets );
 132
 133     my $loop_basket = [];
 134
 135     for my $basket ( @{$baskets} ) {
 136         if (CanUserManageBasket($loggedinuser, $basket, $userflags)) {
 137             my $patron = Koha::Patrons->find( $basket->{authorisedby} );
 138             foreach (qw(total_items total_biblios expected_items)) {
 139                 $basket->{$_} ||= 0;
 140             }
 141             if ( $patron ) {
 142                 $basket->{authorisedby_firstname} = $patron->firstname;
 143                 $basket->{authorisedby_surname} = $patron->surname;
 144             }
 145             if ($basket->{basketgroupid}) {
 146                 my $basketgroup = C4::Acquisition::GetBasketgroup($basket->{basketgroupid});
 147                 if ($basketgroup) {
 148                     $basket->{basketgroup} = $basketgroup;
 149                 }
 150             }
 151             push @{$loop_basket}, $basket;
 152         }
 153     }
 154
 155     push @{$loop_suppliers},
 156       { loop_basket => $loop_basket,
 157         booksellerid  => $vendor->id,
 158         name        => $vendor->name,
 159         active      => $vendor->active,
 160       };
 161
 162 }
 163 $template->param(
 164     loop_suppliers => $loop_suppliers,
 165     supplier       => ( $booksellerid || $supplier ),
 166     count          => $supplier_count,
 167     has_budgets          => $has_budgets,
 168 );
 169 $template->{VARS}->{'allbaskets'} = $allbaskets;
 170
 171 output_html_with_http_headers $query, $cookie, $template->output;