C4/Auth_with_ldap.pm

   1 package C4::Auth_with_ldap;
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use strict;
  21 #use warnings; FIXME - Bug 2505
  22 use Carp;
  23
  24 use C4::Debug;
  25 use C4::Context;
  26 use C4::Members qw(AddMember changepassword);
  27 use C4::Members::Attributes;
  28 use C4::Members::AttributeTypes;
  29 use C4::Members::Messaging;
  30 use C4::Auth qw(checkpw_internal);
  31 use Koha::AuthUtils qw(hash_password);
  32 use List::MoreUtils qw( any );
  33 use Net::LDAP;
  34 use Net::LDAP::Filter;
  35
  36 use vars qw($VERSION @ISA @EXPORT @EXPORT_OK %EXPORT_TAGS $debug);
  37
  38 BEGIN {
  39         require Exporter;
  40     $VERSION = 3.07.00.049;     # set the version for version checking
  41         @ISA    = qw(Exporter);
  42         @EXPORT = qw( checkpw_ldap );
  43 }
  44
  45 # Redefine checkpw_ldap:
  46 # connect to LDAP (named or anonymous)
  47 # ~ retrieves $userid from KOHA_CONF mapping
  48 # ~ then compares $password with userPassword
  49 # ~ then gets the LDAP entry
  50 # ~ and calls the memberadd if necessary
  51
  52 sub ldapserver_error {
  53         return sprintf('No ldapserver "%s" defined in KOHA_CONF: ' . $ENV{KOHA_CONF}, shift);
  54 }
  55
  56 use vars qw($mapping @ldaphosts $base $ldapname $ldappassword);
  57 my $context = C4::Context->new()        or die 'C4::Context->new failed';
  58 my $ldap = C4::Context->config("ldapserver") or die 'No "ldapserver" in server hash from KOHA_CONF: ' . $ENV{KOHA_CONF};
  59 my $prefhost  = $ldap->{hostname}       or die ldapserver_error('hostname');
  60 my $base      = $ldap->{base}           or die ldapserver_error('base');
  61 $ldapname     = $ldap->{user}           ;
  62 $ldappassword = $ldap->{pass}           ;
  63 our %mapping  = %{$ldap->{mapping}}; # FIXME dpavlin -- don't die because of || (); from 6eaf8511c70eb82d797c941ef528f4310a15e9f9
  64 my @mapkeys = keys %mapping;
  65 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (  total  ): ", join ' ', @mapkeys, "\n";
  66 @mapkeys = grep {defined $mapping{$_}->{is}} @mapkeys;
  67 $debug and print STDERR "Got ", scalar(@mapkeys), " ldap mapkeys (populated): ", join ' ', @mapkeys, "\n";
  68
  69 my %config = (
  70         anonymous => ($ldapname and $ldappassword) ? 0 : 1,
  71     replicate => defined($ldap->{replicate}) ? $ldap->{replicate} : 1,  #    add from LDAP to Koha database for new user
  72        update => defined($ldap->{update}   ) ? $ldap->{update}    : 1,  # update from LDAP to Koha database for existing user
  73 );
  74
  75 sub description {
  76         my $result = shift or return;
  77         return "LDAP error #" . $result->code
  78                         . ": " . $result->error_name . "\n"
  79                         . "# " . $result->error_text . "\n";
  80 }
  81
  82 sub search_method {
  83     my $db     = shift or return;
  84     my $userid = shift or return;
  85         my $uid_field = $mapping{userid}->{is} or die ldapserver_error("mapping for 'userid'");
  86         my $filter = Net::LDAP::Filter->new("$uid_field=$userid") or die "Failed to create new Net::LDAP::Filter";
  87         my $search = $db->search(
  88                   base => $base,
  89                 filter => $filter,
  90                 # attrs => ['*'],
  91     );
  92     die "LDAP search failed to return object : " . $search->error if $search->code;
  93
  94         my $count = $search->count;
  95         if ($search->code > 0) {
  96                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count) . description($search);
  97                 return 0;
  98         }
  99         if ($count != 1) {
 100                 warn sprintf("LDAP Auth rejected : %s gets %d hits\n", $filter->as_string, $count);
 101                 return 0;
 102         }
 103     return $search;
 104 }
 105
 106 sub checkpw_ldap {
 107     my ($dbh, $userid, $password) = @_;
 108     my @hosts = split(',', $prefhost);
 109     my $db = Net::LDAP->new(\@hosts);
 110     unless ( $db ) {
 111         warn "LDAP connexion failed";
 112         return 0;
 113     }
 114
 115         #$debug and $db->debug(5);
 116     my $userldapentry;
 117
 118     if ( $ldap->{auth_by_bind} ) {
 119         my $principal_name;
 120         if ( $ldap->{anonymous_bind} ) {
 121
 122             # Perform an anonymous bind
 123             my $res = $db->bind;
 124             if ( $res->code ) {
 125                 warn "Anonymous LDAP bind failed: " . description($res);
 126                 return 0;
 127             }
 128
 129             # Perform a LDAP search for the given username
 130             my $search = search_method( $db, $userid )
 131               or return 0;    # warnings are in the sub
 132             $userldapentry = $search->shift_entry;
 133             $principal_name = $userldapentry->dn;
 134         }
 135         else {
 136             $principal_name = $ldap->{principal_name};
 137             if ( $principal_name and $principal_name =~ /\%/ ) {
 138                 $principal_name = sprintf( $principal_name, $userid );
 139             }
 140             else {
 141                 $principal_name = $userid;
 142             }
 143         }
 144
 145         # Perform a LDAP bind for the given username using the matched DN
 146         my $res = $db->bind( $principal_name, password => $password );
 147         if ( $res->code ) {
 148             if ( $ldap->{anonymous_bind} ) {
 149                 # With anonymous_bind approach we can be sure we have found the correct user
 150                 # and that any 'code' response indicates a 'bad' user (be that blocked, banned
 151                 # or password changed). We should not fall back to local accounts in this case.
 152                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 153                 return -1;
 154             } else {
 155                 # Without a anonymous_bind, we cannot be sure we are looking at a valid ldap user
 156                 # at all, and thus we should fall back to local logins to restore previous behaviour
 157                 # see bug 12831
 158                 warn "LDAP bind failed as kohauser $userid: " . description($res);
 159                 return 0;
 160             }
 161         }
 162         if ( !defined($userldapentry)
 163             && ( $config{update} or $config{replicate} ) )
 164         {
 165             my $search = search_method( $db, $userid ) or return 0;
 166             $userldapentry = $search->shift_entry;
 167         }
 168     } else {
 169                 my $res = ($config{anonymous}) ? $db->bind : $db->bind($ldapname, password=>$ldappassword);
 170                 if ($res->code) {               # connection refused
 171                         warn "LDAP bind failed as ldapuser " . ($ldapname || '[ANONYMOUS]') . ": " . description($res);
 172                         return 0;
 173                 }
 174         my $search = search_method($db, $userid) or return 0;   # warnings are in the sub
 175         $userldapentry = $search->shift_entry;
 176                 my $cmpmesg = $db->compare( $userldapentry, attr=>'userpassword', value => $password );
 177                 if ($cmpmesg->code != 6) {
 178                         warn "LDAP Auth rejected : invalid password for user '$userid'. " . description($cmpmesg);
 179                         return -1;
 180                 }
 181         }
 182
 183     # To get here, LDAP has accepted our user's login attempt.
 184     # But we still have work to do.  See perldoc below for detailed breakdown.
 185
 186     my (%borrower);
 187         my ($borrowernumber,$cardnumber,$local_userid,$savedpw) = exists_local($userid);
 188
 189     if (( $borrowernumber and $config{update}   ) or
 190         (!$borrowernumber and $config{replicate})   ) {
 191         %borrower = ldap_entry_2_hash($userldapentry,$userid);
 192         $debug and print STDERR "checkpw_ldap received \%borrower w/ " . keys(%borrower), " keys: ", join(' ', keys %borrower), "\n";
 193     }
 194
 195     if ($borrowernumber) {
 196         if ($config{update}) { # A1, B1
 197             my $c2 = &update_local($local_userid,$password,$borrowernumber,\%borrower) || '';
 198             ($cardnumber eq $c2) or warn "update_local returned cardnumber '$c2' instead of '$cardnumber'";
 199         } else { # C1, D1
 200             # maybe update just the password?
 201                 return(1, $cardnumber, $local_userid);
 202         }
 203     } elsif ($config{replicate}) { # A2, C2
 204         $borrowernumber = AddMember(%borrower) or die "AddMember failed";
 205         C4::Members::Messaging::SetMessagingPreferencesFromDefaults( { borrowernumber => $borrowernumber, categorycode => $borrower{'categorycode'} } );
 206    } else {
 207         return 0;   # B2, D2
 208     }
 209     if (C4::Context->preference('ExtendedPatronAttributes') && $borrowernumber && ($config{update} ||$config{replicate})) {
 210         foreach my $attribute_type ( C4::Members::AttributeTypes::GetAttributeTypes() ) {
 211             my $code = $attribute_type->{code};
 212             unless (exists($borrower{$code}) && $borrower{$code} !~ m/^\s*$/ ) {
 213                 next;
 214             }
 215             if (C4::Members::Attributes::CheckUniqueness($code, $borrower{$code}, $borrowernumber)) {
 216                 C4::Members::Attributes::UpdateBorrowerAttribute($borrowernumber, {code => $code, value => $borrower{$code}});
 217             } else {
 218                 warn "ERROR_extended_unique_id_failed $code $borrower{$code}";
 219             }
 220         }
 221     }
 222     return(1, $cardnumber, $userid);
 223 }
 224
 225 # Pass LDAP entry object and local cardnumber (userid).
 226 # Returns borrower hash.
 227 # Edit KOHA_CONF so $memberhash{'xxx'} fits your ldap structure.
 228 # Ensure that mandatory fields are correctly filled!
 229 #
 230 sub ldap_entry_2_hash {
 231         my $userldapentry = shift;
 232         my %borrower = ( cardnumber => shift );
 233         my %memberhash;
 234         $userldapentry->exists('uid');  # This is bad, but required!  By side-effect, this initializes the attrs hash.
 235         if ($debug) {
 236                 foreach (keys %$userldapentry) {
 237                         print STDERR "\n\nLDAP key: $_\t", sprintf('(%s)', ref $userldapentry->{$_}), "\n";
 238                 }
 239         }
 240         my $x = $userldapentry->{attrs} or return;
 241         foreach (keys %$x) {
 242                 $memberhash{$_} = join ' ', @{$x->{$_}};
 243                 $debug and print STDERR sprintf("building \$memberhash{%s} = ", $_, join(' ', @{$x->{$_}})), "\n";
 244         }
 245         $debug and print STDERR "Finsihed \%memberhash has ", scalar(keys %memberhash), " keys\n",
 246                                         "Referencing \%mapping with ", scalar(keys %mapping), " keys\n";
 247         foreach my $key (keys %mapping) {
 248                 my  $data = $memberhash{ lc($mapping{$key}->{is}) }; # Net::LDAP returns all names in lowercase
 249                 $debug and printf STDERR "mapping %20s ==> %-20s (%s)\n", $key, $mapping{$key}->{is}, $data;
 250                 unless (defined $data) {
 251                         $data = $mapping{$key}->{content} || '';        # default or failsafe ''
 252                 }
 253                 $borrower{$key} = ($data ne '') ? $data : ' ' ;
 254         }
 255         $borrower{initials} = $memberhash{initials} ||
 256                 ( substr($borrower{'firstname'},0,1)
 257                 . substr($borrower{ 'surname' },0,1)
 258                 . " ");
 259
 260         # check if categorycode exists, if not, fallback to default from koha-conf.xml
 261         my $dbh = C4::Context->dbh;
 262         my $sth = $dbh->prepare("SELECT categorycode FROM categories WHERE categorycode = ?");
 263         $sth->execute( uc($borrower{'categorycode'}) );
 264         unless ( my $row = $sth->fetchrow_hashref ) {
 265                 my $default = $mapping{'categorycode'}->{content};
 266                 $debug && warn "Can't find ", $borrower{'categorycode'}, " default to: $default for ", $borrower{userid};
 267                 $borrower{'categorycode'} = $default
 268         }
 269
 270         return %borrower;
 271 }
 272
 273 sub exists_local {
 274         my $arg = shift;
 275         my $dbh = C4::Context->dbh;
 276         my $select = "SELECT borrowernumber,cardnumber,userid,password FROM borrowers ";
 277
 278         my $sth = $dbh->prepare("$select WHERE userid=?");      # was cardnumber=?
 279         $sth->execute($arg);
 280         $debug and printf STDERR "Userid '$arg' exists_local? %s\n", $sth->rows;
 281         ($sth->rows == 1) and return $sth->fetchrow;
 282
 283         $sth = $dbh->prepare("$select WHERE cardnumber=?");
 284         $sth->execute($arg);
 285         $debug and printf STDERR "Cardnumber '$arg' exists_local? %s\n", $sth->rows;
 286         ($sth->rows == 1) and return $sth->fetchrow;
 287         return 0;
 288 }
 289
 290 # This function performs a password update, given the userid, borrowerid,
 291 # and digested password. It will verify that things are correct and return the
 292 # borrowers cardnumber. The idea is that it is used to keep the local
 293 # passwords in sync with the LDAP passwords.
 294 #
 295 #   $cardnum = _do_changepassword($userid, $borrowerid, $digest)
 296 #
 297 # Note: if the LDAP config has the update_password tag set to a false value,
 298 # then this will not update the password, it will simply return the cardnumber.
 299 sub _do_changepassword {
 300     my ($userid, $borrowerid, $password) = @_;
 301
 302     if ( exists( $ldap->{update_password} ) && !$ldap->{update_password} ) {
 303
 304         # We don't store the password in the database
 305         my $sth = C4::Context->dbh->prepare(
 306             'SELECT cardnumber FROM borrowers WHERE borrowernumber=?');
 307         $sth->execute($borrowerid);
 308         die "Unable to access borrowernumber "
 309             . "with userid=$userid, "
 310             . "borrowernumber=$borrowerid"
 311           if !$sth->rows;
 312         my ($cardnum) = $sth->fetchrow;
 313         $sth = C4::Context->dbh->prepare(
 314             'UPDATE borrowers SET password = null WHERE borrowernumber=?');
 315         $sth->execute($borrowerid);
 316         return $cardnum;
 317     }
 318     my $digest = hash_password($password);
 319
 320     $debug and print STDERR "changing local password for borrowernumber=$borrowerid to '$digest'\n";
 321     changepassword($userid, $borrowerid, $digest);
 322
 323     my ($ok, $cardnum) = checkpw_internal(C4::Context->dbh, $userid, $password);
 324     return $cardnum if $ok;
 325
 326     warn "Password mismatch after update to borrowernumber=$borrowerid";
 327     return;
 328 }
 329
 330 sub update_local {
 331     my $userid     = shift or croak "No userid";
 332     my $password   = shift or croak "No password";
 333     my $borrowerid = shift or croak "No borrowerid";
 334     my $borrower   = shift or croak "No borrower record";
 335
 336     my @keys = keys %$borrower;
 337     my $dbh = C4::Context->dbh;
 338     my $query = "UPDATE  borrowers\nSET     " .
 339         join(',', map {"$_=?"} @keys) .
 340         "\nWHERE   borrowernumber=? ";
 341     my $sth = $dbh->prepare($query);
 342     if ($debug) {
 343         print STDERR $query, "\n",
 344             join "\n", map {"$_ = '" . $borrower->{$_} . "'"} @keys;
 345         print STDERR "\nuserid = $userid\n";
 346     }
 347     $sth->execute(
 348         ((map {$borrower->{$_}} @keys), $borrowerid)
 349     );
 350
 351     # MODIFY PASSWORD/LOGIN if password was mapped
 352     _do_changepassword($userid, $borrowerid, $password) if $borrower->{'password'};
 353 }
 354
 355 1;
 356 __END__
 357
 358 =head1 NAME
 359
 360 C4::Auth - Authenticates Koha users
 361
 362 =head1 SYNOPSIS
 363
 364   use C4::Auth_with_ldap;
 365
 366 =head1 LDAP Configuration
 367
 368     This module is specific to LDAP authentification. It requires Net::LDAP package and one or more
 369         working LDAP servers.
 370         To use it :
 371            * Modify ldapserver element in KOHA_CONF
 372            * Establish field mapping in <mapping> element.
 373
 374         For example, if your user records are stored according to the inetOrgPerson schema, RFC#2798,
 375         the username would match the "uid" field, and the password should match the "userpassword" field.
 376
 377         Make sure that ALL required fields are populated by your LDAP database (and mapped in KOHA_CONF).
 378         What are the required fields?  Well, in mysql you can check the database table "borrowers" like this:
 379
 380         mysql> show COLUMNS from borrowers;
 381                 +---------------------+--------------+------+-----+---------+----------------+
 382                 | Field               | Type         | Null | Key | Default | Extra          |
 383                 +---------------------+--------------+------+-----+---------+----------------+
 384                 | borrowernumber      | int(11)      | NO   | PRI | NULL    | auto_increment |
 385                 | cardnumber          | varchar(16)  | YES  | UNI | NULL    |                |
 386                 | surname             | mediumtext   | NO   |     | NULL    |                |
 387                 | firstname           | text         | YES  |     | NULL    |                |
 388                 | title               | mediumtext   | YES  |     | NULL    |                |
 389                 | othernames          | mediumtext   | YES  |     | NULL    |                |
 390                 | initials            | text         | YES  |     | NULL    |                |
 391                 | streetnumber        | varchar(10)  | YES  |     | NULL    |                |
 392                 | streettype          | varchar(50)  | YES  |     | NULL    |                |
 393                 | address             | mediumtext   | NO   |     | NULL    |                |
 394                 | address2            | text         | YES  |     | NULL    |                |
 395                 | city                | mediumtext   | NO   |     | NULL    |                |
 396                 | state               | mediumtext   | YES  |     | NULL    |                |
 397                 | zipcode             | varchar(25)  | YES  |     | NULL    |                |
 398                 | country             | text         | YES  |     | NULL    |                |
 399                 | email               | mediumtext   | YES  |     | NULL    |                |
 400                 | phone               | text         | YES  |     | NULL    |                |
 401                 | mobile              | varchar(50)  | YES  |     | NULL    |                |
 402                 | fax                 | mediumtext   | YES  |     | NULL    |                |
 403                 | emailpro            | text         | YES  |     | NULL    |                |
 404                 | phonepro            | text         | YES  |     | NULL    |                |
 405                 | B_streetnumber      | varchar(10)  | YES  |     | NULL    |                |
 406                 | B_streettype        | varchar(50)  | YES  |     | NULL    |                |
 407                 | B_address           | varchar(100) | YES  |     | NULL    |                |
 408                 | B_address2          | text         | YES  |     | NULL    |                |
 409                 | B_city              | mediumtext   | YES  |     | NULL    |                |
 410                 | B_state             | mediumtext   | YES  |     | NULL    |                |
 411                 | B_zipcode           | varchar(25)  | YES  |     | NULL    |                |
 412                 | B_country           | text         | YES  |     | NULL    |                |
 413                 | B_email             | text         | YES  |     | NULL    |                |
 414                 | B_phone             | mediumtext   | YES  |     | NULL    |                |
 415                 | dateofbirth         | date         | YES  |     | NULL    |                |
 416                 | branchcode          | varchar(10)  | NO   | MUL |         |                |
 417                 | categorycode        | varchar(10)  | NO   | MUL |         |                |
 418                 | dateenrolled        | date         | YES  |     | NULL    |                |
 419                 | dateexpiry          | date         | YES  |     | NULL    |                |
 420                 | gonenoaddress       | tinyint(1)   | YES  |     | NULL    |                |
 421                 | lost                | tinyint(1)   | YES  |     | NULL    |                |
 422                 | debarred            | date         | YES  |     | NULL    |                |
 423                 | debarredcomment     | varchar(255) | YES  |     | NULL    |                |
 424                 | contactname         | mediumtext   | YES  |     | NULL    |                |
 425                 | contactfirstname    | text         | YES  |     | NULL    |                |
 426                 | contacttitle        | text         | YES  |     | NULL    |                |
 427                 | guarantorid         | int(11)      | YES  | MUL | NULL    |                |
 428                 | borrowernotes       | mediumtext   | YES  |     | NULL    |                |
 429                 | relationship        | varchar(100) | YES  |     | NULL    |                |
 430                 | ethnicity           | varchar(50)  | YES  |     | NULL    |                |
 431                 | ethnotes            | varchar(255) | YES  |     | NULL    |                |
 432                 | sex                 | varchar(1)   | YES  |     | NULL    |                |
 433                 | password            | varchar(30)  | YES  |     | NULL    |                |
 434                 | flags               | int(11)      | YES  |     | NULL    |                |
 435                 | userid              | varchar(30)  | YES  | MUL | NULL    |                |
 436                 | opacnote            | mediumtext   | YES  |     | NULL    |                |
 437                 | contactnote         | varchar(255) | YES  |     | NULL    |                |
 438                 | sort1               | varchar(80)  | YES  |     | NULL    |                |
 439                 | sort2               | varchar(80)  | YES  |     | NULL    |                |
 440                 | altcontactfirstname | varchar(255) | YES  |     | NULL    |                |
 441                 | altcontactsurname   | varchar(255) | YES  |     | NULL    |                |
 442                 | altcontactaddress1  | varchar(255) | YES  |     | NULL    |                |
 443                 | altcontactaddress2  | varchar(255) | YES  |     | NULL    |                |
 444                 | altcontactaddress3  | varchar(255) | YES  |     | NULL    |                |
 445                 | altcontactstate     | mediumtext   | YES  |     | NULL    |                |
 446                 | altcontactzipcode   | varchar(50)  | YES  |     | NULL    |                |
 447                 | altcontactcountry   | text         | YES  |     | NULL    |                |
 448                 | altcontactphone     | varchar(50)  | YES  |     | NULL    |                |
 449                 | smsalertnumber      | varchar(50)  | YES  |     | NULL    |                |
 450                 | privacy             | int(11)      | NO   |     | 1       |                |
 451                 +---------------------+--------------+------+-----+---------+----------------+
 452                 66 rows in set (0.00 sec)
 453                 Where Null="NO", the field is required.
 454
 455 =head1 KOHA_CONF and field mapping
 456
 457 Example XML stanza for LDAP configuration in KOHA_CONF.
 458
 459  <config>
 460   ...
 461   <useldapserver>1</useldapserver>
 462   <!-- LDAP SERVER (optional) -->
 463   <ldapserver id="ldapserver">
 464     <hostname>localhost</hostname>
 465     <base>dc=metavore,dc=com</base>
 466     <user>cn=Manager,dc=metavore,dc=com</user>             <!-- DN, if not anonymous -->
 467     <pass>metavore</pass>          <!-- password, if not anonymous -->
 468     <replicate>1</replicate>       <!-- add new users from LDAP to Koha database -->
 469     <update>1</update>             <!-- update existing users in Koha database -->
 470     <auth_by_bind>0</auth_by_bind> <!-- set to 1 to authenticate by binding instead of
 471                                         password comparison, e.g., to use Active Directory -->
 472     <anonymous_bind>0</anonymous_bind> <!-- set to 1 if users should be searched using
 473                                             an anonymous bind, even when auth_by_bind is on -->
 474     <principal_name>%s@my_domain.com</principal_name>
 475                                    <!-- optional, for auth_by_bind: a printf format to make userPrincipalName from koha userid.
 476                                         Not used with anonymous_bind. -->
 477     <update_password>1</update_password> <!-- set to 0 if you don't want LDAP passwords
 478                                               synced to the local database -->
 479     <mapping>                  <!-- match koha SQL field names to your LDAP record field names -->
 480       <firstname    is="givenname"      ></firstname>
 481       <surname      is="sn"             ></surname>
 482       <address      is="postaladdress"  ></address>
 483       <city         is="l"              >Athens, OH</city>
 484       <zipcode      is="postalcode"     ></zipcode>
 485       <branchcode   is="branch"         >MAIN</branchcode>
 486       <userid       is="uid"            ></userid>
 487       <password     is="userpassword"   ></password>
 488       <email        is="mail"           ></email>
 489       <categorycode is="employeetype"   >PT</categorycode>
 490       <phone        is="telephonenumber"></phone>
 491     </mapping>
 492   </ldapserver>
 493  </config>
 494
 495 The <mapping> subelements establish the relationship between mysql fields and LDAP attributes. The element name
 496 is the column in mysql, with the "is" characteristic set to the LDAP attribute name.  Optionally, any content
 497 between the element tags is taken as the default value.  In this example, the default categorycode is "PT" (for
 498 patron).
 499
 500 =head1 CONFIGURATION
 501
 502 Once a user has been accepted by the LDAP server, there are several possibilities for how Koha will behave, depending on
 503 your configuration and the presence of a matching Koha user in your local DB:
 504
 505                          LOCAL_USER
 506  OPTION UPDATE REPLICATE  EXISTS?  RESULT
 507    A1      1       1        1      OK : We're updating them anyway.
 508    A2      1       1        0      OK : We're adding them anyway.
 509    B1      1       0        1      OK : We update them.
 510    B2      1       0        0     FAIL: We cannot add new user.
 511    C1      0       1        1      OK : We do nothing.  (maybe should update password?)
 512    C2      0       1        0      OK : We add the new user.
 513    D1      0       0        1      OK : We do nothing.  (maybe should update password?)
 514    D2      0       0        0     FAIL: We cannot add new user.
 515
 516 Note: failure here just means that Koha will fallback to checking the local DB.  That is, a given user could login with
 517 their LDAP password OR their local one.  If this is a problem, then you should enable update and supply a mapping for
 518 password.  Then the local value will be updated at successful LDAP login and the passwords will be synced.
 519
 520 If you choose NOT to update local users, the borrowers table will not be affected at all.
 521 Note that this means that patron passwords may appear to change if LDAP is ever disabled, because
 522 the local table never contained the LDAP values.
 523
 524 =head2 auth_by_bind
 525
 526 Binds as the user instead of retrieving their record.  Recommended if update disabled.
 527
 528 =head2 principal_name
 529
 530 Provides an optional sprintf-style format for manipulating the userid before the bind.
 531 Even though the userPrincipalName is one intended target, any uniquely identifying
 532 attribute that the server allows to be used for binding could be used.
 533
 534 Currently, principal_name only operates when auth_by_bind is enabled.
 535
 536 =head2 update_password
 537
 538 If this tag is left out or set to a true value, then the user's LDAP password
 539 will be stored (hashed) in the local Koha database. If you don't want this
 540 to happen, then set the value of this to '0'. Note that if passwords are not
 541 stored locally, and the connection to the LDAP system fails, then the users
 542 will not be able to log in at all.
 543
 544 =head2 Active Directory
 545
 546 The auth_by_bind and principal_name settings are recommended for Active Directory.
 547
 548 Under default Active Directory rules, we cannot determine the distinguishedName attribute from the Koha userid as reliably as
 549 we would typically under openldap.  Instead of:
 550
 551     distinguishedName: CN=barnes.7,DC=my_company,DC=com
 552
 553 We might get:
 554
 555     distinguishedName: CN=Barnes\, Jim,OU=Test Accounts,OU=User Accounts,DC=my_company,DC=com
 556
 557 Matching that would require us to know more info about the account (firstname, surname) and to include punctuation and whitespace
 558 in Koha userids.  But the userPrincipalName should be consistent, something like:
 559
 560     userPrincipalName: barnes.7@my_company.com
 561
 562 Therefore it is often easier to bind to Active Directory with userPrincipalName, effectively the
 563 canonical email address for that user, or what it would be if email were enabled for them.  If Koha userid values
 564 will match the username portion of the userPrincipalName, and the domain suffix is the same for all users, then use principal_name
 565 like this:
 566     <principal_name>%s@core.my_company.com</principal_name>
 567
 568 The user of the previous example, barnes.7, would then attempt to bind as:
 569     barnes.7@core.my_company.com
 570
 571 =head1 SEE ALSO
 572
 573 CGI(3)
 574
 575 Net::LDAP()
 576
 577 XML::Simple()
 578
 579 Digest::MD5(3)
 580
 581 sprintf()
 582
 583 =cut
 584
 585 # For reference, here's an important difference in the data structure we rely on.
 586 # ========================================
 587 # Using attrs instead of {asn}->attributes
 588 # ========================================
 589 #
 590 #       LDAP key: ->{             cn} = ARRAY w/ 3 members.
 591 #       LDAP key: ->{             cn}->{           sss} = sss
 592 #       LDAP key: ->{             cn}->{   Steve Smith} = Steve Smith
 593 #       LDAP key: ->{             cn}->{Steve S. Smith} = Steve S. Smith
 594 #
 595 #       LDAP key: ->{      givenname} = ARRAY w/ 1 members.
 596 #       LDAP key: ->{      givenname}->{Steve} = Steve
 597 #