Koha/Objects.pm

   1 package Koha::Objects;
   2
   3 # Copyright ByWater Solutions 2014
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 3 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along
  17 # with Koha; if not, write to the Free Software Foundation, Inc.,
  18 # 51 Franklin Street, Fifth Floor, Boston, MA 02110-1301 USA.
  19
  20 use Modern::Perl;
  21
  22 use Carp;
  23
  24 use Koha::Database;
  25
  26 =head1 NAME
  27
  28 Koha::Objects - Koha Object set base class
  29
  30 =head1 SYNOPSIS
  31
  32     use Koha::Objects;
  33     my @objects = Koha::Objects->search({ borrowernumber => $borrowernumber});
  34
  35 =head1 DESCRIPTION
  36
  37 This class must be subclassed.
  38
  39 =head1 API
  40
  41 =head2 Class Methods
  42
  43 =cut
  44
  45 =head3 Koha::Objects->new();
  46
  47 my $object = Koha::Objects->new();
  48
  49 =cut
  50
  51 sub new {
  52     my ($class) = @_;
  53     my $self = {};
  54
  55     bless( $self, $class );
  56 }
  57
  58 =head3 Koha::Objects->_new_from_dbic();
  59
  60 my $object = Koha::Objects->_new_from_dbic( $resultset );
  61
  62 =cut
  63
  64 sub _new_from_dbic {
  65     my ( $class, $resultset ) = @_;
  66     my $self = { _resultset => $resultset };
  67
  68     bless( $self, $class );
  69 }
  70
  71 =head3 Koha::Objects->find();
  72
  73 my $object = Koha::Objects->find($id);
  74 my $object = Koha::Objects->find( { keypart1 => $keypart1, keypart2 => $keypart2 } );
  75
  76 =cut
  77
  78 sub find {
  79     my ( $self, $id ) = @_;
  80
  81     return unless defined($id);
  82
  83     my $result = $self->_resultset()->find($id);
  84
  85     return unless $result;
  86
  87     my $object = $self->object_class()->_new_from_dbic( $result );
  88
  89     return $object;
  90 }
  91
  92 =head3 Koha::Objects->search();
  93
  94 my @objects = Koha::Objects->search($params);
  95
  96 =cut
  97
  98 sub search {
  99     my ( $self, $params, $attributes ) = @_;
 100
 101     if (wantarray) {
 102         my @dbic_rows = $self->_resultset()->search($params, $attributes);
 103
 104         return $self->_wrap(@dbic_rows);
 105
 106     }
 107     else {
 108         my $class = ref($self) ? ref($self) : $self;
 109         my $rs = $self->_resultset()->search($params, $attributes);
 110
 111         return $class->_new_from_dbic($rs);
 112     }
 113 }
 114
 115 =head3 Koha::Objects->count();
 116
 117 my @objects = Koha::Objects->count($params);
 118
 119 =cut
 120
 121 sub count {
 122     my ( $self, $params ) = @_;
 123
 124     return $self->_resultset()->count($params);
 125 }
 126
 127 =head3 Koha::Objects->pager();
 128
 129 my $pager = Koha::Objects->pager;
 130
 131 =cut
 132
 133 sub pager {
 134     my ( $self ) = @_;
 135     return $self->_resultset->pager;
 136 }
 137
 138 =head3 Koha::Objects->next();
 139
 140 my $object = Koha::Objects->next();
 141
 142 Returns the next object that is part of this set.
 143 Returns undef if there are no more objects to return.
 144
 145 =cut
 146
 147 sub next {
 148     my ( $self ) = @_;
 149
 150     my $result = $self->_resultset()->next();
 151     return unless $result;
 152
 153     my $object = $self->object_class()->_new_from_dbic( $result );
 154
 155     return $object;
 156 }
 157
 158 =head3 Koha::Objects->reset();
 159
 160 Koha::Objects->reset();
 161
 162 resets iteration so the next call to next() will start agein
 163 with the first object in a set.
 164
 165 =cut
 166
 167 sub reset {
 168     my ( $self ) = @_;
 169
 170     $self->_resultset()->reset();
 171
 172     return $self;
 173 }
 174
 175 =head3 Koha::Objects->as_list();
 176
 177 Koha::Objects->as_list();
 178
 179 Returns an arrayref of the objects in this set.
 180
 181 =cut
 182
 183 sub as_list {
 184     my ( $self ) = @_;
 185
 186     my @dbic_rows = $self->_resultset()->all();
 187
 188     my @objects = $self->_wrap(@dbic_rows);
 189
 190     return wantarray ? @objects : \@objects;
 191 }
 192
 193 =head3 Koha::Objects->unblessed
 194
 195 Returns an unblessed representation of objects.
 196
 197 =cut
 198
 199 sub unblessed {
 200     my ($self) = @_;
 201
 202     return [ map { $_->unblessed } $self->as_list ];
 203 }
 204
 205 =head3 Koha::Objects->_wrap
 206
 207 wraps the DBIC object in a corresponding Koha object
 208
 209 =cut
 210
 211 sub _wrap {
 212     my ( $self, @dbic_rows ) = @_;
 213
 214     my @objects = map { $self->object_class()->_new_from_dbic( $_ ) } @dbic_rows;
 215
 216     return @objects;
 217 }
 218
 219 =head3 Koha::Objects->_resultset
 220
 221 Returns the internal resultset or creates it if undefined
 222
 223 =cut
 224
 225 sub _resultset {
 226     my ($self) = @_;
 227
 228     if ( ref($self) ) {
 229         $self->{_resultset} ||=
 230           Koha::Database->new()->schema()->resultset( $self->_type() );
 231
 232         return $self->{_resultset};
 233     }
 234     else {
 235         return Koha::Database->new()->schema()->resultset( $self->_type() );
 236     }
 237 }
 238
 239 =head3 _type
 240
 241 The _type method must be set for all child classes.
 242 The value returned by it should be the DBIC resultset name.
 243 For example, for holds, _type should return 'Reserve'.
 244
 245 =cut
 246
 247 sub _type { }
 248
 249 =head3 object_class
 250
 251 This method must be set for all child classes.
 252 The value returned by it should be the name of the Koha
 253 object class that is returned by this class.
 254 For example, for holds, object_class should return 'Koha::Hold'.
 255
 256 =cut
 257
 258 sub object_class { }
 259
 260 sub DESTROY { }
 261
 262 =head1 AUTHOR
 263
 264 Kyle M Hall <kyle@bywatersolutions.com>
 265
 266 =cut
 267
 268 1;