patroncards/edit-layout.pl

   1 #!/usr/bin/perl
   2 #
   3 # Copyright 2006 Katipo Communications.
   4 # Parts Copyright 2009 Foundations Bible College.
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 use strict;
  22 use warnings;
  23
  24 use CGI qw ( -utf8 );
  25 use Text::CSV_XS;
  26 use XML::Simple;
  27 use autouse 'Data::Dumper' => qw(Dumper);
  28
  29 use C4::Auth qw(get_template_and_user);
  30 use C4::Output qw(output_html_with_http_headers);
  31 use C4::Creators;
  32 use C4::Patroncards;
  33
  34 my $cgi = new CGI;
  35 my ( $template, $loggedinuser, $cookie ) = get_template_and_user(
  36     {
  37         template_name   => "patroncards/edit-layout.tt",
  38         query           => $cgi,
  39         type            => "intranet",
  40         authnotrequired => 0,
  41         flagsrequired   => { catalogue => 1 },
  42         debug           => 1,
  43     }
  44 );
  45
  46 my $op = $cgi->param('op') || 'new'; # make 'new' the default operation if none is submitted
  47 my $layout_id = $cgi->param('layout_id') || $cgi->param('element_id') || '';
  48 my $layout_choice = $cgi->param('layout_choice') || '';
  49 my $layout = '';
  50 my $layout_xml = undef;
  51
  52 my $units = get_unit_values();
  53 my $font_types = get_font_types();
  54 my $alignment_types = get_text_justification_types();
  55 my $barcode_types = get_barcode_types();
  56 my $image_sources = [
  57     {type => 'none', name => 'None', selected => 1},
  58     {type => 'patronimages', name => 'Patron Image', selected => 0},
  59     {type => 'creator_images', name => 'Other Image', selected => 0},
  60 ];
  61 my $image_names = get_all_image_names();
  62 unshift @$image_names, {type => 'none', name => 'Select Image', selected => 1};
  63
  64 sub _set_selected {
  65     my ($selection, $source_list) = @_;
  66     my @select_list = ();       # we must make a copy of the referent otherwise we modify the original which causes bad things to happen
  67     my $selected = 0;
  68     SET_SELECTED:
  69     foreach my $type (@$source_list) {
  70         if (($selection) && ($type->{'type'} eq $selection)) {  # even if there is no current selection we must still build the select box
  71             $selected = 1;
  72         }
  73         else {
  74             $selected = 0;
  75         }
  76         push @select_list, {type => $type->{'type'}, name => $type->{'name'}, selected => $selected};
  77     };
  78     return \@select_list;
  79 }
  80
  81 if ($op eq 'edit') {
  82     warn sprintf("Error performing '%s': No 'layout_id' passed in.", $op) unless ($layout_id);
  83     $layout = C4::Patroncards::Layout->retrieve(layout_id => $layout_id);
  84     $layout_xml = XMLin($layout->get_attr('layout_xml'), ForceArray => 1);
  85 #       Handle text fields...
  86     my $field_number = 0;
  87     my @text_fields = ();
  88     if ($layout_xml->{'text'}) {
  89         while (scalar @{$layout_xml->{'text'}}) {
  90             $field_number++;
  91             push @text_fields, (
  92                                 "field_" . $field_number => 1,      # indicate field as currently "selected" for display in form
  93                                 "field_" . $field_number . "_text" => shift @{$layout_xml->{'text'}},
  94                                 );
  95             my $field_params = shift @{$layout_xml->{'text'}};
  96             push @text_fields, (
  97                                 "field_" . $field_number . "_llx" => $field_params->{'llx'},
  98                                 "field_" . $field_number . "_lly" => $field_params->{'lly'},
  99                                 "field_" . $field_number . "_height_scale" => $field_params->{'height_scale'},
 100                                 "field_" . $field_number . "_width_scale" => $field_params->{'width_scale'},
 101                                 "field_" . $field_number . "_font" => _set_selected($field_params->{'font'}, $font_types),
 102                                 "field_" . $field_number . "_font_size" => $field_params->{'font_size'},
 103                                 "field_" . $field_number . "_text_alignment" => _set_selected($field_params->{'text_alignment'}, $alignment_types),
 104                                 );
 105         }
 106     }
 107
 108 #   Handle fields not currently used
 109     UNUSED_TEXT_FIELDS:
 110     for (my $field = $field_number + 1; $field < 4; $field++) {     # limit 3 text fields
 111         push @text_fields, (
 112                         "field_$field" . "_font" => get_font_types(),
 113                         "field_$field" . "_text_alignment" => get_text_justification_types(),
 114                         );
 115     }
 116
 117 #   Handle images...
 118     my $image_count = 0;
 119     my @images = ();
 120     foreach my $image (keys %{$layout_xml->{'images'}}) {
 121         $image_count++;
 122         push @images, ( $image . "_image" => "$image",
 123                         $image . "_Dx" => $layout_xml->{'images'}->{$image}->{'Dx'},
 124                         $image . "_Tx" => $layout_xml->{'images'}->{$image}->{'Tx'},
 125                         $image . "_Ty" => $layout_xml->{'images'}->{$image}->{'Ty'},
 126                         $image . "_image_source" => _set_selected($layout_xml->{'images'}->{$image}->{'data_source'}->[0]->{'image_source'}, $image_sources),
 127                         $image . "_image_name" => _set_selected($layout_xml->{'images'}->{$image}->{'data_source'}->[0]->{'image_name'}, $image_names),
 128                         );
 129     }
 130
 131 #   Handle image fields not currently used
 132     UNUSED_IMAGE_FIELDS:
 133     for (my $image = $image_count + 1; $image < 3; $image++) {     #limit 2 images
 134         push @images, (
 135                         "image_$image" . "_image_source" => $image_sources,
 136                         "image_$image" . "_image_name" => $image_names,
 137                         );
 138     }
 139
 140 #   Handle barcodes...
 141     my @barcode = ();
 142     foreach my $barcode_param (keys %{$layout_xml->{'barcode'}->[0]}) {
 143         push @barcode, (($barcode_param eq 'type' ? ("barcode_" . $barcode_param => _set_selected($layout_xml->{'barcode'}->[0]->{'type'}, $barcode_types)) : ("barcode_" . $barcode_param => $layout_xml->{'barcode'}->[0]->{$barcode_param})));
 144     }
 145
 146     foreach my $unit (@$units){
 147         if ($unit->{'type'} eq $layout->get_attr('units')) {
 148             $unit->{'selected'} = 1;
 149         } else {
 150             $unit->{'selected'} = 0;
 151         }
 152     }
 153
 154     $template->param(
 155             layout_id       => $layout->get_attr('layout_id') > -1 ? $layout->get_attr('layout_id') : '',
 156             layout_name     => $layout->get_attr('layout_name'),
 157             page_side       => ($layout_xml->{'page_side'} eq 'F' ? 0 : 1),
 158             guide_box       => $layout_xml->{'guide_box'},
 159             units           => $units,
 160             @barcode,
 161             barcode_type    => _set_selected($layout_xml->{'barcode'}->[0]->{'type'}, $barcode_types),
 162             @text_fields,
 163             @images,
 164             guidebox        => 0,
 165     );
 166     output_html_with_http_headers $cgi, $cookie, $template->output;
 167     exit;
 168 }
 169 elsif  ($op eq 'save') {
 170     my $format_string = undef;
 171     my $layout = {};
 172     my $layout_name = undef;
 173     my $layout_id = undef;
 174     my $text_lines = [];
 175     my $array_index = 0;
 176     my $image_select = 0;
 177     my $field_enabled = 0;
 178     CGI_PARAMS:
 179     foreach my $parameter ($cgi->param()) {     # parse the field values and build a hash of the layout for conversion to xml and storage in the db
 180         if ($parameter =~ m/^field_([0-9])_(.*)$/) {
 181             my $field_number = $1;
 182             my $field_data = $2;
 183             $field_enabled = $field_number if $field_data eq 'enable';
 184             next CGI_PARAMS unless $field_number == $field_enabled;
 185             if ($field_data eq 'text') {
 186                 push @$text_lines, $cgi->param($parameter);
 187                 if ($array_index <= 0) {
 188                     $array_index++;
 189                 }
 190                 else {
 191                     $array_index += 2; # after hitting 1, increment by 2 so counting odds
 192                 }
 193             }
 194             elsif ($array_index > 0) {
 195                 $text_lines->[$array_index]->{$field_data} = $cgi->param($parameter);
 196             }
 197         }
 198         elsif ($parameter =~ m/^barcode_(.*)$/) {
 199             $field_enabled = $1 if $1 eq 'print';
 200             next CGI_PARAMS unless $field_enabled eq 'print';
 201             $layout->{'barcode'}->{$1} = $cgi->param($parameter);
 202         }
 203         elsif ($parameter =~m/^image_([0-9])_(.*)$/) {
 204             my $image_number = $1;
 205             my $image_data = $2;
 206             $field_enabled = $image_number if $cgi->param("image_$image_number" . "_image_source") ne 'none';
 207             next CGI_PARAMS unless $image_number == $field_enabled;
 208             if ($image_data =~ m/^image_(.*)$/) {
 209                 $layout->{'images'}->{"image_$image_number"}->{'data_source'}->{"image_$1"} = $cgi->param($parameter);
 210             }
 211             else {
 212                 $layout->{'images'}->{"image_$image_number"}->{$image_data} = $cgi->param($parameter);
 213             }
 214         }
 215         else {
 216             $layout_name = $cgi->param($parameter) if $parameter eq 'layout_name';
 217             $layout_id = $cgi->param($parameter) if $parameter eq 'layout_id';
 218             $layout->{'units'} = $cgi->param($parameter) if $parameter eq 'units';
 219             $layout->{'page_side'} = $cgi->param($parameter) if $parameter eq 'page_side';
 220             $layout->{'guide_box'} = $cgi->param($parameter) if $parameter eq 'guide_box';
 221         }
 222     }
 223     $layout->{'text'} = $text_lines;
 224     my @params = (layout_name => $layout_name, layout_id => $layout_id, layout_xml => XMLout($layout));
 225     push(@params,units => $layout->{'units'}) if $layout->{'units'};
 226     if ($layout_id) {   # if a label_id was passed in, this is an update to an existing layout
 227         $layout = C4::Patroncards::Layout->retrieve(layout_id => $layout_id);
 228         $layout->set_attr(@params);
 229         $layout_id = $layout->save();
 230     }
 231     else {      # if no label_id, this is a new layout so insert it
 232         $layout = C4::Patroncards::Layout->new(@params);
 233         $layout_id = $layout->save();
 234     }
 235     print $cgi->redirect("manage.pl?card_element=layout" . ($layout_id == -1 ? "&element_id=$layout_id&op=$op&error=101" : ''));
 236     exit;
 237 }
 238 elsif  ($op eq 'new') { # this is a new layout
 239     $layout = C4::Patroncards::Layout->new();
 240     my @fields = ();
 241     for (my $field = 0; $field < 4; $field++) {     # limit 3 text fields
 242         push @fields, (
 243                         "field_$field" . "_font" => get_font_types(),
 244                         "field_$field" . "_text_alignment" => get_text_justification_types(),
 245                         );
 246     }
 247
 248     my @images = ();
 249     for (my $image = 0; $image < 3; $image++) {     #limit 2 images
 250         push @images, (
 251                         "image_$image" . "_image_source" => $image_sources,
 252                         "image_$image" . "_image_name" => $image_names,
 253                         );
 254     }
 255
 256     $template->param(
 257                     units               => get_unit_values(),
 258                     @fields,
 259                     barcode_type        => get_barcode_types(),
 260                     @images,
 261                     );
 262
 263 output_html_with_http_headers $cgi, $cookie, $template->output;
 264 exit;
 265 }
 266 else { # trap unsupported operation here
 267     warn sprintf("Unsupported operation type submitted: %s", $op);
 268     print $cgi->redirect("manage.pl?card_element=layout&element_id=$layout_id&error=201");
 269     exit;
 270 }
 271
 272 __END__