virtualshelves/sendshelf.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2009 BibLibre
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 3 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  19
  20 use Modern::Perl;
  21
  22 use CGI qw ( -utf8 );
  23 use Encode qw( encode );
  24 use Carp;
  25
  26 use Mail::Sendmail;
  27 use MIME::QuotedPrint;
  28 use MIME::Base64;
  29 use C4::Auth;
  30 use C4::Biblio;
  31 use C4::Items;
  32 use C4::Output;
  33 use Koha::Email;
  34 use Koha::Virtualshelves;
  35
  36 my $query = new CGI;
  37
  38 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  39     {
  40         template_name   => "virtualshelves/sendshelfform.tt",
  41         query           => $query,
  42         type            => "intranet",
  43         authnotrequired => 0,
  44         flagsrequired   => { catalogue => 1 },
  45     }
  46 );
  47
  48 my $shelfid = $query->param('shelfid');
  49 my $email   = $query->param('email');
  50
  51 my $dbh = C4::Context->dbh;
  52
  53 if ($email) {
  54     my $comment = $query->param('comment');
  55     my $message = Koha::Email->new();
  56     my %mail    = $message->create_message_headers(
  57         {
  58             to => $email
  59         }
  60     );
  61
  62     my ( $template2, $borrowernumber, $cookie ) = get_template_and_user(
  63         {
  64         template_name   => "virtualshelves/sendshelf.tt",
  65         query           => $query,
  66         type            => "intranet",
  67         authnotrequired => 0,
  68         flagsrequired   => { catalogue => 1 },
  69         }
  70     );
  71
  72     my $shelf = Koha::Virtualshelves->find( $shelfid );
  73     my $contents = $shelf->get_contents;
  74     my $marcflavour = C4::Context->preference('marcflavour');
  75     my $iso2709;
  76     my @results;
  77
  78     while ( my $content = $contents->next ) {
  79         my $biblionumber     = $content->biblionumber;
  80         my $dat              = GetBiblioData($biblionumber);
  81         my $record           = GetMarcBiblio({
  82             biblionumber => $biblionumber,
  83             embed_items  => 1 });
  84         my $marcauthorsarray = GetMarcAuthors( $record, $marcflavour );
  85         my $marcsubjctsarray = GetMarcSubjects( $record, $marcflavour );
  86
  87         my @items = GetItemsInfo($biblionumber);
  88
  89         $dat->{ISBN}           = GetMarcISBN($record, $marcflavour);
  90         $dat->{MARCSUBJCTS}    = $marcsubjctsarray;
  91         $dat->{MARCAUTHORS}    = $marcauthorsarray;
  92         $dat->{'biblionumber'} = $biblionumber;
  93         $dat->{ITEM_RESULTS}   = \@items;
  94         $dat->{HASAUTHORS}     = $dat->{'author'} || @$marcauthorsarray;
  95
  96         $iso2709 .= $record->as_usmarc();
  97
  98         push( @results, $dat );
  99     }
 100
 101     $template2->param(
 102         BIBLIO_RESULTS => \@results,
 103         comment        => $comment,
 104         shelfname      => $shelf->shelfname,
 105     );
 106
 107     # Getting template result
 108     my $template_res = $template2->output();
 109     my $body;
 110
 111     # Analysing information and getting mail properties
 112     if ( $template_res =~ /<SUBJECT>(.*)<END_SUBJECT>/s ) {
 113         $mail{subject} = $1;
 114         $mail{subject} =~ s|\n?(.*)\n?|$1|;
 115     }
 116     else { $mail{'subject'} = "no subject"; }
 117     $mail{subject} = encode( 'MIME-Header', $mail{subject} );
 118
 119     my $email_header = "";
 120     if ( $template_res =~ /<HEADER>(.*)<END_HEADER>/s ) {
 121         $email_header = $1;
 122         $email_header =~ s|\n?(.*)\n?|$1|;
 123         $email_header = encode_qp(Encode::encode("UTF-8", $email_header));
 124     }
 125
 126     my $email_file = "list.txt";
 127     if ( $template_res =~ /<FILENAME>(.*)<END_FILENAME>/s ) {
 128         $email_file = $1;
 129         $email_file =~ s|\n?(.*)\n?|$1|;
 130     }
 131
 132     if ( $template_res =~ /<MESSAGE>(.*)<END_MESSAGE>/s ) {
 133         $body = $1;
 134         $body =~ s|\n?(.*)\n?|$1|;
 135         $body = encode_qp(Encode::encode("UTF-8", $body));
 136     }
 137
 138     my $boundary = "====" . time() . "====";
 139
 140     # We set and put the multipart content
 141     $mail{'content-type'} = "multipart/mixed; boundary=\"$boundary\"";
 142
 143     my $isofile = encode_base64( encode( "UTF-8", $iso2709 ) );
 144     $boundary = '--' . $boundary;
 145
 146     $mail{body} = <<END_OF_BODY;
 147 $boundary
 148 Content-Type: text/plain; charset="utf-8"
 149 Content-Transfer-Encoding: quoted-printable
 150
 151 $email_header
 152 $body
 153 $boundary
 154 Content-Type: application/octet-stream; name="shelf.iso2709"
 155 Content-Transfer-Encoding: base64
 156 Content-Disposition: attachment; filename="shelf.iso2709"
 157
 158 $isofile
 159 $boundary--
 160 END_OF_BODY
 161
 162     # Sending mail
 163     if ( sendmail %mail ) {
 164
 165         # do something if it works....
 166         $template->param( SENT => "1" );
 167     }
 168     else {
 169         # do something if it doesn't work....
 170         carp "Error sending mail: $Mail::Sendmail::error \n";
 171         $template->param( error => 1 );
 172     }
 173
 174     $template->param( email => $email );
 175     output_html_with_http_headers $query, $cookie, $template->output;
 176
 177 }
 178 else {
 179     $template->param(
 180         shelfid => $shelfid,
 181         url     => "/cgi-bin/koha/virtualshelves/sendshelf.pl",
 182     );
 183     output_html_with_http_headers $query, $cookie, $template->output;
 184 }