admin/itemtypes.pl

   1 #!/usr/bin/perl
   2
   3 # Copyright 2000-2002 Katipo Communications
   4 #
   5 # This file is part of Koha.
   6 #
   7 # Koha is free software; you can redistribute it and/or modify it under the
   8 # terms of the GNU General Public License as published by the Free Software
   9 # Foundation; either version 2 of the License, or (at your option) any later
  10 # version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but WITHOUT ANY
  13 # WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS FOR
  14 # A PARTICULAR PURPOSE.  See the GNU General Public License for more details.
  15 #
  16 # You should have received a copy of the GNU General Public License along with
  17 # Koha; if not, write to the Free Software Foundation, Inc., 59 Temple Place,
  18 # Suite 330, Boston, MA  02111-1307 USA
  19
  20 =head1 admin/itemtypes.pl
  21
  22 script to administer the categories table
  23 written 20/02/2002 by paul.poulain@free.fr
  24  This software is placed under the gnu General Public License, v2 (http://www.gnu.org/licenses/gpl.html)
  25
  26  ALGO :
  27  this script use an $op to know what to do.
  28  if $op is empty or none of the above values,
  29         - the default screen is build (with all records, or filtered datas).
  30         - the   user can clic on add, modify or delete record.
  31  if $op=add_form
  32         - if primkey exists, this is a modification,so we read the $primkey record
  33         - builds the add/modify form
  34  if $op=add_validate
  35         - the user has just send datas, so we create/modify the record
  36  if $op=delete_form
  37         - we show the record having primkey=$primkey and ask for deletion validation form
  38  if $op=delete_confirm
  39         - we delete the record having primkey=$primkey
  40
  41 =cut
  42
  43 use strict;
  44 use CGI;
  45
  46 use List::Util qw/min/;
  47 use File::Spec;
  48
  49 use C4::Koha;
  50 use C4::Context;
  51 use C4::Auth;
  52 use C4::Output;
  53
  54 sub StringSearch {
  55     my ( $searchstring, $type ) = @_;
  56     my $dbh = C4::Context->dbh;
  57     $searchstring =~ s/\'/\\\'/g;
  58     my @data = split( ' ', $searchstring );
  59     my $sth = $dbh->prepare(
  60         "SELECT * FROM itemtypes WHERE (description LIKE ?) ORDER BY itemtype"
  61         );
  62     $sth->execute("$data[0]%");
  63     return $sth->fetchall_arrayref({});         # return ref-to-array of ref-to-hashes
  64                                                                 # like [ fetchrow_hashref(), fetchrow_hashref() ... ]
  65 }
  66
  67 my $input       = new CGI;
  68 my $searchfield = $input->param('description');
  69 my $script_name = "/cgi-bin/koha/admin/itemtypes.pl";
  70 my $itemtype    = $input->param('itemtype');
  71 my $pagesize    = 10;
  72 my $op          = $input->param('op');
  73 $searchfield =~ s/\,//g;
  74 my ( $template, $borrowernumber, $cookie ) = get_template_and_user(
  75     {
  76         template_name   => "admin/itemtypes.tmpl",
  77         query           => $input,
  78         type            => "intranet",
  79         authnotrequired => 0,
  80         flagsrequired   => { parameters => 1 },
  81         debug           => 1,
  82     }
  83 );
  84
  85 $template->param(script_name => $script_name);
  86 if ($op) {
  87         $template->param($op  => 1); # we show only the TMPL_VAR names $op
  88 } else {
  89     $template->param(else => 1);
  90 }
  91
  92 my $dbh = C4::Context->dbh;
  93
  94 ################## ADD_FORM ##################################
  95 # called by default. Used to create form to add or  modify a record
  96 if ( $op eq 'add_form' ) {
  97     #---- if primkey exists, it's a modify action, so read values to modify...
  98     my $data;
  99     if ($itemtype) {
 100         my $sth = $dbh->prepare("select * from itemtypes where itemtype=?");
 101         $sth->execute($itemtype);
 102         $data = $sth->fetchrow_hashref;
 103     }
 104
 105     my $imagesets = C4::Koha::getImageSets( checked => $data->{'imageurl'} );
 106
 107     my $remote_image = undef;
 108     if ( defined $data->{imageurl} and $data->{imageurl} =~ /^http/i ) {
 109         $remote_image = $data->{imageurl};
 110     }
 111
 112     $template->param(
 113         itemtype        => $itemtype,
 114         description     => $data->{'description'},
 115         rentalcharge    => sprintf( "%.2f", $data->{'rentalcharge'} ),
 116         notforloan      => $data->{'notforloan'},
 117         imageurl        => $data->{'imageurl'},
 118         template        => C4::Context->preference('template'),
 119         summary         => $data->{summary},
 120         imagesets       => $imagesets,
 121         remote_image    => $remote_image,
 122     );
 123
 124     # END $OP eq ADD_FORM
 125 ################## ADD_VALIDATE ##################################
 126     # called by add_form, used to insert/modify data in DB
 127 }
 128 elsif ( $op eq 'add_validate' ) {
 129     my $query = "
 130         SELECT itemtype
 131         FROM   itemtypes
 132         WHERE  itemtype = ?
 133     ";
 134     my $sth = $dbh->prepare($query);
 135     $sth->execute($itemtype);
 136     if ( $sth->fetchrow ) {             # it's a modification
 137         my $query2 = '
 138             UPDATE itemtypes
 139             SET    description = ?
 140                  , rentalcharge = ?
 141                  , notforloan = ?
 142                  , imageurl = ?
 143                  , summary = ?
 144             WHERE itemtype = ?
 145         ';
 146         $sth = $dbh->prepare($query2);
 147         $sth->execute(
 148             $input->param('description'),
 149             $input->param('rentalcharge'),
 150             ( $input->param('notforloan') ? 1 : 0 ),
 151             (
 152                 $input->param('image') eq 'removeImage' ? '' : (
 153                       $input->param('image') eq 'remoteImage'
 154                     ? $input->param('remoteImage')
 155                     : $input->param('image') . ""
 156                 )
 157             ),
 158             $input->param('summary'),
 159             $input->param('itemtype')
 160         );
 161     }
 162     else {    # add a new itemtype & not modif an old
 163         my $query = "
 164             INSERT INTO itemtypes
 165                 (itemtype,description,rentalcharge, notforloan, imageurl,summary)
 166             VALUES
 167                 (?,?,?,?,?,?);
 168             ";
 169         my $sth = $dbh->prepare($query);
 170                 my $image = $input->param('image');
 171         $sth->execute(
 172             $input->param('itemtype'),
 173             $input->param('description'),
 174             $input->param('rentalcharge'),
 175             $input->param('notforloan') ? 1 : 0,
 176             $image eq 'removeImage' ?           ''                 :
 177             $image eq 'remoteImage' ? $input->param('remoteImage') :
 178             $image,
 179             $input->param('summary'),
 180         );
 181     }
 182
 183     print $input->redirect('itemtypes.pl');
 184     exit;
 185
 186     # END $OP eq ADD_VALIDATE
 187 ################## DELETE_CONFIRM ##################################
 188     # called by default form, used to confirm deletion of data in DB
 189 }
 190 elsif ( $op eq 'delete_confirm' ) {
 191     # Check both categoryitem and biblioitems, see Bug 199
 192     my $total = 0;
 193     for my $table ('biblioitems') {
 194         my $sth =
 195           $dbh->prepare(
 196             "select count(*) as total from $table where itemtype=?");
 197         $sth->execute($itemtype);
 198         $total += $sth->fetchrow_hashref->{total};
 199     }
 200
 201     my $sth =
 202       $dbh->prepare(
 203 "select itemtype,description,rentalcharge from itemtypes where itemtype=?"
 204       );
 205     $sth->execute($itemtype);
 206     my $data = $sth->fetchrow_hashref;
 207     $template->param(
 208         itemtype        => $itemtype,
 209         description     => $data->{description},
 210         rentalcharge    => sprintf( "%.2f", $data->{rentalcharge} ),
 211         imageurl        => $data->{imageurl},
 212         total           => $total
 213     );
 214
 215     # END $OP eq DELETE_CONFIRM
 216 ################## DELETE_CONFIRMED ##################################
 217   # called by delete_confirm, used to effectively confirm deletion of data in DB
 218 }
 219 elsif ( $op eq 'delete_confirmed' ) {
 220     my $itemtype = uc( $input->param('itemtype') );
 221     my $sth      = $dbh->prepare("delete from itemtypes where itemtype=?");
 222     $sth->execute($itemtype);
 223     $sth = $dbh->prepare("delete from issuingrules where itemtype=?");
 224     $sth->execute($itemtype);
 225     print $input->redirect('itemtypes.pl');
 226     exit;
 227     # END $OP eq DELETE_CONFIRMED
 228 ################## DEFAULT ##################################
 229 }
 230 else {    # DEFAULT
 231     my ($results) = StringSearch( $searchfield, 'web' );
 232     my $page = $input->param('page') || 1;
 233     my $first = ( $page - 1 ) * $pagesize;
 234
 235     # if we are on the last page, the number of the last word to display
 236     # must not exceed the length of the results array
 237     my $last = min( $first + $pagesize - 1, scalar @{$results} - 1, );
 238     my @loop;
 239     foreach my $itemtype ( @{$results}[ $first .. $last ] ) {
 240         $itemtype->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtype->{imageurl} );
 241         $itemtype->{rentalcharge} = sprintf( '%.2f', $itemtype->{rentalcharge} );
 242         push( @loop, $itemtype );
 243     }
 244
 245     $template->param(
 246         loop           => \@loop,
 247         pagination_bar => pagination_bar(
 248             $script_name, getnbpages( scalar @{$results}, $pagesize ),
 249             $page,        'page'
 250         )
 251     );
 252 }    #---- END $OP eq DEFAULT
 253
 254 output_html_with_http_headers $input, $cookie, $template->output;