Koha/Cache.pm

   1 package Koha::Cache;
   2
   3 # Copyright 2009 Chris Cormack and The Koha Dev Team
   4 # Parts copyright 2012-2013 C & P Bibliography Services
   5 #
   6 # This file is part of Koha.
   7 #
   8 # Koha is free software; you can redistribute it and/or modify it
   9 # under the terms of the GNU General Public License as published by
  10 # the Free Software Foundation; either version 3 of the License, or
  11 # (at your option) any later version.
  12 #
  13 # Koha is distributed in the hope that it will be useful, but
  14 # WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  16 # GNU General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU General Public License
  19 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  20
  21 =head1 NAME
  22
  23 Koha::Cache - Handling caching of html and Objects for Koha
  24
  25 =head1 SYNOPSIS
  26
  27   use Koha::Cache;
  28   my $cache = Koha::Cache->new({cache_type => $cache_type, %params});
  29
  30 =head1 DESCRIPTION
  31
  32 Koha caching routines. This class provides two interfaces for cache access.
  33 The first, traditional OO interface provides the following functions:
  34
  35 =head1 FUNCTIONS
  36
  37 =cut
  38 use strict;
  39 use warnings;
  40 use Carp;
  41 use Clone qw( clone );
  42 use Module::Load::Conditional qw(can_load);
  43 use Koha::Cache::Object;
  44
  45 use base qw(Class::Accessor);
  46
  47 __PACKAGE__->mk_ro_accessors(
  48     qw( cache memcached_cache fastmmap_cache memory_cache ));
  49
  50 our %L1_cache;
  51
  52 =head2 get_instance
  53
  54     my $cache = Koha::Cache->get_instance();
  55
  56 This gets a shared instance of the cache, set up in a very default way. This is
  57 the recommended way to fetch a cache object. If possible, it'll be
  58 persistent across multiple instances.
  59
  60 =cut
  61
  62 our $singleton_cache;
  63 sub get_instance {
  64     my ($class) = @_;
  65     $singleton_cache = $class->new() unless $singleton_cache;
  66     return $singleton_cache;
  67 }
  68
  69 =head2 new
  70
  71 Create a new Koha::Cache object. This is required for all cache-related functionality.
  72
  73 =cut
  74
  75 sub new {
  76     my ( $class, $self ) = @_;
  77     $self->{'default_type'} =
  78          $self->{cache_type}
  79       || $ENV{CACHING_SYSTEM}
  80       || 'memcached';
  81
  82     $ENV{DEBUG} && carp "Default caching system: $self->{'default_type'}";
  83
  84     $self->{'timeout'}   ||= 0;
  85     $self->{'namespace'} ||= $ENV{MEMCACHED_NAMESPACE} || 'koha';
  86
  87     if ( can_load( modules => { 'Cache::Memcached::Fast' => undef } ) ) {
  88         _initialize_memcached($self);
  89         if ( $self->{'default_type'} eq 'memcached'
  90             && defined( $self->{'memcached_cache'} ) )
  91         {
  92             $self->{'cache'} = $self->{'memcached_cache'};
  93         }
  94     }
  95
  96     if ( $self->{'default_type'} eq 'fastmmap'
  97       && defined( $ENV{GATEWAY_INTERFACE} )
  98       && can_load( modules => { 'Cache::FastMmap' => undef } ) ) {
  99         _initialize_fastmmap($self);
 100         if ( defined( $self->{'fastmmap_cache'} ) )
 101         {
 102             $self->{'cache'} = $self->{'fastmmap_cache'};
 103         }
 104     }
 105
 106     if ( can_load( modules => { 'Cache::Memory' => undef } ) ) {
 107         _initialize_memory($self);
 108         if ( $self->{'default_type'} eq 'memory'
 109             && defined( $self->{'memory_cache'} ) )
 110         {
 111             $self->{'cache'} = $self->{'memory_cache'};
 112         }
 113     }
 114
 115     # Unless a default has already been picked, we go through in best-to-
 116     # least-best order, looking for something we can use. fastmmap_cache
 117     # is excluded because it doesn't support expiry in a useful way.
 118     unless ( defined( $self->{'cache'} ) ) {
 119         foreach my $cachemember (qw(memcached_cache memory_cache )) {
 120             if ( defined( $self->{$cachemember} ) ) {
 121                 $self->{'cache'} = $self->{$cachemember};
 122                 last;
 123             }
 124         }
 125     }
 126
 127     $ENV{DEBUG} && carp "Selected caching system: " . ($self->{'cache'} // 'none');
 128
 129     return
 130       bless $self,
 131       $class;
 132 }
 133
 134 sub _initialize_memcached {
 135     my ($self) = @_;
 136     my @servers =
 137       split /,/, $self->{'cache_servers'}
 138       ? $self->{'cache_servers'}
 139       : ($ENV{MEMCACHED_SERVERS} || '');
 140     return if !@servers;
 141
 142     $ENV{DEBUG}
 143       && carp "Memcached server settings: "
 144       . join( ', ', @servers )
 145       . " with "
 146       . $self->{'namespace'};
 147     # Cache::Memcached::Fast doesn't allow a default expire time to be set
 148     # so we force it on setting.
 149     my $memcached = Cache::Memcached::Fast->new(
 150         {
 151             servers            => \@servers,
 152             compress_threshold => 10_000,
 153             namespace          => $self->{'namespace'},
 154             utf8               => 1,
 155         }
 156     );
 157     # Ensure we can actually talk to the memcached server
 158     my $ismemcached = $memcached->set('ismemcached','1');
 159     return $self unless $ismemcached;
 160     $self->{'memcached_cache'} = $memcached;
 161     return $self;
 162 }
 163
 164 sub _initialize_fastmmap {
 165     my ($self) = @_;
 166     my ($cache, $share_file);
 167
 168     # Temporary workaround to catch fatal errors when: C4::Context module
 169     # is not loaded beforehand, or Cache::FastMmap init fails for whatever
 170     # other reason (e.g. due to permission issues - see Bug 13431)
 171     eval {
 172         $share_file = join( '-',
 173             "/tmp/sharefile-koha", $self->{'namespace'},
 174             C4::Context->config('hostname'), C4::Context->config('database') );
 175
 176         $cache = Cache::FastMmap->new(
 177             'share_file'  => $share_file,
 178             'expire_time' => $self->{'timeout'},
 179             'unlink_on_exit' => 0,
 180         );
 181     };
 182     if ( $@ ) {
 183         warn "FastMmap cache initialization failed: $@";
 184         return;
 185     }
 186     return unless defined $cache;
 187     $self->{'fastmmap_cache'} = $cache;
 188     return $self;
 189 }
 190
 191 sub _initialize_memory {
 192     my ($self) = @_;
 193
 194     # Default cache time for memory is _always_ short unless it's specially
 195     # defined, to allow it to work reliably in a persistent environment.
 196     my $cache = Cache::Memory->new(
 197         'namespace'       => $self->{'namespace'},
 198         'default_expires' => "$self->{'timeout'} sec" || "10 sec",
 199     );
 200     $self->{'memory_cache'} = $cache;
 201     # Memory cache can't handle complex types for some reason, so we use its
 202     # freeze and thaw functions.
 203     $self->{ref($cache) . '_set'} = sub {
 204         my ($key, $val, $exp) = @_;
 205         # Refer to set_expiry in Cache::Entry for why we do this 'sec' thing.
 206         $exp = "$exp sec" if defined $exp;
 207         # Because we need to use freeze, it must be a reference type.
 208         $cache->freeze($key, [$val], $exp);
 209     };
 210     $self->{ref($cache) . '_get'} = sub {
 211         my $res = $cache->thaw(shift);
 212         return unless defined $res;
 213         return $res->[0];
 214     };
 215     return $self;
 216 }
 217
 218 =head2 is_cache_active
 219
 220 Routine that checks whether or not a default caching method is active on this
 221 object.
 222
 223 =cut
 224
 225 sub is_cache_active {
 226     my $self = shift;
 227     return $self->{'cache'} ? 1 : 0;
 228 }
 229
 230 =head2 set_in_cache
 231
 232     $cache->set_in_cache($key, $value, [$options]);
 233
 234 Save a value to the specified key in the cache. A hashref of options may be
 235 specified.
 236
 237 The possible options are:
 238
 239 =over
 240
 241 =item expiry
 242
 243 Expiry time of this cached entry in seconds.
 244
 245 =item deepcopy
 246
 247 If set, this will perform a deep copy of the item when it's retrieved. This
 248 means that it'll be safe if something later modifies the result of the
 249 function. Will be ignored in situations where the same behaviour comes from
 250 the caching layer anyway.
 251
 252 =item cache
 253
 254 The cache object to use if you want to provide your own. It should be an
 255 instance of C<Cache::*> and follow the same interface as L<Cache::Memcache>.
 256
 257 =back
 258
 259 =cut
 260
 261 sub set_in_cache {
 262     my ( $self, $key, $value, $options, $_cache) = @_;
 263     # This is a bit of a hack to support the old API in case things still use it
 264     if (defined $options && (ref($options) ne 'HASH')) {
 265         my $new_options;
 266         $new_options->{expiry} = $options;
 267         $new_options->{cache} = $_cache if defined $_cache;
 268         $options = $new_options;
 269     }
 270
 271     # the key mustn't contain whitespace (or control characters) for memcache
 272     # but shouldn't be any harm in applying it globally.
 273     $key =~ s/[\x00-\x20]/_/g;
 274
 275     my $cache = $options->{cache} || 'cache';
 276     croak "No key" unless $key;
 277     $ENV{DEBUG} && carp "set_in_cache for $key";
 278
 279     return unless ( $self->{$cache} && ref( $self->{$cache} ) =~ m/^Cache::/ );
 280     my $expiry = $options->{expiry};
 281     $expiry //= $self->{timeout};
 282     my $set_sub = $self->{ref($self->{$cache}) . "_set"};
 283
 284     # Set in L1 cache
 285     $L1_cache{ $key } = $value;
 286
 287     # We consider an expiry of 0 to be inifinite
 288     if ( $expiry ) {
 289         return $set_sub
 290           ? $set_sub->( $key, $value, $expiry )
 291           : $self->{$cache}->set( $key, $value, $expiry );
 292     }
 293     else {
 294         return $set_sub
 295           ? $set_sub->( $key, $value )
 296           : $self->{$cache}->set( $key, $value );
 297     }
 298 }
 299
 300 =head2 get_from_cache
 301
 302     my $value = $cache->get_from_cache($key);
 303
 304 Retrieve the value stored under the specified key in the default cache.
 305
 306 =cut
 307
 308 sub get_from_cache {
 309     my ( $self, $key, $cache ) = @_;
 310     $key =~ s/[\x00-\x20]/_/g;
 311     $cache ||= 'cache';
 312     croak "No key" unless $key;
 313     $ENV{DEBUG} && carp "get_from_cache for $key";
 314     return unless ( $self->{$cache} && ref( $self->{$cache} ) =~ m/^Cache::/ );
 315
 316     # Return L1 cache value if exists
 317     if ( exists $L1_cache{$key} ) {
 318         # No need to deep copy if it's a scalar:
 319         return $L1_cache{$key}
 320             unless ref $L1_cache{$key};
 321         return clone $L1_cache{$key};
 322     }
 323
 324     my $get_sub = $self->{ref($self->{$cache}) . "_get"};
 325     return $get_sub ? $get_sub->($key) : $self->{$cache}->get($key);
 326 }
 327
 328 =head2 clear_from_cache
 329
 330     $cache->clear_from_cache($key);
 331
 332 Remove the value identified by the specified key from the default cache.
 333
 334 =cut
 335
 336 sub clear_from_cache {
 337     my ( $self, $key, $cache ) = @_;
 338     $key =~ s/[\x00-\x20]/_/g;
 339     $cache ||= 'cache';
 340     croak "No key" unless $key;
 341     return unless ( $self->{$cache} && ref( $self->{$cache} ) =~ m/^Cache::/ );
 342
 343     # Clear from L1 cache
 344     delete $L1_cache{$key};
 345
 346     return $self->{$cache}->delete($key)
 347       if ( ref( $self->{$cache} ) =~ m'^Cache::Memcached' );
 348     return $self->{$cache}->remove($key);
 349 }
 350
 351 =head2 flush_all
 352
 353     $cache->flush_all();
 354
 355 Clear the entire default cache.
 356
 357 =cut
 358
 359 sub flush_all {
 360     my ( $self, $cache ) = shift;
 361     $cache ||= 'cache';
 362     return unless ( $self->{$cache} && ref( $self->{$cache} ) =~ m/^Cache::/ );
 363
 364     $self->flush_L1_cache();
 365
 366     return $self->{$cache}->flush_all()
 367       if ( ref( $self->{$cache} ) =~ m'^Cache::Memcached' );
 368     return $self->{$cache}->clear();
 369 }
 370
 371 sub flush_L1_cache {
 372     my( $self ) = @_;
 373     %L1_cache = ();
 374 }
 375
 376 =head1 TIED INTERFACE
 377
 378 Koha::Cache also provides a tied interface which enables users to provide a
 379 constructor closure and (after creation) treat cached data like normal reference
 380 variables and rely on the cache Just Working and getting updated when it
 381 expires, etc.
 382
 383     my $cache = Koha::Cache->new();
 384     my $data = 'whatever';
 385     my $scalar = Koha::Cache->create_scalar(
 386         {
 387             'key'         => 'whatever',
 388             'timeout'     => 2,
 389             'constructor' => sub { return $data; },
 390         }
 391     );
 392     print "$$scalar\n"; # Prints "whatever"
 393     $data = 'somethingelse';
 394     print "$$scalar\n"; # Prints "whatever" because it is cached
 395     sleep 2; # Wait until the cache entry has expired
 396     print "$$scalar\n"; # Prints "somethingelse"
 397
 398     my $hash = Koha::Cache->create_hash(
 399         {
 400             'key'         => 'whatever',
 401             'timeout'     => 2,
 402             'constructor' => sub { return $data; },
 403         }
 404     );
 405     print "$$variable\n"; # Prints "whatever"
 406
 407 The gotcha with this interface, of course, is that the variable returned by
 408 create_scalar and create_hash is a I<reference> to a tied variable and not a
 409 tied variable itself.
 410
 411 The tied variable is configured by means of a hashref passed in to the
 412 create_scalar and create_hash methods. The following parameters are supported:
 413
 414 =over
 415
 416 =item I<key>
 417
 418 Required. The key to use for identifying the variable in the cache.
 419
 420 =item I<constructor>
 421
 422 Required. A closure (or reference to a function) that will return the value that
 423 needs to be stored in the cache.
 424
 425 =item I<preload>
 426
 427 Optional. A closure (or reference to a function) that gets run to initialize
 428 the cache when creating the tied variable.
 429
 430 =item I<arguments>
 431
 432 Optional. Array reference with the arguments that should be passed to the
 433 constructor function.
 434
 435 =item I<timeout>
 436
 437 Optional. The cache timeout in seconds for the variable. Defaults to 600
 438 (ten minutes).
 439
 440 =item I<cache_type>
 441
 442 Optional. Which type of cache to use for the variable. Defaults to whatever is
 443 set in the environment variable CACHING_SYSTEM. If set to 'null', disables
 444 caching for the tied variable.
 445
 446 =item I<allowupdate>
 447
 448 Optional. Boolean flag to allow the variable to be updated directly. When this
 449 is set and the variable is used as an l-value, the cache will be updated
 450 immediately with the new value. Using this is probably a bad idea on a
 451 multi-threaded system. When I<allowupdate> is not set to true, using the
 452 tied variable as an l-value will have no effect.
 453
 454 =item I<destructor>
 455
 456 Optional. A closure (or reference to a function) that should be called when the
 457 tied variable is destroyed.
 458
 459 =item I<unset>
 460
 461 Optional. Boolean flag to tell the object to remove the variable from the cache
 462 when it is destroyed or goes out of scope.
 463
 464 =item I<inprocess>
 465
 466 Optional. Boolean flag to tell the object not to refresh the variable from the
 467 cache every time the value is desired, but rather only when the I<local> copy
 468 of the variable is older than the timeout.
 469
 470 =back
 471
 472 =head2 create_scalar
 473
 474     my $scalar = Koha::Cache->create_scalar(\%params);
 475
 476 Create scalar tied to the cache.
 477
 478 =cut
 479
 480 sub create_scalar {
 481     my ( $self, $args ) = @_;
 482
 483     $self->_set_tied_defaults($args);
 484
 485     tie my $scalar, 'Koha::Cache::Object', $args;
 486     return \$scalar;
 487 }
 488
 489 sub create_hash {
 490     my ( $self, $args ) = @_;
 491
 492     $self->_set_tied_defaults($args);
 493
 494     tie my %hash, 'Koha::Cache::Object', $args;
 495     return \%hash;
 496 }
 497
 498 sub _set_tied_defaults {
 499     my ( $self, $args ) = @_;
 500
 501     $args->{'timeout'}   = '600' unless defined( $args->{'timeout'} );
 502     $args->{'inprocess'} = '0'   unless defined( $args->{'inprocess'} );
 503     unless ( $args->{cache_type} and lc( $args->{cache_type} ) eq 'null' ) {
 504         $args->{'cache'} = $self;
 505         $args->{'cache_type'} ||= $ENV{'CACHING_SYSTEM'};
 506     }
 507
 508     return $args;
 509 }
 510
 511 =head1 EXPORT
 512
 513 None by default.
 514
 515 =head1 SEE ALSO
 516
 517 Koha::Cache::Object
 518
 519 =head1 AUTHOR
 520
 521 Chris Cormack, E<lt>chris@bigballofwax.co.nzE<gt>
 522 Paul Poulain, E<lt>paul.poulain@biblibre.comE<gt>
 523 Jared Camins-Esakov, E<lt>jcamins@cpbibliography.comE<gt>
 524
 525 =cut
 526
 527 1;
 528
 529 __END__