tools/batch_record_modification.pl

   1 #!/usr/bin/perl
   2
   3 # This file is part of Koha.
   4 #
   5 # Copyright 2013 BibLibre
   6 #
   7 # Koha is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as
   9 # published by the Free Software Foundation; either version 3
  10 # of the License, or (at your option) any later version.
  11 #
  12 # Koha is distributed in the hope that it will be useful, but
  13 # WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General
  18 # Public License along with Koha; if not, see
  19 # <http://www.gnu.org/licenses>
  20
  21 use Modern::Perl;
  22
  23 use CGI;
  24 use List::MoreUtils qw( uniq );
  25
  26 use C4::Auth qw( get_template_and_user );
  27 use C4::Output qw( output_html_with_http_headers );
  28 use C4::AuthoritiesMarc qw( BuildSummary GetAuthTypeCode ModAuthority );
  29 use C4::BackgroundJob;
  30 use C4::Biblio qw( GetMarcBiblio ModBiblio );
  31 use C4::MarcModificationTemplates qw( GetModificationTemplateActions GetModificationTemplates ModifyRecordWithTemplate );
  32 use Koha::Authority;
  33
  34 my $input = new CGI;
  35 our $dbh = C4::Context->dbh;
  36 my $op = $input->param('op') // q|form|;
  37 my $recordtype = $input->param('recordtype') // 'biblio';
  38 my $mmtid = $input->param('marc_modification_template_id');
  39
  40 my ( @messages );
  41
  42 my ( $template, $loggedinuser, $cookie ) = get_template_and_user({
  43         template_name => 'tools/batch_record_modification.tt',
  44         query => $input,
  45         type => "intranet",
  46         authnotrequired => 0,
  47         flagsrequired => { tools => 'biblio_batchmod' },
  48 });
  49
  50
  51 my $sessionID = $input->cookie("CGISESSID");
  52
  53 my $runinbackground = $input->param('runinbackground');
  54 my $completedJobID = $input->param('completedJobID');
  55 if ( $completedJobID ) {
  56     my $job = C4::BackgroundJob->fetch($sessionID, $completedJobID);
  57     my $report = $job->get('report');
  58     my $messages = $job->get('messages');
  59     $template->param(
  60         report => $report,
  61         messages => $messages,
  62         view => 'report',
  63     );
  64     output_html_with_http_headers $input, $cookie, $template->output;
  65     $job->clear();
  66     exit;
  67 }
  68
  69 my @templates = GetModificationTemplates( $mmtid );
  70 unless ( @templates ) {
  71     $op = 'error';
  72     $template->param(
  73         view => 'errors',
  74         errors => ['no_template_defined'],
  75     );
  76     output_html_with_http_headers $input, $cookie, $template->output;
  77     exit;
  78 }
  79
  80 if ( $mmtid ) {
  81     my @actions = GetModificationTemplateActions( $mmtid );
  82     unless ( @actions ) {
  83         $op = 'form';
  84         push @messages, {
  85             type => 'error',
  86             code => 'no_action_defined_for_the_template',
  87             mmtid => $mmtid,
  88         };
  89     }
  90 }
  91
  92 if ( $op eq 'form' ) {
  93     # Display the form
  94     $template->param(
  95         view => 'form',
  96     );
  97 } elsif ( $op eq 'list' ) {
  98     # List all records to process
  99     my ( @records, @record_ids );
 100     if ( my $bib_list = $input->param('bib_list') ) {
 101         # Come from the basket
 102         @record_ids = split /\//, $bib_list;
 103         $recordtype = 'biblio';
 104     } elsif ( my $uploadfile = $input->param('uploadfile') ) {
 105         # A file of id is given
 106         while ( my $content = <$uploadfile> ) {
 107             next unless $content;
 108             $content =~ s/[\r\n]*$//;
 109             push @record_ids, $content if $content;
 110         }
 111     } else {
 112         # The user enters manually the list of id
 113         push @record_ids, split( /\s\n/, $input->param('recordnumber_list') );
 114     }
 115
 116     for my $record_id ( uniq @record_ids ) {
 117         if ( $recordtype eq 'biblio' ) {
 118             # Retrieve biblio information
 119             my $biblio = C4::Biblio::GetBiblio( $record_id );
 120             unless ( $biblio ) {
 121                 push @messages, {
 122                     type => 'warning',
 123                     code => 'biblio_not_exists',
 124                     biblionumber => $record_id,
 125                 };
 126                 next;
 127             }
 128             push @records, $biblio;
 129         } else {
 130             # Retrieve authority information
 131             my $authority = Koha::Authority->get_from_authid( $record_id );
 132             unless ( $authority ) {
 133                 push @messages, {
 134                     type => 'warning',
 135                     code => 'authority_not_exists',
 136                     authid => $record_id,
 137                 };
 138                 next;
 139             }
 140
 141             push @records, {
 142                 authid => $record_id,
 143                 summary => C4::AuthoritiesMarc::BuildSummary( $authority->record, $record_id ),
 144             };
 145         }
 146     }
 147     $template->param(
 148         records => \@records,
 149         mmtid => $mmtid,
 150         view => 'list',
 151     );
 152 } elsif ( $op eq 'modify' ) {
 153     # We want to modify selected records!
 154     my @record_ids = $input->param('record_id');
 155
 156     my ( $job );
 157     if ( $runinbackground ) {
 158         my $job_size = scalar( @record_ids );
 159         $job = C4::BackgroundJob->new( $sessionID, "FIXME", $ENV{SCRIPT_NAME}, $job_size );
 160         my $job_id = $job->id;
 161         if (my $pid = fork) {
 162             $dbh->{InactiveDestroy}  = 1;
 163
 164             my $reply = CGI->new("");
 165             print $reply->header(-type => 'text/html');
 166             print '{"jobID":"' . $job_id . '"}';
 167             exit 0;
 168         } elsif (defined $pid) {
 169             close STDOUT;
 170             close STDERR;
 171         } else {
 172             warn "fork failed while attempting to run $ENV{'SCRIPT_NAME'} as a background job";
 173             exit 0;
 174         }
 175     }
 176
 177     my $report = {
 178         total_records => 0,
 179         total_success => 0,
 180     };
 181     my $progress = 0;
 182     $dbh->{RaiseError} = 1;
 183     RECORD_IDS: for my $record_id ( sort { $a <=> $b } @record_ids ) {
 184         $report->{total_records}++;
 185         next unless $record_id;
 186
 187         if ( $recordtype eq 'biblio' ) {
 188             # Biblios
 189             my $biblionumber = $record_id;
 190
 191             # Finally, modify the biblio
 192             my $error = eval {
 193                 my $record = GetMarcBiblio( $biblionumber );
 194                 ModifyRecordWithTemplate( $mmtid, $record );
 195                 ModBiblio( $record, $biblionumber );
 196             };
 197             if ( $error and $error != 1 or $@ ) { # ModBiblio returns 1 if everything as gone well
 198                 push @messages, {
 199                     type => 'error',
 200                     code => 'biblio_not_modified',
 201                     biblionumber => $biblionumber,
 202                     error => ($@ ? $@ : $error),
 203                 };
 204             } else {
 205                 push @messages, {
 206                     type => 'success',
 207                     code => 'biblio_modified',
 208                     biblionumber => $biblionumber,
 209                 };
 210                 $report->{total_success}++;
 211             }
 212         } else {
 213             # Authorities
 214             my $authid = $record_id;
 215             my $error = eval {
 216                 my $authority = Koha::Authority->get_from_authid( $authid );
 217                 my $record = $authority->record;
 218                 ModifyRecordWithTemplate( $mmtid, $record );
 219                 ModAuthority( $authid, $record, GetAuthTypeCode( $authid ) );
 220             };
 221             if ( $error and $error != $authid or $@ ) {
 222                 push @messages, {
 223                     type => 'error',
 224                     code => 'authority_not_modified',
 225                     authid => $authid,
 226                     error => ($@ ? $@ : 0),
 227                 };
 228             } else {
 229                 push @messages, {
 230                     type => 'success',
 231                     code => 'authority_modified',
 232                     authid => $authid,
 233                 };
 234                 $report->{total_success}++;
 235             }
 236         }
 237
 238         $job->set({
 239             view => 'report',
 240             report => $report,
 241             messages => \@messages,
 242         });
 243         $job->progress( ++$progress ) if $runinbackground;
 244     }
 245
 246     if ($runinbackground) {
 247         $job->finish if defined $job;
 248     } else {
 249         $template->param(
 250             view => 'report',
 251             report => $report,
 252             messages => \@messages,
 253         );
 254     }
 255 }
 256
 257 $template->param(
 258     messages => \@messages,
 259     recordtype => $recordtype,
 260     MarcModificationTemplatesLoop => \@templates,
 261 );
 262
 263 output_html_with_http_headers $input, $cookie, $template->output;