acqui/basket.pl

   1 #!/usr/bin/perl
   2
   3 #script to show display basket of orders
   4
   5 # Copyright 2000 - 2004 Katipo
   6 # Copyright 2008 - 2009 BibLibre SARL
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 use Modern::Perl;
  24 use C4::Auth;
  25 use C4::Koha;
  26 use C4::Output;
  27 use CGI qw ( -utf8 );
  28 use C4::Acquisition;
  29 use C4::Budgets;
  30 use C4::Contract;
  31 use C4::Debug;
  32 use C4::Biblio;
  33 use C4::Items;
  34 use C4::Suggestions;
  35 use Koha::Biblios;
  36 use Koha::Acquisition::Baskets;
  37 use Koha::Acquisition::Booksellers;
  38 use Koha::Acquisition::Orders;
  39 use Koha::Libraries;
  40 use C4::Letters qw/SendAlerts/;
  41 use Date::Calc qw/Add_Delta_Days/;
  42 use Koha::Database;
  43 use Koha::EDI qw( create_edi_order get_edifact_ean );
  44 use Koha::CsvProfiles;
  45 use Koha::Patrons;
  46
  47 use Koha::AdditionalFields;
  48
  49 =head1 NAME
  50
  51 basket.pl
  52
  53 =head1 DESCRIPTION
  54
  55  This script display all informations about basket for the supplier given
  56  on input arg.  Moreover, it allows us to add a new order for this supplier from
  57  an existing record, a suggestion or a new record.
  58
  59 =head1 CGI PARAMETERS
  60
  61 =over 4
  62
  63 =item $basketno
  64
  65 The basket number.
  66
  67 =item booksellerid
  68
  69 the supplier this script have to display the basket.
  70
  71 =item order
  72
  73 =back
  74
  75 =cut
  76
  77 our $query        = new CGI;
  78 our $basketno     = $query->param('basketno');
  79 our $ean          = $query->param('ean');
  80 our $booksellerid = $query->param('booksellerid');
  81 my $duplinbatch =  $query->param('duplinbatch');
  82
  83 our ( $template, $loggedinuser, $cookie, $userflags ) = get_template_and_user(
  84     {
  85         template_name   => "acqui/basket.tt",
  86         query           => $query,
  87         type            => "intranet",
  88         authnotrequired => 0,
  89         flagsrequired   => { acquisition => 'order_manage' },
  90         debug           => 1,
  91     }
  92 );
  93
  94 our $basket = GetBasket($basketno);
  95 $booksellerid = $basket->{booksellerid} unless $booksellerid;
  96 my $bookseller = Koha::Acquisition::Booksellers->find( $booksellerid );
  97 my $schema = Koha::Database->new()->schema();
  98 my $rs = $schema->resultset('VendorEdiAccount')->search(
  99     { vendor_id => $booksellerid, } );
 100 $template->param( ediaccount => ($rs->count > 0));
 101
 102 unless (CanUserManageBasket($loggedinuser, $basket, $userflags)) {
 103     $template->param(
 104         cannot_manage_basket => 1,
 105         basketno => $basketno,
 106         basketname => $basket->{basketname},
 107         booksellerid => $booksellerid,
 108         booksellername => $bookseller->name,
 109     );
 110     output_html_with_http_headers $query, $cookie, $template->output;
 111     exit;
 112 }
 113
 114 # FIXME : what about the "discount" percentage?
 115 # FIXME : the query->param('booksellerid') below is probably useless. The bookseller is always known from the basket
 116 # if no booksellerid in parameter, get it from basket
 117 # warn "=>".$basket->{booksellerid};
 118 my $op = $query->param('op') // 'list';
 119
 120 our $confirm_pref= C4::Context->preference("BasketConfirmations") || '1';
 121 $template->param( skip_confirm_reopen => 1) if $confirm_pref eq '2';
 122
 123 my @messages;
 124
 125 if ( $op eq 'delete_confirm' ) {
 126     my $basketno = $query->param('basketno');
 127     my $delbiblio = $query->param('delbiblio');
 128     my @orders = GetOrders($basketno);
 129 #Delete all orders included in that basket, and all items received.
 130     foreach my $myorder (@orders){
 131         DelOrder($myorder->{biblionumber},$myorder->{ordernumber});
 132     }
 133 # if $delbiblio = 1, delete the records if possible
 134     if ((defined $delbiblio)and ($delbiblio ==1)){
 135         my @cannotdelbiblios ;
 136         foreach my $myorder (@orders){
 137             my $biblionumber = $myorder->{'biblionumber'};
 138             my $biblio = Koha::Biblios->find( $biblionumber );
 139             my $countbiblio = CountBiblioInOrders($biblionumber);
 140             my $ordernumber = $myorder->{'ordernumber'};
 141             my $cnt_subscriptions = $biblio->subscriptions->count;
 142             my $itemcount = $biblio->items->count;
 143             my $error;
 144             if ($countbiblio == 0 && $itemcount == 0 && not $cnt_subscriptions ) {
 145                 $error = DelBiblio($myorder->{biblionumber}) }
 146             else {
 147                 push @cannotdelbiblios, {biblionumber=> ($myorder->{biblionumber}),
 148                                          title=> $myorder->{'title'},
 149                                          author=> $myorder->{'author'},
 150                                          countbiblio=> $countbiblio,
 151                                          itemcount=>$itemcount,
 152                                          subscriptions => $cnt_subscriptions};
 153             }
 154             if ($error) {
 155                 push @cannotdelbiblios, {biblionumber=> ($myorder->{biblionumber}),
 156                                          title=> $myorder->{'title'},
 157                                          author=> $myorder->{'author'},
 158                                          othererror=> $error};
 159             }
 160         }
 161         $template->param( cannotdelbiblios => \@cannotdelbiblios );
 162     }
 163  # delete the basket
 164     DelBasket($basketno,);
 165     $template->param(
 166         delete_confirmed => 1,
 167         booksellername => $bookseller->name,
 168         booksellerid => $booksellerid,
 169     );
 170 } elsif ( !$bookseller ) {
 171     $template->param( NO_BOOKSELLER => 1 );
 172 } elsif ($op eq 'export') {
 173     print $query->header(
 174         -type       => 'text/csv',
 175         -attachment => 'basket' . $basket->{'basketno'} . '.csv',
 176     );
 177     my $csv_profile_id = $query->param('csv_profile');
 178     print GetBasketAsCSV( scalar $query->param('basketno'), $query, $csv_profile_id ); # if no csv_profile_id passed, using default rows
 179     exit;
 180 } elsif ($op eq 'email') {
 181     my $err = eval {
 182         SendAlerts( 'orderacquisition', $query->param('basketno'), 'ACQORDER' );
 183     };
 184     if ( $@ ) {
 185         push @messages, { type => 'error', code => $@ };
 186     } elsif ( ref $err and exists $err->{error} ) {
 187         push @messages, { type => 'error', code => $err->{error} };
 188     } else {
 189         push @messages, { type => 'message', code => 'email_sent' };
 190     }
 191
 192     $op = 'list';
 193 } elsif ($op eq 'close') {
 194     my $confirm = $query->param('confirm') || $confirm_pref eq '2';
 195     if ($confirm) {
 196         my $basketno = $query->param('basketno');
 197         my $booksellerid = $query->param('booksellerid');
 198         $basketno =~ /^\d+$/ and CloseBasket($basketno);
 199         # if requested, create basket group, close it and attach the basket
 200         if ($query->param('createbasketgroup')) {
 201             my $branchcode;
 202             if(C4::Context->userenv and C4::Context->userenv->{'branch'}
 203               and C4::Context->userenv->{'branch'} ne "NO_LIBRARY_SET") {
 204                 $branchcode = C4::Context->userenv->{'branch'};
 205             }
 206             my $basketgroupid = NewBasketgroup( { name => $basket->{basketname},
 207                             booksellerid => $booksellerid,
 208                             deliveryplace => $branchcode,
 209                             billingplace => $branchcode,
 210                             closed => 1,
 211                             });
 212             ModBasket( { basketno => $basketno,
 213                          basketgroupid => $basketgroupid } );
 214             print $query->redirect('/cgi-bin/koha/acqui/basketgroup.pl?booksellerid='.$booksellerid.'&closed=1');
 215         } else {
 216             print $query->redirect('/cgi-bin/koha/acqui/booksellers.pl?booksellerid=' . $booksellerid);
 217         }
 218         exit;
 219     } else {
 220     $template->param(
 221         confirm_close   => "1",
 222         booksellerid    => $booksellerid,
 223         booksellername  => $bookseller->name,
 224         basketno        => $basket->{'basketno'},
 225         basketname      => $basket->{'basketname'},
 226         basketgroupname => $basket->{'basketname'},
 227     );
 228     }
 229 } elsif ($op eq 'reopen') {
 230     ReopenBasket(scalar $query->param('basketno'));
 231     print $query->redirect('/cgi-bin/koha/acqui/basket.pl?basketno='.$basket->{'basketno'})
 232 }
 233 elsif ( $op eq 'ediorder' ) {
 234     edi_close_and_order()
 235 } elsif ( $op eq 'mod_users' ) {
 236     my $basketusers_ids = $query->param('users_ids');
 237     my @basketusers = split( /:/, $basketusers_ids );
 238     ModBasketUsers($basketno, @basketusers);
 239     print $query->redirect("/cgi-bin/koha/acqui/basket.pl?basketno=$basketno");
 240     exit;
 241 } elsif ( $op eq 'mod_branch' ) {
 242     my $branch = $query->param('branch');
 243     $branch = undef if(defined $branch and $branch eq '');
 244     ModBasket({
 245         basketno => $basket->{basketno},
 246         branch   => $branch
 247     });
 248     print $query->redirect("/cgi-bin/koha/acqui/basket.pl?basketno=$basketno");
 249     exit;
 250 }
 251
 252 if ( $op eq 'list' ) {
 253     my @branches_loop;
 254     # get librarian branch...
 255     if ( C4::Context->preference("IndependentBranches") ) {
 256         my $userenv = C4::Context->userenv;
 257         unless ( C4::Context->IsSuperLibrarian() ) {
 258             my $validtest = ( $basket->{creationdate} eq '' )
 259               || ( $userenv->{branch} eq $basket->{branch} )
 260               || ( $userenv->{branch} eq '' )
 261               || ( $basket->{branch}  eq '' );
 262             unless ($validtest) {
 263                 print $query->redirect("../mainpage.pl");
 264                 exit 0;
 265             }
 266         }
 267
 268         if (!defined $basket->{branch} or $basket->{branch} eq $userenv->{branch}) {
 269             push @branches_loop, {
 270                 branchcode => $userenv->{branch},
 271                 branchname => $userenv->{branchname},
 272                 selected => 1,
 273             };
 274         }
 275     } else {
 276         # get branches
 277         my $branches = Koha::Libraries->search( {}, { order_by => ['branchname'] } )->unblessed;
 278         foreach my $branch (@$branches) {
 279             my $selected = 0;
 280             if (defined $basket->{branch}) {
 281                 $selected = 1 if $branch->{branchcode} eq $basket->{branch};
 282             } else {
 283                 $selected = 1 if $branch->{branchcode} eq C4::Context->userenv->{branch};
 284             }
 285             push @branches_loop, {
 286                 branchcode => $branch->{branchcode},
 287                 branchname => $branch->{branchname},
 288                 selected => $selected
 289             };
 290         }
 291     }
 292
 293 #if the basket is closed,and the user has the permission to edit basketgroups, display a list of basketgroups
 294     my ($basketgroup, $basketgroups);
 295     my $patron = Koha::Patrons->find($loggedinuser);
 296     if ($basket->{closedate} && haspermission($patron->userid, { acquisition => 'group_manage'} )) {
 297         $basketgroups = GetBasketgroups($basket->{booksellerid});
 298         for my $bg ( @{$basketgroups} ) {
 299             if ($basket->{basketgroupid} && $basket->{basketgroupid} == $bg->{id}){
 300                 $bg->{default} = 1;
 301                 $basketgroup = $bg;
 302             }
 303         }
 304     }
 305
 306     # if the basket is closed, calculate estimated delivery date
 307     my $estimateddeliverydate;
 308     if( $basket->{closedate} ) {
 309         my ($year, $month, $day) = ($basket->{closedate} =~ /(\d+)-(\d+)-(\d+)/);
 310         ($year, $month, $day) = Add_Delta_Days($year, $month, $day, $bookseller->deliverytime);
 311         $estimateddeliverydate = sprintf( "%04d-%02d-%02d", $year, $month, $day );
 312     }
 313
 314     # if new basket, pre-fill infos
 315     $basket->{creationdate} = ""            unless ( $basket->{creationdate} );
 316     $basket->{authorisedby} = $loggedinuser unless ( $basket->{authorisedby} );
 317     $debug
 318       and warn sprintf
 319       "loggedinuser: $loggedinuser; creationdate: %s; authorisedby: %s",
 320       $basket->{creationdate}, $basket->{authorisedby};
 321
 322     my @basketusers_ids = GetBasketUsers($basketno);
 323     my @basketusers;
 324     foreach my $basketuser_id (@basketusers_ids) {
 325         # FIXME Could be improved with a search -in
 326         my $basket_patron = Koha::Patrons->find( $basketuser_id );
 327         push @basketusers, $basket_patron if $basket_patron;
 328     }
 329
 330     my $active_currency = Koha::Acquisition::Currencies->get_active;
 331
 332     my @orders = GetOrders( $basketno );
 333     my @books_loop;
 334
 335     my @book_foot_loop;
 336     my %foot;
 337     my $total_quantity = 0;
 338     my $total_tax_excluded = 0;
 339     my $total_tax_included = 0;
 340     my $total_tax_value = 0;
 341     for my $order (@orders) {
 342         my $line = get_order_infos( $order, $bookseller);
 343         if ( $line->{uncertainprice} ) {
 344             $template->param( uncertainprices => 1 );
 345         }
 346
 347         $line->{tax_rate} = $line->{tax_rate_on_ordering} // 0;
 348         $line->{tax_value} = $line->{tax_value_on_ordering} // 0;
 349
 350         push @books_loop, $line;
 351
 352         $foot{$$line{tax_rate}}{tax_rate} = $$line{tax_rate};
 353         $foot{$$line{tax_rate}}{tax_value} += get_rounded_price($$line{tax_value});
 354         $total_tax_value += $$line{tax_value};
 355         $foot{$$line{tax_rate}}{quantity}  += get_rounded_price($$line{quantity});
 356         $total_quantity += $$line{quantity};
 357         $foot{$$line{tax_rate}}{total_tax_excluded} += $$line{total_tax_excluded};
 358         $total_tax_excluded += $$line{total_tax_excluded};
 359         $foot{$$line{tax_rate}}{total_tax_included} += $$line{total_tax_included};
 360         $total_tax_included += $$line{total_tax_included};
 361     }
 362
 363     push @book_foot_loop, map {$_} values %foot;
 364
 365     # Get cancelled orders
 366     my @cancelledorders = GetOrders($basketno, { cancelled => 1 });
 367     my @cancelledorders_loop;
 368     for my $order (@cancelledorders) {
 369         my $line = get_order_infos( $order, $bookseller);
 370         push @cancelledorders_loop, $line;
 371     }
 372
 373     my $contract = GetContract({
 374         contractnumber => $basket->{contractnumber}
 375     });
 376
 377     if ($basket->{basketgroupid}){
 378         $basketgroup = GetBasketgroup($basket->{basketgroupid});
 379     }
 380     my $budgets = GetBudgetHierarchy;
 381     my $has_budgets = 0;
 382     foreach my $r (@{$budgets}) {
 383         if (!defined $r->{budget_amount} || $r->{budget_amount} == 0) {
 384             next;
 385         }
 386         next unless (CanUserUseBudget($loggedinuser, $r, $userflags));
 387
 388         $has_budgets = 1;
 389         last;
 390     }
 391
 392     $template->param(
 393         basketno             => $basketno,
 394         basket               => $basket,
 395         basketname           => $basket->{'basketname'},
 396         basketbranchcode     => $basket->{branch},
 397         basketnote           => $basket->{note},
 398         basketbooksellernote => $basket->{booksellernote},
 399         basketcontractno     => $basket->{contractnumber},
 400         basketcontractname   => $contract->{contractname},
 401         branches_loop        => \@branches_loop,
 402         creationdate         => $basket->{creationdate},
 403         authorisedby         => $basket->{authorisedby},
 404         authorisedbyname     => $basket->{authorisedbyname},
 405         users_ids            => join(':', @basketusers_ids),
 406         users                => \@basketusers,
 407         closedate            => $basket->{closedate},
 408         estimateddeliverydate=> $estimateddeliverydate,
 409         is_standing          => $basket->{is_standing},
 410         deliveryplace        => $basket->{deliveryplace},
 411         billingplace         => $basket->{billingplace},
 412         active               => $bookseller->active,
 413         booksellerid         => $bookseller->id,
 414         booksellername       => $bookseller->name,
 415         books_loop           => \@books_loop,
 416         book_foot_loop       => \@book_foot_loop,
 417         cancelledorders_loop => \@cancelledorders_loop,
 418         total_quantity       => $total_quantity,
 419         total_tax_excluded   => $total_tax_excluded,
 420         total_tax_included   => $total_tax_included,
 421         total_tax_value      => $total_tax_value,
 422         currency             => $active_currency->currency,
 423         listincgst           => $bookseller->listincgst,
 424         basketgroups         => $basketgroups,
 425         basketgroup          => $basketgroup,
 426         grouped              => $basket->{basketgroupid},
 427         # The double negatives and booleans here mean:
 428         # "A basket cannot be closed if there are no orders in it or it's a standing order basket."
 429         #
 430         # (The template has another implicit restriction that the order cannot be closed if there
 431         # are any orders with uncertain prices.)
 432         unclosable           => @orders ? $basket->{is_standing} : 1,
 433         has_budgets          => $has_budgets,
 434         duplinbatch          => $duplinbatch,
 435         csv_profiles         => [ Koha::CsvProfiles->search({ type => 'sql', used_for => 'export_basket' }) ],
 436         available_additional_fields => [ Koha::AdditionalFields->search( { tablename => 'aqbasket' } ) ],
 437         additional_field_values => { map {
 438             $_->field->name => $_->value
 439         } Koha::Acquisition::Baskets->find($basketno)->additional_field_values->as_list },
 440     );
 441 }
 442
 443 $template->param( messages => \@messages );
 444 output_html_with_http_headers $query, $cookie, $template->output;
 445
 446 sub get_order_infos {
 447     my $order = shift;
 448     my $bookseller = shift;
 449     my $qty = $order->{'quantity'} || 0;
 450     if ( !defined $order->{quantityreceived} ) {
 451         $order->{quantityreceived} = 0;
 452     }
 453     my $budget = GetBudget($order->{budget_id});
 454     my $basket = GetBasket($order->{basketno});
 455
 456     my %line = %{ $order };
 457     # Don't show unreceived standing orders as received
 458     $line{order_received} = ( $qty == $order->{'quantityreceived'} && ( $basket->{is_standing} ? $qty : 1 ) );
 459     $line{basketno}       = $basketno;
 460     $line{budget_name}    = $budget->{budget_name};
 461
 462     # If we have an actual cost that should be the total, otherwise use the ecost
 463     my $cost_tax_included = $line{unitprice_tax_included} || $line{ecost_tax_included};
 464     my $cost_tax_excluded = $line{unitprice_tax_excluded} || $line{ecost_tax_excluded};
 465     $line{total_tax_included} = get_rounded_price($cost_tax_included) * $line{quantity};
 466     $line{total_tax_excluded} = get_rounded_price($cost_tax_excluded) * $line{quantity};
 467     $line{tax_value} = $line{tax_value_on_ordering};
 468     $line{tax_rate} = $line{tax_rate_on_ordering};
 469
 470     if ( $line{'title'} ) {
 471         my $volume      = $order->{'volume'};
 472         my $seriestitle = $order->{'seriestitle'};
 473         $line{'title'} .= " / $seriestitle" if $seriestitle;
 474         $line{'title'} .= " / $volume"      if $volume;
 475     }
 476
 477     my $biblionumber = $order->{'biblionumber'};
 478     if ( $biblionumber ) { # The biblio still exists
 479         my $biblio = Koha::Biblios->find( $biblionumber );
 480         my $countbiblio = CountBiblioInOrders($biblionumber);
 481         my $ordernumber = $order->{'ordernumber'};
 482         my $cnt_subscriptions = $biblio->subscriptions->count;
 483         my $itemcount   = $biblio->items->count;
 484         my $holds_count = $biblio->holds->count;
 485         my $order = Koha::Acquisition::Orders->find($ordernumber); # FIXME We should certainly do that at the beginning of this sub
 486         my $items = $order->items;
 487         my $itemholds  = $biblio->holds->search({ itemnumber => { -in => [ $items->get_column('itemnumber') ] } })->count;
 488
 489         # if the biblio is not in other orders and if there is no items elsewhere and no subscriptions and no holds we can then show the link "Delete order and Biblio" see bug 5680
 490         $line{can_del_bib}          = 1 if $countbiblio <= 1 && $itemcount == $items->count && !($cnt_subscriptions) && !($holds_count);
 491         $line{items}                = $itemcount - $items->count;
 492         $line{left_item}            = 1 if $line{items} >= 1;
 493         $line{left_biblio}          = 1 if $countbiblio > 1;
 494         $line{biblios}              = $countbiblio - 1;
 495         $line{left_subscription}    = 1 if $cnt_subscriptions;
 496         $line{subscriptions}        = $cnt_subscriptions;
 497         ($holds_count >= 1) ? $line{left_holds} = 1 : $line{left_holds} = 0;
 498         $line{left_holds_on_order}  = 1 if $line{left_holds}==1 && ($line{items} == 0 || $itemholds );
 499         $line{holds}                = $holds_count;
 500         $line{holds_on_order}       = $itemholds?$itemholds:$holds_count if $line{left_holds_on_order};
 501     }
 502
 503
 504     my $suggestion   = GetSuggestionInfoFromBiblionumber($line{biblionumber});
 505     $line{suggestionid}         = $$suggestion{suggestionid};
 506     $line{surnamesuggestedby}   = $$suggestion{surnamesuggestedby};
 507     $line{firstnamesuggestedby} = $$suggestion{firstnamesuggestedby};
 508
 509     foreach my $key (qw(transferred_from transferred_to)) {
 510         if ($line{$key}) {
 511             my $order = GetOrder($line{$key});
 512             my $basket = GetBasket($order->{basketno});
 513             my $bookseller = Koha::Acquisition::Booksellers->find( $basket->{booksellerid} );
 514             $line{$key} = {
 515                 order => $order,
 516                 basket => $basket,
 517                 bookseller => $bookseller,
 518                 timestamp => $line{$key . '_timestamp'},
 519             };
 520         }
 521     }
 522
 523     return \%line;
 524 }
 525
 526 sub edi_close_and_order {
 527     my $confirm = $query->param('confirm') || $confirm_pref eq '2';
 528     if ($confirm) {
 529             my $edi_params = {
 530                 basketno => $basketno,
 531                 ean    => $ean,
 532             };
 533             if ( $basket->{branch} ) {
 534                 $edi_params->{branchcode} = $basket->{branch};
 535             }
 536             if ( create_edi_order($edi_params) ) {
 537                 #$template->param( edifile => 1 );
 538             }
 539         CloseBasket($basketno);
 540
 541         # if requested, create basket group, close it and attach the basket
 542         if ( $query->param('createbasketgroup') ) {
 543             my $branchcode;
 544             if (    C4::Context->userenv
 545                 and C4::Context->userenv->{'branch'}
 546                 and C4::Context->userenv->{'branch'} ne "NO_LIBRARY_SET" )
 547             {
 548                 $branchcode = C4::Context->userenv->{'branch'};
 549             }
 550             my $basketgroupid = NewBasketgroup(
 551                 {
 552                     name          => $basket->{basketname},
 553                     booksellerid  => $booksellerid,
 554                     deliveryplace => $branchcode,
 555                     billingplace  => $branchcode,
 556                     closed        => 1,
 557                 }
 558             );
 559             ModBasket(
 560                 {
 561                     basketno      => $basketno,
 562                     basketgroupid => $basketgroupid
 563                 }
 564             );
 565             print $query->redirect(
 566 "/cgi-bin/koha/acqui/basketgroup.pl?booksellerid=$booksellerid&closed=1"
 567             );
 568         }
 569         else {
 570             print $query->redirect(
 571                 "/cgi-bin/koha/acqui/booksellers.pl?booksellerid=$booksellerid"
 572             );
 573         }
 574         exit;
 575     }
 576     else {
 577         $template->param(
 578             edi_confirm     => 1,
 579             booksellerid    => $booksellerid,
 580             basketno        => $basket->{basketno},
 581             basketname      => $basket->{basketname},
 582             basketgroupname => $basket->{basketname},
 583         );
 584         if ($ean) {
 585             $template->param( ean => $ean );
 586         }
 587
 588     }
 589     return;
 590 }