reserve/request.pl

   1 #!/usr/bin/perl
   2
   3
   4 #written 2/1/00 by chris@katipo.oc.nz
   5 # Copyright 2000-2002 Katipo Communications
   6 # Parts Copyright 2011 Catalyst IT
   7 #
   8 # This file is part of Koha.
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 =head1 request.pl
  24
  25 script to place reserves/requests
  26
  27 =cut
  28
  29 use Modern::Perl;
  30
  31 use CGI qw ( -utf8 );
  32 use List::MoreUtils qw/uniq/;
  33 use Date::Calc qw/Date_to_Days/;
  34 use C4::Output;
  35 use C4::Auth;
  36 use C4::Reserves;
  37 use C4::Biblio;
  38 use C4::Items;
  39 use C4::Koha;
  40 use C4::Serials;
  41 use C4::Circulation;
  42 use Koha::DateUtils;
  43 use C4::Utils::DataTables::Members;
  44 use C4::Members;
  45 use C4::Search;         # enabled_staff_search_views
  46
  47 use Koha::Biblios;
  48 use Koha::DateUtils;
  49 use Koha::Checkouts;
  50 use Koha::Holds;
  51 use Koha::CirculationRules;
  52 use Koha::Items;
  53 use Koha::ItemTypes;
  54 use Koha::Libraries;
  55 use Koha::Patrons;
  56 use Koha::Clubs;
  57
  58 my $dbh = C4::Context->dbh;
  59 my $input = new CGI;
  60 my ( $template, $borrowernumber, $cookie, $flags ) = get_template_and_user(
  61     {
  62         template_name   => "reserve/request.tt",
  63         query           => $input,
  64         type            => "intranet",
  65         flagsrequired   => { reserveforothers => 'place_holds' },
  66     }
  67 );
  68
  69 my $showallitems = $input->param('showallitems');
  70 my $pickup = $input->param('pickup') || C4::Context->userenv->{'branch'};
  71
  72 my $itemtypes = { map { $_->{itemtype} => $_ } @{ Koha::ItemTypes->search_with_localization->unblessed } };
  73
  74 # Select borrowers infos
  75 my $findborrower = $input->param('findborrower');
  76 $findborrower = '' unless defined $findborrower;
  77 $findborrower =~ s|,| |g;
  78 my $findclub = $input->param('findclub');
  79 $findclub = '' unless defined $findclub && !$findborrower;
  80 my $borrowernumber_hold = $input->param('borrowernumber') || '';
  81 my $club_hold = $input->param('club')||'';
  82 my $messageborrower;
  83 my $messageclub;
  84 my $warnings;
  85 my $messages;
  86 my $exceeded_maxreserves;
  87 my $exceeded_holds_per_record;
  88
  89 my $date = output_pref({ dt => dt_from_string, dateformat => 'iso', dateonly => 1 });
  90 my $action = $input->param('action');
  91 $action ||= q{};
  92
  93 if ( $action eq 'move' ) {
  94   my $where           = $input->param('where');
  95   my $reserve_id      = $input->param('reserve_id');
  96   my $prev_priority   = $input->param('prev_priority');
  97   my $next_priority   = $input->param('next_priority');
  98   my $first_priority  = $input->param('first_priority');
  99   my $last_priority   = $input->param('last_priority');
 100   my $hold_itemnumber = $input->param('itemnumber');
 101   if ( $prev_priority == 0 && $next_priority == 1 ){
 102       C4::Reserves::RevertWaitingStatus({ itemnumber => $hold_itemnumber });
 103   } else {
 104       AlterPriority( $where, $reserve_id, $prev_priority, $next_priority, $first_priority, $last_priority );
 105   }
 106 } elsif ( $action eq 'cancel' ) {
 107   my $reserve_id = $input->param('reserve_id');
 108   my $cancellation_reason = $input->param("cancellation-reason");
 109   my $hold = Koha::Holds->find( $reserve_id );
 110   $hold->cancel({ cancellation_reason => $cancellation_reason }) if $hold;
 111 } elsif ( $action eq 'setLowestPriority' ) {
 112   my $reserve_id = $input->param('reserve_id');
 113   ToggleLowestPriority( $reserve_id );
 114 } elsif ( $action eq 'toggleSuspend' ) {
 115   my $reserve_id = $input->param('reserve_id');
 116   my $suspend_until  = $input->param('suspend_until');
 117   ToggleSuspend( $reserve_id, $suspend_until );
 118 }
 119
 120 if ($findborrower) {
 121     my $patron = Koha::Patrons->find( { cardnumber => $findborrower } );
 122     if ( $patron ) {
 123         $borrowernumber_hold = $patron->borrowernumber;
 124     } else {
 125         my $dt_params = { iDisplayLength => -1 };
 126         my $results = C4::Utils::DataTables::Members::search(
 127             {
 128                 searchmember => $findborrower,
 129                 dt_params => $dt_params,
 130             }
 131         );
 132         my $borrowers = $results->{patrons};
 133         if ( scalar @$borrowers == 1 ) {
 134             $borrowernumber_hold = $borrowers->[0]->{borrowernumber};
 135         } elsif ( @$borrowers ) {
 136             $template->param( borrowers => $borrowers );
 137         } else {
 138             $messageborrower = "'$findborrower'";
 139         }
 140     }
 141 }
 142
 143 if($findclub) {
 144     my $club = Koha::Clubs->find( { name => $findclub } );
 145     if( $club ) {
 146         $club_hold = $club->id;
 147     } else {
 148         my @clubs = Koha::Clubs->search( [
 149             { name => { like => '%'.$findclub.'%' } },
 150             { description => { like => '%'.$findclub.'%' } }
 151         ] );
 152         if( scalar @clubs == 1 ) {
 153             $club_hold = $clubs[0]->id;
 154         } elsif ( @clubs ) {
 155             $template->param( clubs => \@clubs );
 156         } else {
 157             $messageclub = "'$findclub'";
 158         }
 159     }
 160 }
 161
 162 my @biblionumbers = ();
 163 my $biblionumber = $input->param('biblionumber');
 164 my $biblionumbers = $input->param('biblionumbers');
 165 if ( $biblionumbers ) {
 166     @biblionumbers = split '/', $biblionumbers;
 167 } else {
 168     push @biblionumbers, $input->multi_param('biblionumber');
 169 }
 170
 171 my $multi_hold = @biblionumbers > 1;
 172 $template->param(multi_hold => $multi_hold);
 173
 174 # If we have the borrowernumber because we've performed an action, then we
 175 # don't want to try to place another reserve.
 176 if ($borrowernumber_hold && !$action) {
 177     my $patron = Koha::Patrons->find( $borrowernumber_hold );
 178     my $diffbranch;
 179
 180     # we check the reserves of the user, and if they can reserve a document
 181     # FIXME At this time we have a simple count of reservs, but, later, we could improve the infos "title" ...
 182
 183     my $reserves_count = $patron->holds->count;
 184
 185     my $new_reserves_count = scalar( @biblionumbers );
 186
 187     my $maxreserves = C4::Context->preference('maxreserves');
 188     if ( $maxreserves
 189         && ( $reserves_count + $new_reserves_count > $maxreserves ) )
 190     {
 191         my $new_reserves_allowed =
 192             $maxreserves - $reserves_count > 0
 193           ? $maxreserves - $reserves_count
 194           : 0;
 195         $warnings             = 1;
 196         $exceeded_maxreserves = 1;
 197         $template->param(
 198             new_reserves_allowed => $new_reserves_allowed,
 199             new_reserves_count   => $new_reserves_count,
 200             reserves_count       => $reserves_count,
 201             maxreserves          => $maxreserves,
 202         );
 203     }
 204
 205     # we check the date expiry of the borrower (only if there is an expiry date, otherwise, set to 1 (warn)
 206     my $expiry_date = $patron->dateexpiry;
 207     my $expiry = 0; # flag set if patron account has expired
 208     if ($expiry_date and $expiry_date ne '0000-00-00' and
 209         Date_to_Days(split /-/,$date) > Date_to_Days(split /-/,$expiry_date)) {
 210         $expiry = 1;
 211     }
 212
 213     # check if the borrower make the reserv in a different branch
 214     if ( $patron->branchcode ne C4::Context->userenv->{'branch'} ) {
 215         $diffbranch = 1;
 216     }
 217
 218     my $amount_outstanding = $patron->account->balance;
 219     $template->param(
 220                 patron              => $patron,
 221                 expiry              => $expiry,
 222                 diffbranch          => $diffbranch,
 223                 messages            => $messages,
 224                 warnings            => $warnings,
 225                 amount_outstanding  => $amount_outstanding,
 226     );
 227 }
 228
 229 if ($club_hold && !$borrowernumber_hold && !$action) {
 230     my $club = Koha::Clubs->find($club_hold);
 231
 232     my $enrollments = $club->club_enrollments;
 233
 234     my $maxreserves = C4::Context->preference('maxreserves');
 235     my $new_reserves_count = scalar( @biblionumbers );
 236
 237     my @members;
 238
 239     while(my $enrollment = $enrollments->next) {
 240         next if $enrollment->is_canceled;
 241         my $member = { patron => $enrollment->patron->unblessed };
 242         my $reserves_count = $enrollment->patron->holds->count;
 243         if ( $maxreserves
 244             && ( $reserves_count + $new_reserves_count > $maxreserves ) )
 245         {
 246             $member->{new_reserves_allowed} = $maxreserves - $reserves_count > 0
 247                 ? $maxreserves - $reserves_count
 248                 : 0;
 249             $member->{exceeded_maxreserves} = 1;
 250         }
 251         my $expiry_date = $enrollment->patron->dateexpiry;
 252         $member->{expiry} = 0; # flag set if patron account has expired
 253         if ($expiry_date and $expiry_date ne '0000-00-00' and
 254             Date_to_Days(split /-/,$date) > Date_to_Days(split /-/,$expiry_date)) {
 255             $member->{expiry} = 1;
 256         }
 257         $member->{amount_outstanding} = $enrollment->patron->account->balance;
 258         if ( $enrollment->patron->branchcode ne C4::Context->userenv->{'branch'} ) {
 259             $member->{diffbranch} = 1;
 260         }
 261
 262         push @members, $member;
 263     }
 264
 265     $template->param(
 266         club                => $club,
 267         members             => \@members,
 268         maxreserves         => $maxreserves,
 269         new_reserves_count  => $new_reserves_count
 270     );
 271 }
 272
 273 $template->param(
 274     messageborrower => $messageborrower,
 275     messageclub     => $messageclub
 276 );
 277
 278 # FIXME launch another time GetMember perhaps until (Joubu: Why?)
 279 my $patron = Koha::Patrons->find( $borrowernumber_hold );
 280
 281 my $logged_in_patron = Koha::Patrons->find( $borrowernumber );
 282
 283 my $wants_check;
 284 if ($patron) {
 285     $wants_check = $patron->wants_check_for_previous_checkout;
 286 }
 287 my $itemdata_enumchron = 0;
 288 my $itemdata_ccode = 0;
 289 my @biblioloop = ();
 290 foreach my $biblionumber (@biblionumbers) {
 291     next unless $biblionumber =~ m|^\d+$|;
 292
 293     my %biblioloopiter = ();
 294
 295     my $biblio = Koha::Biblios->find( $biblionumber );
 296
 297     my $force_hold_level;
 298     if ( $patron ) {
 299         { # CanBookBeReserved
 300             my $canReserve = CanBookBeReserved( $patron->borrowernumber, $biblionumber );
 301             if ( $canReserve->{status} eq 'OK' ) {
 302
 303                 #All is OK and we can continue
 304             }
 305             elsif ( $canReserve->{status} eq 'tooManyReserves' ) {
 306                 $exceeded_maxreserves = 1;
 307                 $template->param( maxreserves => $canReserve->{limit} );
 308             }
 309             elsif ( $canReserve->{status} eq 'tooManyHoldsForThisRecord' ) {
 310                 $exceeded_holds_per_record = 1;
 311                 $biblioloopiter{ $canReserve->{status} } = 1;
 312             }
 313             elsif ( $canReserve->{status} eq 'ageRestricted' ) {
 314                 $template->param( $canReserve->{status} => 1 );
 315                 $biblioloopiter{ $canReserve->{status} } = 1;
 316             }
 317             else {
 318                 $biblioloopiter{ $canReserve->{status} } = 1;
 319             }
 320         }
 321
 322         # For multiple holds per record, if a patron has previously placed a hold,
 323         # the patron can only place more holds of the same type. That is, if the
 324         # patron placed a record level hold, all the holds the patron places must
 325         # be record level. If the patron placed an item level hold, all holds
 326         # the patron places must be item level
 327         my $holds = Koha::Holds->search(
 328             {
 329                 borrowernumber => $patron->borrowernumber,
 330                 biblionumber   => $biblionumber,
 331                 found          => undef,
 332             }
 333         );
 334         $force_hold_level = $holds->forced_hold_level();
 335         $biblioloopiter{force_hold_level} = $force_hold_level;
 336         $template->param( force_hold_level => $force_hold_level );
 337
 338         # For a librarian to be able to place multiple record holds for a patron for a record,
 339         # we must find out what the maximum number of holds they can place for the patron is
 340         my $max_holds_for_record = GetMaxPatronHoldsForRecord( $patron->borrowernumber, $biblionumber );
 341         my $remaining_holds_for_record = $max_holds_for_record - $holds->count();
 342         $biblioloopiter{remaining_holds_for_record} = $max_holds_for_record;
 343         $template->param( max_holds_for_record => $max_holds_for_record );
 344         $template->param( remaining_holds_for_record => $remaining_holds_for_record );
 345
 346         { # alreadypossession
 347             # Check to see if patron is allowed to place holds on records where the
 348             # patron already has an item from that record checked out
 349             if ( !C4::Context->preference('AllowHoldsOnPatronsPossessions')
 350                 && CheckIfIssuedToPatron( $patron->borrowernumber, $biblionumber ) )
 351             {
 352                 $template->param( alreadypossession => 1, );
 353             }
 354         }
 355     }
 356
 357
 358     my $count = Koha::Holds->search( { biblionumber => $biblionumber } )->count();
 359     my $totalcount = $count;
 360
 361     # FIXME think @optionloop, is maybe obsolete, or  must be switchable by a systeme preference fixed rank or not
 362     # make priorities options
 363
 364     my @optionloop;
 365     for ( 1 .. $count + 1 ) {
 366         push(
 367              @optionloop,
 368              {
 369               num      => $_,
 370               selected => ( $_ == $count + 1 ),
 371              }
 372             );
 373     }
 374     # adding a fixed value for priority options
 375     my $fixedRank = $count+1;
 376
 377     my %itemnumbers_of_biblioitem;
 378
 379     my @hostitems = get_hostitemnumbers_of($biblionumber);
 380     my @itemnumbers;
 381     if (@hostitems){
 382         $template->param('hostitemsflag' => 1);
 383         push(@itemnumbers, @hostitems);
 384     }
 385
 386     my $items = Koha::Items->search({ -or => { biblionumber => $biblionumber, itemnumber => { in => \@itemnumbers } } });
 387
 388     unless ( $items->count ) {
 389         # FIXME Then why do we continue?
 390         $template->param('noitems' => 1);
 391         $biblioloopiter{noitems} = 1;
 392     }
 393
 394     ## Here we go backwards again to create hash of biblioitemnumber to itemnumbers,
 395     ## when by definition all of the itemnumber have the same biblioitemnumber
 396     my ( $iteminfos_of );
 397     while ( my $item = $items->next ) {
 398         $item = $item->unblessed;
 399         my $biblioitemnumber = $item->{biblioitemnumber};
 400         my $itemnumber = $item->{itemnumber};
 401         push( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} }, $itemnumber );
 402         $iteminfos_of->{$itemnumber} = $item;
 403     }
 404
 405     ## Should be same as biblionumber
 406     my @biblioitemnumbers = keys %itemnumbers_of_biblioitem;
 407
 408     my $biblioiteminfos_of = {
 409         map {
 410             my $biblioitem = $_;
 411             ( $biblioitem->{biblioitemnumber} => $biblioitem )
 412           } @{ Koha::Biblioitems->search(
 413                 { biblioitemnumber => { -in => \@biblioitemnumbers } },
 414                 { select => ['biblioitemnumber', 'publicationyear', 'itemtype']}
 415             )->unblessed
 416           }
 417     };
 418
 419     my @bibitemloop;
 420
 421     my @available_itemtypes;
 422     foreach my $biblioitemnumber (@biblioitemnumbers) {
 423         my $biblioitem = $biblioiteminfos_of->{$biblioitemnumber};
 424         my $num_available = 0;
 425         my $num_override  = 0;
 426         my $hiddencount   = 0;
 427         my $num_alreadyheld = 0;
 428
 429         $biblioitem->{force_hold_level} = $force_hold_level;
 430
 431         if ( $biblioitem->{biblioitemnumber} ne $biblionumber ) {
 432             $biblioitem->{hostitemsflag} = 1;
 433         }
 434
 435         $biblioloopiter{description} = $biblioitem->{description};
 436         $biblioloopiter{itypename}   = $biblioitem->{description};
 437         if ( $biblioitem->{itemtype} ) {
 438
 439             $biblioitem->{description} =
 440               $itemtypes->{ $biblioitem->{itemtype} }{description};
 441
 442             $biblioloopiter{imageurl} =
 443               getitemtypeimagelocation( 'intranet',
 444                 $itemtypes->{ $biblioitem->{itemtype} }{imageurl} );
 445         }
 446
 447         # iterating through all items first to check if any of them available
 448         # to pass this value further inside down to IsAvailableForItemLevelRequest to
 449         # it's complicated logic to analyse.
 450         # (before this loop was inside that sub loop so it was O(n^2) )
 451         my $items_any_available;
 452
 453         $items_any_available = ItemsAnyAvailableAndNotRestricted( { biblionumber => $biblioitemnumber, patron => $patron })
 454             if $patron;
 455
 456         foreach my $itemnumber ( @{ $itemnumbers_of_biblioitem{$biblioitemnumber} } )    {
 457             my $item = $iteminfos_of->{$itemnumber};
 458             my $do_check;
 459             if ( $patron ) {
 460                 $do_check = $patron->do_check_for_previous_checkout($item) if $wants_check;
 461                 if ( $do_check && $wants_check ) {
 462                     $item->{checked_previously} = $do_check;
 463                     if ( $multi_hold ) {
 464                         $biblioloopiter{checked_previously} = $do_check;
 465                     } else {
 466                         $template->param( checked_previously => $do_check );
 467                     }
 468                 }
 469             }
 470             $item->{force_hold_level} = $force_hold_level;
 471
 472             unless (C4::Context->preference('item-level_itypes')) {
 473                 $item->{itype} = $biblioitem->{itemtype};
 474             }
 475
 476             $item->{itypename} = $itemtypes->{ $item->{itype} }{description};
 477             $item->{imageurl} = getitemtypeimagelocation( 'intranet', $itemtypes->{ $item->{itype} }{imageurl} );
 478             $item->{homebranch} = $item->{homebranch};
 479
 480             # if the holdingbranch is different than the homebranch, we show the
 481             # holdingbranch of the document too
 482             if ( $item->{homebranch} ne $item->{holdingbranch} ) {
 483                 $item->{holdingbranch} = $item->{holdingbranch};
 484             }
 485
 486             if($item->{biblionumber} ne $biblionumber){
 487                 $item->{hostitemsflag} = 1;
 488                 $item->{hosttitle} = Koha::Biblios->find( $item->{biblionumber} )->title;
 489             }
 490
 491             # if the item is currently on loan, we display its return date and
 492             # change the background color
 493             my $issue = Koha::Checkouts->find( { itemnumber => $itemnumber } );
 494             if ( $issue ) {
 495                 $item->{date_due} = $issue->date_due;
 496                 $item->{backgroundcolor} = 'onloan';
 497             }
 498
 499             # checking reserve
 500             my $item_object = Koha::Items->find( $itemnumber );
 501             my $holds = $item_object->current_holds;
 502             if ( my $first_hold = $holds->next ) {
 503                 my $p = Koha::Patrons->find( $first_hold->borrowernumber );
 504
 505                 $item->{backgroundcolor} = 'reserved';
 506                 $item->{reservedate}     = output_pref({ dt => dt_from_string( $first_hold->reservedate ), dateonly => 1 }); # FIXME Should be formatted in the template
 507                 $item->{ReservedFor}     = $p;
 508                 $item->{ExpectedAtLibrary}     = $first_hold->branchcode;
 509                 $item->{waitingdate} = $first_hold->waitingdate;
 510             }
 511
 512             # Management of the notforloan document
 513             if ( $item->{notforloan} ) {
 514                 $item->{backgroundcolor} = 'other';
 515             }
 516
 517             # Management of lost or long overdue items
 518             if ( $item->{itemlost} ) {
 519                 $item->{backgroundcolor} = 'other';
 520                 if ($logged_in_patron->category->hidelostitems && !$showallitems) {
 521                     $item->{hide} = 1;
 522                     $hiddencount++;
 523                 }
 524             }
 525
 526             # Check the transit status
 527             my ( $transfertwhen, $transfertfrom, $transfertto ) =
 528               GetTransfers($itemnumber);
 529
 530             if ( defined $transfertwhen && $transfertwhen ne '' ) {
 531                 $item->{transfertwhen} = output_pref({ dt => dt_from_string( $transfertwhen ), dateonly => 1 });
 532                 $item->{transfertfrom} = $transfertfrom;
 533                 $item->{transfertto} = $transfertto;
 534                 $item->{nocancel} = 1;
 535             }
 536
 537             # If there is no loan, return and transfer, we show a checkbox.
 538             $item->{notforloan} ||= 0;
 539
 540             # if independent branches is on we need to check if the person can reserve
 541             # for branches they arent logged in to
 542             if ( C4::Context->preference("IndependentBranches") ) {
 543                 if (! C4::Context->preference("canreservefromotherbranches")){
 544                     # can't reserve items so need to check if item homebranch and userenv branch match if not we can't reserve
 545                     my $userenv = C4::Context->userenv;
 546                     unless ( C4::Context->IsSuperLibrarian ) {
 547                         $item->{cantreserve} = 1 if ( $item->{homebranch} ne $userenv->{branch} );
 548                     }
 549                 }
 550             }
 551
 552             if ( $patron ) {
 553                 my $patron_unblessed = $patron->unblessed;
 554                 my $branch = C4::Circulation::_GetCircControlBranch($item, $patron_unblessed);
 555
 556                 my $branchitemrule = GetBranchItemRule( $branch, $item->{'itype'} );
 557
 558                 $item->{'holdallowed'} = $branchitemrule->{'holdallowed'};
 559
 560                 my $can_item_be_reserved = CanItemBeReserved( $patron->borrowernumber, $itemnumber )->{status};
 561                 $item->{not_holdable} = $can_item_be_reserved unless ( $can_item_be_reserved eq 'OK' );
 562
 563                 $item->{item_level_holds} = Koha::CirculationRules->get_opacitemholds_policy( { item => $item_object, patron => $patron } );
 564
 565                 if (
 566                        !$item->{cantreserve}
 567                     && !$exceeded_maxreserves
 568                     && $can_item_be_reserved eq 'OK'
 569                     # items_any_available defined outside of the current loop,
 570                     # so we avoiding loop inside IsAvailableForItemLevelRequest:
 571                     && IsAvailableForItemLevelRequest($item_object, $patron, undef, $items_any_available)
 572                   )
 573                 {
 574                     $item->{available} = 1;
 575                     $num_available++;
 576                     if($branchitemrule->{'hold_fulfillment_policy'} eq 'any' ) {
 577                         $item->{pickup_locations} = 'Any library';
 578                         $item->{pickup_locations_code} = 'all';
 579                     } else {
 580                         my $arr_locations = Koha::Items->find($itemnumber)
 581                                     ->pickup_locations( { patron => $patron } );
 582
 583                         $item->{pickup_locations} = join( ', ',
 584                             map { $_->unblessed->{branchname} } @$arr_locations);
 585                         $item->{pickup_locations_code} = join( ',',
 586                             map { $_->unblessed->{branchcode} } @$arr_locations);
 587                     }
 588
 589                     push( @available_itemtypes, $item->{itype} );
 590                 }
 591                 elsif ( C4::Context->preference('AllowHoldPolicyOverride') ) {
 592                     # If AllowHoldPolicyOverride is set, it should override EVERY restriction, not just branch item rules
 593                     # with the exception of itemAlreadyOnHold because, you know, the item is already on hold
 594                     if ( $can_item_be_reserved ne 'itemAlreadyOnHold' ) {
 595                         $item->{override} = 1;
 596                         $num_override++;
 597                     } else { $num_alreadyheld++ }
 598
 599                     push( @available_itemtypes, $item->{itype} );
 600                 }
 601
 602                 # If none of the conditions hold true, then neither override nor available is set and the item cannot be checked
 603
 604                 # Show serial enumeration when needed
 605                 if ($item->{enumchron}) {
 606                     $itemdata_enumchron = 1;
 607                 }
 608                 # Show collection when needed
 609                 if ($item->{ccode}) {
 610                     $itemdata_ccode = 1;
 611                 }
 612             }
 613
 614             push @{ $biblioitem->{itemloop} }, $item;
 615         }
 616
 617         # While we can't override an alreay held item, we should be able to override the others
 618         # Unless all items are already held
 619         if ( $num_override > 0 && ($num_override + $num_alreadyheld) == scalar( @{ $biblioitem->{itemloop} } ) ) {
 620         # That is, if all items require an override
 621             $template->param( override_required => 1 );
 622         } elsif ( $num_available == 0 ) {
 623             $template->param( none_available => 1 );
 624             $biblioloopiter{warn} = 1;
 625             $biblioloopiter{none_avail} = 1;
 626         }
 627         $template->param( hiddencount => $hiddencount);
 628
 629         push @bibitemloop, $biblioitem;
 630     }
 631
 632     @available_itemtypes = uniq( @available_itemtypes );
 633     $template->param( available_itemtypes => \@available_itemtypes );
 634
 635     # existingreserves building
 636     my @reserveloop;
 637     my @reserves = Koha::Holds->search( { biblionumber => $biblionumber }, { order_by => 'priority' } );
 638     foreach my $res (
 639         sort {
 640             my $a_found = $a->found() || '';
 641             my $b_found = $a->found() || '';
 642             $a_found cmp $b_found;
 643         } @reserves
 644       )
 645     {
 646         my $priority = $res->priority();
 647         my %reserve;
 648         my @optionloop;
 649         for ( my $i = 1 ; $i <= $totalcount ; $i++ ) {
 650             push(
 651                 @optionloop,
 652                 {
 653                     num      => $i,
 654                     selected => ( $i == $priority ),
 655                 }
 656             );
 657         }
 658
 659         if ( $res->is_found() ) {
 660             $reserve{'holdingbranch'} = $res->item()->holdingbranch();
 661             $reserve{'biblionumber'}  = $res->item()->biblionumber();
 662             $reserve{'barcodenumber'} = $res->item()->barcode();
 663             $reserve{'wbrcode'}       = $res->branchcode();
 664             $reserve{'itemnumber'}    = $res->itemnumber();
 665             $reserve{'wbrname'}       = $res->branch()->branchname();
 666
 667             if ( $reserve{'holdingbranch'} eq $reserve{'wbrcode'} ) {
 668
 669                 # Just because the holdingbranch matches the reserve branch doesn't mean the item
 670                 # has arrived at the destination, check for an open transfer for the item as well
 671                 my ( $transfertwhen, $transfertfrom, $transferto ) =
 672                   C4::Circulation::GetTransfers( $res->itemnumber() );
 673                 if ( not $transferto or $transferto ne $res->branchcode() ) {
 674                     $reserve{'atdestination'} = 1;
 675                 }
 676             }
 677
 678             # set found to 1 if reserve is waiting for patron pickup
 679             $reserve{'found'}     = $res->is_found();
 680             $reserve{'intransit'} = $res->is_in_transit();
 681         }
 682         elsif ( $res->priority() > 0 ) {
 683             if ( my $item = $res->item() )  {
 684                 $reserve{'itemnumber'}      = $item->id();
 685                 $reserve{'barcodenumber'}   = $item->barcode();
 686                 $reserve{'item_level_hold'} = 1;
 687             }
 688         }
 689
 690         $reserve{'expirationdate'} = $res->expirationdate;
 691         $reserve{'date'}           = $res->reservedate;
 692         $reserve{'borrowernumber'} = $res->borrowernumber();
 693         $reserve{'biblionumber'}   = $res->biblionumber();
 694         $reserve{'patron'}         = $res->borrower;
 695         $reserve{'notes'}          = $res->reservenotes();
 696         $reserve{'waiting_date'}   = $res->waitingdate();
 697         $reserve{'ccode'}          = $res->item() ? $res->item()->ccode() : undef;
 698         $reserve{'barcode'}        = $res->item() ? $res->item()->barcode() : undef;
 699         $reserve{'priority'}       = $res->priority();
 700         $reserve{'lowestPriority'} = $res->lowestPriority();
 701         $reserve{'optionloop'}     = \@optionloop;
 702         $reserve{'suspend'}        = $res->suspend();
 703         $reserve{'suspend_until'}  = $res->suspend_until();
 704         $reserve{'reserve_id'}     = $res->reserve_id();
 705         $reserve{itemtype}         = $res->itemtype();
 706         $reserve{branchcode}       = $res->branchcode();
 707         $reserve{non_priority}     = $res->non_priority();
 708         $reserve{object}           = $res;
 709
 710         push( @reserveloop, \%reserve );
 711     }
 712
 713     # get the time for the form name...
 714     my $time = time();
 715
 716     $template->param(
 717                      time        => $time,
 718                      fixedRank   => $fixedRank,
 719                     );
 720
 721     # display infos
 722     $template->param(
 723                      optionloop        => \@optionloop,
 724                      bibitemloop       => \@bibitemloop,
 725                      itemdata_enumchron => $itemdata_enumchron,
 726                      itemdata_ccode    => $itemdata_ccode,
 727                      date              => $date,
 728                      biblionumber      => $biblionumber,
 729                      findborrower      => $findborrower,
 730                      biblio            => $biblio,
 731                      holdsview         => 1,
 732                      C4::Search::enabled_staff_search_views,
 733                     );
 734
 735     $biblioloopiter{biblionumber} = $biblionumber;
 736     $biblioloopiter{title} = $biblio->title;
 737     $biblioloopiter{rank} = $fixedRank;
 738     $biblioloopiter{reserveloop} = \@reserveloop;
 739
 740     if (@reserveloop) {
 741         $template->param( reserveloop => \@reserveloop );
 742     }
 743
 744     push @biblioloop, \%biblioloopiter;
 745 }
 746
 747 $template->param( biblioloop => \@biblioloop );
 748 $template->param( biblionumbers => $biblionumbers );
 749 $template->param( exceeded_maxreserves => $exceeded_maxreserves );
 750 $template->param( exceeded_holds_per_record => $exceeded_holds_per_record );
 751 $template->param( subscriptionsnumber => CountSubscriptionFromBiblionumber($biblionumber));
 752 $template->param( pickup => $pickup );
 753
 754 if ( C4::Context->preference( 'AllowHoldDateInFuture' ) ) {
 755     $template->param( reserve_in_future => 1 );
 756 }
 757
 758 $template->param(
 759     SuspendHoldsIntranet => C4::Context->preference('SuspendHoldsIntranet'),
 760     AutoResumeSuspendedHolds => C4::Context->preference('AutoResumeSuspendedHolds'),
 761 );
 762
 763 # printout the page
 764 output_html_with_http_headers $input, $cookie, $template->output;
 765
 766 sub sort_borrowerlist {
 767     my $borrowerslist = shift;
 768     my $ref           = [];
 769     push @{$ref}, sort {
 770         uc( $a->{surname} . $a->{firstname} ) cmp
 771           uc( $b->{surname} . $b->{firstname} )
 772     } @{$borrowerslist};
 773     return $ref;
 774 }