Makefile.PL

   1 # Copyright 2007 MJ Ray
   2 #
   3 # This file is part of Koha.
   4 #
   5 # Koha is free software; you can redistribute it and/or modify it
   6 # under the terms of the GNU General Public License as published by
   7 # the Free Software Foundation; either version 3 of the License, or
   8 # (at your option) any later version.
   9 #
  10 # Koha is distributed in the hope that it will be useful, but
  11 # WITHOUT ANY WARRANTY; without even the implied warranty of
  12 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  13 # GNU General Public License for more details.
  14 #
  15 # You should have received a copy of the GNU General Public License
  16 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  17 #
  18 # Current maintainer MJR http://mjr.towers.org.uk/
  19 #
  20
  21 use strict;
  22 use warnings;
  23 use ExtUtils::MakeMaker;
  24 use POSIX;
  25 use File::Spec;
  26 use Getopt::Long;
  27 use FindBin; # we need to enforce which C4::Installer::PerlModule is used in case more than one is installed
  28
  29 use lib $FindBin::Bin;
  30
  31 use C4::Installer;
  32
  33 my $koha_pm = C4::Installer::PerlModules->new;
  34
  35 my $DEBUG = 0;
  36 die "perl 5.10 or later required" unless ($] >= 5.010000);
  37
  38 # Hash up directory structure & files beginning with the directory we were called from (should be the base of koha)...
  39
  40 my $dirtree = hashdir('.');
  41 my %result = ();
  42
  43 =head1 NAME
  44
  45 Makefile.PL - Koha packager and installer
  46
  47 =head1 SYNOPSIS
  48
  49 =head2 BASIC INSTALLATION
  50
  51     perl Makefile.PL
  52     make
  53     make test
  54     sudo make install
  55
  56 =head2 UPGRADE INSTALLATION
  57
  58     NOTE: This option is only available if koha-install-log exists.
  59
  60     perl Makefile.PL --prev-install-log /path/to/koha-install-log
  61
  62     make
  63     make test
  64     sudo make upgrade
  65
  66 =head2 PACKAGING RELEASE TARBALLS
  67
  68     make manifest tardist
  69     make manifest zipdist
  70
  71 =head2 CLEANING UP
  72
  73         make clean
  74
  75 =head1 DESCRIPTION
  76
  77 This is a packager and installer that uses
  78 ExtUtils::MakeMaker, which is fairly common
  79 on perl systems.
  80 As well as building tar or zip files
  81 and installing with the above commands,
  82 it allows us to check pre-requisites
  83 and generate configuration files.
  84
  85 =head1 VARIABLES
  86
  87 =head2 NAME, VERSION_FROM, ABSTRACT, AUTHOR
  88
  89 Basic metadata about this software.
  90
  91 =head2 NO_META
  92
  93 Suppress generation of META.yml file.
  94
  95 =head2 PREREQ_PM
  96
  97 Hash of perl modules and versions required.
  98
  99 =head2 PM
 100
 101 Hash of file mappings
 102
 103 =head2 PL_FILES
 104
 105 This is a hash of PL scripts to run after installation and
 106 the files to ask them to generate.
 107 Maybe use the values from CONFIGURE
 108 to generate initial configuration files in future.
 109
 110 =cut
 111
 112 =head2 target_map
 113
 114 This is a hash mapping directories and files in the
 115 source tree to installation target directories.  The rules
 116 for this mapping are:
 117
 118 =over 4
 119
 120 =item If a directory or file is specified, it and its
 121 contents will be copied to the installation target directory.
 122
 123 =item If a subdirectory of a mapped directory is specified,
 124 its target overrides the parent's target for that subdirectory.
 125
 126 =item The value of each map entry may either be a scalar containing
 127 one target or a reference to a hash containing 'target' and 'trimdir'
 128 keys.
 129
 130 =item Any files at the top level of the source tree that are
 131 not included in the map will not be installed.
 132
 133 =item Any directories at the top level of the source tree
 134 that are not included in the map will be installed in
 135 INTRANET_CGI_DIR.  This is a sensible default given the
 136 current organization of the source tree, but (FIXME) it
 137 would be better to reorganize the source tree to better
 138 match the installation system, to allow adding new directories
 139 without having to adjust Makefile.PL each time.  The idea
 140 is to make the C<$target_map> hash as minimal as possible.
 141
 142 =back
 143
 144 The permitted installation targets are:
 145
 146 =over 4
 147
 148 =item INTRANET_CGI_DIR
 149
 150 CGI scripts for intranet (staff) interface.
 151
 152 =item INTRANET_TMPL_DIR
 153
 154 HTML templates for the intranet interface.
 155
 156 =item INTRANET_WWW_DIR
 157
 158 HTML files, images, etc. for DocumentRoot for the intranet interface.
 159
 160 =item OPAC_CGI_DIR
 161
 162 CGI scripts for OPAC (public) interface.
 163
 164 =item OPAC_TMPL_DIR
 165
 166 HTML templates for the OPAC interface.
 167
 168 =item OPAC_WWW_DIR
 169
 170 HTML files, images, etc. for DocumentRoot for the OPAC interface.
 171
 172 =item PERL_MODULE_DIR
 173
 174 Perl modules (at present just the C4 modules) that are intimately
 175 tied to Koha.  Depending on the installation options, these
 176 may or may not be installed one of the standard directories
 177 in Perl's default @LIB.
 178
 179 =item KOHA_CONF_DIR
 180
 181 Directory for Koha configuration files.
 182
 183 =item ZEBRA_CONF_DIR
 184
 185 Directory for Zebra configuration files.
 186
 187 =item ZEBRA_LOCK_DIR
 188
 189 Directory for Zebra's lock files.  This includes subdirs for authorities,
 190 biblios, and the zebra rebuild function.  Any activity to reindex
 191 zebra from koha should interlock here with rebuild_zebra.pl.
 192
 193 =item ZEBRA_DATA_DIR
 194
 195 Directory for Zebra's data files.
 196
 197 =item ZEBRA_RUN_DIR
 198
 199 Directory for Zebra's UNIX-domain sockets.
 200
 201 =item MISC_DIR
 202
 203 Directory for for miscellaenous scripts, among other
 204 things the translation toolkit and RSS feed tools.
 205
 206 =item SCRIPT_DIR
 207
 208 Directory for command-line scripts and daemons to
 209 be set up all for installation modes.
 210
 211 =item SCRIPT_NONDEV_DIR
 212
 213 Directory for command-line scripts that should
 214 be installed in the same directory as the
 215 SCRIPT_DIR target except 'dev' installs.
 216
 217 =item MAN_DIR
 218
 219 Directory for man pages created from POD -- will mostly
 220 contain information of interest to Koha developers.
 221
 222 =item DOC_DIR
 223
 224 Directory for Koha documentation accessed from the
 225 command-line, e.g., READMEs.
 226
 227 =item LOG_DIR
 228
 229 Directory for Apache and Zebra logs produced by Koha.
 230
 231 =item BACKUP_DIR
 232
 233 Directory for backup files produced by Koha.
 234
 235 =item PLUGINS_DIR
 236
 237 Directory for external Koha plugins.
 238
 239 =item PAZPAR2_CONF_DIR
 240
 241 Directory for PazPar2 configuration files.
 242
 243 =item FONT_DIR
 244
 245 Directory where DejaVu fonts are installed.
 246
 247 =item NONE
 248
 249 This is a dummy target used to explicitly state
 250 that a given file or directory is not to be installed.
 251 This is used either for parts of the installer itself
 252 or for development tools that are not applicable to a
 253 production installation.
 254
 255 =back
 256
 257 =cut
 258
 259 my $target_map = {
 260   './about.pl'                  => 'INTRANET_CGI_DIR',
 261   './acqui'                     => 'INTRANET_CGI_DIR',
 262   './admin'                     => 'INTRANET_CGI_DIR',
 263   './api'                       => 'API_CGI_DIR',
 264   './authorities'               => 'INTRANET_CGI_DIR',
 265   './basket'                    => 'INTRANET_CGI_DIR',
 266   './C4'                        => 'PERL_MODULE_DIR',
 267   './C4/SIP/t'                  => 'NONE',
 268   './C4/SIP/koha_test'          => 'NONE',
 269   './C4/tests'                  => 'NONE',
 270   './catalogue'                 => 'INTRANET_CGI_DIR',
 271   './cataloguing'               => 'INTRANET_CGI_DIR',
 272   './changelanguage.pl'         => 'INTRANET_CGI_DIR',
 273   './check_sysprefs.pl'         => 'NONE',
 274   './circ'                      => 'INTRANET_CGI_DIR',
 275   './course_reserves'           => 'INTRANET_CGI_DIR',
 276   './docs/history.txt'          => { target => 'DOC_DIR', trimdir => -1 },
 277   './offline_circ'              => 'INTRANET_CGI_DIR',
 278   './edithelp.pl'               => 'INTRANET_CGI_DIR',
 279   './etc'                       => { target => 'KOHA_CONF_DIR', trimdir => -1 },
 280   './etc/zebradb'               => { target => 'ZEBRA_CONF_DIR', trimdir => -1 },
 281   './etc/pazpar2'               => { target => 'PAZPAR2_CONF_DIR', trimdir => -1 },
 282   './help.pl'                   => 'INTRANET_CGI_DIR',
 283   './installer-CPAN.pl'         => 'NONE',
 284   './installer'                 => 'INTRANET_CGI_DIR',
 285   './errors'                    => {target => 'INTRANET_CGI_DIR'},
 286   './Koha'                      => 'PERL_MODULE_DIR',
 287   './Koha.pm'                   => 'PERL_MODULE_DIR',
 288   './koha-tmpl/intranet-tmpl'   => {target => 'INTRANET_TMPL_DIR', trimdir => -1},
 289   './koha-tmpl/opac-tmpl'       => {target => 'OPAC_TMPL_DIR', trimdir => -1},
 290   './kohaversion.pl'            => 'INTRANET_CGI_DIR',
 291   './labels'                    => 'INTRANET_CGI_DIR',
 292   './mainpage.pl'               => 'INTRANET_CGI_DIR',
 293   './Makefile.PL'               => 'NONE',
 294   './MANIFEST.SKIP'             => 'NONE',
 295   './members'                   => 'INTRANET_CGI_DIR',
 296   './misc'                      => { target => 'SCRIPT_NONDEV_DIR', trimdir => -1 },
 297   './misc/bin'                  => { target => 'SCRIPT_DIR', trimdir => -1 },
 298   './misc/release_notes'        => { target => 'DOC_DIR', trimdir => 2 },
 299   './misc/translator'           => { target => 'MISC_DIR', trimdir => 2 },
 300   './misc/koha-install-log'     => { target => 'MISC_DIR', trimdir => -1 },
 301   './misc/installer_devel_notes' => 'NONE',
 302   './opac'                      => 'OPAC_CGI_DIR',
 303   './OpenILS'                   => 'PERL_MODULE_DIR',
 304   './README.txt'                => 'NONE',
 305   './patroncards'               => 'INTRANET_CGI_DIR',
 306   './patron_lists'              => 'INTRANET_CGI_DIR',
 307   './plugins'                   => 'INTRANET_CGI_DIR',
 308   './reports'                   => 'INTRANET_CGI_DIR',
 309   './reserve'                   => 'INTRANET_CGI_DIR',
 310   './reviews'                   => 'INTRANET_CGI_DIR',
 311   './rewrite-config.PL'         => 'NONE',
 312   './reviews'                   => 'INTRANET_CGI_DIR',
 313   './rotating_collections'      => 'INTRANET_CGI_DIR',
 314   './serials'                   => 'INTRANET_CGI_DIR',
 315   './services'                  => 'INTRANET_CGI_DIR',
 316   './skel'                      => 'NONE',
 317   './skel/var/log/koha'         => { target => 'LOG_DIR', trimdir => -1 },
 318   './skel/var/spool/koha'       => { target => 'BACKUP_DIR', trimdir => -1 },
 319   './skel/var/run/koha/zebradb' => { target => 'ZEBRA_RUN_DIR', trimdir => -1 },
 320   './skel/var/lock/koha/zebradb/authorities' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 321   './skel/var/lib/koha/zebradb/authorities/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 322   './skel/var/lib/koha/zebradb/authorities/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 323   './skel/var/lib/koha/zebradb/authorities/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 324   './skel/var/lib/koha/zebradb/authorities/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 325   './skel/var/lock/koha/zebradb/biblios' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 326   './skel/var/lib/koha/zebradb/biblios/key'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 327   './skel/var/lib/koha/zebradb/biblios/register'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 328   './skel/var/lib/koha/zebradb/biblios/shadow'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 329   './skel/var/lib/koha/zebradb/biblios/tmp'  => { target => 'ZEBRA_DATA_DIR', trimdir => 6 },
 330   './skel/var/lock/koha/zebradb/rebuild' => { target => 'ZEBRA_LOCK_DIR', trimdir => 6 },
 331   './skel/var/lib/koha/plugins' => { target => 'PLUGINS_DIR', trimdir => 6 },
 332   './sms'                       => 'INTRANET_CGI_DIR',
 333   './suggestion'                => 'INTRANET_CGI_DIR',
 334   './svc'                       => 'INTRANET_CGI_DIR',
 335   './t'                         => 'NONE',
 336   './tags'                      => 'INTRANET_CGI_DIR',
 337   './tmp'                       => 'NONE', # FIXME need to determine whether
 338                                            # Koha generates any persistent temp files
 339                                            # that should go in /var/tmp/koha
 340   './tools'                     => 'INTRANET_CGI_DIR',
 341   './virtualshelves'            => 'INTRANET_CGI_DIR',
 342   './xml_sax.pl'                => 'PERL_MODULE_DIR',
 343   # ignore files and directories created by the install itself
 344   './pm_to_blib'                => 'NONE',
 345   './blib'                      => 'NONE',
 346 };
 347
 348 =head1 CONFIGURATION OPTIONS
 349
 350 The following configuration options are used by the installer.
 351
 352 =over 4
 353
 354 =item INSTALL_MODE
 355
 356 Specifies whether installation will be FHS-compliant (default,
 357 assumes user has root), put everything under
 358 a single directory (for users installing on a web host
 359 that allows CGI scripts and a MySQL database but not root
 360 access), or development (for a developer who wants to run
 361 Koha from a git clone with no fuss).
 362
 363 =item INSTALL_BASE
 364
 365 Directory under which most components will go.  Default
 366 value will vary depending on INSTALL_MODE.
 367
 368 =item DB_TYPE
 369
 370 Type of DBMS (e.g., mysql or Pg).
 371
 372 =item DB_HOST
 373
 374 Name of DBMS server.
 375
 376 =item DB_PORT
 377
 378 Port that DBMS server is listening on.
 379
 380 =item DB_NAME
 381
 382 Name of the DBMS database for Koha.
 383
 384 =item DB_USER
 385
 386 Name of DBMS user account for Koha's database.
 387
 388 =item DB_PASS
 389
 390 Pasword of DMBS user account for Koha's database.
 391
 392 =item ZEBRA_MARC_FORMAT
 393
 394 Specifies format of MARC records to be indexed by Zebra.
 395
 396 =item ZEBRA_LANGUAGE
 397
 398 Specifies primary language of records that will be
 399 indexed by Zebra.
 400
 401 =item ZEBRA_USER
 402
 403 Internal Zebra user account for the index.
 404
 405 =item ZEBRA_PASS
 406
 407 Internal Zebra user account's password.
 408
 409 =item KOHA_USER
 410
 411 System user account that will own Koha's files.
 412
 413 =item KOHA_GROUP
 414
 415 System group that will own Koha's files.
 416
 417 =back
 418
 419 =cut
 420
 421 # default configuration options
 422 my %config_defaults = (
 423   'DB_TYPE'           => 'mysql',
 424   'DB_HOST'           => 'localhost',
 425   'DB_NAME'           => 'koha',
 426   'DB_USER'           => 'kohaadmin',
 427   'DB_PASS'           => 'katikoan',
 428   'INSTALL_SRU'       => 'yes',
 429   'INSTALL_PAZPAR2'   => 'no',
 430   'AUTH_INDEX_MODE'   => 'dom',
 431   'BIB_INDEX_MODE'    => 'dom',
 432   'ZEBRA_MARC_FORMAT' => 'marc21',
 433   'ZEBRA_LANGUAGE'    => 'en',
 434   'ZEBRA_TOKENIZER'   => 'chr',
 435   'ZEBRA_USER'        => 'kohauser',
 436   'ZEBRA_PASS'        => 'zebrastripes',
 437   'ZEBRA_SRU_HOST'    => 'localhost',
 438   'ZEBRA_SRU_BIBLIOS_PORT'    => '9998',
 439   'ZEBRA_SRU_AUTHORITIES_PORT'    => '9999',
 440   'KOHA_USER'         => 'koha',
 441   'KOHA_GROUP'        => 'koha',
 442   'MERGE_SERVER_HOST' => 'localhost',
 443   'MERGE_SERVER_PORT' => '11001',
 444   'PAZPAR2_HOST' => 'localhost',
 445   'PAZPAR2_PORT' => '11002',
 446   'RUN_DATABASE_TESTS' => 'no',
 447   'PATH_TO_ZEBRA' => '',
 448   'USE_MEMCACHED'     => 'no',
 449   'MEMCACHED_SERVERS' => '127.0.0.1:11211',
 450   'MEMCACHED_NAMESPACE' => 'KOHA',
 451   'FONT_DIR'          => '/usr/share/fonts/truetype/ttf-dejavu'
 452 );
 453
 454 # set some default configuration options based on OS
 455 # more conditions need to be added for other OS's
 456
 457 warn "Your platform appears to be $^O.\n" if $DEBUG;
 458
 459 if ( $^O eq 'cygwin' ) {
 460         # Most Unix2Win32 ports seem to poke everything into the Program Files directory
 461         # this could be changed to put some files (ie. libraries) into system32, etc.
 462         $config_defaults{'INSTALL_MODE'} = 'single';
 463         $config_defaults{'INSTALL_BASE'} = 'c:/progra~1/koha';  # Use 8.3 names to be safe...
 464 }
 465 else {
 466         $config_defaults{'INSTALL_MODE'} = 'standard';
 467         $config_defaults{'INSTALL_BASE'} = '/usr/share/koha';
 468 }
 469
 470 # valid values for certain configuration options
 471 my %valid_config_values = (
 472   'INSTALL_MODE'  => { 'standard' => 1, 'single' => 1, 'dev' => 1 },
 473   'DB_TYPE' => { 'mysql' => 1, 'Pg' => 1 },
 474   'INSTALL_SRU' => { 'yes' => 1, 'no' => 1 },
 475   'AUTH_INDEX_MODE' => { 'grs1' => 1, 'dom' => 1 },
 476   'BIB_INDEX_MODE'  => { 'grs1' => 1, 'dom' => 1 },
 477   'ZEBRA_MARC_FORMAT' => { 'marc21' => 1, 'normarc' => 1, 'unimarc' => 1 }, # FIXME should generate from contents of distributation
 478   'ZEBRA_LANGUAGE'    => { 'en' => 1, 'es' => 1, 'fr' => 1, 'gr' => 1, 'nb' => 1, 'ru' => 1, 'uk' => 1 }, # FIXME should generate from contents of distribution
 479   'ZEBRA_TOKENIZER' => { chr => 1, icu => 1 },
 480   'RUN_DATABASE_TESTS' => { 'yes' => 1, 'no' => 1 },
 481   'USE_MEMCACHED'      => { 'yes' => 1, 'no' => 1 },
 482 );
 483
 484 # get settings from command-line
 485 my $koha_install_log = "";
 486 Getopt::Long::Configure('pass_through');
 487 my $results = GetOptions(
 488     "prev-install-log=s" => \$koha_install_log
 489 );
 490
 491 my %install_log_values = ();
 492 if ($koha_install_log ne "") {
 493     get_install_log_values($koha_install_log, \%install_log_values);
 494 }
 495
 496 my %config = get_configuration(\%config_defaults, \%valid_config_values, \%install_log_values);
 497 my ($target_directories, $skip_directories) = get_target_directories(\%config);
 498 display_configuration(\%config, $target_directories);
 499 my $file_map = {};
 500 get_file_map($target_map, $dirtree, $file_map);
 501
 502 my $pl_files = {
 503       'rewrite-config.PL' => [
 504          'blib/KOHA_CONF_DIR/koha-conf.xml',
 505          'blib/KOHA_CONF_DIR/koha-httpd.conf',
 506          'blib/KOHA_CONF_DIR/log4perl.conf',
 507          'blib/ZEBRA_CONF_DIR/etc/default.idx',
 508          'blib/MISC_DIR/koha-install-log'
 509          ],
 510           'fix-perl-path.PL' => [       # this script ensures the correct shebang line for the platform installed on...
 511                  'blib'
 512                  ],
 513 };
 514
 515 push @{ $pl_files->{'rewrite-config.PL'} }, (
 516     'blib/ZEBRA_CONF_DIR/etc/passwd',
 517     'blib/ZEBRA_CONF_DIR/zebra-biblios.cfg',
 518     'blib/ZEBRA_CONF_DIR/zebra-biblios-dom.cfg',
 519     'blib/ZEBRA_CONF_DIR/zebra-authorities.cfg',
 520     'blib/ZEBRA_CONF_DIR/zebra-authorities-dom.cfg',
 521     'blib/ZEBRA_CONF_DIR/explain-authorities.xml',
 522     'blib/ZEBRA_CONF_DIR/explain-biblios.xml',
 523     'blib/ZEBRA_CONF_DIR/retrieval-info-auth-grs1.xml',
 524     'blib/ZEBRA_CONF_DIR/retrieval-info-auth-dom.xml',
 525     'blib/ZEBRA_CONF_DIR/retrieval-info-bib-grs1.xml',
 526     'blib/ZEBRA_CONF_DIR/retrieval-info-bib-dom.xml',
 527 );
 528 push @{ $pl_files->{'rewrite-config.PL'} }, (
 529     'blib/SCRIPT_DIR/koha-zebra-ctl.sh',
 530     'blib/SCRIPT_DIR/koha-pazpar2-ctl.sh',
 531     'blib/SCRIPT_DIR/koha-index-daemon-ctl.sh',
 532 );
 533 if ($config{'INSTALL_PAZPAR2'} eq 'yes') {
 534     push @{ $pl_files->{'rewrite-config.PL'} }, (
 535         'blib/PAZPAR2_CONF_DIR/koha-biblios.xml',
 536         'blib/PAZPAR2_CONF_DIR/pazpar2.xml'
 537     );
 538 }
 539 $config{'ZEBRA_AUTH_CFG'} = $config{'AUTH_INDEX_MODE'} eq 'dom'
 540                               ? 'zebra-authorities-dom.cfg'
 541                               : 'zebra-authorities.cfg';
 542 $config{'ZEBRA_BIB_CFG'}  = $config{'BIB_INDEX_MODE'} eq 'dom'
 543                               ? 'zebra-biblios-dom.cfg'
 544                               : 'zebra-biblios.cfg';
 545 $config{'AUTH_RETRIEVAL_CFG'} = $config{'AUTH_INDEX_MODE'} eq 'dom'
 546                                   ? 'retrieval-info-auth-dom.xml'
 547                                   : 'retrieval-info-auth-grs1.xml';
 548 $config{'BIB_RETRIEVAL_CFG'}  = $config{'BIB_INDEX_MODE'} eq 'dom'
 549                                   ? 'retrieval-info-bib-dom.xml'
 550                                   : 'retrieval-info-bib-grs1.xml';
 551
 552
 553 if ($config{'INSTALL_MODE'} ne "dev") {
 554     push @{ $pl_files->{'rewrite-config.PL'} }, (
 555         'blib/PERL_MODULE_DIR/C4/Context.pm',
 556         'blib/SCRIPT_NONDEV_DIR/kohalib.pl'
 557     );
 558 }
 559
 560 $config{ZEBRA_TOKENIZER_STMT} = $config{ZEBRA_TOKENIZER} eq 'icu'
 561     ? 'icuchain words-icu.xml'
 562     : 'charmap word-phrase-utf.chr';
 563
 564 $config{ZEBRA_PTOKENIZER_STMT} = $config{ZEBRA_TOKENIZER} eq 'icu'
 565     ? 'icuchain phrases-icu.xml'
 566     : 'charmap word-phrase-utf.chr';
 567
 568 my %test_suite_override_dirs = (
 569     KOHA_CONF_DIR  => ['etc'],
 570     ZEBRA_CONF_DIR => ['etc', 'zebradb'],
 571     LOG_DIR        => ['var', 'log'],
 572     BACKUP_DIR     => ['var', 'spool'],
 573     SCRIPT_DIR     => ['bin'],
 574     ZEBRA_LOCK_DIR => ['var', 'lock', 'zebradb'],
 575     ZEBRA_DATA_DIR => ['var', 'lib', 'zebradb'],
 576     ZEBRA_RUN_DIR  => ['var', 'run', 'zebradb'],
 577 );
 578
 579 WriteMakefile(
 580               NAME         => 'koha',
 581               #VERSION     => strftime('2.9.%Y%m%d%H',gmtime),
 582               VERSION_FROM => 'kohaversion.pl',
 583               ABSTRACT     => 'Award-winning integrated library system (ILS) and Web OPAC',
 584               AUTHOR       => 'Koha Contributors <http://koha-community.org/>',
 585               NO_META      => 1,
 586               PREREQ_PM    => $koha_pm->prereq_pm,
 587
 588               # File tree mapping
 589               PM => $file_map,
 590
 591               # Man pages generated from POD
 592               # ExtUtils::MakeMaker already manage $(DESTDIR)
 593               INSTALLMAN1DIR => File::Spec->catdir(_strip_destdir($target_directories->{'MAN_DIR'}), 'man1'),
 594               INSTALLMAN3DIR => File::Spec->catdir(_strip_destdir($target_directories->{'MAN_DIR'}), 'man3'),
 595
 596               PL_FILES => $pl_files,
 597 );
 598
 599 =head1 FUNCTIONS
 600
 601 =head2 hashdir
 602
 603 This function recurses through the directory structure and builds
 604 a hash of hashes containing the structure with arrays holding filenames.
 605 This directory hashing routine was taken from BrowserUK @ http://www.perlmonks.org/?node_id=219919
 606
 607 =cut
 608
 609 sub hashdir{
 610     my $dir = shift;
 611     opendir my $dh, $dir or die $!;
 612     my $tree = {}->{$dir} = {};
 613     while( my $file = readdir($dh) ) {
 614         next if $file =~ m/^\.{1,2}/ and $file !~ /^\.htaccess/; # .htaccess is a special case
 615         my $path = $dir .'/' . $file;
 616         $tree->{$file} = hashdir($path), next if -d $path;
 617         push @{$tree->{'.'}}, $file;
 618     }
 619     return $tree;
 620 }
 621
 622 =head2 get_file_map
 623
 624 This function combines the target_map and file hash to
 625 map each source file to its destination relative to
 626 the set of installation targets.
 627
 628 Output will be a hash mapping from each source file
 629 to its destination value, like this:
 630
 631 'mainpage.pl' => '$(INTRANET_CGI_DIR)/mainpage.pl'
 632
 633 =cut
 634
 635 sub get_file_map {
 636     my $target_map = shift;
 637     my $dirtree = shift;
 638     my $file_map = shift;
 639     my $curr_path = @_ ? shift : ['.'];
 640
 641     # Traverse the directory tree.
 642     # For each file or directory, identify the
 643     # most specific match in the target_map
 644     foreach my $dir (sort keys %{ $dirtree }) {
 645         if ($dir eq '.') {
 646             # deal with files in directory
 647             foreach my $file (sort @{ $dirtree->{$dir} }) {
 648                 my $targetdir = undef;
 649                 my $matchlevel = undef;
 650                 # first, see if there is a match on this specific
 651                 # file in the target map
 652                 my $filepath = join("/", @$curr_path, $file);
 653                 if (exists $target_map->{$filepath}) {
 654                     $targetdir = $target_map->{$filepath};
 655                     $matchlevel = scalar(@$curr_path) + 1;
 656                 } else {
 657                     # no match on the specific file; look for
 658                     # a directory match
 659                     for (my $i = scalar(@$curr_path) - 1; $i >= 0; $i--)  {
 660                         my $dirpath = join("/", @$curr_path[0..$i]);
 661                         if (exists $target_map->{$dirpath}) {
 662                             $targetdir = $target_map->{$dirpath};
 663                             $matchlevel = $i + 1;
 664                             last;
 665                         }
 666                     }
 667                 }
 668                 if (defined $targetdir) {
 669                      _add_to_file_map($file_map, $targetdir, $curr_path, $file, $matchlevel);
 670                 } else {
 671                     my $path = join("/", @$curr_path);
 672                     print "failed to map: $path/$file\n" if $DEBUG;
 673                 }
 674             }
 675         } else {
 676             # dealing with subdirectory
 677             push @$curr_path, $dir;
 678             get_file_map($target_map, $dirtree->{$dir}, $file_map, $curr_path);
 679             pop @$curr_path;
 680         }
 681     }
 682 }
 683
 684 sub _add_to_file_map {
 685     my $file_map = shift;
 686     my $targetdir = shift;
 687     my $curr_path = shift;
 688     my $file = shift;
 689     my $matchlevel = shift;
 690     my $dest_path = @_ ? shift : $curr_path;
 691
 692     # The target can be one of the following:
 693     # 1. scalar representing target symbol
 694     # 2. hash ref containing target and trimdir keys
 695     #
 696     # Consequently, this routine traverses this structure,
 697     # calling itself recursively, until it deals with
 698     # all of the scalar target symbols.
 699     if (ref $targetdir eq 'HASH') {
 700         my $subtarget = $targetdir->{target};
 701         if (exists $targetdir->{trimdir}) {
 702             # if we get here, we've specified that
 703             # rather than installing the file to
 704             # $(TARGET)/matching/dirs/subdirs/file,
 705             # we want to install it to
 706             # $(TARGET)/subdirs/file
 707             #
 708             # Note that this the only place where
 709             # $matchlevel is used.
 710             my @new_dest_path = @$dest_path;
 711             if ($targetdir->{trimdir} == -1)  {
 712                 splice @new_dest_path, 0, $matchlevel;
 713             } else {
 714                 splice @new_dest_path, 0, $targetdir->{trimdir};
 715             }
 716             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel, \@new_dest_path);
 717         } else {
 718             # actually getting here means that the
 719             # target was unnecessarily listed
 720             # as a hash, but we'll forgive that
 721             _add_to_file_map($file_map, $subtarget, $curr_path, $file, $matchlevel);
 722         }
 723     } elsif ($targetdir ne 'NONE' and $targetdir ne '') {
 724         my $source = File::Spec->catfile(@$curr_path, $file);
 725         my $destination = File::Spec->catfile('blib', $targetdir, @$dest_path, $file);
 726         #print "$source => $destination\n"; # DEBUG
 727         # quote spaces in file names
 728         # FIXME: this is of questionable portability and
 729         # probably depends on user's make recognizing this
 730         # quoting syntax -- probably better to remove
 731         # spaces and shell metacharacters from all file names
 732         $source =~ s/ /\\ /g;
 733         $destination =~ s/ /\\ /g;
 734
 735         $file_map->{$source} = $destination;
 736     }
 737 }
 738
 739 =head2 get_install_log_values
 740
 741 Reads value from the Koha install log specified by
 742 --prev-install-log
 743
 744 =cut
 745
 746 sub get_install_log_values {
 747     my $install_log = shift;
 748     my $values = shift;
 749
 750     open LOG, "<$install_log" or die "Cannot open install log $install_log: $!\n";
 751     while (<LOG>) {
 752         chomp;
 753         next if /^#/ or /^\s*$/;
 754         next if /^=/;
 755         next unless m/=/;
 756         s/\s+$//g;
 757         my ($key, $value) = split /=/, $_, 2;
 758         $values->{$key} = $value;
 759     }
 760     close LOG;
 761
 762     print <<_EXPLAIN_INSTALL_LOG_;
 763 Reading values from install log $install_log.  You
 764 will be prompted only for settings that have been
 765 added since the last time you installed Koha.  To
 766 be prompted for all settings, run 'perl Makefile.PL'
 767 without the --prev-install-log option.
 768 _EXPLAIN_INSTALL_LOG_
 769 }
 770
 771 =head2 get_configuration
 772
 773 This prompts the user for various configuration options.
 774
 775 =cut
 776
 777 sub get_configuration {
 778   my $defaults = shift;
 779   my $valid_values = shift;
 780   my $install_log_values = shift;
 781   my %config = ();
 782
 783   my $msg = q(
 784 By default, Koha can be installed in one of three ways:
 785
 786 standard: Install files in conformance with the Filesystem
 787           Hierarchy Standard (FHS).  This is the default mode
 788           and should be used when installing a production
 789           Koha system.  On Unix systems, root access is
 790           needed to complete a standard installation.
 791
 792 single:   Install files under a single directory.  This option
 793           is useful for installing Koha without root access, e.g.,
 794           on a web host that allows CGI scripts and MySQL databases
 795           but requires the user to keep all files under the user's
 796           HOME directory.
 797
 798 dev:      Create a set of symbolic links and configuration files to
 799           allow Koha to run directly from the source distribution.
 800           This mode is useful for developers who want to run
 801           Koha from a git clone.
 802
 803 Installation mode);
 804     $msg .= _add_valid_values_disp('INSTALL_MODE', $valid_values);
 805     $config{'INSTALL_MODE'} = _get_value('INSTALL_MODE', $msg, $defaults->{'INSTALL_MODE'}, $valid_values, $install_log_values);
 806
 807     # set message and default value for INSTALL_BASE
 808     # depending on value of INSTALL_MODE
 809     my $install_base_default = $defaults->{'INSTALL_BASE'};
 810     if ($config{'INSTALL_MODE'} eq 'dev') {
 811         $msg = q(
 812 Please specify the directory in which to install Koha's
 813 active configuration files and (if applicable) the
 814 Zebra database.  Koha's CGI scripts and templates will
 815 be run from the current directory.
 816
 817 Configuration directory:);
 818         # FIXME - home directory portability consideration apply
 819         $install_base_default =
 820             $ENV{DESTDIR}
 821             || ( exists $ENV{HOME} ? "$ENV{HOME}/koha-dev" : "$defaults->{'INSTALL_BASE'}-dev" )
 822         ;
 823     } elsif ($config{'INSTALL_MODE'} eq 'single') {
 824         $msg = "\nPlease specify the directory in which to install Koha";
 825         # FIXME -- we're assuming under a 'single' mode install
 826         # that user will likely want to install under the home
 827         # directory.  This is OK in and of itself, but we should
 828         # use File::HomeDir to locate the home directory portably.
 829         # This is deferred for now because File::HomeDir is not yet
 830         # core.
 831                 # --we must also keep this portable to the major OS's -fbcit
 832         $install_base_default = (exists $ENV{'HOME'}) ? "$ENV{'HOME'}/koha" : $defaults->{'INSTALL_BASE'};
 833     } else {
 834         # must be standard
 835         $msg = q(
 836 Please specify the directory under which most Koha files
 837 will be installed.
 838
 839 Note that if you are planning in installing more than
 840 one instance of Koha, you may want to modify the last
 841 component of the directory path, which will be used
 842 as the package name in the FHS layout.
 843
 844 Base installation directory);
 845     }
 846     $config{'INSTALL_BASE'} = _get_value('INSTALL_BASE', $msg, $install_base_default, $valid_values, $install_log_values);
 847
 848     $config{'INSTALL_BASE'} = File::Spec->rel2abs($config{'INSTALL_BASE'});
 849         print "INSTALL_BASE=$config{'INSTALL_BASE'}\r\n" if $DEBUG;
 850     if ($config{'INSTALL_MODE'} eq "standard") {
 851         $msg = q(
 852 Since you are using the 'standard' install
 853 mode, you should run 'make install' as root.
 854 However, it is recommended that a non-root
 855 user (on Unix and Linux platforms) have
 856 ownership of Koha's files, including the
 857 Zebra indexes if applicable.
 858
 859 Please specify a user account.  This
 860 user account does not need to exist
 861 right now, but it needs to exist
 862 before you run 'make install'.  Please
 863 note that for security reasons, this
 864 user should not be the same as the user
 865 account Apache runs under.
 866
 867 User account);
 868         $config{'KOHA_USER'} = _get_value('KOHA_USER', $msg, $defaults->{'KOHA_USER'}, $valid_values, $install_log_values);
 869
 870         $msg = q(
 871 Please specify the group that should own
 872 Koha's files.  As above, this group need
 873 not exist right now, but should be created
 874 before you run 'make install'.
 875
 876 Group);
 877         $config{'KOHA_GROUP'} = _get_value('KOHA_GROUP', $msg, $defaults->{'KOHA_GROUP'}, $valid_values, $install_log_values);
 878     }
 879
 880     $msg = q(
 881 Please specify which database engine you will use
 882 to store data in Koha.  The choices are MySQL and
 883 PostgreSQL; please note that at the moment
 884 PostgreSQL support is highly experimental.
 885
 886 DBMS to use);
 887     $msg .= _add_valid_values_disp('DB_TYPE', $valid_values);
 888     $config{'DB_TYPE'} = _get_value('DB_TYPE', $msg, $defaults->{'DB_TYPE'}, $valid_values, $install_log_values);
 889
 890     $msg = q(
 891 Please specify the name or address of your
 892 database server.  Note that the database
 893 does not have to exist at this point, it
 894 can be created after running 'make install'
 895 and before you try using Koha for the first time.
 896
 897 Database server);
 898     $config{'DB_HOST'} = _get_value('DB_HOST', $msg, $defaults->{'DB_HOST'}, $valid_values, $install_log_values);
 899
 900     $msg = q(
 901 Please specify the port used to connect to the
 902 DMBS);
 903     my $db_port_default = $config{'DB_TYPE'} eq 'mysql' ? '3306' : '5432';
 904     $config{'DB_PORT'} = _get_value('DB_PORT', $msg, $db_port_default, $valid_values, $install_log_values);
 905
 906     $msg = q(
 907 Please specify the name of the database to be
 908 used by Koha);
 909     $config{'DB_NAME'} = _get_value('DB_NAME', $msg, $defaults->{'DB_NAME'}, $valid_values, $install_log_values);
 910
 911     $msg = q(
 912 Please specify the user that owns the database to be
 913 used by Koha);
 914     $config{'DB_USER'} = _get_value('DB_USER', $msg, $defaults->{'DB_USER'}, $valid_values, $install_log_values);
 915
 916     $msg = q(
 917 Please specify the password of the user that owns the
 918 database to be used by Koha);
 919     $config{'DB_PASS'} = _get_value('DB_PASS', $msg, $defaults->{'DB_PASS'}, $valid_values, $install_log_values);
 920
 921     print q(
 922 Koha uses the Zebra search engine for high-performance
 923 searching of bibliographic and authority records.  Checking
 924 to see if you have installed the Zebra software...
 925 );
 926
 927     if (defined(my $zebra_path = find_zebra())) {
 928         $config{'PATH_TO_ZEBRA'} = $zebra_path;
 929         print qq(
 930 Found 'zebrasrv' and 'zebraidx' in $zebra_path.
 931 );
 932     } else {
 933         print q(
 934 Unable to find the Zebra programs 'zebrasrv' and 'zebraidx'
 935 in your PATH or in some of the usual places.  If you haven't
 936 installed Zebra yet, please do so and run Makefile.PL again.
 937
 938 );
 939     }
 940
 941     $msg = q(
 942 You must specify the primary MARC format of the
 943 records to be indexed by Zebra.
 944
 945 Koha provides Zebra configuration files for MARC21,
 946 NORMARC and UNIMARC.
 947
 948 MARC format for Zebra indexing);
 949     $msg .= _add_valid_values_disp('ZEBRA_MARC_FORMAT', $valid_values);
 950     $config{'ZEBRA_MARC_FORMAT'} = _get_value('ZEBRA_MARC_FORMAT', $msg, $defaults->{'ZEBRA_MARC_FORMAT'}, $valid_values, $install_log_values);
 951     $msg = q(
 952 Koha supplies Zebra configuration files tuned for
 953 searching either English (en) or French (fr) MARC
 954 records.
 955
 956 Primary language for Zebra indexing);
 957     $msg .= _add_valid_values_disp('ZEBRA_LANGUAGE', $valid_values);
 958     $config{'ZEBRA_LANGUAGE'} = _get_value('ZEBRA_LANGUAGE', $msg, $defaults->{'ZEBRA_LANGUAGE'}, $valid_values, $install_log_values);
 959
 960     $msg = q(
 961 Koha can use one of  two different indexing modes
 962 for the MARC bibliographic records:
 963
 964 dom  - uses the DOM XML filter; offers improved
 965        functionality.
 966 grs1 - [DEPRECATED] uses the Zebra GRS-1 filter,
 967        available for legacy support
 968
 969 Bibliographic indexing mode);
 970     $msg .= _add_valid_values_disp('BIB_INDEX_MODE', $valid_values);
 971     $config{'BIB_INDEX_MODE'} = _get_value('BIB_INDEX_MODE', $msg, $defaults->{'BIB_INDEX_MODE'}, $valid_values, $install_log_values);
 972
 973
 974     $msg = q(
 975 Koha can use one of  two different indexing modes
 976 for the MARC authorities records:
 977
 978 dom  - uses the DOM XML filter; offers improved
 979        functionality.
 980 grs1 - [DEPRECATED] uses the Zebra GRS-1 filter,
 981        available for legacy support
 982
 983 Authorities indexing mode);
 984     $msg .= _add_valid_values_disp('AUTH_INDEX_MODE', $valid_values);
 985     $config{'AUTH_INDEX_MODE'} = _get_value('AUTH_INDEX_MODE', $msg, $defaults->{'AUTH_INDEX_MODE'}, $valid_values, $install_log_values);
 986
 987     $msg = q(
 988 Zebra has two methods to perform records tokenization
 989 and characters normalization: CHR and ICU. ICU is
 990 recommended for catalogs containing non-Latin
 991 characters.);
 992
 993     $msg .= _add_valid_values_disp('ZEBRA_TOKENIZER', $valid_values);
 994     $config{'ZEBRA_TOKENIZER'} = _get_value('ZEBRA_TOKENIZER', $msg, $defaults->{'ZEBRA_TOKENIZER'}, $valid_values, $install_log_values);
 995
 996     $msg = q(
 997 Please specify Zebra database user);
 998     $config{'ZEBRA_USER'} = _get_value('ZEBRA_USER', $msg, $defaults->{'ZEBRA_USER'}, $valid_values, $install_log_values);
 999
1000     $msg = q(
1001 Please specify the Zebra database password);
1002     $config{'ZEBRA_PASS'} = _get_value('ZEBRA_PASS', $msg, $defaults->{'ZEBRA_PASS'}, $valid_values, $install_log_values);
1003
1004     $msg = q(
1005 Since you've chosen to use Zebra, you can enable the SRU/
1006 Z39.50 Server if you so choose, but you must specify a
1007 few configuration options for it.
1008
1009 Please note that if you choose *NOT* to configure SRU,
1010 koha-conf.xml will still contain some references to SRU
1011 settings.  Those references will be ignored by Koha.
1012
1013 Install the SRU configuration files?);
1014     $msg .= _add_valid_values_disp('INSTALL_SRU', $valid_values);
1015     $config{'INSTALL_SRU'} = _get_value('INSTALL_SRU', $msg, $defaults->{'INSTALL_SRU'}, $valid_values, $install_log_values);
1016
1017     if ($config{'INSTALL_SRU'} eq 'yes') {
1018         $msg = q(
1019 Since you've chosen to configure SRU, you must
1020 specify the host and port(s) that the SRU
1021 Servers (bibliographic and authority) should run on.
1022 );
1023         $msg = q(
1024 SRU Database host?);
1025         $config{'ZEBRA_SRU_HOST'} = _get_value('ZEBRA_SRU_HOST', $msg, $defaults->{'ZEBRA_SRU_HOST'}, $valid_values, $install_log_values);
1026
1027         $msg = q(
1028 SRU port for bibliographic data?);
1029         $config{'ZEBRA_SRU_BIBLIOS_PORT'} = _get_value('ZEBRA_SRU_BIBLIOS_PORT', $msg, $defaults->{'ZEBRA_SRU_BIBLIOS_PORT'}, $valid_values, $install_log_values);
1030
1031         $msg = q(
1032 SRU port for authority data?);
1033         $config{'ZEBRA_SRU_AUTHORITIES_PORT'} = _get_value('ZEBRA_SRU_AUTHORITIES_PORT', $msg, $defaults->{'ZEBRA_SRU_AUTHORITIES_PORT'}, $valid_values, $install_log_values);
1034
1035     }
1036
1037     $msg = q(
1038 Along with Zebra, you can also choose to install PazPar2,
1039 which is a metasearch tool.  With PazPar2,
1040 Koha can perform on-the-fly merging of bibliographic
1041 records during searching, allowing for FRBRization of
1042 the results list.
1043
1044 Install the PazPar2 configuration files?);
1045     $msg .= _add_valid_values_disp('INSTALL_PAZPAR2', $valid_values);
1046     $config{'INSTALL_PAZPAR2'} = _get_value('INSTALL_PAZPAR2', $msg, $defaults->{'INSTALL_PAZPAR2'}, $valid_values, $install_log_values);
1047
1048     if ($config{'INSTALL_PAZPAR2'} eq 'yes') {
1049         $msg = q(
1050 Since you've chosen to configure PazPar2, you must
1051 specify the host and port(s) that PazPar2
1052 uses:
1053 );
1054         $msg = q(
1055 Zebra bibliographic server host?);
1056         $config{'MERGE_SERVER_HOST'} = _get_value('MERGE_SERVER_HOST', $msg, $defaults->{'MERGE_SERVER_HOST'}, $valid_values, $install_log_values);
1057
1058         $msg = q(
1059 Zebra bibliographic port for PazPar2 to use?);
1060         $config{'MERGE_SERVER_PORT'} = _get_value('MERGE_SERVER_PORT', $msg, $defaults->{'MERGE_SERVER_PORT'}, $valid_values, $install_log_values);
1061
1062         $msg = q(
1063 PazPar2 host?);
1064         $config{'PAZPAR2_HOST'} = _get_value('PAZPAR2_HOST', $msg, $defaults->{'PAZPAR2_HOST'}, $valid_values, $install_log_values);
1065
1066         $msg = q(
1067 PazPar2 port?);
1068         $config{'PAZPAR2_PORT'} = _get_value('PAZPAR2_PORT', $msg, $defaults->{'PAZPAR2_PORT'}, $valid_values, $install_log_values);
1069
1070     }
1071
1072   $msg = q(
1073 Use memcached to cache the results of some function calls?
1074 This provides a signficant performance improvement.
1075 You will need a Memcached server running.);
1076   $msg .= _add_valid_values_disp('USE_MEMCACHED', $valid_values);
1077   $config{'USE_MEMCACHED'} = _get_value('USE_MEMCACHED', $msg, $defaults->{'USE_MEMCACHED'}, $valid_values, $install_log_values);
1078   if ($config{'USE_MEMCACHED'} eq 'yes'){
1079       $msg = q(
1080 Since you've chosen to use caching, you must specify the memcached servers and the namespace to use:
1081 );
1082       $msg = q(
1083 Memcached server address?);
1084       $config{'MEMCACHED_SERVERS'} = _get_value('MEMCACHED_SERVERS', $msg, $defaults->{'MEMCACHED_SERVERS'}, $valid_values, $install_log_values);
1085
1086       $msg = q(
1087 Memcached namespace?);
1088       $config{'MEMCACHED_NAMESPACE'} = _get_value('MEMCACHED_NAMESPACE', $msg, $defaults->{'MEMCACHED_NAMESPACE'}, $valid_values, $install_log_values);
1089   }
1090
1091   $msg = q(
1092 Path to DejaVu fonts?);
1093   $config{'FONT_DIR'} = _get_value('FONT_DIR', $msg, $defaults->{'FONT_DIR'}, $valid_values, $install_log_values);
1094
1095
1096   $msg = q(
1097 Would you like to run the database-dependent test suite?);
1098   $msg .= _add_valid_values_disp( 'RUN_DATABASE_TESTS', $valid_values );
1099     $config{'RUN_DATABASE_TESTS'} = _get_value( 'RUN_DATABASE_TESTS', $msg, $defaults->{'RUN_DATABASE_TESTS'}, $valid_values, $install_log_values );
1100
1101   if ( $config{'RUN_DATABASE_TESTS'} eq 'yes' ) {
1102       $config{'TEST_DB_TYPE'} = $config{'DB_TYPE'};
1103       $config{'TEST_DB_HOST'} = $config{'DB_HOST'};
1104       $msg = q(TEST DATABASE
1105
1106 THE DATA IN THIS DATABASE WILL BE DESTROYED during the process of
1107 testing. Please don't do this on your production database. It is not
1108 reversable.
1109
1110 YOU WILL SUFFER DATA LOSS if you run this test suite on your test
1111 database. You are better off not running this optional test suite than
1112 doing it in a database that you don't want to lose.
1113
1114 Please specify the name of the test database to be
1115 used by Koha);
1116
1117       $config{'TEST_DB_NAME'} = _get_value('TEST_DB_NAME', $msg, $defaults->{'TEST_DB_NAME'}, $valid_values, $install_log_values);
1118       while ( $config{'TEST_DB_NAME'} eq $config{'DB_NAME'} ) {
1119           $msg = q(Please do not use the same database for testing as you do for production. You run the severe risk of data loss.);
1120           $config{'TEST_DB_NAME'} = _get_value('TEST_DB_NAME', $msg, $defaults->{'TEST_DB_NAME'}, $valid_values, $install_log_values);
1121       }
1122
1123       $msg = q(
1124 Please specify the user that owns the database to be
1125 used by Koha);
1126     $config{'TEST_DB_USER'} = _get_value('TEST_DB_USER', $msg, $defaults->{'TEST_DB_USER'}, $valid_values, $install_log_values);
1127
1128       $msg = q(
1129 Please specify the password of the user that owns the
1130 database to be used by Koha);
1131       $config{'TEST_DB_PASS'} = _get_value('TEST_DB_PASS', $msg, $defaults->{'TEST_DB_PASS'}, $valid_values, $install_log_values);
1132   }
1133
1134     print "\n\n";
1135
1136     # add version number
1137     my $version = "no_version_found";
1138     eval {
1139         require 'kohaversion.pl';
1140         $version = kohaversion();
1141     };
1142     $config{'KOHA_INSTALLED_VERSION'} = $version;
1143
1144     return %config;
1145 }
1146
1147 sub _add_valid_values_disp {
1148     my $key = shift;
1149     my $valid_values = shift;
1150
1151     my $disp = "";
1152     if (exists $valid_values->{$key}) {
1153         $disp = " (" . join(", ", sort keys %{ $valid_values->{$key} }) . ")";
1154     }
1155     return $disp;
1156 }
1157
1158 sub _get_value {
1159     my $key = shift;
1160     my $msg = shift;
1161     my $default = shift;
1162     my $valid_values = shift;
1163     my $install_log_values = shift;
1164
1165     # take value from install log if present
1166     if (exists $install_log_values{$key}) {
1167         $install_log_values{$key} =~ s/\$/\$\$/g;
1168         return $install_log_values{$key};
1169     }
1170
1171     # override default value from environment
1172     if (exists $ENV{$key}) {
1173         $default = $ENV{$key};
1174         $msg .= " (default from environment)";
1175     }
1176
1177     my $val = prompt($msg, $default);
1178
1179     while (exists $valid_values->{$key} and
1180            $val ne $default and
1181            not exists $valid_values->{$key}->{$val}) {
1182         my $retry_msg = "Value '$val' is not a valid option.\n";
1183         $retry_msg .= "Please enter a value";
1184         $retry_msg .= _add_valid_values_disp($key, $valid_values);
1185         $val = prompt($retry_msg, $default);
1186     }
1187     $val =~ s/\$/\$\$/g;
1188     return $val;
1189 }
1190
1191 =head2 get_target_directories
1192
1193 Creates a hash mapping from symbols for installation target
1194 directories to actual directory paths.
1195
1196 Also returns a hash indicating targets for which
1197 files need not be copied -- this is used for the 'dev'
1198 mode installation, where some files are installed in place.
1199
1200 =cut
1201
1202 sub get_target_directories {
1203     my $config = shift;
1204
1205     my $base = $config->{'INSTALL_BASE'};
1206     my $mode = $config->{'INSTALL_MODE'};
1207
1208     # get last component of install base directory
1209     # to treat as package name
1210     my ($volume, $directories, $file) = File::Spec->splitpath($base, 1);
1211
1212     my @basedir = File::Spec->splitdir($directories);
1213
1214     if ( $^O eq 'cygwin' ) { shift @basedir; unshift @basedir, 'c:'; }   # in a cygwin environment, $volume is returned empty
1215
1216     my $package = pop @basedir;
1217
1218
1219     my %dirmap = ();
1220     my %skipdirs = ();
1221     if ($mode eq 'single') {
1222         $dirmap{'API_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'api');
1223         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
1224         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
1225         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
1226         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
1227         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
1228         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
1229         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1230         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
1231         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
1232         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'pazpar2');
1233         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1234         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1235         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1236         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1237         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1238         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
1239         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
1240         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'spool');
1241         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'koha', 'plugins');
1242         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
1243         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
1244     } elsif ($mode eq 'dev') {
1245         my $curdir = File::Spec->rel2abs(File::Spec->curdir());
1246         $dirmap{'API_CGI_DIR'} = File::Spec->catdir($curdir, 'api');
1247         $skipdirs{'API_CGI_DIR'} = 1;
1248         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir($curdir);
1249         $skipdirs{'INTRANET_CGI_DIR'} = 1;
1250         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'intranet-tmpl');
1251         $skipdirs{'INTRANET_TMPL_DIR'} = 1;
1252         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
1253         $skipdirs{'INTRANET_WWW_DIR'} = 1;
1254         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir($curdir);
1255         $skipdirs{'OPAC_CGI_DIR'} = 1;
1256         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl', 'opac-tmpl');
1257         $skipdirs{'OPAC_TMPL_DIR'} = 1;
1258         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir($curdir, 'koha-tmpl');
1259         $skipdirs{'OPAC_WWW_DIR'} = 1;
1260         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir($curdir);
1261         $skipdirs{'PERL_MODULE_DIR'} = 1;
1262         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc');
1263         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'zebradb');
1264         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(@basedir, $package, 'etc', 'pazpar2');
1265         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1266         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1267         #For dev install, point NONDEV_DIR to misc in current dir (not base)
1268         #Used by supportdir in koha-conf.xml (BZ 12031)
1269         $dirmap{'SCRIPT_NONDEV_DIR'} = File::Spec->catdir($curdir, 'misc');
1270         $skipdirs{'SCRIPT_NONDEV_DIR'} = 1;
1271         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1272         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1273         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(@basedir, $package, 'var', 'lock', 'zebradb');
1274         $dirmap{'LOG_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'log');
1275         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'spool');
1276         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'plugins');
1277         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'lib', 'zebradb');
1278         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(@basedir, $package, 'var', 'run', 'zebradb');
1279     } else {
1280         # mode is standard, i.e., 'fhs'
1281         $dirmap{'API_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'api');
1282         $dirmap{'INTRANET_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'cgi-bin');
1283         $dirmap{'INTRANET_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs', 'intranet-tmpl');
1284         $dirmap{'INTRANET_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'intranet', 'htdocs');
1285         $dirmap{'OPAC_CGI_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'cgi-bin');
1286         $dirmap{'OPAC_TMPL_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs', 'opac-tmpl');
1287         $dirmap{'OPAC_WWW_DIR'} = File::Spec->catdir(@basedir, $package, 'opac', 'htdocs');
1288         $dirmap{'PERL_MODULE_DIR'} = File::Spec->catdir(@basedir, $package, 'lib');
1289         $dirmap{'KOHA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package);
1290         $dirmap{'ZEBRA_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'zebradb');
1291         $dirmap{'PAZPAR2_CONF_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'etc', $package, 'pazpar2');
1292         $dirmap{'MISC_DIR'} = File::Spec->catdir(@basedir, $package, 'misc');
1293         $dirmap{'SCRIPT_DIR'} = File::Spec->catdir(@basedir, $package, 'bin');
1294         $dirmap{'SCRIPT_NONDEV_DIR'} = $dirmap{'SCRIPT_DIR'};
1295         $dirmap{'MAN_DIR'} = File::Spec->catdir(@basedir, $package, 'man');
1296         $dirmap{'DOC_DIR'} = File::Spec->catdir(@basedir, $package, 'doc');
1297         $dirmap{'ZEBRA_LOCK_DIR'} = File::Spec->catdir(File::Spec->rootdir(), 'var', 'lock', $package, 'zebradb');
1298         $dirmap{'LOG_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'log', $package);
1299         $dirmap{'BACKUP_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'spool', $package);
1300         $dirmap{'PLUGINS_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'plugins');
1301         $dirmap{'ZEBRA_DATA_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'lib', $package, 'zebradb');
1302         $dirmap{'ZEBRA_RUN_DIR'} =  File::Spec->catdir(File::Spec->rootdir(), 'var', 'run', $package, 'zebradb');
1303     }
1304
1305     _get_env_overrides(\%dirmap);
1306     _get_argv_overrides(\%dirmap);
1307     _add_destdir(\%dirmap);
1308
1309     return \%dirmap, \%skipdirs;
1310 }
1311
1312 =head2 get_test_dir
1313
1314 Map a directory target to the corresponding path for
1315 the test suite.
1316
1317 =cut
1318
1319 sub get_test_dir {
1320     my ($dirname) = @_;
1321
1322     my @basedir = (File::Spec->rel2abs(File::Spec->curdir()), 't', 'run');
1323     if (exists $test_suite_override_dirs{$dirname}) {
1324         return File::Spec->catdir(@basedir, @{ $test_suite_override_dirs{$dirname} });
1325     } else {
1326         return;
1327     }
1328
1329 }
1330
1331 sub _get_env_overrides {
1332     my $dirmap = shift;
1333
1334     foreach my $key (keys %$dirmap) {
1335         if (exists $ENV{$key}) {
1336             $dirmap->{$key} = $ENV{$key};
1337             print "Setting $key from environment\n";
1338         }
1339     }
1340 }
1341
1342 sub _get_argv_overrides {
1343     my $dirmap = shift;
1344
1345     my @new_argv = ();
1346     for (my $i = 0; $i <= $#ARGV; $i++) {
1347         if ($ARGV[$i] =~ /^([^=]+)=([^=]+)$/ and exists $dirmap->{$1}) {
1348             $dirmap->{$1} = $2;
1349         } else {
1350             push @new_argv, $ARGV[$i];
1351         }
1352     }
1353     @ARGV = @new_argv;
1354 }
1355
1356 sub _strip_destdir {
1357     my $dir = shift;
1358     $dir =~ s/^\$\(DESTDIR\)//;
1359     return $dir;
1360 }
1361
1362 sub _add_destdir {
1363     my $dirmap = shift;
1364
1365     foreach my $key (keys %$dirmap) {
1366         $dirmap->{$key} = '$(DESTDIR)'.$dirmap->{$key};
1367     }
1368 }
1369
1370 sub display_configuration {
1371     my $config = shift;
1372     my $dirmap = shift;
1373     my @version = grep /\/usr\/share\/perl\//, @INC;
1374     push @version, ('/usr/share/perl/5.10') if !$version[0];
1375     print "\n\nKoha will be installed with the following configuration parameters:\n\n";
1376     foreach my $key (sort keys %$config) {
1377         print sprintf("%-25.25s%s\n", $key, $config->{$key});
1378     }
1379
1380     print "\nand in the following directories:\n\n";
1381     foreach my $key (sort keys %$dirmap) {
1382         print sprintf("%-25.25s%s\n", $key, $dirmap->{$key});
1383     }
1384     print "\n\nTo change any configuration setting, please run\n";
1385     print "perl Makefile.PL again.  To override one of the target\n";
1386     print "directories, you can do so on the command line like this:\n";
1387     print "\nperl Makefile.PL PERL_MODULE_DIR=$version[0]\n\n";
1388     print "You can also set different default values for parameters\n";
1389     print "or override directory locations by using environment variables.\n";
1390     print "\nFor example:\n\n";
1391     print "export DB_USER=my_koha\n";
1392     print "perl Makefile.PL\n";
1393     print "\nor\n\n";
1394     print "DB_USER=my_koha DOC_DIR=/usr/local/info perl Makefile.PL\n\n";
1395 }
1396
1397 =head2 find_zebra
1398
1399 Attempt to find Zebra - check user's PATH and
1400 a few other directories for zebrasrv and zebraidx.
1401
1402 =cut
1403
1404 sub find_zebra {
1405     my @search_dirs = map {
1406                             my $abs = File::Spec->rel2abs($_);
1407                             my ($toss, $directories);
1408                             ($toss, $directories, $toss) = File::Spec->splitpath($abs, 1);
1409                             $directories;
1410                         }  split /:/, $ENV{PATH};
1411     push @search_dirs, qw(/usr/local/bin /opt/local/bin /usr/bin);
1412     my @zebrasrv_dirs = grep { -x File::Spec->catpath('', $_, 'zebrasrv') } @search_dirs;
1413     return unless @zebrasrv_dirs;
1414     # verify that directory that contains zebrasrv also contains zebraidx
1415     foreach my $dir (@zebrasrv_dirs) {
1416         return $dir if -x File::Spec->catpath('', $dir, 'zebraidx');
1417     }
1418     return;
1419 }
1420
1421 package MY;
1422
1423 sub test {
1424     my $self = shift;
1425     my $test = $self->SUPER::test(@_);
1426     $test =~ s!\$\(INST_LIB\)!blib/PERL_MODULE_DIR!g;
1427
1428     # set KOHA_CONF
1429     $test =~ s!\$\(FULLPERLRUN\)!KOHA_CONF=blib/KOHA_CONF_DIR/koha-conf.xml \$(FULLPERLRUN)!g;
1430     return $test;
1431 }
1432
1433 sub install {
1434     my $self = shift;
1435     my $install = "";
1436     # NOTE: we're *not* doing this: my $install = $self->SUPER::install(@_);
1437     # This means that we're completely overriding EU::MM's default
1438     # installation and uninstallation targets.
1439
1440 # If installation is on Win32, we need to do permissions different from *nix
1441     if ( $^O =~ /darwin|linux|cygwin|freebsd|solaris/ ) { # this value needs to be verified for each platform and modified accordingly
1442             foreach my $key (sort keys %$target_directories) {
1443                     $install .= qq(
1444 KOHA_INST_$key = blib/$key
1445 KOHA_DEST_$key = $target_directories->{$key}
1446 ) unless exists $skip_directories->{$key};
1447                 }
1448                 $install .= qq(
1449 install :: all install_koha set_koha_ownership set_koha_permissions warn_koha_env_vars
1450 \t\$(NOECHO) \$(NOOP)
1451 );
1452                         $install .= "install_koha ::\n";
1453                         $install .= "\t\$(NOECHO) umask 022; \$(MOD_INSTALL) \\\n";
1454                         foreach my $key (sort keys %$target_directories) {
1455                                 $install .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1456           unless exists $skip_directories->{$key};
1457                         }
1458                         $install .= "\t\t\$(INST_MAN1DIR) \$(DESTINSTALLMAN1DIR) \\\n";
1459                         $install .= "\t\t\$(INST_MAN3DIR) \$(DESTINSTALLMAN3DIR)\n";
1460
1461                         $install .= "\n";
1462                         $install .= "set_koha_ownership ::\n";
1463 # Do not try to change ownership if DESTDIR is set
1464                         if ($config{'INSTALL_MODE'} eq 'standard' and $config{'KOHA_USER'} ne "root") {
1465                                 foreach my $key (sort keys %$target_directories) {
1466             $install .= "\t\$(NOECHO) if test -z \"\$(DESTDIR)\"; then chown -R $config{'KOHA_USER'}:$config{'KOHA_GROUP'} \$(KOHA_DEST_$key); fi\n"
1467             unless exists $skip_directories->{$key};
1468                                 }
1469                         } else {
1470                                 $install .= "\t\t\$(NOECHO) \$(NOOP)\n\n";
1471                         }
1472
1473                         $install .= "\n";
1474                         $install .= "set_koha_permissions ::\n";
1475                         # This is necessary because EU::MM installs files
1476                         # as either 0444 or 0555, and we want the owner
1477                         # of Koha's files to have write permission by default.
1478                         foreach my $key (sort keys %$target_directories) {
1479                                 $install .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_$key)\n"
1480           unless exists $skip_directories->{$key};
1481                         }
1482         }
1483
1484         $install .= "\n";
1485
1486     $install .= "warn_koha_env_vars ::\n";
1487     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1488     $install .= "\t\$(NOECHO) \$(ECHO) Koha\\'s files have now been installed. \n";
1489     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1490     $install .= "\t\$(NOECHO) \$(ECHO) In order to use Koha\\'s command-line batch jobs,\n";
1491     $install .= "\t\$(NOECHO) \$(ECHO) you should set the following environment variables:\n";
1492     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1493     $install .= "\t\$(NOECHO) \$(ECHO) export KOHA_CONF=\$(KOHA_DEST_KOHA_CONF_DIR)/koha-conf.xml\n";
1494     $install .= "\t\$(NOECHO) \$(ECHO) export PERL5LIB=$target_directories->{'PERL_MODULE_DIR'}\n";
1495     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1496     $install .= "\t\$(NOECHO) \$(ECHO) For other post-installation tasks, please consult the README.\n";
1497     $install .= "\t\$(NOECHO) \$(ECHO)\n";
1498
1499     $install .= _update_zebra_conf_target();
1500
1501     $install .= upgrade();
1502
1503     return $install;
1504 }
1505
1506 =head2 _update_zebra_conf_target
1507
1508 Add an installation target for updating
1509 Zebra's configuration files.
1510
1511 =cut
1512
1513 sub _update_zebra_conf_target {
1514
1515     my $target = "\nupdate_zebra_conf ::\n";
1516     $target .= "\tumask 022; \$(MOD_INSTALL) \\\n";
1517     $target .= "\t\t\$(KOHA_INST_ZEBRA_CONF_DIR) \$(KOHA_DEST_ZEBRA_CONF_DIR) \n";
1518     $target .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_ZEBRA_CONF_DIR)\n";
1519     $target .= "\tumask 022; \$(MOD_INSTALL) \\\n";
1520     $target .= "\t\t\$(KOHA_INST_PAZPAR2_CONF_DIR) \$(KOHA_DEST_PAZPAR2_CONF_DIR) \n";
1521     $target .= "\t\$(NOECHO) chmod -R u+w \$(KOHA_DEST_PAZPAR2_CONF_DIR)\n";
1522
1523     return $target;
1524 }
1525
1526 sub upgrade {
1527     my $upgrade = "";
1528
1529     my $backup_suffix;
1530     if (exists $install_log_values{'KOHA_INSTALLED_VERSION'}) {
1531         my $version = $install_log_values{'KOHA_INSTALLED_VERSION'};
1532         $version =~ s/\./_/g;
1533         $backup_suffix = "_koha_$version";
1534     } else {
1535         $backup_suffix = "_upgrade_backup";
1536     }
1537
1538     $upgrade .= qq/
1539 MOD_BACKUP = \$(ABSPERLRUN) -Minstall_misc::UpgradeBackup -e 'backup_changed_files({\@ARGV}, '$backup_suffix', '\''\$(VERBINST)'\'', '\''\$(UNINST)'\'');' --
1540
1541 upgrade :: make_upgrade_backup install
1542 \t\$(NOECHO) \$(NOOP)
1543 make_upgrade_backup ::
1544 \t\$(NOECHO) umask 022; \$(MOD_BACKUP) \\
1545 /;
1546     foreach my $key (qw/KOHA_CONF_DIR INTRANET_TMPL_DIR INTRANET_WWW_DIR OPAC_TMPL_DIR OPAC_WWW_DIR
1547                      PAZPAR2_CONF_DIR ZEBRA_CONF_DIR PLUGINS_DIR/) {
1548         $upgrade .= "\t\t\$(KOHA_INST_$key) \$(KOHA_DEST_$key) \\\n"
1549             unless exists $skip_directories->{$key} or
1550                    not exists $target_directories->{$key};
1551     }
1552     $upgrade =~ s/\\\n$/\n/;
1553
1554     return $upgrade;
1555 }
1556 sub postamble {
1557     # put directory mappings into Makefile
1558     # so that Make will export as environment
1559     # variables -- this is for the use of
1560     # rewrite-confg.PL
1561
1562     my $env;
1563         # Hereagain, we must alter syntax per platform...
1564         {
1565                 $env = join("\n", map { "export __${_}__ := $target_directories->{$_}" } keys %$target_directories);
1566                 $env .= "\n\n";
1567                 $env .= join("\n", map { "export __${_}__ := $config{$_}" } keys %config);
1568         }
1569
1570     return "$env\n";
1571 }
1572
1573
1574 __END__
1575
1576
1577 =head1 SEE ALSO
1578
1579 ExtUtils::MakeMaker(3)
1580
1581 =head1 AUTHORS
1582
1583 MJ Ray mjr at phonecoop.coop
1584 Galen Charlton galen.charlton at liblime.com
1585
1586 =cut
1587
1588 FIXME: deal with .htaccess