t/db_dependent/SIP/Message.t

   1 #!/usr/bin/perl
   2
   3 # Tests for SIP::Sip::MsgType
   4 # Please help to extend it!
   5
   6 # This file is part of Koha.
   7 #
   8 # Copyright 2016 Rijksmuseum
   9 #
  10 # Koha is free software; you can redistribute it and/or modify it
  11 # under the terms of the GNU General Public License as published by
  12 # the Free Software Foundation; either version 3 of the License, or
  13 # (at your option) any later version.
  14 #
  15 # Koha is distributed in the hope that it will be useful, but
  16 # WITHOUT ANY WARRANTY; without even the implied warranty of
  17 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
  18 # GNU General Public License for more details.
  19 #
  20 # You should have received a copy of the GNU General Public License
  21 # along with Koha; if not, see <http://www.gnu.org/licenses>.
  22
  23 use Modern::Perl;
  24 use Test::More tests => 4;
  25 use Test::MockObject;
  26 use Test::MockModule;
  27 use Test::Warn;
  28
  29 use t::lib::Mocks;
  30 use t::lib::TestBuilder;
  31
  32 use Koha::Database;
  33 use Koha::AuthUtils qw(hash_password);
  34 use Koha::DateUtils;
  35 use Koha::Items;
  36 use Koha::Checkouts;
  37 use Koha::Old::Checkouts;
  38 use Koha::Patrons;
  39
  40 use C4::SIP::ILS;
  41 use C4::SIP::ILS::Patron;
  42 use C4::SIP::Sip qw(write_msg);
  43 use C4::SIP::Sip::Constants qw(:all);
  44 use C4::SIP::Sip::MsgType;
  45
  46 use constant PATRON_PW => 'do_not_ever_use_this_one';
  47
  48 # START testing
  49 subtest 'Testing Patron Status Request V2' => sub {
  50     my $schema = Koha::Database->new->schema;
  51     $schema->storage->txn_begin;
  52     plan tests => 13;
  53     $C4::SIP::Sip::protocol_version = 2;
  54     test_request_patron_status_v2();
  55     $schema->storage->txn_rollback;
  56 };
  57
  58 subtest 'Testing Patron Info Request V2' => sub {
  59     my $schema = Koha::Database->new->schema;
  60     $schema->storage->txn_begin;
  61     plan tests => 18;
  62     $C4::SIP::Sip::protocol_version = 2;
  63     test_request_patron_info_v2();
  64     $schema->storage->txn_rollback;
  65 };
  66
  67 subtest 'Checkin V2' => sub {
  68     my $schema = Koha::Database->new->schema;
  69     $schema->storage->txn_begin;
  70     plan tests => 21;
  71     $C4::SIP::Sip::protocol_version = 2;
  72     test_checkin_v2();
  73     $schema->storage->txn_rollback;
  74 };
  75
  76 subtest 'Lastseen response' => sub {
  77
  78     my $schema = Koha::Database->new->schema;
  79     $schema->storage->txn_begin;
  80
  81     plan tests => 6;
  82     my $builder = t::lib::TestBuilder->new();
  83     my $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
  84     my ( $response, $findpatron );
  85     my $mocks = create_mocks( \$response, \$findpatron, \$branchcode );
  86     my $seen_patron = $builder->build({
  87         source => 'Borrower',
  88         value  => {
  89             lastseen => '2001-01-01',
  90             password => hash_password( PATRON_PW ),
  91             branchcode => $branchcode,
  92         },
  93     });
  94     my $cardnum = $seen_patron->{cardnumber};
  95     my $sip_patron = C4::SIP::ILS::Patron->new( $cardnum );
  96     $findpatron = $sip_patron;
  97
  98     my $siprequest = PATRON_INFO. 'engYYYYMMDDZZZZHHMMSS'.'Y         '.
  99         FID_INST_ID. $branchcode. '|'.
 100         FID_PATRON_ID. $cardnum. '|'.
 101         FID_PATRON_PWD. PATRON_PW. '|';
 102     my $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 103
 104     my $server = { ils => $mocks->{ils} };
 105     undef $response;
 106     t::lib::Mocks::mock_preference( 'TrackLastPatronActivity', '' );
 107     $msg->handle_patron_info( $server );
 108
 109     isnt( $response, undef, 'At least we got a response.' );
 110     my $respcode = substr( $response, 0, 2 );
 111     is( $respcode, PATRON_INFO_RESP, 'Response code fine' );
 112     $seen_patron = Koha::Patrons->find({ cardnumber => $seen_patron->{cardnumber} });
 113     is( output_pref({str => $seen_patron->lastseen(), dateonly => 1}), output_pref({str => '2001-01-01', dateonly => 1}),'Last seen not updated if not tracking patrons');
 114     undef $response;
 115     t::lib::Mocks::mock_preference( 'TrackLastPatronActivity', '1' );
 116     $msg->handle_patron_info( $server );
 117
 118     isnt( $response, undef, 'At least we got a response.' );
 119     $respcode = substr( $response, 0, 2 );
 120     is( $respcode, PATRON_INFO_RESP, 'Response code fine' );
 121     $seen_patron = Koha::Patrons->find({ cardnumber => $seen_patron->cardnumber() });
 122     is( output_pref({str => $seen_patron->lastseen(), dateonly => 1}), output_pref({dt => dt_from_string(), dateonly => 1}),'Last seen updated if tracking patrons');
 123     $schema->storage->txn_rollback;
 124
 125 };
 126 # Here is room for some more subtests
 127
 128 # END of main code
 129
 130 sub test_request_patron_status_v2 {
 131     my $builder = t::lib::TestBuilder->new();
 132     my $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
 133     my ( $response, $findpatron );
 134     my $mocks = create_mocks( \$response, \$findpatron, \$branchcode );
 135
 136     my $patron1 = $builder->build({
 137         source => 'Borrower',
 138         value  => {
 139             password => hash_password( PATRON_PW ),
 140         },
 141     });
 142     my $card1 = $patron1->{cardnumber};
 143     my $sip_patron1 = C4::SIP::ILS::Patron->new( $card1 );
 144     $findpatron = $sip_patron1;
 145
 146     my $siprequest = PATRON_STATUS_REQ. 'engYYYYMMDDZZZZHHMMSS'.
 147         FID_INST_ID. $branchcode. '|'.
 148         FID_PATRON_ID. $card1. '|'.
 149         FID_PATRON_PWD. PATRON_PW. '|';
 150     my $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 151
 152     my $server = { ils => $mocks->{ils} };
 153     undef $response;
 154     $msg->handle_patron_status( $server );
 155
 156     isnt( $response, undef, 'At least we got a response.' );
 157     my $respcode = substr( $response, 0, 2 );
 158     is( $respcode, PATRON_STATUS_RESP, 'Response code fine' );
 159
 160     check_field( $respcode, $response, FID_INST_ID, $branchcode , 'Verified institution id' );
 161     check_field( $respcode, $response, FID_PATRON_ID, $card1, 'Verified patron id' );
 162     check_field( $respcode, $response, FID_PERSONAL_NAME, $patron1->{surname}, 'Verified patron name', 'contains' );
 163     check_field( $respcode, $response, FID_VALID_PATRON, 'Y', 'Verified code BL' );
 164     check_field( $respcode, $response, FID_VALID_PATRON_PWD, 'Y', 'Verified code CQ' );
 165     check_field( $respcode, $response, FID_SCREEN_MSG, '.+', 'Verified non-empty screen message', 'regex' );
 166
 167     # Now, we pass a wrong password and verify CQ again
 168     $siprequest = PATRON_STATUS_REQ. 'engYYYYMMDDZZZZHHMMSS'.
 169         FID_INST_ID. $branchcode. '|'.
 170         FID_PATRON_ID. $card1. '|'.
 171         FID_PATRON_PWD. 'wrong_password'. '|';
 172     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 173     undef $response;
 174     $msg->handle_patron_status( $server );
 175     $respcode = substr( $response, 0, 2 );
 176     check_field( $respcode, $response, FID_VALID_PATRON_PWD, 'N', 'Verified code CQ for wrong pw' );
 177
 178     # Check empty password and verify CQ again
 179     $siprequest = PATRON_STATUS_REQ. 'engYYYYMMDDZZZZHHMMSS'.
 180         FID_INST_ID. $branchcode. '|'.
 181         FID_PATRON_ID. $card1. '|'.
 182         FID_PATRON_PWD. '|';
 183     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 184     undef $response;
 185     $msg->handle_patron_status( $server );
 186     $respcode = substr( $response, 0, 2 );
 187     check_field( $respcode, $response, FID_VALID_PATRON_PWD, 'N', 'code CQ should be N for empty AD' );
 188
 189     # Finally, we send a wrong card number and check AE, BL
 190     # This is done by removing the new patron first
 191     Koha::Patrons->search({ cardnumber => $card1 })->delete;
 192     undef $findpatron;
 193     $siprequest = PATRON_STATUS_REQ. 'engYYYYMMDDZZZZHHMMSS'.
 194         FID_INST_ID. $branchcode. '|'.
 195         FID_PATRON_ID. $card1. '|'.
 196         FID_PATRON_PWD. PATRON_PW. '|';
 197     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 198     undef $response;
 199     $msg->handle_patron_status( $server );
 200     $respcode = substr( $response, 0, 2 );
 201     check_field( $respcode, $response, FID_VALID_PATRON, 'N', 'Verified code BL for wrong cardnumber' );
 202     check_field( $respcode, $response, FID_PERSONAL_NAME, '', 'Name should be empty now' );
 203     check_field( $respcode, $response, FID_SCREEN_MSG, '.+', 'But we have a screen msg', 'regex' );
 204 }
 205
 206 sub test_request_patron_info_v2 {
 207     my $builder = t::lib::TestBuilder->new();
 208     my $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
 209     my ( $response, $findpatron );
 210     my $mocks = create_mocks( \$response, \$findpatron, \$branchcode );
 211
 212     my $patron2 = $builder->build({
 213         source => 'Borrower',
 214         value  => {
 215             password => hash_password( PATRON_PW ),
 216         },
 217     });
 218     my $card = $patron2->{cardnumber};
 219     my $sip_patron2 = C4::SIP::ILS::Patron->new( $card );
 220     $findpatron = $sip_patron2;
 221     my $siprequest = PATRON_INFO. 'engYYYYMMDDZZZZHHMMSS'.'Y         '.
 222         FID_INST_ID. $branchcode. '|'.
 223         FID_PATRON_ID. $card. '|'.
 224         FID_PATRON_PWD. PATRON_PW. '|';
 225     my $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 226
 227     my $server = { ils => $mocks->{ils} };
 228     undef $response;
 229     $msg->handle_patron_info( $server );
 230     isnt( $response, undef, 'At least we got a response.' );
 231     my $respcode = substr( $response, 0, 2 );
 232     is( $respcode, PATRON_INFO_RESP, 'Response code fine' );
 233
 234     check_field( $respcode, $response, FID_INST_ID, $branchcode , 'Verified institution id' );
 235     check_field( $respcode, $response, FID_PATRON_ID, $card, 'Verified patron id' );
 236     check_field( $respcode, $response, FID_PERSONAL_NAME, $patron2->{surname}, 'Verified patron name', 'contains' );
 237     check_field( $respcode, $response, FID_VALID_PATRON, 'Y', 'Verified code BL' );
 238     check_field( $respcode, $response, FID_VALID_PATRON_PWD, 'Y', 'Verified code CQ' );
 239     check_field( $respcode, $response, FID_FEE_LMT, '.*', 'Checked existence of fee limit', 'regex' );
 240     check_field( $respcode, $response, FID_HOME_ADDR, $patron2->{address}, 'Address in BD', 'contains' );
 241     check_field( $respcode, $response, FID_EMAIL, $patron2->{email}, 'Verified email in BE' );
 242     check_field( $respcode, $response, FID_HOME_PHONE, $patron2->{phone}, 'Verified home phone in BF' );
 243     # No check for custom fields here (unofficial PB, PC and PI)
 244     check_field( $respcode, $response, FID_SCREEN_MSG, '.+', 'We have a screen msg', 'regex' );
 245
 246     # Test customized patron name in AE with same sip request
 247     # This implicitly tests C4::SIP::ILS::Patron->name
 248     $server->{account}->{ae_field_template} = "X[% patron.surname %]Y";
 249     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 250     undef $response;
 251     $msg->handle_patron_info( $server );
 252     $respcode = substr( $response, 0, 2 );
 253     check_field( $respcode, $response, FID_PERSONAL_NAME, 'X' . $patron2->{surname} . 'Y', 'Check customized patron name' );
 254
 255     # Check empty password and verify CQ again
 256     $siprequest = PATRON_INFO. 'engYYYYMMDDZZZZHHMMSS'.'Y         '.
 257         FID_INST_ID. $branchcode. '|'.
 258         FID_PATRON_ID. $card. '|'.
 259         FID_PATRON_PWD. '|';
 260     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 261     undef $response;
 262     $msg->handle_patron_info( $server );
 263     $respcode = substr( $response, 0, 2 );
 264     check_field( $respcode, $response, FID_VALID_PATRON_PWD, 'N', 'code CQ should be N for empty AD' );
 265     # Test empty password is OK if account configured to allow
 266     $server->{account}->{allow_empty_passwords} = 1;
 267     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 268     undef $response;
 269     $msg->handle_patron_info( $server );
 270     $respcode = substr( $response, 0, 2 );
 271     check_field( $respcode, $response, FID_VALID_PATRON_PWD, 'Y', 'code CQ should be Y if empty AD allowed' );
 272
 273     # Finally, we send a wrong card number
 274     Koha::Patrons->search({ cardnumber => $card })->delete;
 275     undef $findpatron;
 276     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 277     undef $response;
 278     $msg->handle_patron_info( $server );
 279     $respcode = substr( $response, 0, 2 );
 280     check_field( $respcode, $response, FID_VALID_PATRON, 'N', 'Verified code BL for wrong cardnumber' );
 281     check_field( $respcode, $response, FID_PERSONAL_NAME, '', 'Name should be empty now' );
 282     check_field( $respcode, $response, FID_SCREEN_MSG, '.+', 'But we have a screen msg', 'regex' );
 283 }
 284
 285 sub test_checkin_v2 {
 286     my $builder = t::lib::TestBuilder->new();
 287     my $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
 288     my ( $response, $findpatron );
 289     my $mocks = create_mocks( \$response, \$findpatron, \$branchcode );
 290
 291     # create some data
 292     my $patron1 = $builder->build({
 293         source => 'Borrower',
 294         value  => {
 295             password => hash_password( PATRON_PW ),
 296         },
 297     });
 298     my $card1 = $patron1->{cardnumber};
 299     my $sip_patron1 = C4::SIP::ILS::Patron->new( $card1 );
 300     $findpatron = $sip_patron1;
 301     my $item = $builder->build({
 302         source => 'Item',
 303         value => { damaged => 0, withdrawn => 0, itemlost => 0, restricted => 0, homebranch => $branchcode, holdingbranch => $branchcode },
 304     });
 305
 306     my $mockILS = $mocks->{ils};
 307     my $server = { ils => $mockILS, account => {} };
 308     $mockILS->mock( 'institution', sub { $branchcode; } );
 309     $mockILS->mock( 'supports', sub { return; } );
 310     $mockILS->mock( 'checkin', sub {
 311         shift;
 312         return C4::SIP::ILS->checkin(@_);
 313     });
 314     my $today = dt_from_string;
 315
 316     # Checkin invalid barcode
 317     Koha::Items->search({ barcode => 'not_to_be_found' })->delete;
 318     my $siprequest = CHECKIN . 'N' . 'YYYYMMDDZZZZHHMMSS' .
 319         siprequestdate( $today->clone->add( days => 1) ) .
 320         FID_INST_ID . $branchcode . '|'.
 321         FID_ITEM_ID . 'not_to_be_found' . '|' .
 322         FID_TERMINAL_PWD . 'ignored' . '|';
 323     undef $response;
 324     my $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 325     warnings_like { $msg->handle_checkin( $server ); }
 326         [ qr/No item 'not_to_be_found'/, qr/no item found in object to resensitize/ ],
 327         'Checkin of invalid item with two warnings';
 328     my $respcode = substr( $response, 0, 2 );
 329     is( $respcode, CHECKIN_RESP, 'Response code fine' );
 330     is( substr($response,2,1), '0', 'OK flag is false' );
 331     is( substr($response,5,1), 'Y', 'Alert flag is set' );
 332     check_field( $respcode, $response, FID_SCREEN_MSG, 'Invalid Item', 'Check screen msg', 'regex' );
 333
 334     # Not checked out, toggle option checked_in_ok
 335     $siprequest = CHECKIN . 'N' . 'YYYYMMDDZZZZHHMMSS' .
 336         siprequestdate( $today->clone->add( days => 1) ) .
 337         FID_INST_ID . $branchcode . '|'.
 338         FID_ITEM_ID . $item->{barcode} . '|' .
 339         FID_TERMINAL_PWD . 'ignored' . '|';
 340     undef $response;
 341     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 342     $msg->handle_checkin( $server );
 343     $respcode = substr( $response, 0, 2 );
 344     is( substr($response,2,1), '0', 'OK flag is false when checking in an item that was not checked out' );
 345     is( substr($response,5,1), 'Y', 'Alert flag is set' );
 346     check_field( $respcode, $response, FID_SCREEN_MSG, 'not checked out', 'Check screen msg', 'regex' );
 347     # Toggle option
 348     $server->{account}->{checked_in_ok} = 1;
 349     undef $response;
 350     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 351     $msg->handle_checkin( $server );
 352     is( substr($response,2,1), '1', 'OK flag is true now with checked_in_ok flag set when checking in an item that was not checked out' );
 353     is( substr($response,5,1), 'Y', 'Alert flag is set' );
 354     check_field( $respcode, $response, FID_SCREEN_MSG, undef, 'No screen msg' );
 355     $server->{account}->{checked_in_ok} = 0;
 356
 357     # Checkin at wrong branch: issue item and switch branch, and checkin
 358     my $issue = Koha::Checkout->new({ branchcode => $branchcode, borrowernumber => $patron1->{borrowernumber}, itemnumber => $item->{itemnumber} })->store;
 359     $branchcode = $builder->build({ source => 'Branch' })->{branchcode};
 360     t::lib::Mocks::mock_preference( 'AllowReturnToBranch', 'homebranch' );
 361     undef $response;
 362     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 363     $msg->handle_checkin( $server );
 364     is( substr($response,2,1), '0', 'OK flag is false when we check in at the wrong branch and we do not allow it' );
 365     is( substr($response,5,1), 'Y', 'Alert flag is set' );
 366     check_field( $respcode, $response, FID_SCREEN_MSG, 'Checkin failed', 'Check screen msg' );
 367     $branchcode = $item->{homebranch};  # switch back
 368     t::lib::Mocks::mock_preference( 'AllowReturnToBranch', 'anywhere' );
 369
 370     # Data corrupted: add same issue_id to old_issues
 371     Koha::Old::Checkout->new({ issue_id => $issue->issue_id })->store;
 372     undef $response;
 373     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 374     warnings_like { $msg->handle_checkin( $server ); }
 375         [ qr/Duplicate entry/, qr/data corrupted/ ],
 376         'DBIx error on duplicate issue_id';
 377     is( substr($response,2,1), '0', 'OK flag is false when we encounter data corruption in old_issues' );
 378     is( substr($response,5,1), 'Y', 'Alert flag is set' );
 379     check_field( $respcode, $response, FID_SCREEN_MSG, 'Checkin failed: data problem', 'Check screen msg' );
 380
 381     # Finally checkin without problems (remove duplicate id)
 382     Koha::Old::Checkouts->search({ issue_id => $issue->issue_id })->delete;
 383     undef $response;
 384     $msg = C4::SIP::Sip::MsgType->new( $siprequest, 0 );
 385     $msg->handle_checkin( $server );
 386     is( substr($response,2,1), '1', 'OK flag is true when we checkin after removing the duplicate' );
 387     is( substr($response,5,1), 'N', 'Alert flag is not set' );
 388     is( Koha::Checkouts->find( $issue->issue_id ), undef,
 389         'Issue record is gone now' );
 390 }
 391
 392 # Helper routines
 393
 394 sub create_mocks {
 395     my ( $response, $findpatron, $branchcode ) = @_; # referenced variables !
 396
 397     # mock write_msg (imported from Sip.pm into Message.pm)
 398     my $mockMsg = Test::MockModule->new( 'C4::SIP::Sip::MsgType' );
 399     $mockMsg->mock( 'write_msg', sub { $$response = $_[1]; } ); # save response
 400
 401     # mock ils object
 402     my $mockILS = Test::MockObject->new;
 403     $mockILS->mock( 'check_inst_id', sub {} );
 404     $mockILS->mock( 'institution_id', sub { $$branchcode; } );
 405     $mockILS->mock( 'find_patron', sub { $$findpatron; } );
 406
 407     return { ils => $mockILS, message => $mockMsg };
 408 }
 409
 410 sub check_field {
 411     my ( $code, $resp, $fld, $expr, $msg, $mode ) = @_;
 412     # mode: contains || equals || regex (by default: equals)
 413
 414     # strip fixed part; prefix to simplify next regex
 415     $resp = '|'. substr( $resp, fixed_length( $code ) );
 416     my $fldval;
 417     if( $resp =~ /\|$fld([^\|]*)\|/ ) {
 418         $fldval = $1;
 419     } elsif( !defined($expr) ) { # field should not be found
 420         ok( 1, $msg );
 421         return;
 422     } else { # test fails
 423         is( 0, 1, "Code $fld not found in '$resp'?" );
 424         return;
 425     }
 426
 427     if( !$mode || $mode eq 'equals' ) { # default
 428         is( $fldval, $expr, $msg );
 429     } elsif( $mode eq 'regex' ) {
 430         is( $fldval =~ /$expr/, 1, $msg );
 431     } else { # contains
 432         is( index( $fldval, $expr ) > -1, 1, $msg );
 433     }
 434 }
 435
 436 sub siprequestdate {
 437     my ( $dt ) = @_;
 438     return $dt->ymd('').(' 'x4).$dt->hms('');
 439 }
 440
 441 sub fixed_length { #length of fixed fields including response code
 442     return {
 443       ( PATRON_STATUS_RESP )  => 37,
 444       ( PATRON_INFO_RESP )    => 61,
 445       ( CHECKIN_RESP )        => 24,
 446     }->{$_[0]};
 447 }